cgit.sxemacs.org Git - gnus/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'nnheader)
  29 (require 'nnmail)
  30 (require 'gnus-start)
  31 (require 'nnmh)
  32 (require 'nnoo)
  33 (require 'mm-util)
  34 (eval-when-compile (require 'cl))
  35
  36 (nnoo-declare nndraft
  37   nnmh)
  38
  39 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  40   "Where nndraft will store its files."
  41   nnmh-directory)
  42
  43 (defvar nndraft-required-headers '(Date)
  44   "*Headers to be generated when saving a draft message.
  45 The headers in this variable and the ones in `message-required-headers'
  46 are generated if and only if they are also in `message-draft-headers'.")
  47
  48 \f
  49
  50 (defvoo nndraft-current-group "" nil nnmh-current-group)
  51 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  52 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  53
  54 (defconst nndraft-version "nndraft 1.0")
  55 (defvoo nndraft-status-string "" nil nnmh-status-string)
  56
  57 \f
  58
  59 ;;; Interface functions.
  60
  61 (nnoo-define-basics nndraft)
  62
  63 (deffoo nndraft-open-server (server &optional defs)
  64   (nnoo-change-server 'nndraft server defs)
  65   (cond
  66    ((not (file-exists-p nndraft-directory))
  67     (nndraft-close-server)
  68     (nnheader-report 'nndraft "No such file or directory: %s"
  69                      nndraft-directory))
  70    ((not (file-directory-p (file-truename nndraft-directory)))
  71     (nndraft-close-server)
  72     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  73    (t
  74     (nnheader-report 'nndraft "Opened server %s using directory %s"
  75                      server nndraft-directory)
  76     t)))
  77
  78 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  79   (nndraft-possibly-change-group group)
  80   (with-current-buffer nntp-server-buffer
  81     (erase-buffer)
  82     (let* (article)
  83       ;; We don't support fetching by Message-ID.
  84       (if (stringp (car articles))
  85           'headers
  86         (while articles
  87           (narrow-to-region (point) (point))
  88           (when (nndraft-request-article
  89                  (setq article (pop articles)) group server (current-buffer))
  90             (goto-char (point-min))
  91             (if (search-forward "\n\n" nil t)
  92                 (forward-line -1)
  93               (goto-char (point-max)))
  94             (delete-region (point) (point-max))
  95             (goto-char (point-min))
  96             (insert (format "221 %d Article retrieved.\n" article))
  97             (widen)
  98             (goto-char (point-max))
  99             (insert ".\n")))
 100
 101         (nnheader-fold-continuation-lines)
 102         'headers))))
 103
 104 (deffoo nndraft-request-article (id &optional group server buffer)
 105   (nndraft-possibly-change-group group)
 106   (when (numberp id)
 107     ;; We get the newest file of the auto-saved file and the
 108     ;; "real" file.
 109     (let* ((file (nndraft-article-filename id))
 110            (auto (nndraft-auto-save-file-name file))
 111            (newest (if (file-newer-than-file-p file auto) file auto))
 112            (nntp-server-buffer (or buffer nntp-server-buffer)))
 113       (when (and (file-exists-p newest)
 114                  (let ((nnmail-file-coding-system
 115                         (if (file-newer-than-file-p file auto)
 116                             (if (member group '("drafts" "delayed"))
 117                                 message-draft-coding-system
 118                               mm-text-coding-system)
 119                           mm-auto-save-coding-system)))
 120                    (nnmail-find-file newest)))
 121         (with-current-buffer nntp-server-buffer
 122           (goto-char (point-min))
 123           ;; If there's a mail header separator in this file,
 124           ;; we remove it.
 125           (when (re-search-forward
 126                  (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 127             (replace-match "" t t)))
 128         t))))
 129
 130 (deffoo nndraft-request-restore-buffer (article &optional group server)
 131   "Request a new buffer that is restored to the state of ARTICLE."
 132   (nndraft-possibly-change-group group)
 133   (when (nndraft-request-article article group server (current-buffer))
 134     (message-remove-header "xref")
 135     (message-remove-header "lines")
 136     ;; Articles in nndraft:queue are considered as sent messages.  The
 137     ;; Date field should be the time when they are sent.
 138     ;;(message-remove-header "date")
 139     t))
 140
 141 (deffoo nndraft-request-update-info (group info &optional server)
 142   (nndraft-possibly-change-group group)
 143   (gnus-info-set-read
 144    info
 145    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 146                               (nndraft-articles) t))
 147   (let ((marks (nth 3 info)))
 148     (when marks
 149       ;; Nix out all marks except the `unsend'-able article marks.
 150       (setcar (nthcdr 3 info)
 151               (if (assq 'unsend marks)
 152                   (list (assq 'unsend marks))
 153                 nil))))
 154   t)
 155
 156 (defun nndraft-generate-headers ()
 157   (save-excursion
 158     (message-generate-headers
 159      (message-headers-to-generate
 160       nndraft-required-headers message-draft-headers nil))))
 161
 162 (deffoo nndraft-request-associate-buffer (group)
 163   "Associate the current buffer with some article in the draft group."
 164   (nndraft-open-server "")
 165   (nndraft-request-group group)
 166   (nndraft-possibly-change-group group)
 167   (let ((gnus-verbose-backends nil)
 168         (buf (current-buffer))
 169         article file)
 170     (with-temp-buffer
 171       (insert-buffer-substring buf)
 172       (setq article (nndraft-request-accept-article
 173                      group (nnoo-current-server 'nndraft) t 'noinsert)
 174             file (nndraft-article-filename article)))
 175     (setq buffer-file-name (expand-file-name file)
 176           buffer-auto-save-file-name (make-auto-save-file-name))
 177     (clear-visited-file-modtime)
 178     (let ((hook (if (boundp 'write-contents-functions)
 179                     'write-contents-functions
 180                   'write-contents-hooks)))
 181       (gnus-make-local-hook hook)
 182       (add-hook hook 'nndraft-generate-headers nil t))
 183     article))
 184
 185 (deffoo nndraft-request-group (group &optional server dont-check info)
 186   (nndraft-possibly-change-group group)
 187   (unless dont-check
 188     (let* ((pathname (nnmail-group-pathname group nndraft-directory))
 189            (file-name-coding-system nnmail-pathname-coding-system)
 190            dir file)
 191       (nnheader-re-read-dir pathname)
 192       (setq dir (mapcar (lambda (name) (string-to-number (substring name 1)))
 193                         (ignore-errors (directory-files
 194                                         pathname nil "^#[0-9]+#$" t))))
 195       (dolist (n dir)
 196         (unless (file-exists-p
 197                  (setq file (expand-file-name (int-to-string n) pathname)))
 198           (rename-file (nndraft-auto-save-file-name file) file)))))
 199   (nnoo-parent-function 'nndraft
 200                         'nnmh-request-group
 201                         (list group server dont-check)))
 202
 203 (deffoo nndraft-request-move-article (article group server accept-form
 204                                       &optional last move-is-internal)
 205   (nndraft-possibly-change-group group)
 206   (let ((buf (get-buffer-create " *nndraft move*"))
 207         result)
 208     (and
 209      (nndraft-request-article article group server)
 210      (with-current-buffer buf
 211        (erase-buffer)
 212        (insert-buffer-substring nntp-server-buffer)
 213        (setq result (eval accept-form))
 214        (kill-buffer (current-buffer))
 215        result)
 216      (null (nndraft-request-expire-articles (list article) group server 'force))
 217      result)))
 218
 219 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 220   (nndraft-possibly-change-group group)
 221   (let* ((nnmh-allow-delete-final t)
 222          (res (nnoo-parent-function 'nndraft
 223                                     'nnmh-request-expire-articles
 224                                     (list articles group server force)))
 225          article)
 226     ;; Delete all the "state" files of articles that have been expired.
 227     (while articles
 228       (unless (memq (setq article (pop articles)) res)
 229         (let ((auto (nndraft-auto-save-file-name
 230                      (nndraft-article-filename article))))
 231           (when (file-exists-p auto)
 232             (funcall nnmail-delete-file-function auto)))
 233         (dolist (backup
 234                  (let ((kept-new-versions 1)
 235                        (kept-old-versions 0))
 236                    (find-backup-file-name
 237                     (nndraft-article-filename article))))
 238           (when (file-exists-p backup)
 239             (funcall nnmail-delete-file-function backup)))))
 240     res))
 241
 242 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 243   (nndraft-possibly-change-group group)
 244   (let ((gnus-verbose-backends nil))
 245     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 246                           (list group server last noinsert))))
 247
 248 (deffoo nndraft-request-replace-article (article group buffer)
 249   (nndraft-possibly-change-group group)
 250   (let ((nnmail-file-coding-system
 251          (if (member group '("drafts" "delayed"))
 252              message-draft-coding-system
 253            mm-text-coding-system)))
 254     (nnoo-parent-function 'nndraft 'nnmh-request-replace-article
 255                           (list article group buffer))))
 256
 257 (deffoo nndraft-request-create-group (group &optional server args)
 258   (nndraft-possibly-change-group group)
 259   (if (file-exists-p nndraft-current-directory)
 260       (if (file-directory-p nndraft-current-directory)
 261           t
 262         nil)
 263     (condition-case ()
 264         (progn
 265           (gnus-make-directory nndraft-current-directory)
 266           t)
 267       (file-error nil))))
 268
 269 \f
 270 ;;; Low-Level Interface
 271
 272 (defun nndraft-possibly-change-group (group)
 273   (when (and group
 274              (not (equal group nndraft-current-group)))
 275     (nndraft-open-server "")
 276     (setq nndraft-current-group group)
 277     (setq nndraft-current-directory
 278           (nnheader-concat nndraft-directory group))))
 279
 280 (defun nndraft-article-filename (article &rest args)
 281   (apply 'concat
 282          (file-name-as-directory nndraft-current-directory)
 283          (int-to-string article)
 284          args))
 285
 286 (defun nndraft-auto-save-file-name (file)
 287   (save-excursion
 288     (prog1
 289         (progn
 290           (set-buffer (get-buffer-create " *draft tmp*"))
 291           (setq buffer-file-name file)
 292           (make-auto-save-file-name))
 293       (kill-buffer (current-buffer)))))
 294
 295 (defun nndraft-articles ()
 296   "Return the list of messages in the group."
 297   (gnus-make-directory nndraft-current-directory)
 298   (sort
 299    (mapcar 'string-to-number
 300            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 301    '<))
 302
 303 (nnoo-import nndraft
 304   (nnmh
 305    nnmh-retrieve-headers
 306    nnmh-request-group
 307    nnmh-close-group
 308    nnmh-request-list
 309    nnmh-request-newsgroups))
 310
 311 (provide 'nndraft)
 312
 313 ;;; nndraft.el ends here