cgit.sxemacs.org Git - gnus/blob - lisp/mm-uu.el

   1 ;;; mm-uu.el --- Return uu stuff as mm handles
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   7 ;; Keywords: postscript uudecode binhex shar forward gnatsweb pgp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31 (require 'mail-parse)
  32 (require 'nnheader)
  33 (require 'mm-decode)
  34 (require 'mailcap)
  35 (require 'mml2015)
  36
  37 (autoload 'uudecode-decode-region "uudecode")
  38 (autoload 'uudecode-decode-region-external "uudecode")
  39 (autoload 'uudecode-decode-region-internal "uudecode")
  40
  41 (autoload 'binhex-decode-region "binhex")
  42 (autoload 'binhex-decode-region-external "binhex")
  43 (autoload 'binhex-decode-region-internal "binhex")
  44
  45 (autoload 'yenc-decode-region "yenc")
  46 (autoload 'yenc-extract-filename "yenc")
  47
  48 (defcustom mm-uu-decode-function 'uudecode-decode-region
  49   "*Function to uudecode.
  50 Internal function is done in Lisp by default, therefore decoding may
  51 appear to be horribly slow.  You can make Gnus use an external
  52 decoder, such as uudecode."
  53   :type '(choice
  54           (function-item :tag "Auto detect" uudecode-decode-region)
  55           (function-item :tag "Internal" uudecode-decode-region-internal)
  56           (function-item :tag "External" uudecode-decode-region-external))
  57   :group 'gnus-article-mime)
  58
  59 (defcustom mm-uu-binhex-decode-function 'binhex-decode-region
  60   "*Function to binhex decode.
  61 Internal function is done in elisp by default, therefore decoding may
  62 appear to be horribly slow . You can make Gnus use the external Unix
  63 decoder, such as hexbin."
  64   :type '(choice (function-item :tag "Auto detect" binhex-decode-region)
  65                  (function-item :tag "Internal" binhex-decode-region-internal)
  66                  (function-item :tag "External" binhex-decode-region-external))
  67   :group 'gnus-article-mime)
  68
  69 (defvar mm-uu-yenc-decode-function 'yenc-decode-region)
  70
  71 (defvar mm-uu-beginning-regexp nil)
  72
  73 (defvar mm-dissect-disposition "inline"
  74   "The default disposition of uu parts.
  75 This can be either \"inline\" or \"attachment\".")
  76
  77 (defcustom mm-uu-emacs-sources-regexp "\\.emacs\\.sources"
  78   "The regexp of Emacs sources groups."
  79   :version "22.1"
  80   :type 'regexp
  81   :group 'gnus-article-mime)
  82
  83 (defcustom mm-uu-diff-groups-regexp
  84   "\\(gmane\\|gnu\\)\\..*\\(diff\\|commit\\|cvs\\|bug\\|devel\\)"
  85   "Regexp matching diff groups."
  86   :version "22.1"
  87   :type 'regexp
  88   :group 'gnus-article-mime)
  89
  90 (defcustom mm-uu-tex-groups-regexp "\\.tex\\>"
  91   "*Regexp matching TeX groups."
  92   :version "23.0"
  93   :type 'regexp
  94   :group 'gnus-article-mime)
  95
  96 (defvar mm-uu-type-alist
  97   '((postscript
  98      "^%!PS-"
  99      "^%%EOF$"
 100      mm-uu-postscript-extract
 101      nil)
 102     (uu ;; Maybe we should have a more strict test here.
 103      "^begin[ \t]+0?[0-7][0-7][0-7][ \t]+"
 104      "^end[ \t]*$"
 105      mm-uu-uu-extract
 106      mm-uu-uu-filename)
 107     (binhex
 108      "^:.\\{63,63\\}$"
 109      ":$"
 110      mm-uu-binhex-extract
 111      nil
 112      mm-uu-binhex-filename)
 113     (yenc
 114      "^=ybegin.*size=[0-9]+.*name=.*$"
 115      "^=yend.*size=[0-9]+"
 116      mm-uu-yenc-extract
 117      mm-uu-yenc-filename)
 118     (shar
 119      "^#! */bin/sh"
 120      "^exit 0$"
 121      mm-uu-shar-extract)
 122     (forward
 123      ;; Thanks to Edward J. Sabol <sabol@alderaan.gsfc.nasa.gov> and
 124      ;; Peter von der Ah\'e <pahe@daimi.au.dk>
 125      "^-+ \\(Start of \\)?Forwarded message"
 126      "^-+ End \\(of \\)?forwarded message"
 127      mm-uu-forward-extract
 128      nil
 129      mm-uu-forward-test)
 130     (gnatsweb
 131      "^----gnatsweb-attachment----"
 132      nil
 133      mm-uu-gnatsweb-extract)
 134     (pgp-signed
 135      "^-----BEGIN PGP SIGNED MESSAGE-----"
 136      "^-----END PGP SIGNATURE-----"
 137      mm-uu-pgp-signed-extract
 138      nil
 139      nil)
 140     (pgp-encrypted
 141      "^-----BEGIN PGP MESSAGE-----"
 142      "^-----END PGP MESSAGE-----"
 143      mm-uu-pgp-encrypted-extract
 144      nil
 145      nil)
 146     (pgp-key
 147      "^-----BEGIN PGP PUBLIC KEY BLOCK-----"
 148      "^-----END PGP PUBLIC KEY BLOCK-----"
 149      mm-uu-pgp-key-extract
 150      mm-uu-gpg-key-skip-to-last
 151      nil)
 152     (emacs-sources
 153      "^;;;?[ \t]*[^ \t]+\\.el[ \t]*--"
 154      "^;;;?[ \t]*\\([^ \t]+\\.el\\)[ \t]+ends here"
 155      mm-uu-emacs-sources-extract
 156      nil
 157      mm-uu-emacs-sources-test)
 158     (diff
 159      "^Index: "
 160      nil
 161      mm-uu-diff-extract
 162      nil
 163      mm-uu-diff-test)
 164     (message-marks
 165      ;; Text enclosed with tags similar to `message-mark-insert-begin' and
 166      ;; `message-mark-insert-end'.  Don't use those variables to avoid
 167      ;; dependency on `message.el'.
 168      "^-+[8<>]*-\\{9,\\}[a-z ]+-\\{9,\\}[a-z ]+-\\{9,\\}[8<>]*-+$"
 169      "^-+[8<>]*-\\{9,\\}[a-z ]+-\\{9,\\}[a-z ]+-\\{9,\\}[8<>]*-+$"
 170      (lambda () (mm-uu-verbatim-marks-extract 0 -1 1 -1))
 171      nil)
 172     ;; Omitting [a-z8<] leads to false positives (bogus signature separators
 173     ;; and mailing list banners).
 174     (insert-marks
 175      "^ *\\(-\\|_\\)\\{30,\\}.*[a-z8<].*\\(-\\|_\\)\\{30,\\} *$"
 176      "^ *\\(-\\|_\\)\\{30,\\}.*[a-z8<].*\\(-\\|_\\)\\{30,\\} *$"
 177      (lambda () (mm-uu-verbatim-marks-extract 0 0 1 -1))
 178      nil)
 179     (verbatim-marks
 180      ;; slrn-style verbatim marks, see
 181      ;; http://www.slrn.org/manual/slrn-manual-6.html#ss6.81
 182      "^#v\\+"
 183      "^#v\\-$"
 184      (lambda () (mm-uu-verbatim-marks-extract 0 0))
 185      nil)
 186     (LaTeX
 187      "^\\([\\\\%][^\n]+\n\\)*\\\\documentclass.*[[{%]"
 188      "^\\\\end{document}"
 189      mm-uu-latex-extract
 190      nil
 191      mm-uu-latex-test))
 192   "A list of specifications for non-MIME attachments.
 193 Each element consist of the following entries: label,
 194 start-regexp, end-regexp, extract-function, test-function.
 195
 196 After modifying this list you must run \\[mm-uu-configure].
 197
 198 You can disable elements from this list by customizing
 199 `mm-uu-configure-list'.")
 200
 201 (defcustom mm-uu-configure-list '((shar . disabled))
 202   "A list of mm-uu configuration.
 203 To disable dissecting shar codes, for instance, add
 204 `(shar . disabled)' to this list."
 205   :type 'alist
 206   :options (mapcar (lambda (entry)
 207                      (list (car entry) '(const disabled)))
 208                    mm-uu-type-alist)
 209   :group 'gnus-article-mime)
 210
 211 (defvar mm-uu-text-plain-type '("text/plain" (charset . gnus-decoded))
 212   "MIME type and parameters for text/plain parts.
 213 `gnus-decoded' is a fake charset, which means no further decoding.")
 214
 215 ;; functions
 216
 217 (defsubst mm-uu-type (entry)
 218   (car entry))
 219
 220 (defsubst mm-uu-beginning-regexp (entry)
 221   (nth 1 entry))
 222
 223 (defsubst mm-uu-end-regexp (entry)
 224   (nth 2 entry))
 225
 226 (defsubst mm-uu-function-extract (entry)
 227   (nth 3 entry))
 228
 229 (defsubst mm-uu-function-1 (entry)
 230   (nth 4 entry))
 231
 232 (defsubst mm-uu-function-2 (entry)
 233   (nth 5 entry))
 234
 235 ;; In Emacs 22, we could use `min-colors' in the face definition.  But Emacs
 236 ;; 21 and XEmacs don't support it.
 237 (defcustom mm-uu-hide-markers
 238   (< 16 (or (and (fboundp 'defined-colors)
 239                  (length (defined-colors)))
 240             (and (fboundp 'device-color-cells)
 241                  (device-color-cells))
 242             0))
 243   "If non-nil, hide verbatim markers.
 244 The value should be nil on displays where the face
 245 `mm-uu-extract' isn't distinguishable to the face `default'."
 246   :type '(choice (const :tag "Hide" t)
 247                  (const :tag "Don't hide" nil))
 248   :version "23.0" ;; No Gnus
 249   :group 'gnus-article-mime)
 250
 251 (defface mm-uu-extract '(;; Colors from `gnus-cite-3' plus background:
 252                          (((class color)
 253                            (background dark))
 254                           (:foreground "light yellow"
 255                            :background "dark green"))
 256                          (((class color)
 257                            (background light))
 258                           (:foreground "dark green"
 259                            :background "light yellow"))
 260                          (t
 261                           ()))
 262   "Face for extracted buffers."
 263   ;; See `mm-uu-verbatim-marks-extract'.
 264   :version "23.0" ;; No Gnus
 265   :group 'gnus-article-mime)
 266
 267 (defun mm-uu-copy-to-buffer (&optional from to properties)
 268   "Copy the contents of the current buffer to a fresh buffer.
 269 Return that buffer.
 270
 271 If PROPERTIES is non-nil, PROPERTIES are applied to the buffer,
 272 see `set-text-properties'.  If PROPERTIES equals t, this means to
 273 apply the face `mm-uu-extract'."
 274   (let ((obuf (current-buffer))
 275         (coding-system
 276          ;; Might not exist in non-MULE XEmacs
 277          (when (boundp 'buffer-file-coding-system)
 278            buffer-file-coding-system)))
 279     (with-current-buffer (generate-new-buffer " *mm-uu*")
 280       (setq buffer-file-coding-system coding-system)
 281       (insert-buffer-substring obuf from to)
 282       (cond ((eq properties  t)
 283              (set-text-properties (point-min) (point-max)
 284                                   '(face mm-uu-extract)))
 285             (properties
 286              (set-text-properties (point-min) (point-max) properties)))
 287       (current-buffer))))
 288
 289 (defun mm-uu-configure-p  (key val)
 290   (member (cons key val) mm-uu-configure-list))
 291
 292 (defun mm-uu-configure (&optional symbol value)
 293   "Configure detection of non-MIME attachments."
 294   (interactive)
 295   (if symbol (set-default symbol value))
 296   (setq mm-uu-beginning-regexp nil)
 297   (mapcar (lambda (entry)
 298              (if (mm-uu-configure-p (mm-uu-type entry) 'disabled)
 299                  nil
 300                (setq mm-uu-beginning-regexp
 301                      (concat mm-uu-beginning-regexp
 302                              (if mm-uu-beginning-regexp "\\|")
 303                              (mm-uu-beginning-regexp entry)))))
 304           mm-uu-type-alist))
 305
 306 (mm-uu-configure)
 307
 308 (eval-when-compile
 309   (defvar file-name)
 310   (defvar start-point)
 311   (defvar end-point)
 312   (defvar entry))
 313
 314 (defun mm-uu-uu-filename ()
 315   (if (looking-at ".+")
 316       (setq file-name
 317             (let ((nnheader-file-name-translation-alist
 318                    '((?/ . ?,) (?\  . ?_) (?* . ?_) (?$ . ?_))))
 319               (nnheader-translate-file-chars (match-string 0))))))
 320
 321 (defun mm-uu-binhex-filename ()
 322   (setq file-name
 323         (ignore-errors
 324           (binhex-decode-region start-point end-point t))))
 325
 326 (defun mm-uu-yenc-filename ()
 327   (goto-char start-point)
 328   (setq file-name
 329         (ignore-errors
 330           (yenc-extract-filename))))
 331
 332 (defun mm-uu-forward-test ()
 333   (save-excursion
 334     (goto-char start-point)
 335     (forward-line)
 336     (looking-at "[\r\n]*[a-zA-Z][a-zA-Z0-9-]*:")))
 337
 338 (defun mm-uu-postscript-extract ()
 339   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 340                   '("application/postscript")))
 341
 342 (defun mm-uu-verbatim-marks-extract (start-offset end-offset
 343                                                   &optional
 344                                                   start-hide
 345                                                   end-hide)
 346   (let ((start (or (and mm-uu-hide-markers
 347                         start-hide)
 348                    start-offset
 349                    1))
 350         (end   (or (and mm-uu-hide-markers
 351                         end-hide)
 352                    end-offset
 353                    -1)))
 354     (mm-make-handle
 355      (mm-uu-copy-to-buffer
 356       (progn (goto-char start-point)
 357              (forward-line start)
 358              (point))
 359       (progn (goto-char end-point)
 360            (forward-line end)
 361            (point))
 362       t)
 363      '("text/x-verbatim" (charset . gnus-decoded)))))
 364
 365 (defun mm-uu-latex-extract ()
 366   (mm-make-handle
 367    (mm-uu-copy-to-buffer start-point end-point t)
 368    ;; application/x-tex?
 369    '("text/x-verbatim" (charset . gnus-decoded))))
 370
 371 (defun mm-uu-emacs-sources-extract ()
 372   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 373                   '("application/emacs-lisp" (charset . gnus-decoded))
 374                   nil nil
 375                   (list mm-dissect-disposition
 376                         (cons 'filename file-name))))
 377
 378 (eval-when-compile
 379   (defvar gnus-newsgroup-name))
 380
 381 (defun mm-uu-emacs-sources-test ()
 382   (setq file-name (match-string 1))
 383   (and gnus-newsgroup-name
 384        mm-uu-emacs-sources-regexp
 385        (string-match mm-uu-emacs-sources-regexp gnus-newsgroup-name)))
 386
 387 (defun mm-uu-diff-extract ()
 388   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 389                   '("text/x-patch" (charset . gnus-decoded))))
 390
 391 (defun mm-uu-diff-test ()
 392   (and gnus-newsgroup-name
 393        mm-uu-diff-groups-regexp
 394        (string-match mm-uu-diff-groups-regexp gnus-newsgroup-name)))
 395
 396 (defun mm-uu-latex-test ()
 397   (and gnus-newsgroup-name
 398        mm-uu-tex-groups-regexp
 399        (string-match mm-uu-tex-groups-regexp gnus-newsgroup-name)))
 400
 401 (defun mm-uu-forward-extract ()
 402   (mm-make-handle (mm-uu-copy-to-buffer
 403                    (progn (goto-char start-point) (forward-line) (point))
 404                    (progn (goto-char end-point) (forward-line -1) (point)))
 405                   '("message/rfc822" (charset . gnus-decoded))))
 406
 407 (defun mm-uu-uu-extract ()
 408   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 409                   (list (or (and file-name
 410                                  (string-match "\\.[^\\.]+$"
 411                                                file-name)
 412                                  (mailcap-extension-to-mime
 413                                   (match-string 0 file-name)))
 414                             "application/octet-stream"))
 415                   'x-uuencode nil
 416                   (if (and file-name (not (equal file-name "")))
 417                       (list mm-dissect-disposition
 418                             (cons 'filename file-name)))))
 419
 420 (defun mm-uu-binhex-extract ()
 421   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 422                   (list (or (and file-name
 423                                  (string-match "\\.[^\\.]+$" file-name)
 424                                  (mailcap-extension-to-mime
 425                                   (match-string 0 file-name)))
 426                             "application/octet-stream"))
 427                   'x-binhex nil
 428                   (if (and file-name (not (equal file-name "")))
 429                       (list mm-dissect-disposition
 430                             (cons 'filename file-name)))))
 431
 432 (defun mm-uu-yenc-extract ()
 433   ;; This might not be exactly correct, but we sure can't get the
 434   ;; binary data from the article buffer, since that's already in a
 435   ;; non-binary charset.  So get it from the original article buffer.
 436   (mm-make-handle (save-excursion
 437                     (set-buffer gnus-original-article-buffer)
 438                     (mm-uu-copy-to-buffer start-point end-point))
 439                   (list (or (and file-name
 440                                  (string-match "\\.[^\\.]+$" file-name)
 441                                  (mailcap-extension-to-mime
 442                                   (match-string 0 file-name)))
 443                             "application/octet-stream"))
 444                   'x-yenc nil
 445                   (if (and file-name (not (equal file-name "")))
 446                       (list mm-dissect-disposition
 447                             (cons 'filename file-name)))))
 448
 449
 450 (defun mm-uu-shar-extract ()
 451   (mm-make-handle (mm-uu-copy-to-buffer start-point end-point)
 452                   '("application/x-shar")))
 453
 454 (defun mm-uu-gnatsweb-extract ()
 455   (save-restriction
 456     (goto-char start-point)
 457     (forward-line)
 458     (narrow-to-region (point) end-point)
 459     (mm-dissect-buffer t)))
 460
 461 (defun mm-uu-pgp-signed-test (&rest rest)
 462   (and
 463    mml2015-use
 464    (mml2015-clear-verify-function)
 465    (cond
 466     ((eq mm-verify-option 'never) nil)
 467     ((eq mm-verify-option 'always) t)
 468     ((eq mm-verify-option 'known) t)
 469     (t (prog1
 470            (y-or-n-p "Verify pgp signed part? ")
 471          (message ""))))))
 472
 473 (eval-when-compile
 474   (defvar gnus-newsgroup-charset))
 475
 476 (defun mm-uu-pgp-signed-extract-1 (handles ctl)
 477   (let ((buf (mm-uu-copy-to-buffer (point-min) (point-max))))
 478     (with-current-buffer buf
 479       (if (mm-uu-pgp-signed-test)
 480           (progn
 481             (mml2015-clean-buffer)
 482             (let ((coding-system-for-write (or gnus-newsgroup-charset
 483                                                'iso-8859-1))
 484                   (coding-system-for-read (or gnus-newsgroup-charset
 485                                               'iso-8859-1)))
 486               (funcall (mml2015-clear-verify-function))))
 487         (when (and mml2015-use (null (mml2015-clear-verify-function)))
 488           (mm-set-handle-multipart-parameter
 489            mm-security-handle 'gnus-details
 490            (format "Clear verification not supported by `%s'.\n" mml2015-use)))
 491         (mml2015-extract-cleartext-signature))
 492       (list (mm-make-handle buf mm-uu-text-plain-type)))))
 493
 494 (defun mm-uu-pgp-signed-extract ()
 495   (let ((mm-security-handle (list (format "multipart/signed"))))
 496     (mm-set-handle-multipart-parameter
 497      mm-security-handle 'protocol "application/x-gnus-pgp-signature")
 498     (save-restriction
 499       (narrow-to-region start-point end-point)
 500       (add-text-properties 0 (length (car mm-security-handle))
 501                            (list 'buffer (mm-uu-copy-to-buffer))
 502                            (car mm-security-handle))
 503       (setcdr mm-security-handle
 504               (mm-uu-pgp-signed-extract-1 nil
 505                                           mm-security-handle)))
 506     mm-security-handle))
 507
 508 (defun mm-uu-pgp-encrypted-test (&rest rest)
 509   (and
 510    mml2015-use
 511    (mml2015-clear-decrypt-function)
 512    (cond
 513     ((eq mm-decrypt-option 'never) nil)
 514     ((eq mm-decrypt-option 'always) t)
 515     ((eq mm-decrypt-option 'known) t)
 516     (t (prog1
 517            (y-or-n-p "Decrypt pgp encrypted part? ")
 518          (message ""))))))
 519
 520 (defun mm-uu-pgp-encrypted-extract-1 (handles ctl)
 521   (let ((buf (mm-uu-copy-to-buffer (point-min) (point-max)))
 522         (first t)
 523         charset)
 524     ;; Make sure there's a blank line between header and body.
 525     (with-current-buffer buf
 526       (goto-char (point-min))
 527       (while (prog2
 528                  (forward-line 1)
 529                  (if first
 530                      (looking-at "[^\t\n ]+:")
 531                    (looking-at "[^\t\n ]+:\\|[\t ]"))
 532                (setq first nil)))
 533       (unless (memq (char-after) '(?\n nil))
 534         (insert "\n"))
 535       (save-restriction
 536         (narrow-to-region (point-min) (point))
 537         (setq charset (mail-fetch-field "charset")))
 538       (if (and (mm-uu-pgp-encrypted-test)
 539                (progn
 540                  (mml2015-clean-buffer)
 541                  (funcall (mml2015-clear-decrypt-function))
 542                  (equal (mm-handle-multipart-ctl-parameter mm-security-handle
 543                                                            'gnus-info)
 544                         "OK")))
 545           (progn
 546             ;; Decode charset.
 547             (if (and (or charset
 548                          (setq charset gnus-newsgroup-charset))
 549                      (setq charset (mm-charset-to-coding-system charset))
 550                      (not (eq charset 'ascii)))
 551                 ;; Assume that buffer's multibyteness is turned off.
 552                 ;; See `mml2015-pgg-clear-decrypt'.
 553                 (insert (mm-decode-coding-string (prog1
 554                                                      (buffer-string)
 555                                                    (erase-buffer)
 556                                                    (mm-enable-multibyte))
 557                                                  charset))
 558               (mm-enable-multibyte))
 559             (list (mm-make-handle buf mm-uu-text-plain-type)))
 560         (list (mm-make-handle buf '("application/pgp-encrypted")))))))
 561
 562 (defun mm-uu-pgp-encrypted-extract ()
 563   (let ((mm-security-handle (list (format "multipart/encrypted"))))
 564     (mm-set-handle-multipart-parameter
 565      mm-security-handle 'protocol "application/x-gnus-pgp-encrypted")
 566     (save-restriction
 567       (narrow-to-region start-point end-point)
 568       (add-text-properties 0 (length (car mm-security-handle))
 569                            (list 'buffer (mm-uu-copy-to-buffer))
 570                            (car mm-security-handle))
 571       (setcdr mm-security-handle
 572               (mm-uu-pgp-encrypted-extract-1 nil
 573                                              mm-security-handle)))
 574     mm-security-handle))
 575
 576 (defun mm-uu-gpg-key-skip-to-last ()
 577   (let ((point (point))
 578         (end-regexp (mm-uu-end-regexp entry))
 579         (beginning-regexp (mm-uu-beginning-regexp entry)))
 580     (when (and end-regexp
 581                (not (mm-uu-configure-p (mm-uu-type entry) 'disabled)))
 582       (while (re-search-forward end-regexp nil t)
 583         (skip-chars-forward " \t\n\r")
 584         (if (looking-at beginning-regexp)
 585             (setq point (match-end 0)))))
 586     (goto-char point)))
 587
 588 (defun mm-uu-pgp-key-extract ()
 589   (let ((buf (mm-uu-copy-to-buffer start-point end-point)))
 590     (mm-make-handle buf
 591                     '("application/pgp-keys"))))
 592
 593 ;;;###autoload
 594 (defun mm-uu-dissect (&optional noheader mime-type)
 595   "Dissect the current buffer and return a list of uu handles.
 596 The optional NOHEADER means there's no header in the buffer.
 597 MIME-TYPE specifies a MIME type and parameters, which defaults to the
 598 value of `mm-uu-text-plain-type'."
 599   (let ((case-fold-search t)
 600         (mm-uu-text-plain-type (or mime-type mm-uu-text-plain-type))
 601         text-start start-point end-point file-name result entry func)
 602     (save-excursion
 603       (goto-char (point-min))
 604       (cond
 605        (noheader)
 606        ((looking-at "\n")
 607         (forward-line))
 608        ((search-forward "\n\n" nil t)
 609         t)
 610        (t (goto-char (point-max))))
 611       (setq text-start (point))
 612       (while (re-search-forward mm-uu-beginning-regexp nil t)
 613         (setq start-point (match-beginning 0)
 614               entry nil)
 615         (let ((alist mm-uu-type-alist)
 616               (beginning-regexp (match-string 0)))
 617           (while (not entry)
 618             (if (string-match (mm-uu-beginning-regexp (car alist))
 619                               beginning-regexp)
 620                 (setq entry (car alist))
 621               (pop alist))))
 622         (if (setq func (mm-uu-function-1 entry))
 623             (funcall func))
 624         (forward-line);; in case of failure
 625         (when (and (not (mm-uu-configure-p (mm-uu-type entry) 'disabled))
 626                    (let ((end-regexp (mm-uu-end-regexp entry)))
 627                      (if (not end-regexp)
 628                          (or (setq end-point (point-max)) t)
 629                        (prog1
 630                            (re-search-forward end-regexp nil t)
 631                          (forward-line)
 632                          (setq end-point (point)))))
 633                    (or (not (setq func (mm-uu-function-2 entry)))
 634                        (funcall func)))
 635           (if (and (> start-point text-start)
 636                    (progn
 637                      (goto-char text-start)
 638                      (re-search-forward "." start-point t)))
 639               (push
 640                (mm-make-handle (mm-uu-copy-to-buffer text-start start-point)
 641                                mm-uu-text-plain-type)
 642                result))
 643           (push
 644            (funcall (mm-uu-function-extract entry))
 645            result)
 646           (goto-char (setq text-start end-point))))
 647       (when result
 648         (if (and (> (point-max) (1+ text-start))
 649                  (save-excursion
 650                    (goto-char text-start)
 651                    (re-search-forward "." nil t)))
 652             (push
 653              (mm-make-handle (mm-uu-copy-to-buffer text-start (point-max))
 654                              mm-uu-text-plain-type)
 655              result))
 656         (setq result (cons "multipart/mixed" (nreverse result))))
 657       result)))
 658
 659 ;;;###autoload
 660 (defun mm-uu-dissect-text-parts (handle &optional decoded)
 661   "Dissect text parts and put uu handles into HANDLE.
 662 Assume text has been decoded if DECODED is non-nil."
 663   (let ((buffer (mm-handle-buffer handle)))
 664     (cond ((stringp buffer)
 665            (dolist (elem (cdr handle))
 666              (mm-uu-dissect-text-parts elem decoded)))
 667           ((bufferp buffer)
 668            (let ((type (mm-handle-media-type handle))
 669                  (case-fold-search t) ;; string-match
 670                  children charset encoding)
 671              (when (and
 672                     (stringp type)
 673                     ;; Mutt still uses application/pgp even though
 674                     ;; it has already been withdrawn.
 675                     (string-match "\\`text/\\|\\`application/pgp\\'" type)
 676                     (setq
 677                      children
 678                      (with-current-buffer buffer
 679                        (cond
 680                         ((or decoded
 681                              (eq (setq charset (mail-content-type-get
 682                                                 (mm-handle-type handle)
 683                                                 'charset))
 684                                  'gnus-decoded))
 685                          (setq decoded t)
 686                          (mm-uu-dissect
 687                           t (cons type '((charset . gnus-decoded)))))
 688                         (charset
 689                          (setq decoded t)
 690                          (mm-with-multibyte-buffer
 691                            (insert (mm-decode-string (mm-get-part handle)
 692                                                      charset))
 693                            (mm-uu-dissect
 694                             t (cons type '((charset . gnus-decoded))))))
 695                         ((setq encoding (mm-handle-encoding handle))
 696                          (setq decoded nil)
 697                          ;; Inherit the multibyteness of the `buffer'.
 698                          (with-temp-buffer
 699                            (insert-buffer-substring buffer)
 700                            (mm-decode-content-transfer-encoding
 701                             encoding type)
 702                            (mm-uu-dissect t (list type))))
 703                         (t
 704                          (setq decoded nil)
 705                          (mm-uu-dissect t (list type)))))))
 706                ;; Ignore it if a given part is dissected into a single
 707                ;; part of which the type is the same as the given one.
 708                (if (and (<= (length children) 2)
 709                         (string-equal (mm-handle-media-type (cadr children))
 710                                       type))
 711                    (kill-buffer (mm-handle-buffer (cadr children)))
 712                  (kill-buffer buffer)
 713                  (setcdr handle (cdr children))
 714                  (setcar handle (car children)) ;; "multipart/mixed"
 715                  (dolist (elem (cdr children))
 716                    (mm-uu-dissect-text-parts elem decoded))))))
 717           (t
 718            (dolist (elem handle)
 719              (mm-uu-dissect-text-parts elem decoded))))))
 720
 721 (provide 'mm-uu)
 722
 723 ;; arch-tag: 7db076bf-53db-4320-aa19-ca76a1d2ab2c
 724 ;;; mm-uu.el ends here