cgit.sxemacs.org Git - gnus/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nnmail)
  31 (require 'gnus-start)
  32 (require 'nnmh)
  33 (require 'nnoo)
  34 (require 'mm-util)
  35 (eval-when-compile
  36   (require 'cl)
  37   ;; This is just to shut up the byte-compiler.
  38   (defalias 'nndraft-request-group 'ignore))
  39
  40 (nnoo-declare nndraft
  41   nnmh)
  42
  43 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  44   "Where nndraft will store its files."
  45   nnmh-directory)
  46
  47 \f
  48
  49 (defvoo nndraft-current-group "" nil nnmh-current-group)
  50 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  51 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  52
  53 (defconst nndraft-version "nndraft 1.0")
  54 (defvoo nndraft-status-string "" nil nnmh-status-string)
  55
  56 \f
  57
  58 ;;; Interface functions.
  59
  60 (nnoo-define-basics nndraft)
  61
  62 (deffoo nndraft-open-server (server &optional defs)
  63   (nnoo-change-server 'nndraft server defs)
  64   (cond
  65    ((not (file-exists-p nndraft-directory))
  66     (nndraft-close-server)
  67     (nnheader-report 'nndraft "No such file or directory: %s"
  68                      nndraft-directory))
  69    ((not (file-directory-p (file-truename nndraft-directory)))
  70     (nndraft-close-server)
  71     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  72    (t
  73     (nnheader-report 'nndraft "Opened server %s using directory %s"
  74                      server nndraft-directory)
  75     t)))
  76
  77 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  78   (nndraft-possibly-change-group group)
  79   (save-excursion
  80     (set-buffer nntp-server-buffer)
  81     (erase-buffer)
  82     (let* (article)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (narrow-to-region (point) (point))
  88           (when (nndraft-request-article
  89                  (setq article (pop articles)) group server (current-buffer))
  90             (goto-char (point-min))
  91             (if (search-forward "\n\n" nil t)
  92                 (forward-line -1)
  93               (goto-char (point-max)))
  94             (delete-region (point) (point-max))
  95             (goto-char (point-min))
  96             (insert (format "221 %d Article retrieved.\n" article))
  97             (widen)
  98             (goto-char (point-max))
  99             (insert ".\n")))
 100
 101         (nnheader-fold-continuation-lines)
 102         'headers))))
 103
 104 (deffoo nndraft-request-article (id &optional group server buffer)
 105   (nndraft-possibly-change-group group)
 106   (when (numberp id)
 107     ;; We get the newest file of the auto-saved file and the
 108     ;; "real" file.
 109     (let* ((file (nndraft-article-filename id))
 110            (auto (nndraft-auto-save-file-name file))
 111            (newest (if (file-newer-than-file-p file auto) file auto))
 112            (nntp-server-buffer (or buffer nntp-server-buffer)))
 113       (when (and (file-exists-p newest)
 114                  (let ((nnmail-file-coding-system
 115                         (if (file-newer-than-file-p file auto)
 116                             (if (equal group "drafts")
 117                                 message-draft-coding-system
 118                               mm-text-coding-system)
 119                           mm-auto-save-coding-system)))
 120                    (nnmail-find-file newest)))
 121         (save-excursion
 122           (set-buffer nntp-server-buffer)
 123           (goto-char (point-min))
 124           ;; If there's a mail header separator in this file,
 125           ;; we remove it.
 126           (when (re-search-forward
 127                  (concat "^" mail-header-separator "$") nil t)
 128             (replace-match "" t t)))
 129         t))))
 130
 131 (deffoo nndraft-request-restore-buffer (article &optional group server)
 132   "Request a new buffer that is restored to the state of ARTICLE."
 133   (nndraft-possibly-change-group group)
 134   (when (nndraft-request-article article group server (current-buffer))
 135     (message-remove-header "xref")
 136     (message-remove-header "lines")
 137     (message-remove-header "date")
 138     t))
 139
 140 (deffoo nndraft-request-update-info (group info &optional server)
 141   (nndraft-possibly-change-group group)
 142   (gnus-info-set-read
 143    info
 144    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 145                               (nndraft-articles) t))
 146   (let ((marks (nth 3 info)))
 147     (when marks
 148       ;; Nix out all marks except the `unsend'-able article marks.
 149       (setcar (nthcdr 3 info)
 150               (if (assq 'unsend marks)
 151                   (list (assq 'unsend marks))
 152                 nil))))
 153   t)
 154
 155 (deffoo nndraft-request-associate-buffer (group)
 156   "Associate the current buffer with some article in the draft group."
 157   (nndraft-open-server "")
 158   (nndraft-request-group group)
 159   (nndraft-possibly-change-group group)
 160   (let ((gnus-verbose-backends nil)
 161         (buf (current-buffer))
 162         article file)
 163     (with-temp-buffer
 164       (insert-buffer-substring buf)
 165       (setq article (nndraft-request-accept-article
 166                      group (nnoo-current-server 'nndraft) t 'noinsert)
 167             file (nndraft-article-filename article)))
 168     (setq buffer-file-name (expand-file-name file)
 169           buffer-auto-save-file-name (make-auto-save-file-name))
 170     (clear-visited-file-modtime)
 171     article))
 172
 173 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 174   (nndraft-possibly-change-group group)
 175   (let* ((nnmh-allow-delete-final t)
 176          (res (nnoo-parent-function 'nndraft
 177                                     'nnmh-request-expire-articles
 178                                     (list articles group server force)))
 179          article)
 180     ;; Delete all the "state" files of articles that have been expired.
 181     (while articles
 182       (unless (memq (setq article (pop articles)) res)
 183         (let ((auto (nndraft-auto-save-file-name
 184                      (nndraft-article-filename article))))
 185           (when (file-exists-p auto)
 186             (funcall nnmail-delete-file-function auto)))
 187         (dolist (backup
 188                  (let ((kept-new-versions 1)
 189                        (kept-old-versions 0))
 190                    (find-backup-file-name
 191                     (nndraft-article-filename article))))
 192           (when (file-exists-p backup)
 193             (funcall nnmail-delete-file-function backup)))))
 194     res))
 195
 196 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 197   (nndraft-possibly-change-group group)
 198   (let ((gnus-verbose-backends nil))
 199     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 200                           (list group server last noinsert))))
 201
 202 (deffoo nndraft-request-replace-article (article group buffer)
 203   (nndraft-possibly-change-group group)
 204   (let ((nnmail-file-coding-system
 205          (if (equal group "drafts")
 206              mm-auto-save-coding-system
 207            mm-text-coding-system)))
 208     (nnoo-parent-function 'nndraft 'nnmh-request-replace-article
 209                           (list article group buffer))))
 210
 211 (deffoo nndraft-request-create-group (group &optional server args)
 212   (nndraft-possibly-change-group group)
 213   (if (file-exists-p nndraft-current-directory)
 214       (if (file-directory-p nndraft-current-directory)
 215           t
 216         nil)
 217     (condition-case ()
 218         (progn
 219           (gnus-make-directory nndraft-current-directory)
 220           t)
 221       (file-error nil))))
 222
 223 \f
 224 ;;; Low-Level Interface
 225
 226 (defun nndraft-possibly-change-group (group)
 227   (when (and group
 228              (not (equal group nndraft-current-group)))
 229     (nndraft-open-server "")
 230     (setq nndraft-current-group group)
 231     (setq nndraft-current-directory
 232           (nnheader-concat nndraft-directory group))))
 233
 234 (defun nndraft-article-filename (article &rest args)
 235   (apply 'concat
 236          (file-name-as-directory nndraft-current-directory)
 237          (int-to-string article)
 238          args))
 239
 240 (defun nndraft-auto-save-file-name (file)
 241   (save-excursion
 242     (prog1
 243         (progn
 244           (set-buffer (get-buffer-create " *draft tmp*"))
 245           (setq buffer-file-name file)
 246           (make-auto-save-file-name))
 247       (kill-buffer (current-buffer)))))
 248
 249 (defun nndraft-articles ()
 250   "Return the list of messages in the group."
 251   (gnus-make-directory nndraft-current-directory)
 252   (sort
 253    (mapcar 'string-to-int
 254            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 255    '<))
 256
 257 (nnoo-import nndraft
 258   (nnmh
 259    nnmh-retrieve-headers
 260    nnmh-request-group
 261    nnmh-close-group
 262    nnmh-request-list
 263    nnmh-request-newsgroups
 264    nnmh-request-move-article))
 265
 266 (provide 'nndraft)
 267
 268 ;;; nndraft.el ends here