cgit.sxemacs.org Git - gnus/blob - lisp/mm-bodies.el

   1 ;;; mm-bodies.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-and-compile
  30   (or (fboundp  'base64-decode-region)
  31       (require 'base64)))
  32
  33 (eval-when-compile
  34   (defvar mm-uu-decode-function)
  35   (defvar mm-uu-binhex-decode-function))
  36
  37 (require 'mm-util)
  38 (require 'rfc2047)
  39 (require 'mm-encode)
  40
  41 ;; 8bit treatment gets any char except: 0x32 - 0x7f, CR, LF, TAB, BEL,
  42 ;; BS, vertical TAB, form feed, and ^_
  43 (defvar mm-7bit-chars "\x20-\x7f\r\n\t\x7\x8\xb\xc\x1f")
  44
  45 (defcustom mm-body-charset-encoding-alist
  46   '((iso-2022-jp . 7bit)
  47     (iso-2022-jp-2 . 7bit)
  48     ;; We MUST encode UTF-16 because it can contain \0's which is
  49     ;; known to break servers.
  50     ;; Note: UTF-16 variants are invalid for text parts [RFC 2781],
  51     ;; so this can't happen :-/.
  52     (utf-16 . base64)
  53     (utf-16be . base64)
  54     (utf-16le . base64))
  55   "Alist of MIME charsets to encodings.
  56 Valid encodings are `7bit', `8bit', `quoted-printable' and `base64'."
  57   :type '(repeat (cons (symbol :tag "charset")
  58                        (choice :tag "encoding"
  59                                (const 7bit)
  60                                (const 8bit)
  61                                (const quoted-printable)
  62                                (const base64))))
  63   :group 'mime)
  64
  65 (defun mm-encode-body (&optional charset)
  66   "Encode a body.
  67 Should be called narrowed to the body that is to be encoded.
  68 If there is more than one non-ASCII MULE charset in the body, then the
  69 list of MULE charsets found is returned.
  70 If CHARSET is non-nil, it is used as the MIME charset to encode the body.
  71 If successful, the MIME charset is returned.
  72 If no encoding was done, nil is returned."
  73   (if (not (mm-multibyte-p))
  74       ;; In the non-Mule case, we search for non-ASCII chars and
  75       ;; return the value of `mail-parse-charset' if any are found.
  76       (or charset
  77           (save-excursion
  78             (goto-char (point-min))
  79             (if (re-search-forward "[^\x0-\x7f]" nil t)
  80                 (or mail-parse-charset
  81                     (message-options-get 'mm-encody-body-charset)
  82                     (message-options-set
  83                      'mm-encody-body-charset
  84                      (mm-read-coding-system "Charset used in the article: ")))
  85               ;; The logic in `mml-generate-mime-1' confirms that it's OK
  86               ;; to return nil here.
  87               nil)))
  88     (save-excursion
  89       (if charset
  90           (progn
  91             (mm-encode-coding-region (point-min) (point-max) charset)
  92             charset)
  93         (goto-char (point-min))
  94         (let ((charsets (mm-find-mime-charset-region (point-min) (point-max)
  95                                                      mm-hack-charsets)))
  96           (cond
  97            ;; No encoding.
  98            ((null charsets)
  99             nil)
 100            ;; Too many charsets.
 101            ((> (length charsets) 1)
 102             charsets)
 103            ;; We encode.
 104            (t
 105             (prog1
 106                 (setq charset (car charsets))
 107               (mm-encode-coding-region (point-min) (point-max)
 108                                        (mm-charset-to-coding-system charset))))
 109            ))))))
 110
 111 (defun mm-long-lines-p (length)
 112   "Say whether any of the lines in the buffer is longer than LENGTH."
 113   (save-excursion
 114     (goto-char (point-min))
 115     (end-of-line)
 116     (while (and (not (eobp))
 117                 (not (> (current-column) length)))
 118       (forward-line 1)
 119       (end-of-line))
 120     (and (> (current-column) length)
 121          (current-column))))
 122
 123 (defvar message-posting-charset)
 124
 125 (defun mm-body-encoding (charset &optional encoding)
 126   "Do Content-Transfer-Encoding and return the encoding of the current buffer."
 127   (when (stringp encoding)
 128     (setq encoding (intern (downcase encoding))))
 129   (let ((bits (mm-body-7-or-8))
 130         (longp (mm-long-lines-p 1000)))
 131     (require 'message)
 132     (cond
 133      ((and (not longp)
 134            (eq bits '7bit))
 135       bits)
 136      ((and (not mm-use-ultra-safe-encoding)
 137            (not longp)
 138            (not (cdr (assq charset mm-body-charset-encoding-alist)))
 139            (or (eq t (cdr message-posting-charset))
 140                (memq charset (cdr message-posting-charset))
 141                (eq charset mail-parse-charset)))
 142       bits)
 143      (t
 144       (let ((encoding (or encoding
 145                           (cdr (assq charset mm-body-charset-encoding-alist))
 146                           (mm-qp-or-base64))))
 147         (when mm-use-ultra-safe-encoding
 148           (setq encoding (mm-safer-encoding encoding)))
 149         (mm-encode-content-transfer-encoding encoding "text/plain")
 150         encoding)))))
 151
 152 (defun mm-body-7-or-8 ()
 153   "Say whether the body is 7bit or 8bit."
 154   (if (save-excursion
 155         (goto-char (point-min))
 156         (skip-chars-forward mm-7bit-chars)
 157         (eobp))
 158       '7bit
 159     '8bit))
 160
 161 ;;;
 162 ;;; Functions for decoding
 163 ;;;
 164
 165 (eval-when-compile (defvar mm-uu-yenc-decode-function))
 166
 167 (defun mm-decode-content-transfer-encoding (encoding &optional type)
 168   "Decodes buffer encoded with ENCODING, returning success status.
 169 If TYPE is `text/plain' CRLF->LF translation may occur."
 170   (prog1
 171       (condition-case error
 172           (cond
 173            ((eq encoding 'quoted-printable)
 174             (quoted-printable-decode-region (point-min) (point-max))
 175             t)
 176            ((eq encoding 'base64)
 177             (base64-decode-region
 178              (point-min)
 179              ;; Some mailers insert whitespace
 180              ;; junk at the end which
 181              ;; base64-decode-region dislikes.
 182              ;; Also remove possible junk which could
 183              ;; have been added by mailing list software.
 184              (save-excursion
 185                (goto-char (point-min))
 186                (while (re-search-forward "^[\t ]*\r?\n" nil t)
 187                  (delete-region (match-beginning 0) (match-end 0)))
 188                (goto-char (point-max))
 189                (when (re-search-backward "^[A-Za-z0-9+/]+=*[\t ]*$" nil t)
 190                  (forward-line))
 191                (point))))
 192            ((memq encoding '(7bit 8bit binary))
 193             ;; Do nothing.
 194             t)
 195            ((null encoding)
 196             ;; Do nothing.
 197             t)
 198            ((memq encoding '(x-uuencode x-uue))
 199             (require 'mm-uu)
 200             (funcall mm-uu-decode-function (point-min) (point-max))
 201             t)
 202            ((eq encoding 'x-binhex)
 203             (require 'mm-uu)
 204             (funcall mm-uu-binhex-decode-function (point-min) (point-max))
 205             t)
 206            ((eq encoding 'x-yenc)
 207             (require 'mm-uu)
 208             (funcall mm-uu-yenc-decode-function (point-min) (point-max))
 209             )
 210            ((functionp encoding)
 211             (funcall encoding (point-min) (point-max))
 212             t)
 213            (t
 214             (message "Unknown encoding %s; defaulting to 8bit" encoding)))
 215         (error
 216          (message "Error while decoding: %s" error)
 217          nil))
 218     (when (and
 219            (memq encoding '(base64 x-uuencode x-uue x-binhex x-yenc))
 220            (equal type "text/plain"))
 221       (goto-char (point-min))
 222       (while (search-forward "\r\n" nil t)
 223         (replace-match "\n" t t)))))
 224
 225 (defun mm-decode-body (charset &optional encoding type)
 226   "Decode the current article that has been encoded with ENCODING to CHARSET.
 227 ENCODING is a MIME content transfer encoding.
 228 CHARSET is the MIME charset with which to decode the data after transfer
 229 decoding.  If it is nil, default to `mail-parse-charset'."
 230   (when (stringp charset)
 231     (setq charset (intern (downcase charset))))
 232   (when (or (not charset)
 233             (eq 'gnus-all mail-parse-ignored-charsets)
 234             (memq 'gnus-all mail-parse-ignored-charsets)
 235             (memq charset mail-parse-ignored-charsets))
 236     (setq charset mail-parse-charset))
 237   (save-excursion
 238     (when encoding
 239       (mm-decode-content-transfer-encoding encoding type))
 240     (when (featurep 'mule)  ; Fixme: Wrong test for unibyte session.
 241       (let ((coding-system (mm-charset-to-coding-system charset)))
 242         (if (and (not coding-system)
 243                  (listp mail-parse-ignored-charsets)
 244                  (memq 'gnus-unknown mail-parse-ignored-charsets))
 245             (setq coding-system
 246                   (mm-charset-to-coding-system mail-parse-charset)))
 247         (when (and charset coding-system
 248                    ;; buffer-file-coding-system
 249                    ;;Article buffer is nil coding system
 250                    ;;in XEmacs
 251                    (mm-multibyte-p)
 252                    (or (not (eq coding-system 'ascii))
 253                        (setq coding-system mail-parse-charset))
 254                    (not (eq coding-system 'gnus-decoded)))
 255           (mm-decode-coding-region (point-min) (point-max)
 256                                    coding-system))
 257         (setq buffer-file-coding-system
 258               (if (boundp 'last-coding-system-used)
 259                   (symbol-value 'last-coding-system-used)
 260                 coding-system))))))
 261
 262 (defun mm-decode-string (string charset)
 263   "Decode STRING with CHARSET."
 264   (when (stringp charset)
 265     (setq charset (intern (downcase charset))))
 266   (when (or (not charset)
 267             (eq 'gnus-all mail-parse-ignored-charsets)
 268             (memq 'gnus-all mail-parse-ignored-charsets)
 269             (memq charset mail-parse-ignored-charsets))
 270     (setq charset mail-parse-charset))
 271   (or
 272    (when (featurep 'mule)
 273      (let ((coding-system (mm-charset-to-coding-system charset)))
 274        (if (and (not coding-system)
 275                 (listp mail-parse-ignored-charsets)
 276                 (memq 'gnus-unknown mail-parse-ignored-charsets))
 277            (setq coding-system
 278                  (mm-charset-to-coding-system mail-parse-charset)))
 279        (when (and charset coding-system
 280                   (mm-multibyte-p)
 281                   (or (not (eq coding-system 'ascii))
 282                       (setq coding-system mail-parse-charset)))
 283          (mm-decode-coding-string string coding-system))))
 284    string))
 285
 286 (provide 'mm-bodies)
 287
 288 ;;; mm-bodies.el ends here