cgit.sxemacs.org Git - gnus/blob - lisp/mm-url.el

   1 ;;; mm-url.el --- a wrapper of url functions/commands for Gnus
   2 ;; Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published
  10 ;; by the Free Software Foundation; either version 2, or (at your
  11 ;; option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Some codes are stolen from w3 and url packages. Some are moved from
  26 ;; nnweb.
  27
  28 ;; TODO: Support POST, cookie.
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (require 'mm-util)
  35 (require 'gnus)
  36
  37 (eval-when-compile
  38   (if (featurep 'xemacs)
  39       (require 'timer-funcs)
  40     (require 'timer)))
  41
  42 (defgroup mm-url nil
  43   "A wrapper of url package and external url command for Gnus."
  44   :group 'gnus)
  45
  46 (defcustom mm-url-use-external (not
  47                                 (condition-case nil
  48                                     (require 'url)
  49                                   (error nil)))
  50   "*If non-nil, use external grab program `mm-url-program'."
  51   :version "21.4"
  52   :type 'boolean
  53   :group 'mm-url)
  54
  55 (defvar mm-url-predefined-programs
  56   '((wget "wget" "--user-agent=mm-url" "-q" "-O" "-")
  57     (w3m  "w3m" "-dump_source")
  58     (lynx "lynx" "-source")
  59     (curl "curl" "--silent")))
  60
  61 (defcustom mm-url-program
  62   (cond
  63    ((executable-find "wget") 'wget)
  64    ((executable-find "w3m") 'w3m)
  65    ((executable-find "lynx") 'lynx)
  66    ((executable-find "curl") 'curl)
  67    (t "GET"))
  68   "The url grab program.
  69 Likely values are `wget', `w3m', `lynx' and `curl'."
  70   :version "21.4"
  71   :type '(choice
  72           (symbol :tag "wget" wget)
  73           (symbol :tag "w3m" w3m)
  74           (symbol :tag "lynx" lynx)
  75           (symbol :tag "curl" curl)
  76           (string :tag "other"))
  77   :group 'mm-url)
  78
  79 (defcustom mm-url-arguments nil
  80   "The arguments for `mm-url-program'."
  81   :version "21.4"
  82   :type '(repeat string)
  83   :group 'mm-url)
  84
  85 \f
  86 ;;; Internal variables
  87
  88 (defvar mm-url-package-name
  89   (gnus-replace-in-string
  90    (gnus-replace-in-string gnus-version " v.*$" "")
  91    " " "-"))
  92
  93 (defvar mm-url-package-version gnus-version-number)
  94
  95 ;; Stolen from w3.
  96 (defvar mm-url-html-entities
  97   '(
  98     ;;(excl        .  33)
  99     (quot        .  34)
 100     ;;(num         .  35)
 101     ;;(dollar      .  36)
 102     ;;(percent     .  37)
 103     (amp         .  38)
 104     (rsquo       .  39)                 ; should be U+8217
 105     ;;(apos        .  39)
 106     ;;(lpar        .  40)
 107     ;;(rpar        .  41)
 108     ;;(ast         .  42)
 109     ;;(plus        .  43)
 110     ;;(comma       .  44)
 111     ;;(period      .  46)
 112     ;;(colon       .  58)
 113     ;;(semi        .  59)
 114     (lt          .  60)
 115     ;;(equals      .  61)
 116     (gt          .  62)
 117     ;;(quest       .  63)
 118     ;;(commat      .  64)
 119     ;;(lsqb        .  91)
 120     ;;(rsqb        .  93)
 121     (uarr        .  94)                 ; should be U+8593
 122     ;;(lowbar      .  95)
 123     (lsquo       .  96)                 ; should be U+8216
 124     (lcub        . 123)
 125     ;;(verbar      . 124)
 126     (rcub        . 125)
 127     (tilde       . 126)
 128     (nbsp        . 160)
 129     (iexcl       . 161)
 130     (cent        . 162)
 131     (pound       . 163)
 132     (curren      . 164)
 133     (yen         . 165)
 134     (brvbar      . 166)
 135     (sect        . 167)
 136     (uml         . 168)
 137     (copy        . 169)
 138     (ordf        . 170)
 139     (laquo       . 171)
 140     (not         . 172)
 141     (shy         . 173)
 142     (reg         . 174)
 143     (macr        . 175)
 144     (deg         . 176)
 145     (plusmn      . 177)
 146     (sup2        . 178)
 147     (sup3        . 179)
 148     (acute       . 180)
 149     (micro       . 181)
 150     (para        . 182)
 151     (middot      . 183)
 152     (cedil       . 184)
 153     (sup1        . 185)
 154     (ordm        . 186)
 155     (raquo       . 187)
 156     (frac14      . 188)
 157     (frac12      . 189)
 158     (frac34      . 190)
 159     (iquest      . 191)
 160     (Agrave      . 192)
 161     (Aacute      . 193)
 162     (Acirc       . 194)
 163     (Atilde      . 195)
 164     (Auml        . 196)
 165     (Aring       . 197)
 166     (AElig       . 198)
 167     (Ccedil      . 199)
 168     (Egrave      . 200)
 169     (Eacute      . 201)
 170     (Ecirc       . 202)
 171     (Euml        . 203)
 172     (Igrave      . 204)
 173     (Iacute      . 205)
 174     (Icirc       . 206)
 175     (Iuml        . 207)
 176     (ETH         . 208)
 177     (Ntilde      . 209)
 178     (Ograve      . 210)
 179     (Oacute      . 211)
 180     (Ocirc       . 212)
 181     (Otilde      . 213)
 182     (Ouml        . 214)
 183     (times       . 215)
 184     (Oslash      . 216)
 185     (Ugrave      . 217)
 186     (Uacute      . 218)
 187     (Ucirc       . 219)
 188     (Uuml        . 220)
 189     (Yacute      . 221)
 190     (THORN       . 222)
 191     (szlig       . 223)
 192     (agrave      . 224)
 193     (aacute      . 225)
 194     (acirc       . 226)
 195     (atilde      . 227)
 196     (auml        . 228)
 197     (aring       . 229)
 198     (aelig       . 230)
 199     (ccedil      . 231)
 200     (egrave      . 232)
 201     (eacute      . 233)
 202     (ecirc       . 234)
 203     (euml        . 235)
 204     (igrave      . 236)
 205     (iacute      . 237)
 206     (icirc       . 238)
 207     (iuml        . 239)
 208     (eth         . 240)
 209     (ntilde      . 241)
 210     (ograve      . 242)
 211     (oacute      . 243)
 212     (ocirc       . 244)
 213     (otilde      . 245)
 214     (ouml        . 246)
 215     (divide      . 247)
 216     (oslash      . 248)
 217     (ugrave      . 249)
 218     (uacute      . 250)
 219     (ucirc       . 251)
 220     (uuml        . 252)
 221     (yacute      . 253)
 222     (thorn       . 254)
 223     (yuml        . 255)
 224
 225     ;; Special handling of these
 226     (frac56      . "5/6")
 227     (frac16      . "1/6")
 228     (frac45      . "4/5")
 229     (frac35      . "3/5")
 230     (frac25      . "2/5")
 231     (frac15      . "1/5")
 232     (frac23      . "2/3")
 233     (frac13      . "1/3")
 234     (frac78      . "7/8")
 235     (frac58      . "5/8")
 236     (frac38      . "3/8")
 237     (frac18      . "1/8")
 238
 239     ;; The following 5 entities are not mentioned in the HTML 2.0
 240     ;; standard, nor in any other HTML proposed standard of which I
 241     ;; am aware.  I am not even sure they are ISO entity names.  ***
 242     ;; Hence, some arrangement should be made to give a bad HTML
 243     ;; message when they are seen.
 244     (ndash       .  45)
 245     (mdash       .  45)
 246     (emsp        .  32)
 247     (ensp        .  32)
 248     (sim         . 126)
 249     (le          . "<=")
 250     (agr         . "alpha")
 251     (rdquo       . "''")
 252     (ldquo       . "``")
 253     (trade       . "(TM)")
 254     ;; To be done
 255     ;; (shy      . ????) ; soft hyphen
 256     )
 257   "*An assoc list of entity names and how to actually display them.")
 258
 259 (defconst mm-url-unreserved-chars
 260   '(
 261     ?a ?b ?c ?d ?e ?f ?g ?h ?i ?j ?k ?l ?m ?n ?o ?p ?q ?r ?s ?t ?u ?v ?w ?x ?y ?z
 262     ?A ?B ?C ?D ?E ?F ?G ?H ?I ?J ?K ?L ?M ?N ?O ?P ?Q ?R ?S ?T ?U ?V ?W ?X ?Y ?Z
 263     ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9
 264     ?- ?_ ?. ?! ?~ ?* ?' ?\( ?\))
 265   "A list of characters that are _NOT_ reserved in the URL spec.
 266 This is taken from RFC 2396.")
 267
 268 (defun mm-url-load-url ()
 269   "Load `url-insert-file-contents'."
 270   (unless (condition-case ()
 271               (require 'url-handlers)
 272             (error nil))
 273     ;; w3-4.0pre0.46 or earlier version.
 274     (require 'w3-vars)
 275     (require 'url)))
 276
 277 ;;;###autoload
 278 (defun mm-url-insert-file-contents (url)
 279   "Insert file contents of URL.
 280 If `mm-url-use-external' is non-nil, use `mm-url-program'."
 281   (if mm-url-use-external
 282       (progn
 283         (if (string-match "^file:/+" url)
 284             (insert-file-contents (substring url (1- (match-end 0))))
 285           (mm-url-insert-file-contents-external url))
 286         (goto-char (point-min))
 287         (if (fboundp 'url-generic-parse-url)
 288             (setq url-current-object
 289                   (url-generic-parse-url url)))
 290         (list url (buffer-size)))
 291     (mm-url-load-url)
 292     (let ((name buffer-file-name)
 293           (url-request-extra-headers (list (cons "Connection" "Close")))
 294           (url-package-name (or mm-url-package-name
 295                                 url-package-name))
 296           (url-package-version (or mm-url-package-version
 297                                    url-package-version))
 298           result)
 299       (setq result (url-insert-file-contents url))
 300       (save-excursion
 301         (goto-char (point-min))
 302         (while (re-search-forward "\r 1000\r ?" nil t)
 303           (replace-match "")))
 304       (setq buffer-file-name name)
 305       (if (and (fboundp 'url-generic-parse-url)
 306                (listp result))
 307           (setq url-current-object (url-generic-parse-url
 308                                     (car result))))
 309       result)))
 310
 311 ;;;###autoload
 312 (defun mm-url-insert-file-contents-external (url)
 313   "Insert file contents of URL using `mm-url-program'."
 314   (let (program args)
 315     (if (symbolp mm-url-program)
 316         (let ((item (cdr (assq mm-url-program mm-url-predefined-programs))))
 317           (setq program (car item)
 318                 args (append (cdr item) (list url))))
 319       (setq program mm-url-program
 320             args (append mm-url-arguments (list url))))
 321     (unless (eq 0 (apply 'call-process program nil t nil args))
 322       (error "Couldn't fetch %s" url))))
 323
 324 (defvar mm-url-timeout 30
 325   "The number of seconds before timing out an URL fetch.")
 326
 327 (defvar mm-url-retries 10
 328   "The number of retries after timing out when fetching an URL.")
 329
 330 (defun mm-url-insert (url &optional follow-refresh)
 331   "Insert the contents from an URL in the current buffer.
 332 If FOLLOW-REFRESH is non-nil, redirect refresh url in META."
 333   (let ((times mm-url-retries)
 334         (done nil)
 335         (first t)
 336         result)
 337     (while (and (not (zerop (decf times)))
 338                 (not done))
 339       (with-timeout (mm-url-timeout)
 340         (unless first
 341           (message "Trying again (%s)..." (- mm-url-retries times)))
 342         (setq first nil)
 343         (if follow-refresh
 344             (save-restriction
 345               (narrow-to-region (point) (point))
 346               (mm-url-insert-file-contents url)
 347               (goto-char (point-min))
 348               (when (re-search-forward
 349                      "<meta[ \t\r\n]*http-equiv=\"Refresh\"[^>]*URL=\\([^\"]+\\)\"" nil t)
 350                 (let ((url (match-string 1)))
 351                   (delete-region (point-min) (point-max))
 352                   (setq result (mm-url-insert url t)))))
 353           (setq result (mm-url-insert-file-contents url)))
 354         (setq done t)))
 355     result))
 356
 357 (defun mm-url-decode-entities ()
 358   "Decode all HTML entities."
 359   (goto-char (point-min))
 360   (while (re-search-forward "&\\(#[0-9]+\\|[a-z]+\\);" nil t)
 361     (let ((elem (if (eq (aref (match-string 1) 0) ?\#)
 362                         (let ((c
 363                                (string-to-number (substring
 364                                                   (match-string 1) 1))))
 365                           (if (mm-char-or-char-int-p c) c 32))
 366                       (or (cdr (assq (intern (match-string 1))
 367                                      mm-url-html-entities))
 368                           ?#))))
 369       (unless (stringp elem)
 370         (setq elem (char-to-string elem)))
 371       (replace-match elem t t))))
 372
 373 (defun mm-url-decode-entities-nbsp ()
 374   "Decode all HTML entities and &nbsp; to a space."
 375   (let ((mm-url-html-entities (cons '(nbsp . 32) mm-url-html-entities)))
 376     (mm-url-decode-entities)))
 377
 378 (defun mm-url-decode-entities-string (string)
 379   (with-temp-buffer
 380     (insert string)
 381     (mm-url-decode-entities)
 382     (buffer-string)))
 383
 384 (defun mm-url-form-encode-xwfu (chunk)
 385   "Escape characters in a string for application/x-www-form-urlencoded.
 386 Blasphemous crap because someone didn't think %20 was good enough for encoding
 387 spaces.  Die Die Die."
 388   ;; This will get rid of the 'attributes' specified by the file type,
 389   ;; which are useless for an application/x-www-form-urlencoded form.
 390   (if (consp chunk)
 391       (setq chunk (cdr chunk)))
 392
 393   (mapconcat
 394    (lambda (char)
 395      (cond
 396       ((= char ?  ) "+")
 397       ((memq char mm-url-unreserved-chars) (char-to-string char))
 398       (t (upcase (format "%%%02x" char)))))
 399    ;; Fixme: Should this actually be accepting multibyte?  Is there a
 400    ;; better way in XEmacs?
 401    (if (featurep 'mule)
 402        (encode-coding-string chunk
 403                              (if (fboundp 'find-coding-systems-string)
 404                                  (car (find-coding-systems-string chunk))
 405                                  buffer-file-coding-system))
 406      chunk)
 407    ""))
 408
 409 (defun mm-url-encode-www-form-urlencoded (pairs)
 410   "Return PAIRS encoded for forms."
 411   (mapconcat
 412    (lambda (data)
 413      (concat (mm-url-form-encode-xwfu (car data)) "="
 414              (mm-url-form-encode-xwfu (cdr data))))
 415    pairs "&"))
 416
 417 (defun mm-url-fetch-form (url pairs)
 418   "Fetch a form from URL with PAIRS as the data using the POST method."
 419   (mm-url-load-url)
 420   (let ((url-request-data (mm-url-encode-www-form-urlencoded pairs))
 421         (url-request-method "POST")
 422         (url-request-extra-headers
 423          '(("Content-type" . "application/x-www-form-urlencoded"))))
 424     (url-insert-file-contents url)
 425     (setq buffer-file-name nil))
 426   t)
 427
 428 (defun mm-url-fetch-simple (url content)
 429   (mm-url-load-url)
 430   (let ((url-request-data content)
 431         (url-request-method "POST")
 432         (url-request-extra-headers
 433          '(("Content-type" . "application/x-www-form-urlencoded"))))
 434     (url-insert-file-contents url)
 435     (setq buffer-file-name nil))
 436   t)
 437
 438 (defun mm-url-remove-markup ()
 439   "Remove all HTML markup, leaving just plain text."
 440   (goto-char (point-min))
 441   (while (search-forward "<!--" nil t)
 442     (delete-region (match-beginning 0)
 443                    (or (search-forward "-->" nil t)
 444                        (point-max))))
 445   (goto-char (point-min))
 446   (while (re-search-forward "<[^>]+>" nil t)
 447     (replace-match "" t t)))
 448
 449 (provide 'mm-url)
 450
 451 ;;; arch-tag: 0594f9b3-417c-48b0-adc2-5082e1e7917f
 452 ;;; mm-url.el ends here