cgit.sxemacs.org Git - gnus/blob - lisp/nnbabyl.el

   1 ;;; nnbabyl.el --- rmail mbox access for Gnus
   2 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;; Keywords: news, mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; For an overview of what the interface functions do, please see the
  27 ;; Gnus sources.
  28
  29 ;;; Code:
  30
  31 (require 'nnheader)
  32 (require 'rmail)
  33 (require 'nnmail)
  34
  35 (defvar nnbabyl-mbox-file (expand-file-name "~/RMAIL")
  36   "The name of the rmail box file in the users home directory.")
  37
  38 (defvar nnbabyl-active-file (expand-file-name "~/.rmail-active")
  39   "The name of the active file for the rmail box.")
  40
  41 (defvar nnbabyl-get-new-mail t
  42   "If non-nil, nnbabyl will check the incoming mail file and split the mail.")
  43
  44 (defvar nnbabyl-prepare-save-mail-hook nil
  45   "Hook run narrowed to an article before saving.")
  46
  47 \f
  48
  49 (defvar nnbabyl-mail-delimiter "\^_")
  50
  51 (defconst nnbabyl-version "nnbabyl 0.1"
  52   "nnbabyl version.")
  53
  54 (defvar nnbabyl-mbox-buffer nil)
  55 (defvar nnbabyl-current-group nil)
  56 (defvar nnbabyl-status-string "")
  57 (defvar nnbabyl-group-alist nil)
  58
  59 \f
  60
  61 (defvar nnbabyl-current-server nil)
  62 (defvar nnbabyl-server-alist nil)
  63 (defvar nnbabyl-server-variables
  64   (list
  65    (list 'nnbabyl-mbox-file nnbabyl-mbox-file)
  66    (list 'nnbabyl-active-file nnbabyl-active-file)
  67    (list 'nnbabyl-get-new-mail nnbabyl-get-new-mail)
  68    '(nnbabyl-current-group nil)
  69    '(nnbabyl-status-string "")
  70    '(nnbabyl-group-alist nil)))
  71
  72 \f
  73
  74 ;;; Interface functions
  75
  76 (defun nnbabyl-retrieve-headers (sequence &optional newsgroup server)
  77   (save-excursion
  78     (set-buffer nntp-server-buffer)
  79     (erase-buffer)
  80     (let ((number (length sequence))
  81           (count 0)
  82           article art-string start stop)
  83       (nnbabyl-possibly-change-newsgroup newsgroup)
  84       (if (stringp (car sequence))
  85           'headers
  86         (while sequence
  87           (setq article (car sequence))
  88           (setq art-string (nnbabyl-article-string article))
  89           (set-buffer nnbabyl-mbox-buffer)
  90           (if (or (search-forward art-string nil t)
  91                   (search-backward art-string nil t))
  92               (progn
  93                 (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
  94                 (while (and (not (looking-at ".+:"))
  95                             (zerop (forward-line 1))))
  96                 (setq start (point))
  97                 (search-forward "\n\n" nil t)
  98                 (setq stop (1- (point)))
  99                 (set-buffer nntp-server-buffer)
 100                 (insert "221 " (int-to-string article) " Article retrieved.\n")
 101                 (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 102                 (goto-char (point-max))
 103                 (insert ".\n")))
 104           (setq sequence (cdr sequence))
 105           (setq count (1+ count))
 106           (and (numberp nnmail-large-newsgroup)
 107                (> number nnmail-large-newsgroup)
 108                (zerop (% count 20))
 109                gnus-verbose-backends
 110                (message "nnbabyl: Receiving headers... %d%%"
 111                         (/ (* count 100) number))))
 112
 113         (and (numberp nnmail-large-newsgroup)
 114              (> number nnmail-large-newsgroup)
 115              gnus-verbose-backends
 116              (message "nnbabyl: Receiving headers...done"))
 117
 118         ;; Fold continuation lines.
 119         (set-buffer nntp-server-buffer)
 120         (goto-char (point-min))
 121         (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 122           (replace-match " " t t))
 123         'headers))))
 124
 125 (defun nnbabyl-open-server (server &optional defs)
 126   (nnheader-init-server-buffer)
 127   (if (equal server nnbabyl-current-server)
 128       t
 129     (if nnbabyl-current-server
 130         (setq nnbabyl-server-alist
 131               (cons (list nnbabyl-current-server
 132                           (nnheader-save-variables nnbabyl-server-variables))
 133                     nnbabyl-server-alist)))
 134     (let ((state (assoc server nnbabyl-server-alist)))
 135       (if state
 136           (progn
 137             (nnheader-restore-variables (nth 1 state))
 138             (setq nnbabyl-server-alist (delq state nnbabyl-server-alist)))
 139         (nnheader-set-init-variables nnbabyl-server-variables defs)))
 140     (setq nnbabyl-current-server server)))
 141
 142 (defun nnbabyl-close-server (&optional server)
 143   t)
 144
 145 (defun nnbabyl-server-opened (&optional server)
 146   (and (equal server nnbabyl-current-server)
 147        nnbabyl-mbox-buffer
 148        (buffer-name nnbabyl-mbox-buffer)
 149        nntp-server-buffer
 150        (buffer-name nntp-server-buffer)))
 151
 152 (defun nnbabyl-status-message (&optional server)
 153   nnbabyl-status-string)
 154
 155 (defun nnbabyl-request-article (article &optional newsgroup server buffer)
 156   (nnbabyl-possibly-change-newsgroup newsgroup)
 157   (if (stringp article)
 158       nil
 159     (save-excursion
 160       (set-buffer nnbabyl-mbox-buffer)
 161       (goto-char (point-min))
 162       (if (search-forward (nnbabyl-article-string article) nil t)
 163           (let (start stop)
 164             (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 165             (while (and (not (looking-at ".+:"))
 166                         (zerop (forward-line 1))))
 167             (setq start (point))
 168             (or (and (re-search-forward
 169                       (concat "^" nnbabyl-mail-delimiter) nil t)
 170                      (forward-line -1))
 171                 (goto-char (point-max)))
 172             (setq stop (point))
 173             (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 174               (set-buffer nntp-server-buffer)
 175               (erase-buffer)
 176               (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 177               (goto-char (point-min))
 178               (if (search-forward "\n*** EOOH ***" nil t)
 179                   (progn
 180                     (delete-region (progn (beginning-of-line) (point))
 181                                    (or (search-forward "\n\n" nil t)
 182                                        (point)))))
 183               t))))))
 184
 185 (defun nnbabyl-request-group (group &optional server dont-check)
 186   (save-excursion
 187     (if (nnbabyl-possibly-change-newsgroup group)
 188         (if dont-check
 189             t
 190           (nnbabyl-get-new-mail group)
 191           (save-excursion
 192             (set-buffer nntp-server-buffer)
 193             (erase-buffer)
 194             (let ((active (assoc group nnbabyl-group-alist)))
 195               (insert (format "211 %d %d %d %s\n"
 196                               (1+ (- (cdr (car (cdr active)))
 197                                      (car (car (cdr active)))))
 198                               (car (car (cdr active)))
 199                               (cdr (car (cdr active)))
 200                               (car active))))
 201             t)))))
 202
 203 (defun nnbabyl-close-group (group &optional server)
 204   t)
 205
 206 (defun nnbabyl-request-create-group (group &optional server)
 207   (nnbabyl-request-list)
 208   (setq nnbabyl-group-alist (nnmail-get-active))
 209   (or (assoc group nnbabyl-group-alist)
 210       (let (active)
 211         (setq nnbabyl-group-alist (cons (list group (setq active (cons 1 0)))
 212                                         nnbabyl-group-alist))
 213         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))
 214   t)
 215
 216 (defun nnbabyl-request-list (&optional server)
 217   (if server (nnbabyl-get-new-mail))
 218   (save-excursion
 219     (or (nnmail-find-file nnbabyl-active-file)
 220         (progn
 221           (setq nnbabyl-group-alist (nnmail-get-active))
 222           (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 223           (nnmail-find-file nnbabyl-active-file)))))
 224
 225 (defun nnbabyl-request-newgroups (date &optional server)
 226   (nnbabyl-request-list server))
 227
 228 (defun nnbabyl-request-list-newsgroups (&optional server)
 229   (setq nnbabyl-status-string "nnbabyl: LIST NEWSGROUPS is not implemented.")
 230   nil)
 231
 232 (defun nnbabyl-request-post (&optional server)
 233   (mail-send-and-exit nil))
 234
 235 (defalias 'nnbabyl-request-post-buffer 'nnmail-request-post-buffer)
 236
 237 (defun nnbabyl-request-expire-articles
 238   (articles newsgroup &optional server force)
 239   (nnbabyl-possibly-change-newsgroup newsgroup)
 240   (let* ((days (or (and nnmail-expiry-wait-function
 241                         (funcall nnmail-expiry-wait-function newsgroup))
 242                    nnmail-expiry-wait))
 243          (is-old t)
 244          rest)
 245     (nnbabyl-request-list)
 246     (setq nnbabyl-group-alist (nnmail-get-active))
 247
 248     (save-excursion
 249       (set-buffer nnbabyl-mbox-buffer)
 250       (while articles
 251         (goto-char (point-min))
 252         (if (search-forward (nnbabyl-article-string (car articles)) nil t)
 253             (if (or force
 254                     (setq is-old
 255                           (> (nnmail-days-between
 256                               (current-time-string)
 257                               (buffer-substring
 258                                (point) (progn (end-of-line) (point))))
 259                              days)))
 260                 (progn
 261                   (and gnus-verbose-backends
 262                        (message "Deleting: %s" (car articles)))
 263                   (nnbabyl-delete-mail))
 264               (setq rest (cons (car articles) rest))))
 265         (setq articles (cdr articles)))
 266       (save-buffer)
 267       ;; Find the lowest active article in this group.
 268       (let ((active (nth 1 (assoc newsgroup nnbabyl-group-alist))))
 269         (goto-char (point-min))
 270         (while (and (not (search-forward
 271                           (nnbabyl-article-string (car active)) nil t))
 272                     (<= (car active) (cdr active)))
 273           (setcar active (1+ (car active)))
 274           (goto-char (point-min))))
 275       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 276       (nconc rest articles))))
 277
 278 (defun nnbabyl-request-move-article
 279   (article group server accept-form &optional last)
 280   (nnbabyl-possibly-change-newsgroup group)
 281   (let ((buf (get-buffer-create " *nnbabyl move*"))
 282         result)
 283     (and
 284      (nnbabyl-request-article article group server)
 285      (save-excursion
 286        (set-buffer buf)
 287        (insert-buffer-substring nntp-server-buffer)
 288        (goto-char (point-min))
 289        (if (re-search-forward
 290             "^X-Gnus-Newsgroup:"
 291             (save-excursion (search-forward "\n\n" nil t) (point)) t)
 292            (delete-region (progn (beginning-of-line) (point))
 293                           (progn (forward-line 1) (point))))
 294        (setq result (eval accept-form))
 295        (kill-buffer (current-buffer))
 296        result)
 297      (save-excursion
 298        (set-buffer nnbabyl-mbox-buffer)
 299        (goto-char (point-min))
 300        (if (search-forward (nnbabyl-article-string article) nil t)
 301            (nnbabyl-delete-mail))
 302        (and last (save-buffer))))
 303     result))
 304
 305 (defun nnbabyl-request-accept-article (group &optional last)
 306   (let ((buf (current-buffer))
 307         result beg)
 308     (and
 309      (nnbabyl-request-list)
 310      (setq nnbabyl-group-alist (nnmail-get-active))
 311      (save-excursion
 312        (goto-char (point-min))
 313        (search-forward "\n\n" nil t)
 314        (forward-line -1)
 315        (save-excursion
 316          (while (re-search-backward "^X-Gnus-Newsgroup: " beg t)
 317            (delete-region (point) (progn (forward-line 1) (point)))))
 318        (let ((nnmail-split-methods
 319               (if (stringp group) (list (list group ""))
 320                 nnmail-split-methods)))
 321          (setq result (car (nnbabyl-save-mail))))
 322        (set-buffer nnbabyl-mbox-buffer)
 323        (goto-char (point-max))
 324        (search-backward "\n\^_")
 325        (goto-char (match-end 0))
 326        (insert-buffer buf)
 327        (and last (progn
 328                    (save-buffer)
 329                    (nnmail-save-active
 330                     nnbabyl-group-alist nnbabyl-active-file)))
 331        result))))
 332
 333 (defun nnbabyl-request-replace-article (article group buffer)
 334   (nnbabyl-possibly-change-newsgroup group)
 335   (save-excursion
 336     (set-buffer nnbabyl-mbox-buffer)
 337     (goto-char (point-min))
 338     (if (not (search-forward (nnbabyl-article-string article) nil t))
 339         nil
 340       (nnbabyl-delete-mail t t)
 341       (insert-buffer-substring buffer)
 342       (save-buffer)
 343       t)))
 344
 345 \f
 346 ;;; Low-Level Interface
 347
 348 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 349 ;; headers there are. If LEAVE-DELIM, don't delete the Unix mbox
 350 ;; delimeter line.
 351 (defun nnbabyl-delete-mail (&optional force leave-delim)
 352   ;; Delete the current X-Gnus-Newsgroup line.
 353   (or force
 354       (delete-region
 355        (progn (beginning-of-line) (point))
 356        (progn (forward-line 1) (point))))
 357   ;; Beginning of the article.
 358   (save-excursion
 359     (save-restriction
 360       (widen)
 361       (narrow-to-region
 362        (save-excursion
 363          (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 364          (if leave-delim (progn (forward-line 1) (point))
 365            (match-beginning 0)))
 366        (progn
 367          (forward-line 1)
 368          (or (and (re-search-forward (concat "^" nnbabyl-mail-delimiter)
 369                                      nil t)
 370                   (if (and (not (bobp)) leave-delim)
 371                       (progn (forward-line -2) (point))
 372                     (match-beginning 0)))
 373              (point-max))))
 374       (goto-char (point-min))
 375       ;; Only delete the article if no other groups owns it as well.
 376       (if (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 377           (delete-region (point-min) (point-max))))))
 378
 379 (defun nnbabyl-possibly-change-newsgroup (newsgroup)
 380   (if (or (not nnbabyl-mbox-buffer)
 381           (not (buffer-name nnbabyl-mbox-buffer)))
 382       (save-excursion (nnbabyl-read-mbox)))
 383   (or nnbabyl-group-alist
 384       (progn
 385         (nnbabyl-request-list)
 386         (setq nnbabyl-group-alist (nnmail-get-active))))
 387   (if newsgroup
 388       (if (assoc newsgroup nnbabyl-group-alist)
 389           (setq nnbabyl-current-group newsgroup)
 390         (setq nnbabyl-status-string "No such group in file")
 391         nil)))
 392
 393 (defun nnbabyl-article-string (article)
 394   (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"
 395           (int-to-string article) " "))
 396
 397 (defun nnbabyl-insert-lines ()
 398   "Insert how many lines and chars there are in the body of the mail."
 399   (let (lines chars)
 400     (save-excursion
 401       (goto-char (point-min))
 402       (if (search-forward "\n\n" nil t)
 403           (progn
 404             ;; There may be an EOOH line here...
 405             (if (looking-at "\\*\\*\\* EOOH \\*\\*\\*")
 406                 (search-forward "\n\n" nil t))
 407             (setq chars (- (point-max) (point)))
 408             (setq lines (- (count-lines (point) (point-max)) 1))
 409             ;; Move back to the end of the headers.
 410             (goto-char (point-min))
 411             (search-forward "\n\n" nil t)
 412             (forward-char -1)
 413             (save-excursion
 414               (if (re-search-backward "^Lines: " nil t)
 415                   (delete-region (point) (progn (forward-line 1) (point)))))
 416             (insert (format "Lines: %d\n" lines))
 417             chars)))))
 418
 419 (defun nnbabyl-save-mail ()
 420   ;; Called narrowed to an article.
 421   (let ((group-art (nreverse (nnmail-article-group 'nnbabyl-active-number))))
 422     (nnbabyl-insert-lines)
 423     (nnmail-insert-xref group-art)
 424     (nnbabyl-insert-newsgroup-line group-art)
 425     (run-hooks 'nnbabyl-prepare-save-mail-hook)
 426     group-art))
 427
 428 (defun nnbabyl-insert-newsgroup-line (group-art)
 429   (save-excursion
 430     (goto-char (point-min))
 431     ;; If there is a C-l at the beginning of the narrowed region, this
 432     ;; isn't really a "save", but rather a "scan".
 433     (while (looking-at "From ")
 434       (replace-match "Mail-from: From " t t)
 435       (forward-line 1))
 436     (goto-char (point-min))
 437     (or (looking-at "\^L")
 438         (save-excursion
 439           (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 440           (goto-char (point-max))
 441           (insert "\^_\n")))
 442     (if (search-forward "\n\n" nil t)
 443         (progn
 444           (forward-char -1)
 445           (while group-art
 446             (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 447                             (car (car group-art)) (cdr (car group-art))
 448                             (current-time-string)))
 449             (setq group-art (cdr group-art)))))
 450     t))
 451
 452 (defun nnbabyl-active-number (group)
 453   ;; Find the next article number in GROUP.
 454   (let ((active (car (cdr (assoc group nnbabyl-group-alist)))))
 455     (setcdr active (1+ (cdr active)))
 456     (cdr active)))
 457
 458 (defun nnbabyl-read-mbox ()
 459   (nnbabyl-request-list)
 460   (setq nnbabyl-group-alist (nnmail-get-active))
 461   (or (file-exists-p nnbabyl-mbox-file)
 462       (save-excursion
 463         (set-buffer (setq nnbabyl-mbox-buffer
 464                           (create-file-buffer nnbabyl-mbox-file)))
 465         (setq buffer-file-name nnbabyl-mbox-file)
 466         (insert "BABYL OPTIONS:\n\n\^_")
 467         (write-region (point-min) (point-max) nnbabyl-mbox-file t 'nomesg)))
 468
 469   (if (and nnbabyl-mbox-buffer
 470            (buffer-name nnbabyl-mbox-buffer)
 471            (save-excursion
 472              (set-buffer nnbabyl-mbox-buffer)
 473              (= (buffer-size) (nth 7 (file-attributes nnbabyl-mbox-file)))))
 474       ()
 475     (save-excursion
 476       (let ((delim (concat "^" nnbabyl-mail-delimiter))
 477             (buf (or (get-buffer (file-name-nondirectory nnbabyl-mbox-file))
 478                      (create-file-buffer nnbabyl-mbox-file)))
 479             start end)
 480         (set-buffer (setq nnbabyl-mbox-buffer buf))
 481         (buffer-disable-undo (current-buffer))
 482
 483         (insert-file-contents nnbabyl-mbox-file)
 484         (setq buffer-file-name nnbabyl-mbox-file)
 485         (set-buffer-modified-p nil)
 486
 487         (goto-char (point-min))
 488         (while (re-search-forward delim nil t)
 489           (setq start (match-beginning 0))
 490           (if (and
 491                (save-excursion (re-search-forward delim nil t))
 492                (not (search-forward
 493                      "\nX-Gnus-Newsgroup: "
 494                      (save-excursion
 495                        (setq end (or (and (re-search-forward delim nil t)
 496                                           (match-beginning 0))
 497                                      (point-max)))) t)))
 498               (progn
 499                 (goto-char end)
 500                 (save-excursion
 501                   (save-restriction
 502                     (goto-char start)
 503                     (narrow-to-region (1+ start) end)
 504                     (nnbabyl-save-mail))))))
 505         (and (buffer-modified-p (current-buffer)) (save-buffer))
 506         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))))
 507
 508 (defun nnbabyl-remove-incoming-delims ()
 509   (goto-char (point-min))
 510   (while (search-forward "\^_" nil t)
 511     (replace-match "?" t t)))
 512
 513 (defun nnbabyl-get-new-mail (&optional group)
 514   "Read new incoming mail."
 515   (let* ((spools (nnmail-get-spool-files group))
 516          (group-in group)
 517          incoming incomings)
 518     (nnbabyl-read-mbox)
 519     (if (or (not nnbabyl-get-new-mail) (not nnmail-spool-file))
 520         ()
 521       ;; We go through all the existing spool files and split the
 522       ;; mail from each.
 523       (while spools
 524         (and
 525          (file-exists-p (car spools))
 526          (> (nth 7 (file-attributes (car spools))) 0)
 527          (progn
 528            (and gnus-verbose-backends
 529                 (message "nnbabyl: Reading incoming mail..."))
 530            (setq incoming
 531                  (nnmail-move-inbox
 532                   (car spools) (concat nnbabyl-mbox-file "-Incoming")))
 533            (setq incomings (cons incoming incomings))
 534            (save-excursion
 535              (setq group (nnmail-get-split-group (car spools) group-in))
 536              (let* ((nnmail-prepare-incoming-hook
 537                      (cons 'nnbabyl-remove-incoming-delims
 538                            nnmail-prepare-incoming-hook))
 539                     in-buf)
 540                (setq in-buf (nnmail-split-incoming
 541                              incoming 'nnbabyl-save-mail t group))
 542                (set-buffer in-buf)
 543                (goto-char (point-min))
 544                (while (search-forward "\n\^_\n" nil t)
 545                  (delete-char -1))
 546                (set-buffer nnbabyl-mbox-buffer)
 547                (goto-char (point-max))
 548                (search-backward "\n\^_" nil t)
 549                (goto-char (match-end 0))
 550                (insert-buffer-substring in-buf)
 551                (kill-buffer in-buf)))))
 552         (setq spools (cdr spools)))
 553       ;; If we did indeed read any incoming spools, we save all info.
 554       (and (buffer-modified-p nnbabyl-mbox-buffer)
 555            (save-excursion
 556              (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 557              (set-buffer nnbabyl-mbox-buffer)
 558              (save-buffer)))
 559       (if incomings (run-hooks 'nnmail-read-incoming-hook))
 560       (while incomings
 561         (and nnmail-delete-incoming
 562              (file-writable-p incoming)
 563              (delete-file incoming))
 564         (setq incomings (cdr incomings))))))
 565
 566 (provide 'nnbabyl)
 567
 568 ;;; nnbabyl.el ends here