cgit.sxemacs.org Git - gnus/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28 (require 'mailcap)
  29 (require 'mm-bodies)
  30
  31 ;;; Convenience macros.
  32
  33 (defmacro mm-handle-buffer (handle)
  34   `(nth 0 ,handle))
  35 (defmacro mm-handle-type (handle)
  36   `(nth 1 ,handle))
  37 (defmacro mm-handle-encoding (handle)
  38   `(nth 2 ,handle))
  39 (defmacro mm-handle-undisplayer (handle)
  40   `(nth 3 ,handle))
  41 (defmacro mm-handle-set-undisplayer (handle function)
  42   `(setcar (nthcdr 3 ,handle) ,function))
  43 (defmacro mm-handle-disposition (handle)
  44   `(nth 4 ,handle))
  45 (defmacro mm-handle-description (handle)
  46   `(nth 5 ,handle))
  47
  48 (defvar mm-inline-media-tests
  49   '(("image/jpeg" mm-inline-image (featurep 'jpeg))
  50     ("image/png" mm-inline-image (featurep 'png))
  51     ("image/gif" mm-inline-image (featurep 'gif))
  52     ("image/tiff" mm-inline-image (featurep 'tiff))
  53     ("image/xbm" mm-inline-image (eq (device-type) 'x))
  54     ("image/xpm" mm-inline-image (featurep 'xpm))
  55     ("image/bmp" mm-inline-image (featurep 'bmp))
  56     ("text/plain" mm-inline-text t)
  57     ("text/enriched" mm-inline-text t)
  58     ("text/richtext" mm-inline-text t)
  59     ("text/html" mm-inline-text (featurep 'w3))
  60     ("message/delivery-status" mm-inline-text t)
  61     ("audio/wav" mm-inline-audio
  62      (and (or (featurep 'nas-sound) (featurep 'native-sound))
  63           (device-sound-enabled-p)))
  64     ("audio/au" mm-inline-audio
  65      (and (or (featurep 'nas-sound) (featurep 'native-sound))
  66           (device-sound-enabled-p))))
  67   "Alist of media types/test that say whether the media types can be displayed inline.")
  68
  69 (defvar mm-user-display-methods
  70   '(("image/.*" . inline)
  71     ("text/.*" . inline)
  72     ("message/delivery-status" . inline)))
  73
  74 (defvar mm-user-automatic-display
  75   '("text/plain" "text/enriched" "text/richtext" "text/html" "image/gif"
  76     "message/delivery-status"))
  77
  78 (defvar mm-alternative-precedence
  79   '("text/plain" "text/enriched" "text/richtext" "text/html")
  80   "List that describes the precedence of alternative parts.")
  81
  82 (defvar mm-tmp-directory "/tmp/"
  83   "Where mm will store its temporary files.")
  84
  85 ;;; Internal variables.
  86
  87 (defvar mm-dissection-list nil)
  88 (defvar mm-last-shell-command "")
  89 (defvar mm-content-id-alist nil)
  90
  91 ;;; The functions.
  92
  93 (defun mm-dissect-buffer (&optional no-strict-mime)
  94   "Dissect the current buffer and return a list of MIME handles."
  95   (save-excursion
  96     (let (ct ctl type subtype cte cd description id result)
  97       (save-restriction
  98         (mail-narrow-to-head)
  99         (when (and (or no-strict-mime
 100                        (mail-fetch-field "mime-version"))
 101                    (setq ct (mail-fetch-field "content-type")))
 102           (setq ctl (condition-case () (mail-header-parse-content-type ct)
 103                       (error nil))
 104                 cte (mail-fetch-field "content-transfer-encoding")
 105                 cd (mail-fetch-field "content-disposition")
 106                 description (mail-fetch-field "content-description")
 107                 id (mail-fetch-field "content-id"))))
 108       (if (not ctl)
 109           (mm-dissect-singlepart '("text/plain") nil no-strict-mime nil nil)
 110         (setq type (split-string (car ctl) "/"))
 111         (setq subtype (cadr type)
 112               type (pop type))
 113         (setq
 114          result
 115          (cond
 116           ((equal type "multipart")
 117            (mm-dissect-multipart ctl))
 118           (t
 119            (mm-dissect-singlepart
 120             ctl
 121             (and cte (intern (downcase (mail-header-remove-whitespace
 122                                         (mail-header-remove-comments
 123                                          cte)))))
 124             no-strict-mime
 125             (and cd (condition-case ()
 126                         (mail-header-parse-content-disposition cd)
 127                       (error nil)))))))
 128         (when id
 129           (push (cons id result) mm-content-id-alist))
 130         result))))
 131
 132 (defun mm-dissect-singlepart (ctl cte &optional force cdl description)
 133   (when (or force
 134             (not (equal "text/plain" (car ctl))))
 135     (let ((res (list (list (mm-copy-to-buffer) ctl cte nil cdl description))))
 136       (push (car res) mm-dissection-list)
 137       res)))
 138
 139 (defun mm-remove-all-parts ()
 140   "Remove all MIME handles."
 141   (interactive)
 142   (mapcar 'mm-remove-part mm-dissection-list)
 143   (setq mm-dissection-list nil))
 144
 145 (defun mm-dissect-multipart (ctl)
 146   (goto-char (point-min))
 147   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 148         (close-delimiter (concat boundary "--[ \t]*$"))
 149         start parts
 150         (end (save-excursion
 151                (goto-char (point-max))
 152                (if (re-search-backward close-delimiter nil t)
 153                    (match-beginning 0)
 154                  (point-max)))))
 155     (while (search-forward boundary end t)
 156       (goto-char (match-beginning 0))
 157       (when start
 158         (save-excursion
 159           (save-restriction
 160             (narrow-to-region start (point))
 161             (setq parts (nconc (mm-dissect-buffer t) parts)))))
 162       (forward-line 2)
 163       (setq start (point)))
 164     (when start
 165       (save-excursion
 166         (save-restriction
 167           (narrow-to-region start end)
 168           (setq parts (nconc (mm-dissect-buffer t) parts)))))
 169     (nreverse parts)))
 170
 171 (defun mm-copy-to-buffer ()
 172   "Copy the contents of the current buffer to a fresh buffer."
 173   (save-excursion
 174     (let ((obuf (current-buffer))
 175           beg)
 176       (goto-char (point-min))
 177       (search-forward "\n\n" nil t)
 178       (setq beg (point))
 179       (set-buffer (generate-new-buffer " *mm*"))
 180       (insert-buffer-substring obuf beg)
 181       (current-buffer))))
 182
 183 (defun mm-inlinable-part-p (type)
 184   "Say whether TYPE can be displayed inline."
 185   (eq (mm-user-method type) 'inline))
 186
 187 (defun mm-display-part (handle &optional no-default)
 188   "Display the MIME part represented by HANDLE."
 189   (save-excursion
 190     (mailcap-parse-mailcaps)
 191     (if (mm-handle-displayed-p handle)
 192         (mm-remove-part handle)
 193       (let* ((type (car (mm-handle-type handle)))
 194              (method (mailcap-mime-info type))
 195              (user-method (mm-user-method type)))
 196         (if (eq user-method 'inline)
 197             (progn
 198               (forward-line 1)
 199               (mm-display-inline handle))
 200           (when (or user-method
 201                     method
 202                     (not no-default))
 203             (mm-display-external
 204              handle (or user-method method 'mailcap-save-binary-file))))))))
 205
 206 (defun mm-display-external (handle method)
 207   "Display HANDLE using METHOD."
 208   (mm-with-unibyte-buffer
 209     (insert-buffer-substring (mm-handle-buffer handle))
 210     (mm-decode-content-transfer-encoding
 211      (mm-handle-encoding handle) (car (mm-handle-type handle)))
 212     (if (functionp method)
 213         (let ((cur (current-buffer)))
 214           (if (eq method 'mailcap-save-binary-file)
 215               (set-buffer (generate-new-buffer "*mm*"))
 216             (select-window (get-buffer-window cur t))
 217             (switch-to-buffer (generate-new-buffer "*mm*")))
 218           (buffer-disable-undo)
 219           (mm-set-buffer-file-coding-system 'no-conversion)
 220           (insert-buffer-substring cur)
 221           (funcall method)
 222           (mm-handle-set-undisplayer handle (current-buffer)))
 223       (let* ((dir (make-temp-name (expand-file-name "emm." mm-tmp-directory)))
 224              (filename (mail-content-type-get
 225                         (mm-handle-disposition handle) 'filename))
 226              (needsterm (assoc "needsterm"
 227                                (mailcap-mime-info
 228                                 (car (mm-handle-type handle)) t)))
 229              process file)
 230         ;; We create a private sub-directory where we store our files.
 231         (make-directory dir)
 232         (set-file-modes dir 448)
 233         (if filename
 234             (setq file (expand-file-name (file-name-nondirectory filename)
 235                                          dir))
 236           (setq file (make-temp-name (expand-file-name "mm." dir))))
 237         (write-region (point-min) (point-max)
 238                       file nil 'nomesg nil 'no-conversion)
 239         (setq process
 240               (if needsterm
 241                   (start-process "*display*" nil
 242                                  "xterm"
 243                                  "-e" shell-file-name "-c"
 244                                  (format method
 245                                          (mm-quote-arg file)))
 246                 (start-process "*display*" (generate-new-buffer "*mm*")
 247                                shell-file-name
 248                                "-c" (format method
 249                                             (mm-quote-arg file)))))
 250         (mm-handle-set-undisplayer handle (cons file process))
 251         (message "Displaying %s..." (format method file))))))
 252
 253 (defun mm-remove-part (handle)
 254   "Remove the displayed MIME part represented by HANDLE."
 255   (let ((object (mm-handle-undisplayer handle)))
 256     (condition-case ()
 257         (cond
 258          ;; Internally displayed part.
 259          ((mm-annotationp object)
 260           (delete-annotation object))
 261          ((or (functionp object)
 262               (and (listp object)
 263                    (eq (car object) 'lambda)))
 264           (funcall object))
 265          ;; Externally displayed part.
 266          ((consp object)
 267           (condition-case ()
 268               (delete-file (car object))
 269             (error nil))
 270           (condition-case ()
 271               (delete-directory (file-name-directory (car object)))
 272             (error nil))
 273           (condition-case ()
 274               (kill-process (cdr object))
 275             (error nil)))
 276          ((bufferp object)
 277           (when (buffer-live-p object)
 278             (kill-buffer object))))
 279       (error nil))
 280     (mm-handle-set-undisplayer handle nil)))
 281
 282 (defun mm-display-inline (handle)
 283   (let* ((type (car (mm-handle-type handle)))
 284          (function (cadr (assoc type mm-inline-media-tests))))
 285     (funcall function handle)
 286     (goto-char (point-min))))
 287
 288 (defun mm-inlinable-p (type)
 289   "Say whether TYPE can be displayed inline."
 290   (let ((alist mm-inline-media-tests)
 291         test)
 292     (while alist
 293       (when (equal type (caar alist))
 294         (setq test (caddar alist)
 295               alist nil)
 296         (setq test (eval test)))
 297       (pop alist))
 298     test))
 299
 300 (defun mm-user-method (type)
 301   "Return the user-defined method for TYPE."
 302   (let ((methods mm-user-display-methods)
 303         method result)
 304     (while (setq method (pop methods))
 305       (when (string-match (car method) type)
 306         (when (or (not (eq (cdr method) 'inline))
 307                   (mm-inlinable-p type))
 308           (setq result (cdr method)
 309                 methods nil))))
 310     result))
 311
 312 (defun mm-automatic-display-p (type)
 313   "Return the user-defined method for TYPE."
 314   (let ((methods mm-user-automatic-display)
 315         method result)
 316     (while (setq method (pop methods))
 317       (when (string-match method type)
 318         (setq result t
 319               methods nil)))
 320     result))
 321
 322 (defun add-mime-display-method (type method)
 323   "Make parts of TYPE be displayed with METHOD.
 324 This overrides entries in the mailcap file."
 325   (push (cons type method) mm-user-display-methods))
 326
 327 (defun mm-destroy-part (handle)
 328   "Destroy the data structures connected to HANDLE."
 329   (mm-remove-part handle)
 330   (when (buffer-live-p (mm-handle-buffer handle))
 331     (kill-buffer (mm-handle-buffer handle))))
 332
 333 (defun mm-handle-displayed-p (handle)
 334   "Say whether HANDLE is displayed or not."
 335   (mm-handle-undisplayer handle))
 336
 337 (defun mm-quote-arg (arg)
 338   "Return a version of ARG that is safe to evaluate in a shell."
 339   (let ((pos 0) new-pos accum)
 340     ;; *** bug: we don't handle newline characters properly
 341     (while (setq new-pos (string-match "[!`\"$\\& \t{} ]" arg pos))
 342       (push (substring arg pos new-pos) accum)
 343       (push "\\" accum)
 344       (push (list (aref arg new-pos)) accum)
 345       (setq pos (1+ new-pos)))
 346     (if (= pos 0)
 347         arg
 348       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 349
 350 ;;;
 351 ;;; Functions for outputting parts
 352 ;;;
 353
 354 (defun mm-get-part (handle)
 355   "Return the contents of HANDLE as a string."
 356   (mm-with-unibyte-buffer
 357     (insert-buffer-substring (mm-handle-buffer handle))
 358     (mm-decode-content-transfer-encoding
 359      (mm-handle-encoding handle)
 360      (car (mm-handle-type handle)))
 361     (buffer-string)))
 362
 363 (defvar mm-default-directory nil)
 364
 365 (defun mm-save-part (handle)
 366   "Write HANDLE to a file."
 367   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
 368          (filename (mail-content-type-get
 369                     (mm-handle-disposition handle) 'filename))
 370          file)
 371     (when filename
 372       (setq filename (file-name-nondirectory filename)))
 373     (setq file
 374           (read-file-name "Save MIME part to: "
 375                           (expand-file-name
 376                            (or filename name "")
 377                            (or mm-default-directory default-directory))))
 378     (setq mm-default-directory (file-name-directory file))
 379     (mm-with-unibyte-buffer
 380       (insert-buffer-substring (mm-handle-buffer handle))
 381       (mm-decode-content-transfer-encoding
 382        (mm-handle-encoding handle)
 383        (car (mm-handle-type handle)))
 384       (when (or (not (file-exists-p file))
 385                 (yes-or-no-p (format "File %s already exists; overwrite? "
 386                                      file)))
 387         (write-region (point-min) (point-max) file)))))
 388
 389 (defun mm-pipe-part (handle)
 390   "Pipe HANDLE to a process."
 391   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
 392          (command
 393           (read-string "Shell command on MIME part: " mm-last-shell-command)))
 394     (mm-with-unibyte-buffer
 395       (insert-buffer-substring (mm-handle-buffer handle))
 396       (mm-decode-content-transfer-encoding
 397        (mm-handle-encoding handle)
 398        (car (mm-handle-type handle)))
 399       (shell-command-on-region (point-min) (point-max) command nil))))
 400
 401 (defun mm-interactively-view-part (handle)
 402   "Display HANDLE using METHOD."
 403   (let* ((type (car (mm-handle-type handle)))
 404          (methods
 405           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
 406                   (mailcap-mime-info type 'all)))
 407          (method (completing-read "Viewer: " methods)))
 408     (mm-display-external (copy-sequence handle) method)))
 409
 410 (defun mm-preferred-alternative (handles &optional preferred)
 411   "Say which of HANDLES are preferred."
 412   (let ((prec (if preferred (list preferred) mm-alternative-precedence))
 413         p h result type)
 414     (while (setq p (pop prec))
 415       (setq h handles)
 416       (while h
 417         (setq type (car (mm-handle-type (car h))))
 418         (when (and (equal p type)
 419                    (mm-automatic-display-p type)
 420                    (or (not (mm-handle-disposition (car h)))
 421                        (equal (car (mm-handle-disposition (car h)))
 422                               "inline")))
 423           (setq result (car h)
 424                 h nil
 425                 prec nil))
 426         (pop h)))
 427     result))
 428
 429 (defun mm-get-content-id (id)
 430   "Return the handle(s) referred to by ID."
 431   (cdr (assoc id mm-content-id-alist)))
 432
 433 (provide 'mm-decode)
 434
 435 ;; mm-decode.el ends here