cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Scott Byer <byer@mv.us.adobe.com>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; For an overview of what the interface functions do, please see the
  29 ;; Gnus sources.
  30
  31 ;; Various enhancements by byer@mv.us.adobe.com (Scott Byer).
  32
  33 ;;; Code:
  34
  35 (require 'nnheader)
  36 (require 'message)
  37 (require 'nnmail)
  38 (require 'nnoo)
  39 (eval-when-compile (require 'cl))
  40
  41 (nnoo-declare nnfolder)
  42
  43 (defvoo nnfolder-directory (expand-file-name message-directory)
  44   "The name of the nnfolder directory.")
  45
  46 (defvoo nnfolder-active-file
  47   (nnheader-concat nnfolder-directory "active")
  48   "The name of the active file.")
  49
  50 ;; I renamed this variable to something more in keeping with the general GNU
  51 ;; style. -SLB
  52
  53 (defvoo nnfolder-ignore-active-file nil
  54   "If non-nil, causes nnfolder to do some extra work in order to determine
  55 the true active ranges of an mbox file.  Note that the active file is still
  56 saved, but it's values are not used.  This costs some extra time when
  57 scanning an mbox when opening it.")
  58
  59 (defvoo nnfolder-distrust-mbox nil
  60   "If non-nil, causes nnfolder to not trust the user with respect to
  61 inserting unaccounted for mail in the middle of an mbox file.  This can greatly
  62 slow down scans, which now must scan the entire file for unmarked messages.
  63 When nil, scans occur forward from the last marked message, a huge
  64 time saver for large mailboxes.")
  65
  66 (defvoo nnfolder-newsgroups-file
  67   (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  68   "Mail newsgroups description file.")
  69
  70 (defvoo nnfolder-get-new-mail t
  71   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  72
  73 (defvoo nnfolder-prepare-save-mail-hook nil
  74   "Hook run narrowed to an article before saving.")
  75
  76 (defvoo nnfolder-save-buffer-hook nil
  77   "Hook run before saving the nnfolder mbox buffer.")
  78
  79 (defvoo nnfolder-inhibit-expiry nil
  80   "If non-nil, inhibit expiry.")
  81
  82 \f
  83
  84 (defconst nnfolder-version "nnfolder 1.0"
  85   "nnfolder version.")
  86
  87 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  88   "String used to demarcate what the article number for a message is.")
  89
  90 (defvoo nnfolder-current-group nil)
  91 (defvoo nnfolder-current-buffer nil)
  92 (defvoo nnfolder-status-string "")
  93 (defvoo nnfolder-group-alist nil)
  94 (defvoo nnfolder-buffer-alist nil)
  95 (defvoo nnfolder-scantime-alist nil)
  96
  97 \f
  98
  99 ;;; Interface functions
 100
 101 (nnoo-define-basics nnfolder)
 102
 103 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 104   (save-excursion
 105     (set-buffer nntp-server-buffer)
 106     (erase-buffer)
 107     (let ((delim-string (concat "^" message-unix-mail-delimiter))
 108           article art-string start stop)
 109       (nnfolder-possibly-change-group group server)
 110       (when nnfolder-current-buffer
 111         (set-buffer nnfolder-current-buffer)
 112         (goto-char (point-min))
 113         (if (stringp (car articles))
 114             'headers
 115           (while articles
 116             (setq article (car articles))
 117             (setq art-string (nnfolder-article-string article))
 118             (set-buffer nnfolder-current-buffer)
 119             (if (or (search-forward art-string nil t)
 120                     ;; Don't search the whole file twice!  Also, articles
 121                     ;; probably have some locality by number, so searching
 122                     ;; backwards will be faster.  Especially if we're at the
 123                     ;; beginning of the buffer :-). -SLB
 124                     (search-backward art-string nil t))
 125                 (progn
 126                   (setq start (or (re-search-backward delim-string nil t)
 127                                   (point)))
 128                   (search-forward "\n\n" nil t)
 129                   (setq stop (1- (point)))
 130                   (set-buffer nntp-server-buffer)
 131                   (insert (format "221 %d Article retrieved.\n" article))
 132                   (insert-buffer-substring nnfolder-current-buffer start stop)
 133                   (goto-char (point-max))
 134                   (insert ".\n")))
 135             (setq articles (cdr articles)))
 136
 137           (set-buffer nntp-server-buffer)
 138           (nnheader-fold-continuation-lines)
 139           'headers)))))
 140
 141 (deffoo nnfolder-open-server (server &optional defs)
 142   (nnoo-change-server 'nnfolder server defs)
 143   (when (not (file-exists-p nnfolder-directory))
 144     (condition-case ()
 145         (gnus-make-directory nnfolder-directory)
 146       (error t)))
 147   (cond
 148    ((not (file-exists-p nnfolder-directory))
 149     (nnfolder-close-server)
 150     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 151                      nnfolder-directory))
 152    ((not (file-directory-p (file-truename nnfolder-directory)))
 153     (nnfolder-close-server)
 154     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 155    (t
 156     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 157                      server nnfolder-directory)
 158     t)))
 159
 160 (deffoo nnfolder-request-close ()
 161   (let ((alist nnfolder-buffer-alist))
 162     (while alist
 163       (nnfolder-close-group (caar alist) nil t)
 164       (setq alist (cdr alist))))
 165   (nnoo-close-server 'nnfolder)
 166   (setq nnfolder-buffer-alist nil
 167         nnfolder-group-alist nil))
 168
 169 (deffoo nnfolder-request-article (article &optional group server buffer)
 170   (nnfolder-possibly-change-group group server)
 171   (save-excursion
 172     (set-buffer nnfolder-current-buffer)
 173     (goto-char (point-min))
 174     (if (search-forward (nnfolder-article-string article) nil t)
 175         (let (start stop)
 176           (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 177           (setq start (point))
 178           (forward-line 1)
 179           (or (and (re-search-forward
 180                     (concat "^" message-unix-mail-delimiter) nil t)
 181                    (forward-line -1))
 182               (goto-char (point-max)))
 183           (setq stop (point))
 184           (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 185             (set-buffer nntp-server-buffer)
 186             (erase-buffer)
 187             (insert-buffer-substring nnfolder-current-buffer start stop)
 188             (goto-char (point-min))
 189             (while (looking-at "From ")
 190               (delete-char 5)
 191               (insert "X-From-Line: ")
 192               (forward-line 1))
 193             (if (numberp article)
 194                 (cons nnfolder-current-group article)
 195               (goto-char (point-min))
 196               (search-forward (concat "\n" nnfolder-article-marker))
 197               (cons nnfolder-current-group
 198                     (string-to-int
 199                      (buffer-substring
 200                       (point) (progn (end-of-line) (point)))))))))))
 201
 202 (deffoo nnfolder-request-group (group &optional server dont-check)
 203   (save-excursion
 204     (nnmail-activate 'nnfolder)
 205     (if (not (assoc group nnfolder-group-alist))
 206         (nnheader-report 'nnfolder "No such group: %s" group)
 207       (nnfolder-possibly-change-group group server)
 208       (if dont-check
 209           (progn
 210             (nnheader-report 'nnfolder "Selected group %s" group)
 211             t)
 212         (let* ((active (assoc group nnfolder-group-alist))
 213                (group (car active))
 214                (range (cadr active)))
 215           (cond
 216            ((null active)
 217             (nnheader-report 'nnfolder "No such group: %s" group))
 218            ((null nnfolder-current-group)
 219             (nnheader-report 'nnfolder "Empty group: %s" group))
 220            (t
 221             (nnheader-report 'nnfolder "Selected group %s" group)
 222             (nnheader-insert "211 %d %d %d %s\n"
 223                              (1+ (- (cdr range) (car range)))
 224                              (car range) (cdr range) group))))))))
 225
 226 (deffoo nnfolder-request-scan (&optional group server)
 227   (nnfolder-possibly-change-group group server t)
 228   (nnmail-get-new-mail
 229    'nnfolder
 230    (lambda ()
 231      (let ((bufs nnfolder-buffer-alist))
 232        (save-excursion
 233          (while bufs
 234            (if (not (buffer-name (nth 1 (car bufs))))
 235                (setq nnfolder-buffer-alist
 236                      (delq (car bufs) nnfolder-buffer-alist))
 237              (set-buffer (nth 1 (car bufs)))
 238              (nnfolder-save-buffer)
 239              (kill-buffer (current-buffer)))
 240            (setq bufs (cdr bufs))))))
 241    nnfolder-directory
 242    group))
 243
 244 ;; Don't close the buffer if we're not shutting down the server.  This way,
 245 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 246 ;; over the buffer again unless we add new mail to it or modify it in some
 247 ;; way.
 248
 249 (deffoo nnfolder-close-group (group &optional server force)
 250   ;; Make sure we _had_ the group open.
 251   (when (or (assoc group nnfolder-buffer-alist)
 252             (equal group nnfolder-current-group))
 253     (let ((inf (assoc group nnfolder-buffer-alist)))
 254       (when inf
 255         (when nnfolder-current-group
 256           (push (list nnfolder-current-group nnfolder-current-buffer)
 257                 nnfolder-buffer-alist))
 258         (setq nnfolder-buffer-alist
 259               (delq inf nnfolder-buffer-alist))
 260         (setq nnfolder-current-buffer (cadr inf)
 261               nnfolder-current-group (car inf))))
 262     (when (and nnfolder-current-buffer
 263                (buffer-name nnfolder-current-buffer))
 264       (save-excursion
 265         (set-buffer nnfolder-current-buffer)
 266         ;; If the buffer was modified, write the file out now.
 267         (nnfolder-save-buffer)
 268         ;; If we're shutting the server down, we need to kill the
 269         ;; buffer and remove it from the open buffer list.  Or, of
 270         ;; course, if we're trying to minimize our space impact.
 271         (kill-buffer (current-buffer))
 272         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 273                                           nnfolder-buffer-alist)))))
 274   (setq nnfolder-current-group nil
 275         nnfolder-current-buffer nil)
 276   t)
 277
 278 (deffoo nnfolder-request-create-group (group &optional server args)
 279   (nnfolder-possibly-change-group nil server)
 280   (nnmail-activate 'nnfolder)
 281   (when group
 282     (unless (assoc group nnfolder-group-alist)
 283       (push (list group (cons 1 0)) nnfolder-group-alist)
 284       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 285   t)
 286
 287 (deffoo nnfolder-request-list (&optional server)
 288   (nnfolder-possibly-change-group nil server)
 289   (save-excursion
 290     (nnmail-find-file nnfolder-active-file)
 291     (setq nnfolder-group-alist (nnmail-get-active))))
 292
 293 (deffoo nnfolder-request-newgroups (date &optional server)
 294   (nnfolder-possibly-change-group nil server)
 295   (nnfolder-request-list server))
 296
 297 (deffoo nnfolder-request-list-newsgroups (&optional server)
 298   (nnfolder-possibly-change-group nil server)
 299   (save-excursion
 300     (nnmail-find-file nnfolder-newsgroups-file)))
 301
 302 (deffoo nnfolder-request-expire-articles
 303   (articles newsgroup &optional server force)
 304   (nnfolder-possibly-change-group newsgroup server)
 305   (let* ((is-old t)
 306          rest)
 307     (nnmail-activate 'nnfolder)
 308
 309     (save-excursion
 310       (set-buffer nnfolder-current-buffer)
 311       (while (and articles is-old)
 312         (goto-char (point-min))
 313         (if (search-forward (nnfolder-article-string (car articles)) nil t)
 314             (if (setq is-old
 315                       (nnmail-expired-article-p
 316                        newsgroup
 317                        (buffer-substring
 318                         (point) (progn (end-of-line) (point)))
 319                        force nnfolder-inhibit-expiry))
 320                 (progn
 321                   (nnheader-message 5 "Deleting article %d..."
 322                                     (car articles) newsgroup)
 323                   (nnfolder-delete-mail))
 324               (setq rest (cons (car articles) rest))))
 325         (setq articles (cdr articles)))
 326       (nnfolder-save-buffer)
 327       ;; Find the lowest active article in this group.
 328       (let* ((active (cadr (assoc newsgroup nnfolder-group-alist)))
 329              (marker (concat "\n" nnfolder-article-marker))
 330              (number "[0-9]+")
 331              (activemin (cdr active)))
 332         (goto-char (point-min))
 333         (while (and (search-forward marker nil t)
 334                     (re-search-forward number nil t))
 335           (setq activemin (min activemin
 336                                (string-to-number (buffer-substring
 337                                                   (match-beginning 0)
 338                                                   (match-end 0))))))
 339         (setcar active activemin))
 340       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 341       (nconc rest articles))))
 342
 343 (deffoo nnfolder-request-move-article
 344   (article group server accept-form &optional last)
 345   (nnfolder-possibly-change-group group server)
 346   (let ((buf (get-buffer-create " *nnfolder move*"))
 347         result)
 348     (and
 349      (nnfolder-request-article article group server)
 350      (save-excursion
 351        (set-buffer buf)
 352        (buffer-disable-undo (current-buffer))
 353        (erase-buffer)
 354        (insert-buffer-substring nntp-server-buffer)
 355        (goto-char (point-min))
 356        (while (re-search-forward
 357                (concat "^" nnfolder-article-marker)
 358                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 359          (delete-region (progn (beginning-of-line) (point))
 360                         (progn (forward-line 1) (point))))
 361        (setq result (eval accept-form))
 362        (kill-buffer buf)
 363        result)
 364      (save-excursion
 365        (nnfolder-possibly-change-group group server)
 366        (set-buffer nnfolder-current-buffer)
 367        (goto-char (point-min))
 368        (if (search-forward (nnfolder-article-string article) nil t)
 369            (nnfolder-delete-mail))
 370        (and last (nnfolder-save-buffer))))
 371     result))
 372
 373 (deffoo nnfolder-request-accept-article (group &optional server last)
 374   (nnfolder-possibly-change-group group server)
 375   (nnmail-check-syntax)
 376   (and (stringp group) (nnfolder-possibly-change-group group))
 377   (let ((buf (current-buffer))
 378         result)
 379     (goto-char (point-min))
 380     (when (looking-at "X-From-Line: ")
 381       (replace-match "From "))
 382     (and
 383      (nnfolder-request-list)
 384      (save-excursion
 385        (set-buffer buf)
 386        (goto-char (point-min))
 387        (search-forward "\n\n" nil t)
 388        (forward-line -1)
 389        (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 390          (delete-region (point) (progn (forward-line 1) (point))))
 391        (setq result
 392              (car (nnfolder-save-mail
 393                    (if (stringp group)
 394                        (list (cons group (nnfolder-active-number group)))
 395                      (nnmail-article-group 'nnfolder-active-number))))))
 396      (save-excursion
 397        (set-buffer nnfolder-current-buffer)
 398        (and last (nnfolder-save-buffer))))
 399     (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 400     (unless result
 401       (nnheader-report 'nnfolder "Couldn't store article"))
 402     result))
 403
 404 (deffoo nnfolder-request-replace-article (article group buffer)
 405   (nnfolder-possibly-change-group group)
 406   (save-excursion
 407     (set-buffer nnfolder-current-buffer)
 408     (goto-char (point-min))
 409     (if (not (search-forward (nnfolder-article-string article) nil t))
 410         nil
 411       (nnfolder-delete-mail t t)
 412       (insert-buffer-substring buffer)
 413       (nnfolder-save-buffer)
 414       t)))
 415
 416 (deffoo nnfolder-request-delete-group (group &optional force server)
 417   (nnfolder-close-group group server t)
 418   ;; Delete all articles in GROUP.
 419   (if (not force)
 420       ()                                ; Don't delete the articles.
 421     ;; Delete the file that holds the group.
 422     (condition-case nil
 423         (delete-file (nnfolder-group-pathname group))
 424       (error nil)))
 425   ;; Remove the group from all structures.
 426   (setq nnfolder-group-alist
 427         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 428         nnfolder-current-group nil
 429         nnfolder-current-buffer nil)
 430   ;; Save the active file.
 431   (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 432   t)
 433
 434 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 435   (nnfolder-possibly-change-group group server)
 436   (save-excursion
 437     (set-buffer nnfolder-current-buffer)
 438     (and (file-writable-p buffer-file-name)
 439          (condition-case ()
 440              (progn
 441                (rename-file
 442                 buffer-file-name
 443                 (nnfolder-group-pathname new-name))
 444                t)
 445            (error nil))
 446          ;; That went ok, so we change the internal structures.
 447          (let ((entry (assoc group nnfolder-group-alist)))
 448            (and entry (setcar entry new-name))
 449            (setq nnfolder-current-buffer nil
 450                  nnfolder-current-group nil)
 451            ;; Save the new group alist.
 452            (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 453            ;; We kill the buffer instead of renaming it and stuff.
 454            (kill-buffer (current-buffer))
 455            t))))
 456
 457 \f
 458 ;;; Internal functions.
 459
 460 (defun nnfolder-article-string (article)
 461   (if (numberp article)
 462       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 463     (concat "\nMessage-ID: " article)))
 464
 465 (defun nnfolder-delete-mail (&optional force leave-delim)
 466   "Delete the message that point is in."
 467   (save-excursion
 468     (delete-region
 469      (save-excursion
 470        (re-search-backward (concat "^" message-unix-mail-delimiter) nil t)
 471        (if leave-delim (progn (forward-line 1) (point))
 472          (match-beginning 0)))
 473      (progn
 474        (forward-line 1)
 475        (if (re-search-forward (concat "^" message-unix-mail-delimiter) nil t)
 476            (if (and (not (bobp)) leave-delim)
 477                (progn (forward-line -2) (point))
 478              (match-beginning 0))
 479          (point-max))))))
 480
 481 ;; When scanning, we're not looking t immediately switch into the group - if
 482 ;; we know our information is up to date, don't even bother reading the file.
 483 (defun nnfolder-possibly-change-group (group &optional server scanning)
 484   (when (and server
 485              (not (nnfolder-server-opened server)))
 486     (nnfolder-open-server server))
 487   (when (and group (or nnfolder-current-buffer
 488                        (not (equal group nnfolder-current-group))))
 489     (gnus-make-directory (directory-file-name nnfolder-directory))
 490     (nnfolder-possibly-activate-groups nil)
 491     (or (assoc group nnfolder-group-alist)
 492         (not (file-exists-p
 493               (nnfolder-group-pathname group)))
 494         (progn
 495           (setq nnfolder-group-alist
 496                 (cons (list group (cons 1 0)) nnfolder-group-alist))
 497           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 498     (let (inf file)
 499       (if (and (equal group nnfolder-current-group)
 500                nnfolder-current-buffer
 501                (buffer-name nnfolder-current-buffer))
 502           ()
 503         (setq nnfolder-current-group group)
 504
 505         ;; If we have to change groups, see if we don't already have the mbox
 506         ;; in memory.  If we do, verify the modtime and destroy the mbox if
 507         ;; needed so we can rescan it.
 508         (if (setq inf (assoc group nnfolder-buffer-alist))
 509             (setq nnfolder-current-buffer (nth 1 inf)))
 510
 511         ;; If the buffer is not live, make sure it isn't in the alist.  If it
 512         ;; is live, verify that nobody else has touched the file since last
 513         ;; time.
 514         (if (or (not (and nnfolder-current-buffer
 515                           (buffer-name nnfolder-current-buffer)))
 516                 (not (and (bufferp nnfolder-current-buffer)
 517                           (verify-visited-file-modtime
 518                            nnfolder-current-buffer))))
 519             (progn
 520               (if (and nnfolder-current-buffer
 521                        (buffer-name nnfolder-current-buffer)
 522                        (bufferp nnfolder-current-buffer))
 523                   (kill-buffer nnfolder-current-buffer))
 524               (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist))
 525               (setq inf nil)))
 526
 527         (unless inf
 528           (save-excursion
 529             (setq file (nnfolder-group-pathname group))
 530             (unless (file-directory-p (file-truename file))
 531               (unless (file-exists-p file)
 532                 (gnus-make-directory (file-name-directory file))
 533                 (nnmail-write-region 1 1 file t 'nomesg))
 534               (setq nnfolder-current-buffer
 535                     (nnfolder-read-folder file scanning))
 536               (when nnfolder-current-buffer
 537                 (set-buffer nnfolder-current-buffer)
 538                 (setq nnfolder-buffer-alist
 539                       (cons (list group nnfolder-current-buffer)
 540                             nnfolder-buffer-alist))))))))
 541     (setq nnfolder-current-group group)))
 542
 543 (defun nnfolder-save-mail (group-art-list)
 544   "Called narrowed to an article."
 545   (let* ((delim (concat "^" message-unix-mail-delimiter))
 546          save-list group-art)
 547     (goto-char (point-min))
 548     ;; The From line may have been quoted by movemail.
 549     (when (looking-at (concat ">" message-unix-mail-delimiter))
 550       (delete-char 1))
 551     ;; This might come from somewhere else.
 552     (unless (looking-at delim)
 553       (insert "From nobody " (current-time-string) "\n")
 554       (goto-char (point-min)))
 555     ;; Quote all "From " lines in the article.
 556     (forward-line 1)
 557     (while (re-search-forward delim nil t)
 558       (beginning-of-line)
 559       (insert "> "))
 560     (setq save-list group-art-list)
 561     (nnmail-insert-lines)
 562     (nnmail-insert-xref group-art-list)
 563     (run-hooks 'nnmail-prepare-save-mail-hook)
 564     (run-hooks 'nnfolder-prepare-save-mail-hook)
 565
 566     ;; Insert the mail into each of the destination groups.
 567     (while group-art-list
 568       (setq group-art (car group-art-list)
 569             group-art-list (cdr group-art-list))
 570
 571       ;; Kill the previous newsgroup markers.
 572       (goto-char (point-min))
 573       (search-forward "\n\n" nil t)
 574       (forward-line -1)
 575       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
 576         (delete-region (1+ (point)) (progn (forward-line 2) (point))))
 577
 578       (nnfolder-possibly-change-group (car group-art))
 579       ;; Insert the new newsgroup marker.
 580       (nnfolder-insert-newsgroup-line group-art)
 581       (unless nnfolder-current-buffer
 582         (nnfolder-close-group (car group-art))
 583         (nnfolder-request-create-group (car group-art))
 584         (nnfolder-possibly-change-group (car group-art)))
 585       (let ((beg (point-min))
 586             (end (point-max))
 587             (obuf (current-buffer)))
 588         (set-buffer nnfolder-current-buffer)
 589         (goto-char (point-max))
 590         (unless (eolp)
 591           (insert "\n"))
 592         (insert "\n")
 593         (insert-buffer-substring obuf beg end)
 594         (set-buffer obuf)))
 595
 596     ;; Did we save it anywhere?
 597     save-list))
 598
 599 (defun nnfolder-insert-newsgroup-line (group-art)
 600   (save-excursion
 601     (goto-char (point-min))
 602     (if (search-forward "\n\n" nil t)
 603         (progn
 604           (forward-char -1)
 605           (insert (format (concat nnfolder-article-marker "%d   %s\n")
 606                           (cdr group-art) (current-time-string)))))))
 607
 608 (defun nnfolder-possibly-activate-groups (&optional group)
 609   (save-excursion
 610     ;; If we're looking for the activation of a specific group, find out
 611     ;; its real name and switch to it.
 612     (if group (nnfolder-possibly-change-group group))
 613     ;; If the group alist isn't active, activate it now.
 614     (nnmail-activate 'nnfolder)))
 615
 616 (defun nnfolder-active-number (group)
 617   (when group
 618     (save-excursion
 619       ;; Find the next article number in GROUP.
 620       (prog1
 621           (let ((active (cadr (assoc group nnfolder-group-alist))))
 622             (if active
 623                 (setcdr active (1+ (cdr active)))
 624               ;; This group is new, so we create a new entry for it.
 625               ;; This might be a bit naughty... creating groups on the drop of
 626               ;; a hat, but I don't know...
 627               (setq nnfolder-group-alist
 628                     (cons (list group (setq active (cons 1 1)))
 629                           nnfolder-group-alist)))
 630             (cdr active))
 631         (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 632         (nnfolder-possibly-activate-groups group)))))
 633
 634
 635 ;; This method has a problem if you've accidentally let the active list get
 636 ;; out of sync with the files.  This could happen, say, if you've
 637 ;; accidentally gotten new mail with something other than Gnus (but why
 638 ;; would _that_ ever happen? :-).  In that case, we will be in the middle of
 639 ;; processing the file, ready to add new X-Gnus article number markers, and
 640 ;; we'll run across a message with no ID yet - the active list _may_not_ be
 641 ;; ready for us yet.
 642
 643 ;; To handle this, I'm modifying this routine to maintain the maximum ID seen
 644 ;; so far, and when we hit a message with no ID, we will _manually_ scan the
 645 ;; rest of the message looking for any more, possibly higher IDs.  We'll
 646 ;; assume the maximum that we find is the highest active.  Note that this
 647 ;; shouldn't cost us much extra time at all, but will be a lot less
 648 ;; vulnerable to glitches between the mbox and the active file.
 649
 650 (defun nnfolder-read-folder (file &optional scanning)
 651   ;; This is an attempt at a serious shortcut - don't even read in the file
 652   ;; if we know we've seen it since the last time it was touched.
 653   (let ((scantime (cadr (assoc nnfolder-current-group
 654                                nnfolder-scantime-alist)))
 655         (modtime (nth 5 (or (file-attributes file) '(nil nil nil nil nil)))))
 656     (if (and scanning scantime
 657              (eq (car scantime) (car modtime))
 658              (eq (cdr scantime) (cadr modtime)))
 659         nil
 660       (save-excursion
 661         (nnfolder-possibly-activate-groups nil)
 662         ;; Read in the file.
 663         (set-buffer (setq nnfolder-current-buffer
 664                           (nnheader-find-file-noselect file nil 'raw)))
 665         (buffer-disable-undo (current-buffer))
 666         ;; If the file hasn't been touched since the last time we scanned it,
 667         ;; don't bother doing anything with it.
 668         (let ((delim (concat "^" message-unix-mail-delimiter))
 669               (marker (concat "\n" nnfolder-article-marker))
 670               (number "[0-9]+")
 671               (active (or (cadr (assoc nnfolder-current-group
 672                                        nnfolder-group-alist))
 673                           (cons 1 0)))
 674               (scantime (assoc nnfolder-current-group nnfolder-scantime-alist))
 675               (minid (lsh -1 -1))
 676               maxid start end newscantime)
 677
 678           (setq maxid (or (cdr active) 0))
 679           (goto-char (point-min))
 680
 681           ;; Anytime the active number is 1 or 0, it is suspect.  In that
 682           ;; case, search the file manually to find the active number.  Or,
 683           ;; of course, if we're being paranoid.  (This would also be the
 684           ;; place to build other lists from the header markers, such as
 685           ;; expunge lists, etc., if we ever desired to abandon the active
 686           ;; file entirely for mboxes.)
 687           (when (or nnfolder-ignore-active-file
 688                     (< maxid 2))
 689             (while (and (search-forward marker nil t)
 690                         (re-search-forward number nil t))
 691               (let ((newnum (string-to-number (match-string 0))))
 692                 (setq maxid (max maxid newnum))
 693                 (setq minid (min minid newnum))))
 694             (setcar active (max 1 (min minid maxid)))
 695             (setcdr active (max maxid (cdr active)))
 696             (goto-char (point-min)))
 697
 698           ;; As long as we trust that the user will only insert unmarked mail
 699           ;; at the end, go to the end and search backwards for the last
 700           ;; marker.  Find the start of that message, and begin to search for
 701           ;; unmarked messages from there.
 702           (if (not (or nnfolder-distrust-mbox
 703                        (< maxid 2)))
 704               (progn
 705                 (goto-char (point-max))
 706                 (if (not (re-search-backward marker nil t))
 707                     (goto-char (point-min))
 708                   (if (not (re-search-backward delim nil t))
 709                       (goto-char (point-min))))))
 710
 711           ;; Keep track of the active number on our own, and insert it back
 712           ;; into the active list when we're done.  Also, prime the pump to
 713           ;; cut down on the number of searches we do.
 714           (setq end (point-marker))
 715           (set-marker end (or (and (re-search-forward delim nil t)
 716                                    (match-beginning 0))
 717                               (point-max)))
 718           (while (not (= end (point-max)))
 719             (setq start (marker-position end))
 720             (goto-char end)
 721             ;; There may be more than one "From " line, so we skip past
 722             ;; them.
 723             (while (looking-at delim)
 724               (forward-line 1))
 725             (set-marker end (or (and (re-search-forward delim nil t)
 726                                      (match-beginning 0))
 727                                 (point-max)))
 728             (goto-char start)
 729             (if (not (search-forward marker end t))
 730                 (progn
 731                   (narrow-to-region start end)
 732                   (nnmail-insert-lines)
 733                   (nnfolder-insert-newsgroup-line
 734                    (cons nil (nnfolder-active-number nnfolder-current-group)))
 735                   (widen))))
 736
 737           ;; Make absolutely sure that the active list reflects reality!
 738           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 739           ;; Set the scantime for this group.
 740           (setq newscantime (visited-file-modtime))
 741           (if scantime
 742               (setcdr scantime (list newscantime))
 743             (push (list nnfolder-current-group newscantime)
 744                   nnfolder-scantime-alist))
 745           (current-buffer))))))
 746
 747 ;;;###autoload
 748 (defun nnfolder-generate-active-file ()
 749   "Look for mbox folders in the nnfolder directory and make them into groups."
 750   (interactive)
 751   (nnmail-activate 'nnfolder)
 752   (let ((files (directory-files nnfolder-directory))
 753         file)
 754     (while (setq file (pop files))
 755       (when (and (not (backup-file-name-p file))
 756                  (nnheader-mail-file-mbox-p
 757                   (concat nnfolder-directory file)))
 758         (nnheader-message 5 "Adding group %s..." file)
 759         (push (list file (cons 1 0)) nnfolder-group-alist)
 760         (nnfolder-possibly-change-group file)
 761         (nnfolder-close-group file))
 762       (message ""))))
 763
 764 (defun nnfolder-group-pathname (group)
 765   "Make pathname for GROUP."
 766   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
 767     ;; If this file exists, we use it directly.
 768     (if (or nnmail-use-long-file-names
 769             (file-exists-p (concat dir group)))
 770         (concat dir group)
 771       ;; If not, we translate dots into slashes.
 772       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
 773
 774 (defun nnfolder-save-buffer ()
 775   "Save the buffer."
 776   (when (buffer-modified-p)
 777     (run-hooks 'nnfolder-save-buffer-hook)
 778     (save-buffer)))
 779
 780 (provide 'nnfolder)
 781
 782 ;;; nnfolder.el ends here