cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Scott Byer <byer@mv.us.adobe.com>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'message)
  32 (require 'nnmail)
  33 (require 'nnoo)
  34 (eval-when-compile (require 'cl))
  35 (require 'gnus-util)
  36
  37 (nnoo-declare nnfolder)
  38
  39 (defvoo nnfolder-directory (expand-file-name message-directory)
  40   "The name of the nnfolder directory.")
  41
  42 (defvoo nnfolder-active-file
  43   (nnheader-concat nnfolder-directory "active")
  44   "The name of the active file.")
  45
  46 ;; I renamed this variable to something more in keeping with the general GNU
  47 ;; style. -SLB
  48
  49 (defvoo nnfolder-ignore-active-file nil
  50   "If non-nil, causes nnfolder to do some extra work in order to determine
  51 the true active ranges of an mbox file.  Note that the active file is still
  52 saved, but it's values are not used.  This costs some extra time when
  53 scanning an mbox when opening it.")
  54
  55 (defvoo nnfolder-distrust-mbox nil
  56   "If non-nil, causes nnfolder to not trust the user with respect to
  57 inserting unaccounted for mail in the middle of an mbox file.  This can greatly
  58 slow down scans, which now must scan the entire file for unmarked messages.
  59 When nil, scans occur forward from the last marked message, a huge
  60 time saver for large mailboxes.")
  61
  62 (defvoo nnfolder-newsgroups-file
  63   (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  64   "Mail newsgroups description file.")
  65
  66 (defvoo nnfolder-get-new-mail t
  67   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  68
  69 (defvoo nnfolder-prepare-save-mail-hook nil
  70   "Hook run narrowed to an article before saving.")
  71
  72 (defvoo nnfolder-save-buffer-hook nil
  73   "Hook run before saving the nnfolder mbox buffer.")
  74
  75 (defvoo nnfolder-inhibit-expiry nil
  76   "If non-nil, inhibit expiry.")
  77
  78 \f
  79
  80 (defconst nnfolder-version "nnfolder 1.0"
  81   "nnfolder version.")
  82
  83 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  84   "String used to demarcate what the article number for a message is.")
  85
  86 (defvoo nnfolder-current-group nil)
  87 (defvoo nnfolder-current-buffer nil)
  88 (defvoo nnfolder-status-string "")
  89 (defvoo nnfolder-group-alist nil)
  90 (defvoo nnfolder-buffer-alist nil)
  91 (defvoo nnfolder-scantime-alist nil)
  92 (defvoo nnfolder-active-timestamp nil)
  93
  94 \f
  95
  96 ;;; Interface functions
  97
  98 (nnoo-define-basics nnfolder)
  99
 100 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 101   (save-excursion
 102     (set-buffer nntp-server-buffer)
 103     (erase-buffer)
 104     (let (article start stop)
 105       (nnfolder-possibly-change-group group server)
 106       (when nnfolder-current-buffer
 107         (set-buffer nnfolder-current-buffer)
 108         (goto-char (point-min))
 109         (if (stringp (car articles))
 110             'headers
 111           (while (setq article (pop articles))
 112             (set-buffer nnfolder-current-buffer)
 113             (when (nnfolder-goto-article article)
 114               (setq start (point))
 115               (search-forward "\n\n" nil t)
 116               (setq stop (1- (point)))
 117               (set-buffer nntp-server-buffer)
 118               (insert (format "221 %d Article retrieved.\n" article))
 119               (insert-buffer-substring nnfolder-current-buffer start stop)
 120               (goto-char (point-max))
 121               (insert ".\n")))
 122
 123           (set-buffer nntp-server-buffer)
 124           (nnheader-fold-continuation-lines)
 125           'headers)))))
 126
 127 (deffoo nnfolder-open-server (server &optional defs)
 128   (nnoo-change-server 'nnfolder server defs)
 129   (nnmail-activate 'nnfolder t)
 130   (gnus-make-directory nnfolder-directory)
 131   (cond
 132    ((not (file-exists-p nnfolder-directory))
 133     (nnfolder-close-server)
 134     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 135                      nnfolder-directory))
 136    ((not (file-directory-p (file-truename nnfolder-directory)))
 137     (nnfolder-close-server)
 138     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 139    (t
 140     (nnmail-activate 'nnfolder)
 141     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 142                      server nnfolder-directory)
 143     t)))
 144
 145 (deffoo nnfolder-request-close ()
 146   (let ((alist nnfolder-buffer-alist))
 147     (while alist
 148       (nnfolder-close-group (caar alist) nil t)
 149       (setq alist (cdr alist))))
 150   (nnoo-close-server 'nnfolder)
 151   (setq nnfolder-buffer-alist nil
 152         nnfolder-group-alist nil))
 153
 154 (deffoo nnfolder-request-article (article &optional group server buffer)
 155   (nnfolder-possibly-change-group group server)
 156   (save-excursion
 157     (set-buffer nnfolder-current-buffer)
 158     (goto-char (point-min))
 159     (when (nnfolder-goto-article article)
 160       (let (start stop)
 161         (setq start (point))
 162         (forward-line 1)
 163         (unless (and (nnmail-search-unix-mail-delim)
 164                      (forward-line -1))
 165           (goto-char (point-max)))
 166         (setq stop (point))
 167         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 168           (set-buffer nntp-server-buffer)
 169           (erase-buffer)
 170           (insert-buffer-substring nnfolder-current-buffer start stop)
 171           (goto-char (point-min))
 172           (while (looking-at "From ")
 173             (delete-char 5)
 174             (insert "X-From-Line: ")
 175             (forward-line 1))
 176           (if (numberp article)
 177               (cons nnfolder-current-group article)
 178             (goto-char (point-min))
 179             (search-forward (concat "\n" nnfolder-article-marker))
 180             (cons nnfolder-current-group
 181                   (string-to-int
 182                    (buffer-substring
 183                     (point) (progn (end-of-line) (point)))))))))))
 184
 185 (deffoo nnfolder-request-group (group &optional server dont-check)
 186   (nnfolder-possibly-change-group group server t)
 187   (save-excursion
 188     (if (not (assoc group nnfolder-group-alist))
 189         (nnheader-report 'nnfolder "No such group: %s" group)
 190       (if dont-check
 191           (progn
 192             (nnheader-report 'nnfolder "Selected group %s" group)
 193             t)
 194         (let* ((active (assoc group nnfolder-group-alist))
 195                (group (car active))
 196                (range (cadr active)))
 197           (cond
 198            ((null active)
 199             (nnheader-report 'nnfolder "No such group: %s" group))
 200            ((null nnfolder-current-group)
 201             (nnheader-report 'nnfolder "Empty group: %s" group))
 202            (t
 203             (nnheader-report 'nnfolder "Selected group %s" group)
 204             (nnheader-insert "211 %d %d %d %s\n"
 205                              (1+ (- (cdr range) (car range)))
 206                              (car range) (cdr range) group))))))))
 207
 208 (deffoo nnfolder-request-scan (&optional group server)
 209   (nnfolder-possibly-change-group nil server)
 210   (when nnfolder-get-new-mail
 211     (nnfolder-possibly-change-group group server)
 212     (nnmail-get-new-mail
 213      'nnfolder
 214      (lambda ()
 215        (let ((bufs nnfolder-buffer-alist))
 216          (save-excursion
 217            (while bufs
 218              (if (not (gnus-buffer-live-p (nth 1 (car bufs))))
 219                  (setq nnfolder-buffer-alist
 220                        (delq (car bufs) nnfolder-buffer-alist))
 221                (set-buffer (nth 1 (car bufs)))
 222                (nnfolder-save-buffer)
 223                (kill-buffer (current-buffer)))
 224              (setq bufs (cdr bufs))))))
 225      nnfolder-directory
 226      group)))
 227
 228 ;; Don't close the buffer if we're not shutting down the server.  This way,
 229 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 230 ;; over the buffer again unless we add new mail to it or modify it in some
 231 ;; way.
 232
 233 (deffoo nnfolder-close-group (group &optional server force)
 234   ;; Make sure we _had_ the group open.
 235   (when (or (assoc group nnfolder-buffer-alist)
 236             (equal group nnfolder-current-group))
 237     (let ((inf (assoc group nnfolder-buffer-alist)))
 238       (when inf
 239         (when (and nnfolder-current-group
 240                    nnfolder-current-buffer)
 241           (push (list nnfolder-current-group nnfolder-current-buffer)
 242                 nnfolder-buffer-alist))
 243         (setq nnfolder-buffer-alist
 244               (delq inf nnfolder-buffer-alist))
 245         (setq nnfolder-current-buffer (cadr inf)
 246               nnfolder-current-group (car inf))))
 247     (when (and nnfolder-current-buffer
 248                (buffer-name nnfolder-current-buffer))
 249       (save-excursion
 250         (set-buffer nnfolder-current-buffer)
 251         ;; If the buffer was modified, write the file out now.
 252         (nnfolder-save-buffer)
 253         ;; If we're shutting the server down, we need to kill the
 254         ;; buffer and remove it from the open buffer list.  Or, of
 255         ;; course, if we're trying to minimize our space impact.
 256         (kill-buffer (current-buffer))
 257         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 258                                           nnfolder-buffer-alist)))))
 259   (setq nnfolder-current-group nil
 260         nnfolder-current-buffer nil)
 261   t)
 262
 263 (deffoo nnfolder-request-create-group (group &optional server args)
 264   (nnfolder-possibly-change-group nil server)
 265   (nnmail-activate 'nnfolder)
 266   (when group
 267     (unless (assoc group nnfolder-group-alist)
 268       (push (list group (cons 1 0)) nnfolder-group-alist)
 269       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 270       (nnfolder-read-folder group)))
 271   t)
 272
 273 (deffoo nnfolder-request-list (&optional server)
 274   (nnfolder-possibly-change-group nil server)
 275   (save-excursion
 276     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
 277           (pathname-coding-system 'binary))
 278       (nnmail-find-file nnfolder-active-file)
 279       (setq nnfolder-group-alist (nnmail-get-active)))
 280     t))
 281
 282 (deffoo nnfolder-request-newgroups (date &optional server)
 283   (nnfolder-possibly-change-group nil server)
 284   (nnfolder-request-list server))
 285
 286 (deffoo nnfolder-request-list-newsgroups (&optional server)
 287   (nnfolder-possibly-change-group nil server)
 288   (save-excursion
 289     (nnmail-find-file nnfolder-newsgroups-file)))
 290
 291 (deffoo nnfolder-request-expire-articles
 292   (articles newsgroup &optional server force)
 293   (nnfolder-possibly-change-group newsgroup server)
 294   (let* ((is-old t)
 295          rest)
 296     (nnmail-activate 'nnfolder)
 297
 298     (save-excursion
 299       (set-buffer nnfolder-current-buffer)
 300       (while (and articles is-old)
 301         (goto-char (point-min))
 302         (when (nnfolder-goto-article (car articles))
 303           (if (setq is-old
 304                     (nnmail-expired-article-p
 305                      newsgroup
 306                      (buffer-substring
 307                       (point) (progn (end-of-line) (point)))
 308                      force nnfolder-inhibit-expiry))
 309               (progn
 310                 (nnheader-message 5 "Deleting article %d..."
 311                                   (car articles) newsgroup)
 312                 (nnfolder-delete-mail))
 313             (push (car articles) rest)))
 314         (setq articles (cdr articles)))
 315       (unless nnfolder-inhibit-expiry
 316         (nnheader-message 5 "Deleting articles...done"))
 317       (nnfolder-save-buffer)
 318       (nnfolder-adjust-min-active newsgroup)
 319       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 320       (nconc rest articles))))
 321
 322 (deffoo nnfolder-request-move-article (article group server
 323                                                accept-form &optional last)
 324   (save-excursion
 325     (let ((buf (get-buffer-create " *nnfolder move*"))
 326           result)
 327       (and
 328        (nnfolder-request-article article group server)
 329        (save-excursion
 330          (set-buffer buf)
 331          (buffer-disable-undo (current-buffer))
 332          (erase-buffer)
 333          (insert-buffer-substring nntp-server-buffer)
 334          (goto-char (point-min))
 335          (while (re-search-forward
 336                  (concat "^" nnfolder-article-marker)
 337                  (save-excursion (search-forward "\n\n" nil t) (point)) t)
 338            (delete-region (progn (beginning-of-line) (point))
 339                           (progn (forward-line 1) (point))))
 340          (setq result (eval accept-form))
 341          (kill-buffer buf)
 342          result)
 343        (save-excursion
 344          (nnfolder-possibly-change-group group server)
 345          (set-buffer nnfolder-current-buffer)
 346          (goto-char (point-min))
 347          (when (nnfolder-goto-article article)
 348            (nnfolder-delete-mail))
 349          (when last
 350            (nnfolder-save-buffer)
 351            (nnfolder-adjust-min-active group)
 352            (nnmail-save-active nnfolder-group-alist nnfolder-active-file))))
 353       result)))
 354
 355 (deffoo nnfolder-request-accept-article (group &optional server last)
 356   (save-excursion
 357     (nnfolder-possibly-change-group group server)
 358     (nnmail-check-syntax)
 359     (let ((buf (current-buffer))
 360           result art-group)
 361       (goto-char (point-min))
 362       (when (looking-at "X-From-Line: ")
 363         (replace-match "From "))
 364       (and
 365        (nnfolder-request-list)
 366        (save-excursion
 367          (set-buffer buf)
 368          (goto-char (point-min))
 369          (search-forward "\n\n" nil t)
 370          (forward-line -1)
 371          (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 372            (delete-region (point) (progn (forward-line 1) (point))))
 373          (when nnmail-cache-accepted-message-ids
 374            (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 375          (setq result (if (stringp group)
 376                           (list (cons group (nnfolder-active-number group)))
 377                         (setq art-group
 378                               (nnmail-article-group 'nnfolder-active-number))))
 379          (if (and (null result)
 380                   (yes-or-no-p "Moved to `junk' group; delete article? "))
 381              (setq result 'junk)
 382            (setq result
 383                  (car (nnfolder-save-mail result)))))
 384        (when last
 385          (save-excursion
 386            (nnfolder-possibly-change-folder (or (caar art-group) group))
 387            (nnfolder-save-buffer)
 388            (when nnmail-cache-accepted-message-ids
 389              (nnmail-cache-close)))))
 390       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 391       (unless result
 392         (nnheader-report 'nnfolder "Couldn't store article"))
 393       result)))
 394
 395 (deffoo nnfolder-request-replace-article (article group buffer)
 396   (nnfolder-possibly-change-group group)
 397   (save-excursion
 398     (set-buffer buffer)
 399     (goto-char (point-min))
 400     (if (looking-at "X-From-Line: ")
 401         (replace-match "From ")
 402       (unless (looking-at message-unix-mail-delimiter)
 403         (insert "From nobody " (current-time-string) "\n")))
 404     (nnfolder-normalize-buffer)
 405     (set-buffer nnfolder-current-buffer)
 406     (goto-char (point-min))
 407     (if (not (nnfolder-goto-article article))
 408         nil
 409       (nnfolder-delete-mail)
 410       (insert-buffer-substring buffer)
 411       (nnfolder-save-buffer)
 412       t)))
 413
 414 (deffoo nnfolder-request-delete-group (group &optional force server)
 415   (nnfolder-close-group group server t)
 416   ;; Delete all articles in GROUP.
 417   (if (not force)
 418       ()                                ; Don't delete the articles.
 419     ;; Delete the file that holds the group.
 420     (ignore-errors
 421       (delete-file (nnfolder-group-pathname group))))
 422   ;; Remove the group from all structures.
 423   (setq nnfolder-group-alist
 424         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 425         nnfolder-current-group nil
 426         nnfolder-current-buffer nil)
 427   ;; Save the active file.
 428   (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 429   t)
 430
 431 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 432   (nnfolder-possibly-change-group group server)
 433   (save-excursion
 434     (set-buffer nnfolder-current-buffer)
 435     (and (file-writable-p buffer-file-name)
 436          (ignore-errors
 437            (rename-file
 438             buffer-file-name
 439             (nnfolder-group-pathname new-name))
 440            t)
 441          ;; That went ok, so we change the internal structures.
 442          (let ((entry (assoc group nnfolder-group-alist)))
 443            (and entry (setcar entry new-name))
 444            (setq nnfolder-current-buffer nil
 445                  nnfolder-current-group nil)
 446            ;; Save the new group alist.
 447            (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 448            ;; We kill the buffer instead of renaming it and stuff.
 449            (kill-buffer (current-buffer))
 450            t))))
 451
 452 (defun nnfolder-request-regenerate (server)
 453   (nnfolder-possibly-change-group nil server)
 454   (nnfolder-generate-active-file)
 455   t)
 456
 457 \f
 458 ;;; Internal functions.
 459
 460 (defun nnfolder-adjust-min-active (group)
 461   ;; Find the lowest active article in this group.
 462   (let* ((active (cadr (assoc group nnfolder-group-alist)))
 463          (marker (concat "\n" nnfolder-article-marker))
 464          (number "[0-9]+")
 465          (activemin (cdr active)))
 466     (save-excursion
 467       (set-buffer nnfolder-current-buffer)
 468       (goto-char (point-min))
 469       (while (and (search-forward marker nil t)
 470                   (re-search-forward number nil t))
 471         (let ((newnum (string-to-number (match-string 0))))
 472           (if (nnmail-within-headers-p)
 473               (setq activemin (min activemin newnum)))))
 474       (setcar active activemin))))
 475
 476 (defun nnfolder-article-string (article)
 477   (if (numberp article)
 478       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 479     (concat "\nMessage-ID: " article)))
 480
 481 (defun nnfolder-goto-article (article)
 482   "Place point at the start of the headers of ARTICLE.
 483 ARTICLE can be an article number or a Message-ID.
 484 Returns t if successful, nil otherwise."
 485   (let ((art-string (nnfolder-article-string article))
 486         start found)
 487     ;; It is likely that we are at or before the delimiter line.
 488     ;; We therefore go to the end of the previous line, and start
 489     ;; searching from there.
 490     (beginning-of-line)
 491     (unless (bobp)
 492       (forward-char -1))
 493     (setq start (point))
 494     ;; First search forward.
 495     (while (and (setq found (search-forward art-string nil t))
 496                 (not (nnmail-within-headers-p))))
 497     ;; If unsuccessful, search backward from where we started,
 498     (unless found
 499       (goto-char start)
 500       (while (and (setq found (search-backward art-string nil t))
 501                   (not (nnmail-within-headers-p)))))
 502     (when found
 503       (nnmail-search-unix-mail-delim-backward))))
 504
 505 (defun nnfolder-delete-mail (&optional leave-delim)
 506   "Delete the message that point is in.
 507 If optional argument LEAVE-DELIM is t, then mailbox delimiter is not
 508 deleted.  Point is left where the deleted region was."
 509   (delete-region
 510    (save-excursion
 511      (forward-line 1) ; in case point is at beginning of message already
 512      (nnmail-search-unix-mail-delim-backward)
 513      (if leave-delim (progn (forward-line 1) (point))
 514        (point)))
 515    (progn
 516      (forward-line 1)
 517      (if (nnmail-search-unix-mail-delim)
 518          (point)
 519        (point-max)))))
 520
 521 (defun nnfolder-possibly-change-group (group &optional server dont-check)
 522   ;; Change servers.
 523   (when (and server
 524              (not (nnfolder-server-opened server)))
 525     (nnfolder-open-server server))
 526   (unless (gnus-buffer-live-p nnfolder-current-buffer)
 527     (setq nnfolder-current-buffer nil
 528           nnfolder-current-group nil))
 529   ;; Change group.
 530   (when (and group
 531              (not (equal group nnfolder-current-group)))
 532     (let ((pathname-coding-system 'binary))
 533       (nnmail-activate 'nnfolder)
 534       (when (and (not (assoc group nnfolder-group-alist))
 535                  (not (file-exists-p
 536                        (nnfolder-group-pathname group))))
 537         ;; The group doesn't exist, so we create a new entry for it.
 538         (push (list group (cons 1 0)) nnfolder-group-alist)
 539         (nnmail-save-active nnfolder-group-alist nnfolder-active-file))
 540
 541       (if dont-check
 542           (setq nnfolder-current-group group
 543                 nnfolder-current-buffer nil)
 544         (let (inf file)
 545           ;; If we have to change groups, see if we don't already have the
 546           ;; folder in memory.  If we do, verify the modtime and destroy
 547           ;; the folder if needed so we can rescan it.
 548           (setq nnfolder-current-buffer
 549                 (nth 1 (assoc group nnfolder-buffer-alist)))
 550
 551           ;; If the buffer is not live, make sure it isn't in the alist.  If it
 552           ;; is live, verify that nobody else has touched the file since last
 553           ;; time.
 554           (when (and nnfolder-current-buffer
 555                      (not (gnus-buffer-live-p nnfolder-current-buffer)))
 556             (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)
 557                   nnfolder-current-buffer nil))
 558
 559           (setq nnfolder-current-group group)
 560
 561           (when (or (not nnfolder-current-buffer)
 562                     (not (verify-visited-file-modtime
 563                           nnfolder-current-buffer)))
 564             (save-excursion
 565               (setq file (nnfolder-group-pathname group))
 566               ;; See whether we need to create the new file.
 567               (unless (file-exists-p file)
 568                 (gnus-make-directory (file-name-directory file))
 569                 (nnmail-write-region 1 1 file t 'nomesg))
 570               (when (setq nnfolder-current-buffer (nnfolder-read-folder group))
 571                 (set-buffer nnfolder-current-buffer)
 572                 (push (list group nnfolder-current-buffer)
 573                       nnfolder-buffer-alist)))))))))
 574
 575 (defun nnfolder-save-mail (group-art-list)
 576   "Called narrowed to an article."
 577   (let* (save-list group-art)
 578     (goto-char (point-min))
 579     ;; The From line may have been quoted by movemail.
 580     (when (looking-at (concat ">" message-unix-mail-delimiter))
 581       (delete-char 1))
 582     ;; This might come from somewhere else.
 583     (unless (looking-at message-unix-mail-delimiter)
 584       (insert "From nobody " (current-time-string) "\n")
 585       (goto-char (point-min)))
 586     ;; Quote all "From " lines in the article.
 587     (forward-line 1)
 588     (let (case-fold-search)
 589       (while (re-search-forward "^From " nil t)
 590         (beginning-of-line)
 591         (insert "> ")))
 592     (setq save-list group-art-list)
 593     (nnmail-insert-lines)
 594     (nnmail-insert-xref group-art-list)
 595     (run-hooks 'nnmail-prepare-save-mail-hook)
 596     (run-hooks 'nnfolder-prepare-save-mail-hook)
 597
 598     ;; Insert the mail into each of the destination groups.
 599     (while (setq group-art (pop group-art-list))
 600       ;; Kill any previous newsgroup markers.
 601       (goto-char (point-min))
 602       (search-forward "\n\n" nil t)
 603       (forward-line -1)
 604       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
 605         (delete-region (1+ (point)) (progn (forward-line 2) (point))))
 606
 607       ;; Insert the new newsgroup marker.
 608       (nnfolder-insert-newsgroup-line group-art)
 609
 610       (save-excursion
 611         (let ((beg (point-min))
 612               (end (point-max))
 613               (obuf (current-buffer)))
 614           (nnfolder-possibly-change-folder (car group-art))
 615           (let ((buffer-read-only nil))
 616             (nnfolder-normalize-buffer)
 617             (insert-buffer-substring obuf beg end)))))
 618
 619     ;; Did we save it anywhere?
 620     save-list))
 621
 622 (defun nnfolder-normalize-buffer ()
 623   "Make sure there are two newlines at the end of the buffer."
 624   (goto-char (point-max))
 625   (skip-chars-backward "\n")
 626   (delete-region (point) (point-max))
 627   (insert "\n\n"))
 628
 629 (defun nnfolder-insert-newsgroup-line (group-art)
 630   (save-excursion
 631     (goto-char (point-min))
 632     (when (search-forward "\n\n" nil t)
 633       (forward-char -1)
 634       (insert (format (concat nnfolder-article-marker "%d   %s\n")
 635                       (cdr group-art) (current-time-string))))))
 636
 637 (defun nnfolder-active-number (group)
 638   ;; Find the next article number in GROUP.
 639   (let ((active (cadr (assoc group nnfolder-group-alist))))
 640     (if active
 641         (setcdr active (1+ (cdr active)))
 642       ;; This group is new, so we create a new entry for it.
 643       ;; This might be a bit naughty... creating groups on the drop of
 644       ;; a hat, but I don't know...
 645       (push (list group (setq active (cons 1 1)))
 646             nnfolder-group-alist))
 647     (cdr active)))
 648
 649 (defun nnfolder-possibly-change-folder (group)
 650   (let ((inf (assoc group nnfolder-buffer-alist)))
 651     (if (and inf
 652              (gnus-buffer-live-p (cadr inf)))
 653         (set-buffer (cadr inf))
 654       (when inf
 655         (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)))
 656       (when nnfolder-group-alist
 657         (nnmail-save-active nnfolder-group-alist nnfolder-active-file))
 658       (push (list group (nnfolder-read-folder group))
 659             nnfolder-buffer-alist))))
 660
 661 ;; This method has a problem if you've accidentally let the active list get
 662 ;; out of sync with the files.  This could happen, say, if you've
 663 ;; accidentally gotten new mail with something other than Gnus (but why
 664 ;; would _that_ ever happen? :-).  In that case, we will be in the middle of
 665 ;; processing the file, ready to add new X-Gnus article number markers, and
 666 ;; we'll run across a message with no ID yet - the active list _may_not_ be
 667 ;; ready for us yet.
 668
 669 ;; To handle this, I'm modifying this routine to maintain the maximum ID seen
 670 ;; so far, and when we hit a message with no ID, we will _manually_ scan the
 671 ;; rest of the message looking for any more, possibly higher IDs.  We'll
 672 ;; assume the maximum that we find is the highest active.  Note that this
 673 ;; shouldn't cost us much extra time at all, but will be a lot less
 674 ;; vulnerable to glitches between the mbox and the active file.
 675
 676 (defun nnfolder-read-folder (group)
 677   (let* ((file (nnfolder-group-pathname group))
 678          (buffer (set-buffer (nnheader-find-file-noselect file))))
 679     (if (equal (cadr (assoc group nnfolder-scantime-alist))
 680                (nth 5 (file-attributes file)))
 681         ;; This looks up-to-date, so we don't do any scanning.
 682         (if (file-exists-p file)
 683             buffer
 684           (push (list group buffer) nnfolder-buffer-alist)
 685           (set-buffer-modified-p t)
 686           (save-buffer))
 687       ;; Parse the damn thing.
 688       (save-excursion
 689         (nnmail-activate 'nnfolder)
 690         ;; Read in the file.
 691         (let ((delim (concat "^" message-unix-mail-delimiter))
 692               (marker (concat "\n" nnfolder-article-marker))
 693               (number "[0-9]+")
 694               (active (or (cadr (assoc group nnfolder-group-alist))
 695                           (cons 1 0)))
 696               (scantime (assoc group nnfolder-scantime-alist))
 697               (minid (lsh -1 -1))
 698               maxid start end newscantime
 699               buffer-read-only)
 700           (buffer-disable-undo (current-buffer))
 701           (setq maxid (cdr active))
 702           (goto-char (point-min))
 703
 704           ;; Anytime the active number is 1 or 0, it is suspect.  In that
 705           ;; case, search the file manually to find the active number.  Or,
 706           ;; of course, if we're being paranoid.  (This would also be the
 707           ;; place to build other lists from the header markers, such as
 708           ;; expunge lists, etc., if we ever desired to abandon the active
 709           ;; file entirely for mboxes.)
 710           (when (or nnfolder-ignore-active-file
 711                     (< maxid 2))
 712             (while (and (search-forward marker nil t)
 713                         (re-search-forward number nil t))
 714               (let ((newnum (string-to-number (match-string 0))))
 715                 (if (nnmail-within-headers-p)
 716                     (setq maxid (max maxid newnum)
 717                           minid (min minid newnum)))))
 718             (setcar active (max 1 (min minid maxid)))
 719             (setcdr active (max maxid (cdr active)))
 720             (goto-char (point-min)))
 721
 722           ;; As long as we trust that the user will only insert unmarked mail
 723           ;; at the end, go to the end and search backwards for the last
 724           ;; marker.  Find the start of that message, and begin to search for
 725           ;; unmarked messages from there.
 726           (when (not (or nnfolder-distrust-mbox
 727                          (< maxid 2)))
 728             (goto-char (point-max))
 729             (unless (re-search-backward marker nil t)
 730               (goto-char (point-min)))
 731             (when (nnmail-search-unix-mail-delim)
 732               (goto-char (point-min))))
 733
 734           ;; Keep track of the active number on our own, and insert it back
 735           ;; into the active list when we're done.  Also, prime the pump to
 736           ;; cut down on the number of searches we do.
 737           (unless (nnmail-search-unix-mail-delim)
 738             (goto-char (point-max)))
 739           (setq end (point-marker))
 740           (while (not (= end (point-max)))
 741             (setq start (marker-position end))
 742             (goto-char end)
 743             ;; There may be more than one "From " line, so we skip past
 744             ;; them.
 745             (while (looking-at delim)
 746               (forward-line 1))
 747             (set-marker end (if (nnmail-search-unix-mail-delim)
 748                                 (point)
 749                               (point-max)))
 750             (goto-char start)
 751             (when (not (search-forward marker end t))
 752               (narrow-to-region start end)
 753               (nnmail-insert-lines)
 754               (nnfolder-insert-newsgroup-line
 755                (cons nil (nnfolder-active-number nnfolder-current-group)))
 756               (widen)))
 757
 758           (set-marker end nil)
 759           ;; Make absolutely sure that the active list reflects reality!
 760           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 761           ;; Set the scantime for this group.
 762           (setq newscantime (visited-file-modtime))
 763           (if scantime
 764               (setcdr scantime (list newscantime))
 765             (push (list nnfolder-current-group newscantime)
 766                   nnfolder-scantime-alist))
 767           (current-buffer))))))
 768
 769 ;;;###autoload
 770 (defun nnfolder-generate-active-file ()
 771   "Look for mbox folders in the nnfolder directory and make them into groups."
 772   (interactive)
 773   (nnmail-activate 'nnfolder)
 774   (let ((files (directory-files nnfolder-directory))
 775         file)
 776     (while (setq file (pop files))
 777       (when (and (not (backup-file-name-p file))
 778                  (message-mail-file-mbox-p
 779                   (nnheader-concat nnfolder-directory file)))
 780         (let ((oldgroup (assoc file nnfolder-group-alist)))
 781           (if oldgroup
 782               (nnheader-message 5 "Refreshing group %s..." file)
 783             (nnheader-message 5 "Adding group %s..." file))
 784           (if oldgroup
 785               (setq nnfolder-group-alist
 786                     (delq oldgroup (copy-sequence nnfolder-group-alist))))
 787           (push (list file (cons 1 0)) nnfolder-group-alist)
 788           (nnfolder-possibly-change-folder file)
 789           (nnfolder-possibly-change-group file)
 790           (nnfolder-close-group file))))
 791     (nnheader-message 5 "")))
 792
 793 (defun nnfolder-group-pathname (group)
 794   "Make pathname for GROUP."
 795   (setq group (gnus-encode-coding-string group nnmail-pathname-coding-system))
 796   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
 797     ;; If this file exists, we use it directly.
 798     (if (or nnmail-use-long-file-names
 799             (file-exists-p (concat dir group)))
 800         (concat dir group)
 801       ;; If not, we translate dots into slashes.
 802       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
 803
 804 (defun nnfolder-save-buffer ()
 805   "Save the buffer."
 806   (when (buffer-modified-p)
 807     (run-hooks 'nnfolder-save-buffer-hook)
 808     (gnus-make-directory (file-name-directory (buffer-file-name)))
 809     (save-buffer)))
 810
 811 (provide 'nnfolder)
 812
 813 ;;; nnfolder.el ends here