cgit.sxemacs.org Git - gnus/blob - lisp/nnfolder.el

   1 ;;; nnfolder.el --- mail folder access for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Scott Byer <byer@mv.us.adobe.com>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'message)
  32 (require 'nnmail)
  33 (require 'nnoo)
  34 (require 'cl)
  35 (require 'gnus-util)
  36
  37 (nnoo-declare nnfolder)
  38
  39 (defvoo nnfolder-directory (expand-file-name message-directory)
  40   "The name of the nnfolder directory.")
  41
  42 (defvoo nnfolder-active-file
  43   (nnheader-concat nnfolder-directory "active")
  44   "The name of the active file.")
  45
  46 ;; I renamed this variable to something more in keeping with the general GNU
  47 ;; style. -SLB
  48
  49 (defvoo nnfolder-ignore-active-file nil
  50   "If non-nil, causes nnfolder to do some extra work in order to determine
  51 the true active ranges of an mbox file.  Note that the active file is still
  52 saved, but it's values are not used.  This costs some extra time when
  53 scanning an mbox when opening it.")
  54
  55 (defvoo nnfolder-distrust-mbox nil
  56   "If non-nil, causes nnfolder to not trust the user with respect to
  57 inserting unaccounted for mail in the middle of an mbox file.  This can greatly
  58 slow down scans, which now must scan the entire file for unmarked messages.
  59 When nil, scans occur forward from the last marked message, a huge
  60 time saver for large mailboxes.")
  61
  62 (defvoo nnfolder-newsgroups-file
  63   (concat (file-name-as-directory nnfolder-directory) "newsgroups")
  64   "Mail newsgroups description file.")
  65
  66 (defvoo nnfolder-get-new-mail t
  67   "If non-nil, nnfolder will check the incoming mail file and split the mail.")
  68
  69 (defvoo nnfolder-prepare-save-mail-hook nil
  70   "Hook run narrowed to an article before saving.")
  71
  72 (defvoo nnfolder-save-buffer-hook nil
  73   "Hook run before saving the nnfolder mbox buffer.")
  74
  75 (defvoo nnfolder-inhibit-expiry nil
  76   "If non-nil, inhibit expiry.")
  77
  78 \f
  79
  80 (defconst nnfolder-version "nnfolder 1.0"
  81   "nnfolder version.")
  82
  83 (defconst nnfolder-article-marker "X-Gnus-Article-Number: "
  84   "String used to demarcate what the article number for a message is.")
  85
  86 (defvoo nnfolder-current-group nil)
  87 (defvoo nnfolder-current-buffer nil)
  88 (defvoo nnfolder-status-string "")
  89 (defvoo nnfolder-group-alist nil)
  90 (defvoo nnfolder-buffer-alist nil)
  91 (defvoo nnfolder-scantime-alist nil)
  92 (defvoo nnfolder-active-timestamp nil)
  93
  94 \f
  95
  96 ;;; Interface functions
  97
  98 (nnoo-define-basics nnfolder)
  99
 100 (deffoo nnfolder-retrieve-headers (articles &optional group server fetch-old)
 101   (save-excursion
 102     (set-buffer nntp-server-buffer)
 103     (erase-buffer)
 104     (let (article art-string start stop)
 105       (nnfolder-possibly-change-group group server)
 106       (when nnfolder-current-buffer
 107         (set-buffer nnfolder-current-buffer)
 108         (goto-char (point-min))
 109         (if (stringp (car articles))
 110             'headers
 111           (while articles
 112             (setq article (car articles))
 113             (setq art-string (nnfolder-article-string article))
 114             (set-buffer nnfolder-current-buffer)
 115             (when (or (search-forward art-string nil t)
 116                       ;; Don't search the whole file twice!  Also, articles
 117                       ;; probably have some locality by number, so searching
 118                       ;; backwards will be faster.  Especially if we're at the
 119                       ;; beginning of the buffer :-). -SLB
 120                       (search-backward art-string nil t))
 121               (nnmail-search-unix-mail-delim-backward)
 122               (setq start (point))
 123               (search-forward "\n\n" nil t)
 124               (setq stop (1- (point)))
 125               (set-buffer nntp-server-buffer)
 126               (insert (format "221 %d Article retrieved.\n" article))
 127               (insert-buffer-substring nnfolder-current-buffer start stop)
 128               (goto-char (point-max))
 129               (insert ".\n"))
 130             (setq articles (cdr articles)))
 131
 132           (set-buffer nntp-server-buffer)
 133           (nnheader-fold-continuation-lines)
 134           'headers)))))
 135
 136 (deffoo nnfolder-open-server (server &optional defs)
 137   (nnoo-change-server 'nnfolder server defs)
 138   (nnmail-activate 'nnfolder t)
 139   (gnus-make-directory nnfolder-directory)
 140   (cond
 141    ((not (file-exists-p nnfolder-directory))
 142     (nnfolder-close-server)
 143     (nnheader-report 'nnfolder "Couldn't create directory: %s"
 144                      nnfolder-directory))
 145    ((not (file-directory-p (file-truename nnfolder-directory)))
 146     (nnfolder-close-server)
 147     (nnheader-report 'nnfolder "Not a directory: %s" nnfolder-directory))
 148    (t
 149     (nnmail-activate 'nnfolder)
 150     (nnheader-report 'nnfolder "Opened server %s using directory %s"
 151                      server nnfolder-directory)
 152     t)))
 153
 154 (deffoo nnfolder-request-close ()
 155   (let ((alist nnfolder-buffer-alist))
 156     (while alist
 157       (nnfolder-close-group (caar alist) nil t)
 158       (setq alist (cdr alist))))
 159   (nnoo-close-server 'nnfolder)
 160   (setq nnfolder-buffer-alist nil
 161         nnfolder-group-alist nil))
 162
 163 (deffoo nnfolder-request-article (article &optional group server buffer)
 164   (nnfolder-possibly-change-group group server)
 165   (save-excursion
 166     (set-buffer nnfolder-current-buffer)
 167     (goto-char (point-min))
 168     (when (search-forward (nnfolder-article-string article) nil t)
 169       (let (start stop)
 170         (nnmail-search-unix-mail-delim-backward)
 171         (setq start (point))
 172         (forward-line 1)
 173         (unless (and (nnmail-search-unix-mail-delim)
 174                      (forward-line -1))
 175           (goto-char (point-max)))
 176         (setq stop (point))
 177         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 178           (set-buffer nntp-server-buffer)
 179           (erase-buffer)
 180           (insert-buffer-substring nnfolder-current-buffer start stop)
 181           (goto-char (point-min))
 182           (while (looking-at "From ")
 183             (delete-char 5)
 184             (insert "X-From-Line: ")
 185             (forward-line 1))
 186           (if (numberp article)
 187               (cons nnfolder-current-group article)
 188             (goto-char (point-min))
 189             (search-forward (concat "\n" nnfolder-article-marker))
 190             (cons nnfolder-current-group
 191                   (string-to-int
 192                    (buffer-substring
 193                     (point) (progn (end-of-line) (point)))))))))))
 194
 195 (deffoo nnfolder-request-group (group &optional server dont-check)
 196   (nnfolder-possibly-change-group group server t)
 197   (save-excursion
 198     (if (not (assoc group nnfolder-group-alist))
 199         (nnheader-report 'nnfolder "No such group: %s" group)
 200       (if dont-check
 201           (progn
 202             (nnheader-report 'nnfolder "Selected group %s" group)
 203             t)
 204         (let* ((active (assoc group nnfolder-group-alist))
 205                (group (car active))
 206                (range (cadr active)))
 207           (cond
 208            ((null active)
 209             (nnheader-report 'nnfolder "No such group: %s" group))
 210            ((null nnfolder-current-group)
 211             (nnheader-report 'nnfolder "Empty group: %s" group))
 212            (t
 213             (nnheader-report 'nnfolder "Selected group %s" group)
 214             (nnheader-insert "211 %d %d %d %s\n"
 215                              (1+ (- (cdr range) (car range)))
 216                              (car range) (cdr range) group))))))))
 217
 218 (deffoo nnfolder-request-scan (&optional group server)
 219   (nnfolder-possibly-change-group nil server)
 220   (when nnfolder-get-new-mail
 221     (nnfolder-possibly-change-group group server)
 222     (nnmail-get-new-mail
 223      'nnfolder
 224      (lambda ()
 225        (let ((bufs nnfolder-buffer-alist))
 226          (save-excursion
 227            (while bufs
 228              (if (not (buffer-live-p (nth 1 (car bufs))))
 229                  (setq nnfolder-buffer-alist
 230                        (delq (car bufs) nnfolder-buffer-alist))
 231                (set-buffer (nth 1 (car bufs)))
 232                (nnfolder-save-buffer)
 233                (kill-buffer (current-buffer)))
 234              (setq bufs (cdr bufs))))))
 235      nnfolder-directory
 236      group)))
 237
 238 ;; Don't close the buffer if we're not shutting down the server.  This way,
 239 ;; we can keep the buffer in the group buffer cache, and not have to grovel
 240 ;; over the buffer again unless we add new mail to it or modify it in some
 241 ;; way.
 242
 243 (deffoo nnfolder-close-group (group &optional server force)
 244   ;; Make sure we _had_ the group open.
 245   (when (or (assoc group nnfolder-buffer-alist)
 246             (equal group nnfolder-current-group))
 247     (let ((inf (assoc group nnfolder-buffer-alist)))
 248       (when inf
 249         (when (and nnfolder-current-group
 250                    nnfolder-current-buffer)
 251           (push (list nnfolder-current-group nnfolder-current-buffer)
 252                 nnfolder-buffer-alist))
 253         (setq nnfolder-buffer-alist
 254               (delq inf nnfolder-buffer-alist))
 255         (setq nnfolder-current-buffer (cadr inf)
 256               nnfolder-current-group (car inf))))
 257     (when (and nnfolder-current-buffer
 258                (buffer-name nnfolder-current-buffer))
 259       (save-excursion
 260         (set-buffer nnfolder-current-buffer)
 261         ;; If the buffer was modified, write the file out now.
 262         (nnfolder-save-buffer)
 263         ;; If we're shutting the server down, we need to kill the
 264         ;; buffer and remove it from the open buffer list.  Or, of
 265         ;; course, if we're trying to minimize our space impact.
 266         (kill-buffer (current-buffer))
 267         (setq nnfolder-buffer-alist (delq (assoc group nnfolder-buffer-alist)
 268                                           nnfolder-buffer-alist)))))
 269   (setq nnfolder-current-group nil
 270         nnfolder-current-buffer nil)
 271   t)
 272
 273 (deffoo nnfolder-request-create-group (group &optional server args)
 274   (nnfolder-possibly-change-group nil server)
 275   (nnmail-activate 'nnfolder)
 276   (when group
 277     (unless (assoc group nnfolder-group-alist)
 278       (push (list group (cons 1 0)) nnfolder-group-alist)
 279       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)))
 280   t)
 281
 282 (deffoo nnfolder-request-list (&optional server)
 283   (nnfolder-possibly-change-group nil server)
 284   (save-excursion
 285     (nnmail-find-file nnfolder-active-file)
 286     (setq nnfolder-group-alist (nnmail-get-active))
 287     t))
 288
 289 (deffoo nnfolder-request-newgroups (date &optional server)
 290   (nnfolder-possibly-change-group nil server)
 291   (nnfolder-request-list server))
 292
 293 (deffoo nnfolder-request-list-newsgroups (&optional server)
 294   (nnfolder-possibly-change-group nil server)
 295   (save-excursion
 296     (nnmail-find-file nnfolder-newsgroups-file)))
 297
 298 (deffoo nnfolder-request-expire-articles
 299   (articles newsgroup &optional server force)
 300   (nnfolder-possibly-change-group newsgroup server)
 301   (let* ((is-old t)
 302          rest)
 303     (nnmail-activate 'nnfolder)
 304
 305     (save-excursion
 306       (set-buffer nnfolder-current-buffer)
 307       (while (and articles is-old)
 308         (goto-char (point-min))
 309         (when (search-forward (nnfolder-article-string (car articles)) nil t)
 310           (if (setq is-old
 311                     (nnmail-expired-article-p
 312                      newsgroup
 313                      (buffer-substring
 314                       (point) (progn (end-of-line) (point)))
 315                      force nnfolder-inhibit-expiry))
 316               (progn
 317                 (nnheader-message 5 "Deleting article %d..."
 318                                   (car articles) newsgroup)
 319                 (nnfolder-delete-mail))
 320             (push (car articles) rest)))
 321         (setq articles (cdr articles)))
 322       (unless nnfolder-inhibit-expiry
 323         (nnheader-message 5 "Deleting articles...done"))
 324       (nnfolder-save-buffer)
 325       (nnfolder-adjust-min-active newsgroup)
 326       (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 327       (nconc rest articles))))
 328
 329 (deffoo nnfolder-request-move-article
 330   (article group server accept-form &optional last)
 331   (let ((buf (get-buffer-create " *nnfolder move*"))
 332         result)
 333     (and
 334      (nnfolder-request-article article group server)
 335      (save-excursion
 336        (set-buffer buf)
 337        (buffer-disable-undo (current-buffer))
 338        (erase-buffer)
 339        (insert-buffer-substring nntp-server-buffer)
 340        (goto-char (point-min))
 341        (while (re-search-forward
 342                (concat "^" nnfolder-article-marker)
 343                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 344          (delete-region (progn (beginning-of-line) (point))
 345                         (progn (forward-line 1) (point))))
 346        (setq result (eval accept-form))
 347        (kill-buffer buf)
 348        result)
 349      (save-excursion
 350        (nnfolder-possibly-change-group group server)
 351        (set-buffer nnfolder-current-buffer)
 352        (goto-char (point-min))
 353        (when (search-forward (nnfolder-article-string article) nil t)
 354          (nnfolder-delete-mail))
 355        (when last
 356          (nnfolder-save-buffer)
 357          (nnfolder-adjust-min-active group)
 358          (nnmail-save-active nnfolder-group-alist nnfolder-active-file))))
 359     result))
 360
 361 (deffoo nnfolder-request-accept-article (group &optional server last)
 362   (nnfolder-possibly-change-group group server)
 363   (nnmail-check-syntax)
 364   (let ((buf (current-buffer))
 365         result art-group)
 366     (goto-char (point-min))
 367     (when (looking-at "X-From-Line: ")
 368       (replace-match "From "))
 369     (and
 370      (nnfolder-request-list)
 371      (save-excursion
 372        (set-buffer buf)
 373        (goto-char (point-min))
 374        (search-forward "\n\n" nil t)
 375        (forward-line -1)
 376        (while (re-search-backward (concat "^" nnfolder-article-marker) nil t)
 377          (delete-region (point) (progn (forward-line 1) (point))))
 378        (setq result
 379              (car (nnfolder-save-mail
 380                    (if (stringp group)
 381                        (list (cons group (nnfolder-active-number group)))
 382                      (setq art-group
 383                            (nnmail-article-group 'nnfolder-active-number)))))))
 384      (when last
 385        (save-excursion
 386          (nnfolder-possibly-change-folder (or (caar art-group) group))
 387          (nnfolder-save-buffer))))
 388     (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 389     (unless result
 390       (nnheader-report 'nnfolder "Couldn't store article"))
 391     result))
 392
 393 (deffoo nnfolder-request-replace-article (article group buffer)
 394   (nnfolder-possibly-change-group group)
 395   (save-excursion
 396     (set-buffer nnfolder-current-buffer)
 397     (goto-char (point-min))
 398     (if (not (search-forward (nnfolder-article-string article) nil t))
 399         nil
 400       (nnfolder-delete-mail t t)
 401       (insert-buffer-substring buffer)
 402       (nnfolder-save-buffer)
 403       t)))
 404
 405 (deffoo nnfolder-request-delete-group (group &optional force server)
 406   (nnfolder-close-group group server t)
 407   ;; Delete all articles in GROUP.
 408   (if (not force)
 409       ()                                ; Don't delete the articles.
 410     ;; Delete the file that holds the group.
 411     (ignore-errors
 412       (delete-file (nnfolder-group-pathname group))))
 413   ;; Remove the group from all structures.
 414   (setq nnfolder-group-alist
 415         (delq (assoc group nnfolder-group-alist) nnfolder-group-alist)
 416         nnfolder-current-group nil
 417         nnfolder-current-buffer nil)
 418   ;; Save the active file.
 419   (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 420   t)
 421
 422 (deffoo nnfolder-request-rename-group (group new-name &optional server)
 423   (nnfolder-possibly-change-group group server)
 424   (save-excursion
 425     (set-buffer nnfolder-current-buffer)
 426     (and (file-writable-p buffer-file-name)
 427          (ignore-errors
 428            (rename-file
 429             buffer-file-name
 430             (nnfolder-group-pathname new-name))
 431            t)
 432          ;; That went ok, so we change the internal structures.
 433          (let ((entry (assoc group nnfolder-group-alist)))
 434            (and entry (setcar entry new-name))
 435            (setq nnfolder-current-buffer nil
 436                  nnfolder-current-group nil)
 437            ;; Save the new group alist.
 438            (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 439            ;; We kill the buffer instead of renaming it and stuff.
 440            (kill-buffer (current-buffer))
 441            t))))
 442
 443 \f
 444 ;;; Internal functions.
 445
 446 (defun nnfolder-adjust-min-active (group)
 447   ;; Find the lowest active article in this group.
 448   (let* ((active (cadr (assoc group nnfolder-group-alist)))
 449          (marker (concat "\n" nnfolder-article-marker))
 450          (number "[0-9]+")
 451          (activemin (cdr active)))
 452     (save-excursion
 453       (set-buffer nnfolder-current-buffer)
 454       (goto-char (point-min))
 455       (while (and (search-forward marker nil t)
 456                   (re-search-forward number nil t))
 457         (setq activemin (min activemin
 458                              (string-to-number (buffer-substring
 459                                                 (match-beginning 0)
 460                                                 (match-end 0))))))
 461       (setcar active activemin))))
 462
 463 (defun nnfolder-article-string (article)
 464   (if (numberp article)
 465       (concat "\n" nnfolder-article-marker (int-to-string article) " ")
 466     (concat "\nMessage-ID: " article)))
 467
 468 (defun nnfolder-delete-mail (&optional force leave-delim)
 469   "Delete the message that point is in."
 470   (save-excursion
 471     (delete-region
 472      (save-excursion
 473        (nnmail-search-unix-mail-delim-backward)
 474        (if leave-delim (progn (forward-line 1) (point))
 475          (point)))
 476      (progn
 477        (forward-line 1)
 478        (if (nnmail-search-unix-mail-delim)
 479            (if (and (not (bobp)) leave-delim)
 480                (progn (forward-line -2) (point))
 481              (point))
 482          (point-max))))))
 483
 484 (defun nnfolder-possibly-change-group (group &optional server dont-check)
 485   ;; Change servers.
 486   (when (and server
 487              (not (nnfolder-server-opened server)))
 488     (nnfolder-open-server server))
 489   (unless (gnus-buffer-live-p nnfolder-current-buffer)
 490     (setq nnfolder-current-buffer nil
 491           nnfolder-current-group nil))
 492   ;; Change group.
 493   (when (and group
 494              (not (equal group nnfolder-current-group)))
 495     (nnmail-activate 'nnfolder)
 496     (when (and (not (assoc group nnfolder-group-alist))
 497                (not (file-exists-p
 498                      (nnfolder-group-pathname group))))
 499       ;; The group doesn't exist, so we create a new entry for it.
 500       (push (list group (cons 1 0)) nnfolder-group-alist)
 501       (nnmail-save-active nnfolder-group-alist nnfolder-active-file))
 502
 503     (if dont-check
 504         (setq nnfolder-current-group group)
 505       (let (inf file)
 506         ;; If we have to change groups, see if we don't already have the
 507         ;; folder in memory.  If we do, verify the modtime and destroy
 508         ;; the folder if needed so we can rescan it.
 509         (when (setq inf (assoc group nnfolder-buffer-alist))
 510           (setq nnfolder-current-buffer (nth 1 inf)))
 511
 512         ;; If the buffer is not live, make sure it isn't in the alist.  If it
 513         ;; is live, verify that nobody else has touched the file since last
 514         ;; time.
 515         (when (and nnfolder-current-buffer
 516                    (not (gnus-buffer-live-p nnfolder-current-buffer)))
 517           (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)
 518                 nnfolder-current-buffer nil))
 519
 520         (setq nnfolder-current-group group)
 521
 522         (when (or (not nnfolder-current-buffer)
 523                   (not (verify-visited-file-modtime nnfolder-current-buffer)))
 524           (save-excursion
 525             (setq file (nnfolder-group-pathname group))
 526             ;; See whether we need to create the new file.
 527             (unless (file-exists-p file)
 528               (gnus-make-directory (file-name-directory file))
 529               (nnmail-write-region 1 1 file t 'nomesg))
 530             (when (setq nnfolder-current-buffer (nnfolder-read-folder group))
 531               (set-buffer nnfolder-current-buffer)
 532               (push (list group nnfolder-current-buffer)
 533                     nnfolder-buffer-alist))))))))
 534
 535 (defun nnfolder-save-mail (group-art-list)
 536   "Called narrowed to an article."
 537   (let* (save-list group-art)
 538     (goto-char (point-min))
 539     ;; The From line may have been quoted by movemail.
 540     (when (looking-at (concat ">" message-unix-mail-delimiter))
 541       (delete-char 1))
 542     ;; This might come from somewhere else.
 543     (unless (looking-at message-unix-mail-delimiter)
 544       (insert "From nobody " (current-time-string) "\n")
 545       (goto-char (point-min)))
 546     ;; Quote all "From " lines in the article.
 547     (forward-line 1)
 548     (let (case-fold-search)
 549       (while (re-search-forward "^From " nil t)
 550         (beginning-of-line)
 551         (insert "> ")))
 552     (setq save-list group-art-list)
 553     (nnmail-insert-lines)
 554     (nnmail-insert-xref group-art-list)
 555     (run-hooks 'nnmail-prepare-save-mail-hook)
 556     (run-hooks 'nnfolder-prepare-save-mail-hook)
 557
 558     ;; Insert the mail into each of the destination groups.
 559     (while (setq group-art (pop group-art-list))
 560       ;; Kill any previous newsgroup markers.
 561       (goto-char (point-min))
 562       (search-forward "\n\n" nil t)
 563       (forward-line -1)
 564       (while (search-backward (concat "\n" nnfolder-article-marker) nil t)
 565         (delete-region (1+ (point)) (progn (forward-line 2) (point))))
 566
 567       ;; Insert the new newsgroup marker.
 568       (nnfolder-insert-newsgroup-line group-art)
 569
 570       (save-excursion
 571         (let ((beg (point-min))
 572               (end (point-max))
 573               (obuf (current-buffer)))
 574           (nnfolder-possibly-change-folder (car group-art))
 575           (goto-char (point-max))
 576           (unless (eolp)
 577             (insert "\n"))
 578           (unless (bobp)
 579             (insert "\n"))
 580           (insert-buffer-substring obuf beg end))))
 581
 582     ;; Did we save it anywhere?
 583     save-list))
 584
 585 (defun nnfolder-insert-newsgroup-line (group-art)
 586   (save-excursion
 587     (goto-char (point-min))
 588     (when (search-forward "\n\n" nil t)
 589       (forward-char -1)
 590       (insert (format (concat nnfolder-article-marker "%d   %s\n")
 591                       (cdr group-art) (current-time-string))))))
 592
 593 (defun nnfolder-active-number (group)
 594   ;; Find the next article number in GROUP.
 595   (let ((active (cadr (assoc group nnfolder-group-alist))))
 596     (if active
 597         (setcdr active (1+ (cdr active)))
 598       ;; This group is new, so we create a new entry for it.
 599       ;; This might be a bit naughty... creating groups on the drop of
 600       ;; a hat, but I don't know...
 601       (push (list group (setq active (cons 1 1)))
 602             nnfolder-group-alist))
 603     (cdr active)))
 604
 605 (defun nnfolder-possibly-change-folder (group)
 606   (let ((inf (assoc group nnfolder-buffer-alist)))
 607     (if (and inf
 608              (gnus-buffer-live-p (cadr inf)))
 609         (set-buffer (cadr inf))
 610       (when inf
 611         (setq nnfolder-buffer-alist (delq inf nnfolder-buffer-alist)))
 612       (when nnfolder-group-alist
 613         (nnmail-save-active nnfolder-group-alist nnfolder-active-file))
 614       (push (list group (nnfolder-read-folder group))
 615             nnfolder-buffer-alist))))
 616
 617 ;; This method has a problem if you've accidentally let the active list get
 618 ;; out of sync with the files.  This could happen, say, if you've
 619 ;; accidentally gotten new mail with something other than Gnus (but why
 620 ;; would _that_ ever happen? :-).  In that case, we will be in the middle of
 621 ;; processing the file, ready to add new X-Gnus article number markers, and
 622 ;; we'll run across a message with no ID yet - the active list _may_not_ be
 623 ;; ready for us yet.
 624
 625 ;; To handle this, I'm modifying this routine to maintain the maximum ID seen
 626 ;; so far, and when we hit a message with no ID, we will _manually_ scan the
 627 ;; rest of the message looking for any more, possibly higher IDs.  We'll
 628 ;; assume the maximum that we find is the highest active.  Note that this
 629 ;; shouldn't cost us much extra time at all, but will be a lot less
 630 ;; vulnerable to glitches between the mbox and the active file.
 631
 632 (defun nnfolder-read-folder (group)
 633   (let* ((file (nnfolder-group-pathname group))
 634          (buffer (set-buffer (nnheader-find-file-noselect file))))
 635     (if (equal (cadr (assoc group nnfolder-scantime-alist))
 636                (nth 5 (file-attributes file)))
 637         ;; This looks up-to-date, so we don't do any scanning.
 638         buffer
 639       ;; Parse the damn thing.
 640       (save-excursion
 641         (nnmail-activate 'nnfolder)
 642         ;; Read in the file.
 643         (let ((delim (concat "^" message-unix-mail-delimiter))
 644               (marker (concat "\n" nnfolder-article-marker))
 645               (number "[0-9]+")
 646               (active (cadr (assoc group nnfolder-group-alist)))
 647               (scantime (assoc group nnfolder-scantime-alist))
 648               (minid (lsh -1 -1))
 649               maxid start end newscantime
 650               buffer-read-only)
 651           (buffer-disable-undo (current-buffer))
 652           (setq maxid (cdr active))
 653           (goto-char (point-min))
 654
 655           ;; Anytime the active number is 1 or 0, it is suspect.  In that
 656           ;; case, search the file manually to find the active number.  Or,
 657           ;; of course, if we're being paranoid.  (This would also be the
 658           ;; place to build other lists from the header markers, such as
 659           ;; expunge lists, etc., if we ever desired to abandon the active
 660           ;; file entirely for mboxes.)
 661           (when (or nnfolder-ignore-active-file
 662                     (< maxid 2))
 663             (while (and (search-forward marker nil t)
 664                         (re-search-forward number nil t))
 665               (let ((newnum (string-to-number (match-string 0))))
 666                 (setq maxid (max maxid newnum))
 667                 (setq minid (min minid newnum))))
 668             (setcar active (max 1 (min minid maxid)))
 669             (setcdr active (max maxid (cdr active)))
 670             (goto-char (point-min)))
 671
 672           ;; As long as we trust that the user will only insert unmarked mail
 673           ;; at the end, go to the end and search backwards for the last
 674           ;; marker.  Find the start of that message, and begin to search for
 675           ;; unmarked messages from there.
 676           (when (not (or nnfolder-distrust-mbox
 677                          (< maxid 2)))
 678             (goto-char (point-max))
 679             (if (not (re-search-backward marker nil t))
 680                 (goto-char (point-min))
 681               (when (not (nnmail-search-unix-mail-delim))
 682                 (goto-char (point-min)))))
 683
 684           ;; Keep track of the active number on our own, and insert it back
 685           ;; into the active list when we're done.  Also, prime the pump to
 686           ;; cut down on the number of searches we do.
 687           (unless (nnmail-search-unix-mail-delim)
 688             (goto-char (point-max)))
 689           (setq end (point-marker))
 690           (while (not (= end (point-max)))
 691             (setq start (marker-position end))
 692             (goto-char end)
 693             ;; There may be more than one "From " line, so we skip past
 694             ;; them.
 695             (while (looking-at delim)
 696               (forward-line 1))
 697             (set-marker end (if (nnmail-search-unix-mail-delim)
 698                                 (point)
 699                               (point-max)))
 700             (goto-char start)
 701             (when (not (search-forward marker end t))
 702               (narrow-to-region start end)
 703               (nnmail-insert-lines)
 704               (nnfolder-insert-newsgroup-line
 705                (cons nil (nnfolder-active-number nnfolder-current-group)))
 706               (widen)))
 707
 708           (set-marker end nil)
 709           ;; Make absolutely sure that the active list reflects reality!
 710           (nnmail-save-active nnfolder-group-alist nnfolder-active-file)
 711           ;; Set the scantime for this group.
 712           (setq newscantime (visited-file-modtime))
 713           (if scantime
 714               (setcdr scantime (list newscantime))
 715             (push (list nnfolder-current-group newscantime)
 716                   nnfolder-scantime-alist))
 717           (current-buffer))))))
 718
 719 ;;;###autoload
 720 (defun nnfolder-generate-active-file ()
 721   "Look for mbox folders in the nnfolder directory and make them into groups."
 722   (interactive)
 723   (nnmail-activate 'nnfolder)
 724   (let ((files (directory-files nnfolder-directory))
 725         file)
 726     (while (setq file (pop files))
 727       (when (and (not (backup-file-name-p file))
 728                  (message-mail-file-mbox-p
 729                   (nnheader-concat nnfolder-directory file)))
 730         (let ((oldgroup (assoc file nnfolder-group-alist)))
 731           (if oldgroup
 732               (nnheader-message 5 "Refreshing group %s..." file)
 733             (nnheader-message 5 "Adding group %s..." file))
 734           (setq nnfolder-group-alist (remove oldgroup nnfolder-group-alist))
 735           (push (list file (cons 1 0)) nnfolder-group-alist)
 736           (nnfolder-possibly-change-folder file)
 737           (nnfolder-possibly-change-group file)
 738           (nnfolder-close-group file))))
 739     (message "")))
 740
 741 (defun nnfolder-group-pathname (group)
 742   "Make pathname for GROUP."
 743   (let ((dir (file-name-as-directory (expand-file-name nnfolder-directory))))
 744     ;; If this file exists, we use it directly.
 745     (if (or nnmail-use-long-file-names
 746             (file-exists-p (concat dir group)))
 747         (concat dir group)
 748       ;; If not, we translate dots into slashes.
 749       (concat dir (nnheader-replace-chars-in-string group ?. ?/)))))
 750
 751 (defun nnfolder-save-buffer ()
 752   "Save the buffer."
 753   (when (buffer-modified-p)
 754     (run-hooks 'nnfolder-save-buffer-hook)
 755     (save-buffer)))
 756
 757 (provide 'nnfolder)
 758
 759 ;;; nnfolder.el ends here