cgit.sxemacs.org Git - gnus/blob - lisp/mm-view.el

   1 ;;; mm-view.el --- Functions for viewing MIME objects
   2 ;; Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (eval-when-compile (require 'cl))
  27 (require 'mail-parse)
  28 (require 'mailcap)
  29 (require 'mm-bodies)
  30 (require 'mm-decode)
  31
  32 (eval-and-compile
  33   (autoload 'gnus-article-prepare-display "gnus-art")
  34   (autoload 'vcard-parse-string "vcard")
  35   (autoload 'vcard-format-string "vcard")
  36   (autoload 'fill-flowed "flow-fill")
  37   (autoload 'diff-mode "diff-mode"))
  38
  39 ;;;
  40 ;;; Functions for displaying various formats inline
  41 ;;;
  42 (defun mm-inline-image-emacs (handle)
  43   (let ((b (point-marker))
  44         buffer-read-only)
  45     (insert "\n")
  46     (put-image (mm-get-image handle) b)
  47     (mm-handle-set-undisplayer
  48      handle
  49      `(lambda () (remove-images ,b (1+ ,b))))))
  50
  51 (defun mm-inline-image-xemacs (handle)
  52   (let ((b (point))
  53         (annot (make-annotation (mm-get-image handle) nil 'text))
  54         buffer-read-only)
  55     (insert "\n")
  56     (mm-handle-set-undisplayer
  57      handle
  58      `(lambda ()
  59         (let (buffer-read-only)
  60           (delete-annotation ,annot)
  61           (delete-region ,(set-marker (make-marker) b)
  62                          ,(set-marker (make-marker) (point))))))
  63     (set-extent-property annot 'mm t)
  64     (set-extent-property annot 'duplicable t)))
  65
  66 (eval-and-compile
  67   (if (string-match "XEmacs" (emacs-version))
  68       (defalias 'mm-inline-image 'mm-inline-image-xemacs)
  69     (defalias 'mm-inline-image 'mm-inline-image-emacs)))
  70
  71 (defvar mm-w3-setup nil)
  72 (defun mm-setup-w3 ()
  73   (unless mm-w3-setup
  74     (require 'w3)
  75     (w3-do-setup)
  76     (require 'url)
  77     (require 'w3-vars)
  78     (require 'url-vars)
  79     (setq mm-w3-setup t)))
  80
  81 (defun mm-inline-text (handle)
  82   (let ((type (mm-handle-media-subtype handle))
  83         text buffer-read-only)
  84     (cond
  85      ((equal type "html")
  86       (mm-setup-w3)
  87       (setq text (mm-get-part handle))
  88       (let ((b (point))
  89             (url-standalone-mode t)
  90             (url-current-object
  91              (url-generic-parse-url (format "cid:%s" (mm-handle-id handle))))
  92             (width (window-width))
  93             (charset (mail-content-type-get
  94                       (mm-handle-type handle) 'charset)))
  95         (save-excursion
  96           (insert text)
  97           (save-restriction
  98             (narrow-to-region b (point))
  99             (goto-char (point-min))
 100             (if (or (and (boundp 'w3-meta-content-type-charset-regexp)
 101                          (re-search-forward
 102                           w3-meta-content-type-charset-regexp nil t))
 103                     (and (boundp 'w3-meta-charset-content-type-regexp)
 104                          (re-search-forward
 105                           w3-meta-charset-content-type-regexp nil t)))
 106                 (setq charset (or (w3-coding-system-for-mime-charset
 107                                    (buffer-substring-no-properties
 108                                     (match-beginning 2)
 109                                     (match-end 2)))
 110                                   charset)))
 111             (delete-region (point-min) (point-max))
 112             (insert (mm-decode-string text charset))
 113             (save-window-excursion
 114               (save-restriction
 115                 (let ((w3-strict-width width)
 116                       (url-standalone-mode t))
 117                   (condition-case var
 118                       (w3-region (point-min) (point-max))
 119                     (error)))))
 120             (mm-handle-set-undisplayer
 121              handle
 122              `(lambda ()
 123                 (let (buffer-read-only)
 124                   (if (functionp 'remove-specifier)
 125                       (mapcar (lambda (prop)
 126                                 (remove-specifier
 127                                  (face-property 'default prop)
 128                                  (current-buffer)))
 129                               '(background background-pixmap foreground)))
 130                   (delete-region ,(point-min-marker)
 131                                  ,(point-max-marker)))))))))
 132      ((or (equal type "enriched")
 133           (equal type "richtext"))
 134       (save-excursion
 135         (mm-with-unibyte-buffer
 136           (mm-insert-part handle)
 137           (save-window-excursion
 138             (enriched-decode (point-min) (point-max))
 139             (setq text (buffer-string)))))
 140       (mm-insert-inline handle text))
 141      ((equal type "x-vcard")
 142       (mm-insert-inline
 143        handle
 144        (concat "\n-- \n"
 145                (if (fboundp 'vcard-pretty-print)
 146                    (vcard-pretty-print (mm-get-part handle))
 147                  (vcard-format-string
 148                   (vcard-parse-string (mm-get-part handle)
 149                                       'vcard-standard-filter))))))
 150      (t
 151       (let ((b (point))
 152             (charset (mail-content-type-get
 153                       (mm-handle-type handle) 'charset)))
 154         (if (or (eq charset 'gnus-decoded)
 155                 ;; This is probably not entirely correct, but
 156                 ;; makes rfc822 parts with embedded multiparts work.
 157                 (eq mail-parse-charset 'gnus-decoded))
 158             (mm-insert-part handle)
 159           (insert (mm-decode-string (mm-get-part handle) charset)))
 160         (when (and (equal type "plain")
 161                    (equal (cdr (assoc 'format (mm-handle-type handle)))
 162                           "flowed"))
 163           (save-restriction
 164             (narrow-to-region b (point))
 165             (goto-char b)
 166             (fill-flowed)
 167             (goto-char (point-max))))
 168         (save-restriction
 169           (narrow-to-region b (point))
 170           (set-text-properties (point-min) (point-max) nil)
 171           (mm-handle-set-undisplayer
 172            handle
 173            `(lambda ()
 174               (let (buffer-read-only)
 175                 (delete-region ,(point-min-marker)
 176                                ,(point-max-marker)))))))))))
 177
 178 (defun mm-insert-inline (handle text)
 179   "Insert TEXT inline from HANDLE."
 180   (let ((b (point)))
 181     (insert text)
 182     (mm-handle-set-undisplayer
 183      handle
 184      `(lambda ()
 185         (let (buffer-read-only)
 186           (delete-region ,(set-marker (make-marker) b)
 187                          ,(set-marker (make-marker) (point))))))))
 188
 189 (defun mm-inline-audio (handle)
 190   (message "Not implemented"))
 191
 192 (defun mm-view-sound-file ()
 193   (message "Not implemented"))
 194
 195 (defun mm-w3-prepare-buffer ()
 196   (require 'w3)
 197   (let ((url-standalone-mode t))
 198     (w3-prepare-buffer)))
 199
 200 (defun mm-view-message ()
 201   (mm-enable-multibyte)
 202   (let (handles)
 203     (let (gnus-article-mime-handles)
 204       ;; Double decode problem may happen.  See mm-inline-message.
 205       (run-hooks 'gnus-article-decode-hook)
 206       (gnus-article-prepare-display)
 207       (setq handles gnus-article-mime-handles))
 208     (when handles
 209       (setq gnus-article-mime-handles
 210             (nconc gnus-article-mime-handles
 211                    (if (listp (car handles))
 212                        handles (list handles))))))
 213   (fundamental-mode)
 214   (goto-char (point-min)))
 215
 216 (defun mm-inline-message (handle)
 217   (let ((b (point))
 218         (charset (mail-content-type-get
 219                   (mm-handle-type handle) 'charset))
 220         gnus-displaying-mime handles)
 221     (when (and charset
 222                (stringp charset))
 223       (setq charset (intern (downcase charset)))
 224       (when (eq charset 'us-ascii)
 225         (setq charset nil)))
 226     (save-excursion
 227       (save-restriction
 228         (narrow-to-region b b)
 229         (mm-insert-part handle)
 230         (let (gnus-article-mime-handles
 231               ;; disable prepare hook
 232               gnus-article-prepare-hook
 233               (gnus-newsgroup-charset
 234                (or charset gnus-newsgroup-charset)))
 235           (run-hooks 'gnus-article-decode-hook)
 236           (gnus-article-prepare-display)
 237           (setq handles gnus-article-mime-handles))
 238         (goto-char (point-max))
 239         (unless (bolp)
 240           (insert "\n"))
 241         (insert "----------\n\n")
 242         (when handles
 243           (setq gnus-article-mime-handles
 244                 (nconc gnus-article-mime-handles
 245                        (if (listp (car handles))
 246                            handles (list handles)))))
 247         (mm-handle-set-undisplayer
 248          handle
 249          `(lambda ()
 250             (let (buffer-read-only)
 251               (condition-case nil
 252                   ;; This is only valid on XEmacs.
 253                   (mapcar (lambda (prop)
 254                             (remove-specifier
 255                              (face-property 'default prop) (current-buffer)))
 256                           '(background background-pixmap foreground))
 257                 (error nil))
 258               (delete-region ,(point-min-marker) ,(point-max-marker)))))))))
 259
 260 (defun mm-display-patch-inline (handle)
 261   (let (text)
 262     (with-temp-buffer
 263       (mm-insert-part handle)
 264       (diff-mode)
 265       (font-lock-fontify-buffer)
 266       (when (fboundp 'extent-list)
 267         (map-extents (lambda (ext ignored)
 268                        (set-extent-property ext 'duplicable t)
 269                        nil)
 270                      nil nil nil nil nil 'text-prop))
 271       (setq text (buffer-string)))
 272     (mm-insert-inline handle text)))
 273
 274 (provide 'mm-view)
 275
 276 ;; mm-view.el ends here