cgit.sxemacs.org Git - gnus/blob - lisp/nnbabyl.el

   1 ;;; nnbabyl.el --- rmail mbox access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1099, 2000, 2001
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; For an overview of what the interface functions do, please see the
  30 ;; Gnus sources.
  31
  32 ;;; Code:
  33
  34 (require 'nnheader)
  35 (condition-case nil
  36     (require 'rmail)
  37   (t (nnheader-message
  38       5 "Ignore rmail errors from this file, you don't have rmail")))
  39 (require 'nnmail)
  40 (require 'nnoo)
  41 (eval-when-compile (require 'cl))
  42
  43 (nnoo-declare nnbabyl)
  44
  45 (defvoo nnbabyl-mbox-file (expand-file-name "~/RMAIL")
  46   "The name of the rmail box file in the users home directory.")
  47
  48 (defvoo nnbabyl-active-file (expand-file-name "~/.rmail-active")
  49   "The name of the active file for the rmail box.")
  50
  51 (defvoo nnbabyl-get-new-mail t
  52   "If non-nil, nnbabyl will check the incoming mail file and split the mail.")
  53
  54
  55 (defvoo nnbabyl-prepare-save-mail-hook nil
  56   "Hook run narrowed to an article before saving.")
  57
  58 \f
  59
  60 (defvar nnbabyl-mail-delimiter "\^_")
  61
  62 (defconst nnbabyl-version "nnbabyl 1.0"
  63   "nnbabyl version.")
  64
  65 (defvoo nnbabyl-mbox-buffer nil)
  66 (defvoo nnbabyl-current-group nil)
  67 (defvoo nnbabyl-status-string "")
  68 (defvoo nnbabyl-group-alist nil)
  69 (defvoo nnbabyl-active-timestamp nil)
  70
  71 (defvoo nnbabyl-previous-buffer-mode nil)
  72
  73 (eval-and-compile
  74   (autoload 'gnus-set-text-properties "gnus-ems"))
  75
  76 \f
  77
  78 ;;; Interface functions
  79
  80 (nnoo-define-basics nnbabyl)
  81
  82 (deffoo nnbabyl-retrieve-headers (articles &optional group server fetch-old)
  83   (save-excursion
  84     (set-buffer nntp-server-buffer)
  85     (erase-buffer)
  86     (let ((number (length articles))
  87           (count 0)
  88           (delim (concat "^" nnbabyl-mail-delimiter))
  89           article art-string start stop)
  90       (nnbabyl-possibly-change-newsgroup group server)
  91       (while (setq article (pop articles))
  92         (setq art-string (nnbabyl-article-string article))
  93         (set-buffer nnbabyl-mbox-buffer)
  94         (end-of-line)
  95         (when (or (search-forward art-string nil t)
  96                   (search-backward art-string nil t))
  97           (unless (re-search-backward delim nil t)
  98             (goto-char (point-min)))
  99           (while (and (not (looking-at ".+:"))
 100                       (zerop (forward-line 1))))
 101           (setq start (point))
 102           (search-forward "\n\n" nil t)
 103           (setq stop (1- (point)))
 104           (set-buffer nntp-server-buffer)
 105           (insert "221 ")
 106           (princ article (current-buffer))
 107           (insert " Article retrieved.\n")
 108           (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 109           (goto-char (point-max))
 110           (insert ".\n"))
 111         (and (numberp nnmail-large-newsgroup)
 112              (> number nnmail-large-newsgroup)
 113              (zerop (% (incf count) 20))
 114              (nnheader-message 5 "nnbabyl: Receiving headers... %d%%"
 115                                (/ (* count 100) number))))
 116
 117       (and (numberp nnmail-large-newsgroup)
 118            (> number nnmail-large-newsgroup)
 119            (nnheader-message 5 "nnbabyl: Receiving headers...done"))
 120
 121       (set-buffer nntp-server-buffer)
 122       (nnheader-fold-continuation-lines)
 123       'headers)))
 124
 125 (deffoo nnbabyl-open-server (server &optional defs)
 126   (nnoo-change-server 'nnbabyl server defs)
 127   (nnbabyl-create-mbox)
 128   (cond
 129    ((not (file-exists-p nnbabyl-mbox-file))
 130     (nnbabyl-close-server)
 131     (nnheader-report 'nnbabyl "No such file: %s" nnbabyl-mbox-file))
 132    ((file-directory-p nnbabyl-mbox-file)
 133     (nnbabyl-close-server)
 134     (nnheader-report 'nnbabyl "Not a regular file: %s" nnbabyl-mbox-file))
 135    (t
 136     (nnheader-report 'nnbabyl "Opened server %s using mbox %s" server
 137                      nnbabyl-mbox-file)
 138     t)))
 139
 140 (deffoo nnbabyl-close-server (&optional server)
 141   ;; Restore buffer mode.
 142   (when (and (nnbabyl-server-opened)
 143              nnbabyl-previous-buffer-mode)
 144     (save-excursion
 145       (set-buffer nnbabyl-mbox-buffer)
 146       (narrow-to-region
 147        (caar nnbabyl-previous-buffer-mode)
 148        (cdar nnbabyl-previous-buffer-mode))
 149       (funcall (cdr nnbabyl-previous-buffer-mode))))
 150   (nnoo-close-server 'nnbabyl server)
 151   (setq nnbabyl-mbox-buffer nil)
 152   t)
 153
 154 (deffoo nnbabyl-server-opened (&optional server)
 155   (and (nnoo-current-server-p 'nnbabyl server)
 156        nnbabyl-mbox-buffer
 157        (buffer-name nnbabyl-mbox-buffer)
 158        nntp-server-buffer
 159        (buffer-name nntp-server-buffer)))
 160
 161 (deffoo nnbabyl-request-article (article &optional newsgroup server buffer)
 162   (nnbabyl-possibly-change-newsgroup newsgroup server)
 163   (save-excursion
 164     (set-buffer nnbabyl-mbox-buffer)
 165     (goto-char (point-min))
 166     (when (search-forward (nnbabyl-article-string article) nil t)
 167       (let (start stop summary-line)
 168         (unless (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 169           (goto-char (point-min))
 170           (end-of-line))
 171         (while (and (not (looking-at ".+:"))
 172                     (zerop (forward-line 1))))
 173         (setq start (point))
 174         (or (when (re-search-forward
 175                    (concat "^" nnbabyl-mail-delimiter) nil t)
 176               (beginning-of-line)
 177               t)
 178             (goto-char (point-max)))
 179         (setq stop (point))
 180         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 181           (set-buffer nntp-server-buffer)
 182           (erase-buffer)
 183           (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 184           (goto-char (point-min))
 185           ;; If there is an EOOH header, then we have to remove some
 186           ;; duplicated headers.
 187           (setq summary-line (looking-at "Summary-line:"))
 188           (when (search-forward "\n*** EOOH ***" nil t)
 189             (if summary-line
 190                 ;; The headers to be deleted are located before the
 191                 ;; EOOH line...
 192                 (delete-region (point-min) (progn (forward-line 1)
 193                                                   (point)))
 194               ;; ...or after.
 195               (delete-region (progn (beginning-of-line) (point))
 196                              (or (search-forward "\n\n" nil t)
 197                                  (point)))))
 198           (if (numberp article)
 199               (cons nnbabyl-current-group article)
 200             (nnbabyl-article-group-number)))))))
 201
 202 (deffoo nnbabyl-request-group (group &optional server dont-check)
 203   (let ((active (cadr (assoc group nnbabyl-group-alist))))
 204     (save-excursion
 205       (cond
 206        ((or (null active)
 207             (null (nnbabyl-possibly-change-newsgroup group server)))
 208         (nnheader-report 'nnbabyl "No such group: %s" group))
 209        (dont-check
 210         (nnheader-report 'nnbabyl "Selected group %s" group)
 211         (nnheader-insert ""))
 212        (t
 213         (nnheader-report 'nnbabyl "Selected group %s" group)
 214         (nnheader-insert "211 %d %d %d %s\n"
 215                          (1+ (- (cdr active) (car active)))
 216                          (car active) (cdr active) group))))))
 217
 218 (deffoo nnbabyl-request-scan (&optional group server)
 219   (nnbabyl-possibly-change-newsgroup group server)
 220   (nnbabyl-read-mbox)
 221   (nnmail-get-new-mail
 222    'nnbabyl
 223    (lambda ()
 224      (save-excursion
 225        (set-buffer nnbabyl-mbox-buffer)
 226        (save-buffer)))
 227    (file-name-directory nnbabyl-mbox-file)
 228    group
 229    (lambda ()
 230      (save-excursion
 231        (let ((in-buf (current-buffer)))
 232          (goto-char (point-min))
 233          (while (search-forward "\n\^_\n" nil t)
 234            (delete-char -1))
 235          (set-buffer nnbabyl-mbox-buffer)
 236          (goto-char (point-max))
 237          (search-backward "\n\^_" nil t)
 238          (goto-char (match-end 0))
 239          (insert-buffer-substring in-buf)))
 240      (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))))
 241
 242 (deffoo nnbabyl-close-group (group &optional server)
 243   t)
 244
 245 (deffoo nnbabyl-request-create-group (group &optional server args)
 246   (nnmail-activate 'nnbabyl)
 247   (unless (assoc group nnbabyl-group-alist)
 248     (push (list group (cons 1 0))
 249           nnbabyl-group-alist)
 250     (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))
 251   t)
 252
 253 (deffoo nnbabyl-request-list (&optional server)
 254   (save-excursion
 255     (nnmail-find-file nnbabyl-active-file)
 256     (setq nnbabyl-group-alist (nnmail-get-active))
 257     t))
 258
 259 (deffoo nnbabyl-request-newgroups (date &optional server)
 260   (nnbabyl-request-list server))
 261
 262 (deffoo nnbabyl-request-list-newsgroups (&optional server)
 263   (nnheader-report 'nnbabyl "nnbabyl: LIST NEWSGROUPS is not implemented."))
 264
 265 (deffoo nnbabyl-request-expire-articles
 266     (articles newsgroup &optional server force)
 267   (nnbabyl-possibly-change-newsgroup newsgroup server)
 268   (let* ((is-old t)
 269          rest)
 270     (nnmail-activate 'nnbabyl)
 271
 272     (save-excursion
 273       (set-buffer nnbabyl-mbox-buffer)
 274       (gnus-set-text-properties (point-min) (point-max) nil)
 275       (while (and articles is-old)
 276         (goto-char (point-min))
 277         (when (search-forward (nnbabyl-article-string (car articles)) nil t)
 278           (if (setq is-old
 279                     (nnmail-expired-article-p
 280                      newsgroup
 281                      (buffer-substring
 282                       (point) (progn (end-of-line) (point))) force))
 283               (progn
 284                 (unless (eq nnmail-expiry-target 'delete)
 285                   (with-temp-buffer
 286                     (nnbabyl-request-article (car articles)
 287                                              newsgroup server
 288                                              (current-buffer))
 289                     (let ((nnml-current-directory nil))
 290                       (nnmail-expiry-target-group
 291                        nnmail-expiry-target newsgroup)))
 292                   (nnbabyl-possibly-change-newsgroup newsgroup server))
 293                 (nnheader-message 5 "Deleting article %d in %s..."
 294                                   (car articles) newsgroup)
 295                 (nnbabyl-delete-mail))
 296             (push (car articles) rest)))
 297         (setq articles (cdr articles)))
 298       (save-buffer)
 299       ;; Find the lowest active article in this group.
 300       (let ((active (nth 1 (assoc newsgroup nnbabyl-group-alist))))
 301         (goto-char (point-min))
 302         (while (and (not (search-forward
 303                           (nnbabyl-article-string (car active)) nil t))
 304                     (<= (car active) (cdr active)))
 305           (setcar active (1+ (car active)))
 306           (goto-char (point-min))))
 307       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 308       (nconc rest articles))))
 309
 310 (deffoo nnbabyl-request-move-article
 311     (article group server accept-form &optional last)
 312   (let ((buf (get-buffer-create " *nnbabyl move*"))
 313         result)
 314     (and
 315      (nnbabyl-request-article article group server)
 316      (save-excursion
 317        (set-buffer buf)
 318        (insert-buffer-substring nntp-server-buffer)
 319        (goto-char (point-min))
 320        (while (re-search-forward
 321                "^X-Gnus-Newsgroup:"
 322                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 323          (delete-region (progn (beginning-of-line) (point))
 324                         (progn (forward-line 1) (point))))
 325        (setq result (eval accept-form))
 326        (kill-buffer (current-buffer))
 327        result)
 328      (save-excursion
 329        (nnbabyl-possibly-change-newsgroup group server)
 330        (set-buffer nnbabyl-mbox-buffer)
 331        (goto-char (point-min))
 332        (if (search-forward (nnbabyl-article-string article) nil t)
 333            (nnbabyl-delete-mail))
 334        (and last (save-buffer))))
 335     result))
 336
 337 (deffoo nnbabyl-request-accept-article (group &optional server last)
 338   (nnbabyl-possibly-change-newsgroup group server)
 339   (nnmail-check-syntax)
 340   (let ((buf (current-buffer))
 341         result beg)
 342     (and
 343      (nnmail-activate 'nnbabyl)
 344      (save-excursion
 345        (goto-char (point-min))
 346        (search-forward "\n\n" nil t)
 347        (forward-line -1)
 348        (save-excursion
 349          (while (re-search-backward "^X-Gnus-Newsgroup: " beg t)
 350            (delete-region (point) (progn (forward-line 1) (point)))))
 351        (when nnmail-cache-accepted-message-ids
 352          (nnmail-cache-insert (nnmail-fetch-field "message-id")
 353                               group
 354                               (nnmail-fetch-field "subject")))
 355        (setq result
 356              (if (stringp group)
 357                  (list (cons group (nnbabyl-active-number group)))
 358                (nnmail-article-group 'nnbabyl-active-number)))
 359        (if (and (null result)
 360                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 361            (setq result 'junk)
 362          (setq result (car (nnbabyl-save-mail result))))
 363        (set-buffer nnbabyl-mbox-buffer)
 364        (goto-char (point-max))
 365        (search-backward "\n\^_")
 366        (goto-char (match-end 0))
 367        (insert-buffer-substring buf)
 368        (when last
 369          (when nnmail-cache-accepted-message-ids
 370            (nnmail-cache-insert (nnmail-fetch-field "message-id")
 371                                 group
 372                                 (nnmail-fetch-field "subject")))
 373          (save-buffer)
 374          (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))
 375        result))))
 376
 377 (deffoo nnbabyl-request-replace-article (article group buffer)
 378   (nnbabyl-possibly-change-newsgroup group)
 379   (save-excursion
 380     (set-buffer nnbabyl-mbox-buffer)
 381     (goto-char (point-min))
 382     (if (not (search-forward (nnbabyl-article-string article) nil t))
 383         nil
 384       (nnbabyl-delete-mail t t)
 385       (insert-buffer-substring buffer)
 386       (save-buffer)
 387       t)))
 388
 389 (deffoo nnbabyl-request-delete-group (group &optional force server)
 390   (nnbabyl-possibly-change-newsgroup group server)
 391   ;; Delete all articles in GROUP.
 392   (if (not force)
 393       ()                                ; Don't delete the articles.
 394     (save-excursion
 395       (set-buffer nnbabyl-mbox-buffer)
 396       (goto-char (point-min))
 397       ;; Delete all articles in this group.
 398       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"))
 399             found)
 400         (while (search-forward ident nil t)
 401           (setq found t)
 402           (nnbabyl-delete-mail))
 403         (when found
 404           (save-buffer)))))
 405   ;; Remove the group from all structures.
 406   (setq nnbabyl-group-alist
 407         (delq (assoc group nnbabyl-group-alist) nnbabyl-group-alist)
 408         nnbabyl-current-group nil)
 409   ;; Save the active file.
 410   (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 411   t)
 412
 413 (deffoo nnbabyl-request-rename-group (group new-name &optional server)
 414   (nnbabyl-possibly-change-newsgroup group server)
 415   (save-excursion
 416     (set-buffer nnbabyl-mbox-buffer)
 417     (goto-char (point-min))
 418     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"))
 419           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 420           found)
 421       (while (search-forward ident nil t)
 422         (replace-match new-ident t t)
 423         (setq found t))
 424       (when found
 425         (save-buffer))))
 426   (let ((entry (assoc group nnbabyl-group-alist)))
 427     (and entry (setcar entry new-name))
 428     (setq nnbabyl-current-group nil)
 429     ;; Save the new group alist.
 430     (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 431     t))
 432
 433 \f
 434 ;;; Internal functions.
 435
 436 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 437 ;; headers there are.  If LEAVE-DELIM, don't delete the Unix mbox
 438 ;; delimiter line.
 439 (defun nnbabyl-delete-mail (&optional force leave-delim)
 440   ;; Delete the current X-Gnus-Newsgroup line.
 441   (unless force
 442     (delete-region
 443      (progn (beginning-of-line) (point))
 444      (progn (forward-line 1) (point))))
 445   ;; Beginning of the article.
 446   (save-excursion
 447     (save-restriction
 448       (widen)
 449       (narrow-to-region
 450        (save-excursion
 451          (unless (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 452            (goto-char (point-min))
 453            (end-of-line))
 454          (if leave-delim (progn (forward-line 1) (point))
 455            (match-beginning 0)))
 456        (progn
 457          (forward-line 1)
 458          (or (and (re-search-forward (concat "^" nnbabyl-mail-delimiter)
 459                                      nil t)
 460                   (match-beginning 0))
 461              (point-max))))
 462       (goto-char (point-min))
 463       ;; Only delete the article if no other groups owns it as well.
 464       (when (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 465         (delete-region (point-min) (point-max))))))
 466
 467 (defun nnbabyl-possibly-change-newsgroup (newsgroup &optional server)
 468   (when (and server
 469              (not (nnbabyl-server-opened server)))
 470     (nnbabyl-open-server server))
 471   (when (or (not nnbabyl-mbox-buffer)
 472             (not (buffer-name nnbabyl-mbox-buffer)))
 473     (save-excursion (nnbabyl-read-mbox)))
 474   (unless nnbabyl-group-alist
 475     (nnmail-activate 'nnbabyl))
 476   (if newsgroup
 477       (if (assoc newsgroup nnbabyl-group-alist)
 478           (setq nnbabyl-current-group newsgroup)
 479         (nnheader-report 'nnbabyl "No such group in file"))
 480     t))
 481
 482 (defun nnbabyl-article-string (article)
 483   (if (numberp article)
 484       (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"
 485               (int-to-string article) " ")
 486     (concat "\nMessage-ID: " article)))
 487
 488 (defun nnbabyl-article-group-number ()
 489   (save-excursion
 490     (goto-char (point-min))
 491     (when (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 492                              nil t)
 493       (cons (buffer-substring (match-beginning 1) (match-end 1))
 494             (string-to-int
 495              (buffer-substring (match-beginning 2) (match-end 2)))))))
 496
 497 (defun nnbabyl-insert-lines ()
 498   "Insert how many lines and chars there are in the body of the mail."
 499   (let (lines chars)
 500     (save-excursion
 501       (goto-char (point-min))
 502       (when (search-forward "\n\n" nil t)
 503         ;; There may be an EOOH line here...
 504         (when (looking-at "\\*\\*\\* EOOH \\*\\*\\*")
 505           (search-forward "\n\n" nil t))
 506         (setq chars (- (point-max) (point))
 507               lines (max (- (count-lines (point) (point-max)) 1) 0))
 508         ;; Move back to the end of the headers.
 509         (goto-char (point-min))
 510         (search-forward "\n\n" nil t)
 511         (forward-char -1)
 512         (save-excursion
 513           (when (re-search-backward "^Lines: " nil t)
 514             (delete-region (point) (progn (forward-line 1) (point)))))
 515         (insert (format "Lines: %d\n" lines))
 516         chars))))
 517
 518 (defun nnbabyl-save-mail (group-art)
 519   ;; Called narrowed to an article.
 520   (nnbabyl-insert-lines)
 521   (nnmail-insert-xref group-art)
 522   (nnbabyl-insert-newsgroup-line group-art)
 523   (run-hooks 'nnbabyl-prepare-save-mail-hook)
 524   group-art)
 525
 526 (defun nnbabyl-insert-newsgroup-line (group-art)
 527   (save-excursion
 528     (goto-char (point-min))
 529     (while (looking-at "From ")
 530       (replace-match "Mail-from: From " t t)
 531       (forward-line 1))
 532     ;; If there is a C-l at the beginning of the narrowed region, this
 533     ;; isn't really a "save", but rather a "scan".
 534     (goto-char (point-min))
 535     (unless (looking-at "\^L")
 536       (save-excursion
 537         (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 538         (goto-char (point-max))
 539         (insert "\^_\n")))
 540     (when (search-forward "\n\n" nil t)
 541       (forward-char -1)
 542       (while group-art
 543         (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 544                         (caar group-art) (cdar group-art)
 545                         (current-time-string)))
 546         (setq group-art (cdr group-art))))
 547     t))
 548
 549 (defun nnbabyl-active-number (group)
 550   ;; Find the next article number in GROUP.
 551   (let ((active (cadr (assoc group nnbabyl-group-alist))))
 552     (if active
 553         (setcdr active (1+ (cdr active)))
 554       ;; This group is new, so we create a new entry for it.
 555       ;; This might be a bit naughty... creating groups on the drop of
 556       ;; a hat, but I don't know...
 557       (push (list group (setq active (cons 1 1)))
 558             nnbabyl-group-alist))
 559     (cdr active)))
 560
 561 (defun nnbabyl-create-mbox ()
 562   (unless (file-exists-p nnbabyl-mbox-file)
 563     ;; Create a new, empty RMAIL mbox file.
 564     (save-excursion
 565       (set-buffer (setq nnbabyl-mbox-buffer
 566                         (create-file-buffer nnbabyl-mbox-file)))
 567       (setq buffer-file-name nnbabyl-mbox-file)
 568       (insert "BABYL OPTIONS:\n\n\^_")
 569       (nnmail-write-region
 570        (point-min) (point-max) nnbabyl-mbox-file t 'nomesg))))
 571
 572 (defun nnbabyl-read-mbox ()
 573   (nnmail-activate 'nnbabyl)
 574   (nnbabyl-create-mbox)
 575
 576   (unless (and nnbabyl-mbox-buffer
 577                (buffer-name nnbabyl-mbox-buffer)
 578                (save-excursion
 579                  (set-buffer nnbabyl-mbox-buffer)
 580                  (= (buffer-size) (nnheader-file-size nnbabyl-mbox-file))))
 581     ;; This buffer has changed since we read it last.  Possibly.
 582     (save-excursion
 583       (let ((delim (concat "^" nnbabyl-mail-delimiter))
 584             (alist nnbabyl-group-alist)
 585             start end number)
 586         (set-buffer (setq nnbabyl-mbox-buffer
 587                           (nnheader-find-file-noselect
 588                            nnbabyl-mbox-file nil t)))
 589         ;; Save previous buffer mode.
 590         (setq nnbabyl-previous-buffer-mode
 591               (cons (cons (point-min) (point-max))
 592                     major-mode))
 593
 594         (buffer-disable-undo)
 595         (widen)
 596         (setq buffer-read-only nil)
 597         (fundamental-mode)
 598
 599         ;; Go through the group alist and compare against
 600         ;; the rmail file.
 601         (while alist
 602           (goto-char (point-max))
 603           (when (and (re-search-backward
 604                       (format "^X-Gnus-Newsgroup: %s:\\([0-9]+\\) "
 605                               (caar alist))
 606                       nil t)
 607                      (> (setq number
 608                               (string-to-number
 609                                (buffer-substring
 610                                 (match-beginning 1) (match-end 1))))
 611                         (cdadar alist)))
 612             (setcdr (cadar alist) number))
 613           (setq alist (cdr alist)))
 614
 615         ;; We go through the mbox and make sure that each and
 616         ;; every mail belongs to some group or other.
 617         (goto-char (point-min))
 618         (if (looking-at "\^L")
 619             (setq start (point))
 620           (re-search-forward delim nil t)
 621           (setq start (match-end 0)))
 622         (while (re-search-forward delim nil t)
 623           (setq end (match-end 0))
 624           (unless (search-backward "\nX-Gnus-Newsgroup: " start t)
 625             (goto-char end)
 626             (save-excursion
 627               (save-restriction
 628                 (narrow-to-region (goto-char start) end)
 629                 (nnbabyl-save-mail
 630                  (nnmail-article-group 'nnbabyl-active-number))
 631                 (setq end (point-max)))))
 632           (goto-char (setq start end)))
 633         (when (buffer-modified-p (current-buffer))
 634           (save-buffer))
 635         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))))
 636
 637 (defun nnbabyl-remove-incoming-delims ()
 638   (goto-char (point-min))
 639   (while (search-forward "\^_" nil t)
 640     (replace-match "?" t t)))
 641
 642 (defun nnbabyl-check-mbox ()
 643   "Go through the nnbabyl mbox and make sure that no article numbers are reused."
 644   (interactive)
 645   (let ((idents (make-vector 1000 0))
 646         id)
 647     (save-excursion
 648       (when (or (not nnbabyl-mbox-buffer)
 649                 (not (buffer-name nnbabyl-mbox-buffer)))
 650         (nnbabyl-read-mbox))
 651       (set-buffer nnbabyl-mbox-buffer)
 652       (goto-char (point-min))
 653       (while (re-search-forward "^X-Gnus-Newsgroup: \\([^ ]+\\) "  nil t)
 654         (if (intern-soft (setq id (match-string 1)) idents)
 655             (progn
 656               (delete-region (progn (beginning-of-line) (point))
 657                              (progn (forward-line 1) (point)))
 658               (nnheader-message 7 "Moving %s..." id)
 659               (nnbabyl-save-mail
 660                (nnmail-article-group 'nnbabyl-active-number)))
 661           (intern id idents)))
 662       (when (buffer-modified-p (current-buffer))
 663         (save-buffer))
 664       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 665       (nnheader-message 5 ""))))
 666
 667 (provide 'nnbabyl)
 668
 669 ;;; nnbabyl.el ends here