cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'text-props)
  31 (defvar menu-bar-mode (featurep 'menubar))
  32 (require 'messagexmas)
  33 (require 'wid-edit)
  34
  35 (defgroup gnus-xmas nil
  36   "XEmacsoid support for Gnus"
  37   :group 'gnus)
  38
  39 (defcustom gnus-xmas-glyph-directory nil
  40   "Directory where Gnus logos and icons are located.
  41 If this variable is nil, Gnus will try to locate the directory
  42 automatically."
  43   :type '(choice (const :tag "autodetect" nil)
  44                  directory)
  45   :group 'gnus-xmas)
  46
  47 (unless gnus-xmas-glyph-directory
  48   (unless (setq gnus-xmas-glyph-directory
  49                 (message-xmas-find-glyph-directory "gnus"))
  50     (error "Can't find glyph directory. \
  51 Possibly the `etc' directory has not been installed.")))
  52
  53 ;;; Internal variables.
  54
  55 ;; Don't warn about these undefined variables.
  56
  57 ;;defined in gnus.el
  58 (defvar gnus-active-hashtb)
  59 (defvar gnus-article-buffer)
  60 (defvar gnus-auto-center-summary)
  61 (defvar gnus-current-headers)
  62 (defvar gnus-level-killed)
  63 (defvar gnus-level-zombie)
  64 (defvar gnus-newsgroup-bookmarks)
  65 (defvar gnus-newsgroup-dependencies)
  66 (defvar gnus-newsgroup-selected-overlay)
  67 (defvar gnus-newsrc-hashtb)
  68 (defvar gnus-read-mark)
  69 (defvar gnus-refer-article-method)
  70 (defvar gnus-reffed-article-number)
  71 (defvar gnus-unread-mark)
  72 (defvar gnus-version)
  73 (defvar gnus-view-pseudos)
  74 (defvar gnus-view-pseudos-separately)
  75 (defvar gnus-visual)
  76 (defvar gnus-zombie-list)
  77 ;;defined in gnus-msg.el
  78 (defvar gnus-article-copy)
  79 (defvar gnus-check-before-posting)
  80 ;;defined in gnus-vis.el
  81 (defvar gnus-article-button-face)
  82 (defvar gnus-article-mouse-face)
  83 (defvar gnus-summary-selected-face)
  84 (defvar gnus-group-reading-menu)
  85 (defvar gnus-group-group-menu)
  86 (defvar gnus-group-misc-menu)
  87 (defvar gnus-summary-article-menu)
  88 (defvar gnus-summary-thread-menu)
  89 (defvar gnus-summary-misc-menu)
  90 (defvar gnus-summary-post-menu)
  91 (defvar gnus-summary-kill-menu)
  92 (defvar gnus-article-article-menu)
  93 (defvar gnus-article-treatment-menu)
  94 (defvar gnus-mouse-2)
  95 (defvar standard-display-table)
  96 (defvar gnus-tree-minimize-window)
  97
  98 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
  99   "You should NEVER use this function.  It is ideologically blasphemous.
 100 It is provided only to ease porting of broken FSF Emacs programs."
 101   (if (stringp buffer)
 102       nil
 103     (map-extents (lambda (extent ignored)
 104                    (remove-text-properties
 105                     start end
 106                     (list (extent-property extent 'text-prop) nil)
 107                     buffer)
 108                    nil)
 109                  buffer start end nil nil 'text-prop)
 110     (gnus-add-text-properties start end props buffer)))
 111
 112 (defun gnus-xmas-highlight-selected-summary ()
 113   ;; Highlight selected article in summary buffer
 114   (when gnus-summary-selected-face
 115     (when gnus-newsgroup-selected-overlay
 116       (delete-extent gnus-newsgroup-selected-overlay))
 117     (setq gnus-newsgroup-selected-overlay
 118           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 119     (set-extent-face gnus-newsgroup-selected-overlay
 120                      gnus-summary-selected-face)))
 121
 122 (defcustom gnus-xmas-force-redisplay nil
 123   "*If non-nil, force a redisplay before recentering the summary buffer.
 124 This is ugly, but it works around a bug in `window-displayed-height'."
 125   :type 'boolean
 126   :group 'gnus-xmas)
 127
 128 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 129   (when (featurep 'scrollbar)
 130     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 131
 132 (defun gnus-xmas-summary-recenter ()
 133   "\"Center\" point in the summary window.
 134 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 135 displayed, no centering will be performed."
 136   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 137   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 138   ;; Force redisplay to get properly computed window height.
 139   (when gnus-xmas-force-redisplay
 140     (sit-for 0))
 141   (when gnus-auto-center-summary
 142     (let* ((height (if (fboundp 'window-displayed-height)
 143                        (window-displayed-height)
 144                      (- (window-height) 2)))
 145            (top (cond ((< height 4) 0)
 146                       ((< height 7) 1)
 147                       (t (if (numberp gnus-auto-center-summary)
 148                              gnus-auto-center-summary
 149                            2))))
 150            (bottom (save-excursion (goto-char (point-max))
 151                                    (forward-line (- height))
 152                                    (point)))
 153            (window (get-buffer-window (current-buffer))))
 154       (when (get-buffer-window gnus-article-buffer)
 155         ;; Only do recentering when the article buffer is displayed,
 156         ;; Set the window start to either `bottom', which is the biggest
 157         ;; possible valid number, or the second line from the top,
 158         ;; whichever is the least.
 159         ;; NOFORCE parameter suggested by Daniel Pittman <daniel@danann.net>.
 160         (set-window-start
 161          window (min bottom (save-excursion (forward-line (- top)) (point)))
 162          t))
 163       ;; Do horizontal recentering while we're at it.
 164       (when (and (get-buffer-window (current-buffer) t)
 165                  (not (eq gnus-auto-center-summary 'vertical)))
 166         (let ((selected (selected-window)))
 167           (select-window (get-buffer-window (current-buffer) t))
 168           (gnus-summary-position-point)
 169           (gnus-horizontal-recenter)
 170           (select-window selected))))))
 171
 172 (defun gnus-xmas-summary-set-display-table ()
 173   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 174   ;; but done in an XEmacsish way.
 175   (let ((table (make-display-table))
 176         (i 32))
 177     ;; Nix out all the control chars...
 178     (while (>= (setq i (1- i)) 0)
 179       (aset table i [??]))
 180     ;; ... but not newline and cr, of course.  (cr is necessary for the
 181     ;; selective display).
 182     (aset table ?\n nil)
 183     (aset table ?\r nil)
 184     ;; We keep TAB as well.
 185     (aset table ?\t nil)
 186     ;; We nix out any glyphs over 126 below ctl-arrow.
 187     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 188       (while (>= (setq i (1- i)) 127)
 189         (unless (aref table i)
 190           (aset table i [??]))))
 191     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 192     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 193
 194 (defun gnus-xmas-add-text-properties (start end props &optional object)
 195   (add-text-properties start end props object)
 196   (put-text-property start end 'start-closed nil object))
 197
 198 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 199   (put-text-property start end prop value object)
 200   (put-text-property start end 'start-closed nil object))
 201
 202 (defun gnus-xmas-extent-start-open (point)
 203   (map-extents (lambda (extent arg)
 204                  (set-extent-property extent 'start-open t))
 205                nil point (min (1+ (point)) (point-max))))
 206
 207 (defun gnus-xmas-article-push-button (event)
 208   "Check text under the mouse pointer for a callback function.
 209 If the text under the mouse pointer has a `gnus-callback' property,
 210 call it with the value of the `gnus-data' text property."
 211   (interactive "e")
 212   (set-buffer (window-buffer (event-window event)))
 213   (let* ((pos (event-closest-point event))
 214          (data (get-text-property pos 'gnus-data))
 215          (fun (get-text-property pos 'gnus-callback)))
 216     (goto-char pos)
 217     (when fun
 218       (funcall fun data))))
 219
 220 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 221   (set-extent-endpoints extent start end buffer))
 222
 223 (defun gnus-xmas-kill-all-overlays ()
 224   "Delete all extents in the current buffer."
 225   (map-extents (lambda (extent ignore)
 226                  (delete-extent extent)
 227                  nil)))
 228
 229 (defun gnus-xmas-window-top-edge (&optional window)
 230   (nth 1 (window-pixel-edges window)))
 231
 232 (defun gnus-xmas-tree-minimize ()
 233   (when (and gnus-tree-minimize-window
 234              (not (one-window-p)))
 235     (let* ((window-min-height 2)
 236            (height (1+ (count-lines (point-min) (point-max))))
 237            (min (max (1- window-min-height) height))
 238            (tot (if (numberp gnus-tree-minimize-window)
 239                     (min gnus-tree-minimize-window min)
 240                   min))
 241            (win (get-buffer-window (current-buffer)))
 242            (wh (and win (1- (window-height win)))))
 243       (when (and win
 244                  (not (eq tot wh)))
 245         (let ((selected (selected-window)))
 246           (select-window win)
 247           (enlarge-window (- tot wh))
 248           (select-window selected))))))
 249
 250 ;; Select the lowest window on the frame.
 251 (defun gnus-xmas-appt-select-lowest-window ()
 252   (let* ((lowest-window (selected-window))
 253          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 254          (last-window (previous-window))
 255          (window-search t))
 256     (while window-search
 257       (let* ((this-window (next-window))
 258              (next-bottom-edge (car (cdr (cdr (cdr
 259                                                (window-pixel-edges
 260                                                 this-window)))))))
 261         (when (< bottom-edge next-bottom-edge)
 262           (setq bottom-edge next-bottom-edge)
 263           (setq lowest-window this-window))
 264
 265         (select-window this-window)
 266         (when (eq last-window this-window)
 267           (select-window lowest-window)
 268           (setq window-search nil))))))
 269
 270 (defmacro gnus-xmas-menu-add (type &rest menus)
 271   `(gnus-xmas-menu-add-1 ',type ',menus))
 272 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 273
 274 (defun gnus-xmas-menu-add-1 (type menus)
 275   (when (and menu-bar-mode
 276              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 277     (while menus
 278       (easy-menu-add (symbol-value (pop menus))))))
 279
 280 (defun gnus-xmas-group-menu-add ()
 281   (gnus-xmas-menu-add group
 282     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 283
 284 (defun gnus-xmas-summary-menu-add ()
 285   (gnus-xmas-menu-add summary
 286     gnus-summary-misc-menu gnus-summary-kill-menu
 287     gnus-summary-article-menu gnus-summary-thread-menu
 288     gnus-summary-post-menu ))
 289
 290 (defun gnus-xmas-article-menu-add ()
 291   (gnus-xmas-menu-add article
 292     gnus-article-article-menu gnus-article-treatment-menu
 293     gnus-article-post-menu gnus-article-commands-menu))
 294
 295 (defun gnus-xmas-score-menu-add ()
 296   (gnus-xmas-menu-add score
 297     gnus-score-menu))
 298
 299 (defun gnus-xmas-pick-menu-add ()
 300   (gnus-xmas-menu-add pick
 301     gnus-pick-menu))
 302
 303 (defun gnus-xmas-topic-menu-add ()
 304   (gnus-xmas-menu-add topic
 305     gnus-topic-menu))
 306
 307 (defun gnus-xmas-binary-menu-add ()
 308   (gnus-xmas-menu-add binary
 309     gnus-binary-menu))
 310
 311 (defun gnus-xmas-agent-summary-menu-add ()
 312   (gnus-xmas-menu-add agent-summary
 313     gnus-agent-summary-menu))
 314
 315 (defun gnus-xmas-agent-group-menu-add ()
 316   (gnus-xmas-menu-add agent-group
 317     gnus-agent-group-menu))
 318
 319 (defun gnus-xmas-agent-server-menu-add ()
 320   (gnus-xmas-menu-add agent-server
 321     gnus-agent-server-menu))
 322
 323 (defun gnus-xmas-tree-menu-add ()
 324   (gnus-xmas-menu-add tree
 325     gnus-tree-menu))
 326
 327 (defun gnus-xmas-draft-menu-add ()
 328   (gnus-xmas-menu-add draft
 329     gnus-draft-menu))
 330
 331 (defun gnus-xmas-server-menu-add ()
 332   (gnus-xmas-menu-add menu
 333     gnus-server-server-menu gnus-server-connections-menu))
 334
 335 (defun gnus-xmas-browse-menu-add ()
 336   (gnus-xmas-menu-add browse
 337     gnus-browse-menu))
 338
 339 (defun gnus-xmas-grouplens-menu-add ()
 340   (gnus-xmas-menu-add grouplens
 341     gnus-grouplens-menu))
 342
 343 (defun gnus-xmas-read-event-char ()
 344   "Get the next event."
 345   (let ((event (next-command-event)))
 346     (sit-for 0)
 347     ;; We junk all non-key events.  Is this naughty?
 348     (while (not (or (key-press-event-p event)
 349                     (button-press-event-p event)))
 350       (dispatch-event event)
 351       (setq event (next-command-event)))
 352     (cons (and (key-press-event-p event)
 353                (event-to-character event))
 354           event)))
 355
 356 (defun gnus-xmas-define ()
 357   (setq gnus-mouse-2 [button2])
 358   (setq gnus-mouse-3 [button3])
 359   (setq gnus-widget-button-keymap widget-button-keymap)
 360
 361   (unless (memq 'underline (face-list))
 362     (and (fboundp 'make-face)
 363          (funcall (intern "make-face") 'underline)))
 364   ;; Must avoid calling set-face-underline-p directly, because it
 365   ;; is a defsubst in emacs19, and will make the .elc files non
 366   ;; portable!
 367   (unless (face-differs-from-default-p 'underline)
 368     (funcall (intern "set-face-underline-p") 'underline t))
 369
 370   (cond
 371    ((fboundp 'char-or-char-int-p)
 372     ;; Handle both types of marks for XEmacs-20.x.
 373     (defalias 'gnus-characterp 'char-or-char-int-p))
 374    ;; V19 of XEmacs, probably.
 375    (t
 376     (defalias 'gnus-characterp 'characterp)))
 377
 378   (defalias 'gnus-make-overlay 'make-extent)
 379   (defalias 'gnus-delete-overlay 'delete-extent)
 380   (defalias 'gnus-overlay-put 'set-extent-property)
 381   (defalias 'gnus-move-overlay 'gnus-xmas-move-overlay)
 382   (defalias 'gnus-overlay-buffer 'extent-object)
 383   (defalias 'gnus-overlay-start 'extent-start-position)
 384   (defalias 'gnus-overlay-end 'extent-end-position)
 385   (defalias 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 386   (defalias 'gnus-extent-detached-p 'extent-detached-p)
 387   (defalias 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 388   (defalias 'gnus-put-text-property 'gnus-xmas-put-text-property)
 389   (defalias 'gnus-deactivate-mark 'ignore)
 390   (defalias 'gnus-window-edges 'window-pixel-edges)
 391
 392   (if (and (<= emacs-major-version 19)
 393            (< emacs-minor-version 14))
 394       (defalias 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 395
 396   (unless (boundp 'standard-display-table)
 397     (setq standard-display-table nil))
 398
 399   (defvar gnus-mouse-face-prop 'highlight)
 400
 401   (defun gnus-byte-code (func)
 402     "Return a form that can be `eval'ed based on FUNC."
 403     (let ((fval (indirect-function func)))
 404       (if (compiled-function-p fval)
 405           (list 'funcall fval)
 406         (cons 'progn (cdr (cdr fval))))))
 407
 408   (unless (fboundp 'match-string-no-properties)
 409     (defalias 'match-string-no-properties 'match-string))
 410
 411   (defalias 'gnus-x-color-values
 412         (if (fboundp 'x-color-values)
 413             'x-color-values
 414           (lambda (color)
 415             (color-instance-rgb-components
 416              (make-color-instance color))))))
 417
 418 (defun gnus-xmas-redefine ()
 419   "Redefine lots of Gnus functions for XEmacs."
 420   (defalias 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 421   (defalias 'gnus-visual-turn-off-edit-menu 'identity)
 422   (defalias 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 423   (defalias 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 424   (defalias 'gnus-article-push-button 'gnus-xmas-article-push-button)
 425   (defalias 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 426   (defalias 'gnus-read-event-char 'gnus-xmas-read-event-char)
 427   (defalias 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 428   (defalias 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 429   (defalias 'gnus-appt-select-lowest-window
 430         'gnus-xmas-appt-select-lowest-window)
 431   (defalias 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 432   (defalias 'gnus-character-to-event 'character-to-event)
 433   (defalias 'gnus-mode-line-buffer-identification
 434         'gnus-xmas-mode-line-buffer-identification)
 435   (defalias 'gnus-key-press-event-p 'key-press-event-p)
 436   (defalias 'gnus-region-active-p 'region-active-p)
 437   (defalias 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 438   (defalias 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 439   (defalias 'gnus-image-type-available-p 'gnus-xmas-image-type-available-p)
 440   (defalias 'gnus-put-image 'gnus-xmas-put-image)
 441   (defalias 'gnus-create-image 'gnus-xmas-create-image)
 442   (defalias 'gnus-remove-image 'gnus-xmas-remove-image)
 443
 444   ;; These ones are not defcutom'ed, sometimes not even defvar'ed. They
 445   ;; probably should. If that is done, the code below should then be moved
 446   ;; where each variable is defined, in order not to mess with user settings.
 447   ;; -- didier
 448   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 449   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 450   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 451   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 452   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 453   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 454   (add-hook 'gnus-mailing-list-mode-hook 'gnus-xmas-mailing-list-menu-add))
 455
 456
 457 ;;; XEmacs logo and toolbar.
 458
 459 (defun gnus-xmas-group-startup-message (&optional x y)
 460   "Insert startup message in current buffer."
 461   ;; Insert the message.
 462   (erase-buffer)
 463   (cond
 464    ((and (console-on-window-system-p)
 465          (or (featurep 'xpm)
 466              (featurep 'xbm)))
 467     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 468            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 469            (glyph (make-glyph
 470                    (cond ((featurep 'xpm)
 471                           `[xpm
 472                             :file ,logo-xpm
 473                             :color-symbols
 474                             (("thing" . ,(car gnus-logo-colors))
 475                              ("shadow" . ,(cadr gnus-logo-colors))
 476                              ("background" . ,(face-background 'default)))])
 477                          ((featurep 'xbm)
 478                           `[xbm :file ,logo-xbm])
 479                          (t [nothing])))))
 480       (insert " ")
 481       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 482       (goto-char (point-min))
 483       (while (not (eobp))
 484         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 485                              ?\ ))
 486         (forward-line 1))
 487       (setq gnus-simple-splash nil))
 488     (goto-char (point-min))
 489     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 490            (wheight (window-height))
 491            (rest (- wheight pheight)))
 492       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 493    (t
 494     (insert
 495      (format "              %s
 496           _    ___ _             _
 497           _ ___ __ ___  __    _ ___
 498           __   _     ___    __  ___
 499               _           ___     _
 500              _  _ __             _
 501              ___   __            _
 502                    __           _
 503                     _      _   _
 504                    _      _    _
 505                       _  _    _
 506                   __  ___
 507                  _   _ _     _
 508                 _   _
 509               _    _
 510              _    _
 511             _
 512           __
 513
 514 "
 515              ""))
 516     ;; And then hack it.
 517     (gnus-indent-rigidly (point-min) (point-max)
 518                          (/ (max (- (window-width) (or x 46)) 0) 2))
 519     (goto-char (point-min))
 520     (forward-line 1)
 521     (let* ((pheight (count-lines (point-min) (point-max)))
 522            (wheight (window-height))
 523            (rest (- wheight pheight)))
 524       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 525     ;; Paint it.
 526     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 527   (setq modeline-buffer-identification
 528         (list (concat gnus-version ": *Group*")))
 529   (set-buffer-modified-p t))
 530
 531
 532 ;;; The toolbar.
 533
 534 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 535                                 'default-toolbar
 536                               nil)
 537   "*If nil, do not use a toolbar.
 538 If it is non-nil, it must be a toolbar.  The five valid values are
 539 `default-toolbar', `top-toolbar', `bottom-toolbar',
 540 `right-toolbar', and `left-toolbar'."
 541   :type '(choice (const default-toolbar)
 542                  (const top-toolbar) (const bottom-toolbar)
 543                  (const left-toolbar) (const right-toolbar)
 544                  (const :tag "no toolbar" nil))
 545   :group 'gnus-xmas)
 546
 547 (defvar gnus-group-toolbar
 548   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 549     [gnus-group-get-new-news-this-group
 550      gnus-group-get-new-news-this-group t "Get new news in this group"]
 551     [gnus-group-catchup-current
 552      gnus-group-catchup-current t "Catchup group"]
 553     [gnus-group-describe-group
 554      gnus-group-describe-group t "Describe group"]
 555     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 556     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 557     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 558     [gnus-group-exit gnus-group-exit t "Exit Gnus"])
 559   "The group buffer toolbar.")
 560
 561 (defvar gnus-summary-toolbar
 562   '([gnus-summary-prev-unread
 563      gnus-summary-prev-page-or-article t "Page up"]
 564     [gnus-summary-next-unread
 565      gnus-summary-next-page t "Page down"]
 566     [gnus-summary-post-news
 567      gnus-summary-post-news t "Post an article"]
 568     [gnus-summary-followup-with-original
 569      gnus-summary-followup-with-original t
 570      "Post a followup and yank the original"]
 571     [gnus-summary-followup
 572      gnus-summary-followup t "Post a followup"]
 573     [gnus-summary-reply-with-original
 574      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 575     [gnus-summary-reply
 576      gnus-summary-reply t "Mail a reply"]
 577     [gnus-summary-caesar-message
 578      gnus-summary-caesar-message t "Rot 13"]
 579     [gnus-uu-decode-uu
 580      gnus-uu-decode-uu t "Decode uuencoded articles"]
 581     [gnus-summary-save-article-file
 582      gnus-summary-save-article-file t "Save article in file"]
 583     [gnus-summary-save-article
 584      gnus-summary-save-article t "Save article"]
 585     [gnus-uu-post-news
 586      gnus-uu-post-news t "Post a uuencoded article"]
 587     [gnus-summary-cancel-article
 588      gnus-summary-cancel-article t "Cancel article"]
 589     [gnus-summary-catchup
 590      gnus-summary-catchup t "Catchup"]
 591     [gnus-summary-catchup-and-exit
 592      gnus-summary-catchup-and-exit t "Catchup and exit"]
 593     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 594   "The summary buffer toolbar.")
 595
 596 (defvar gnus-summary-mail-toolbar
 597   '(
 598     [gnus-summary-prev-unread
 599      gnus-summary-prev-unread-article t "Prev unread article"]
 600     [gnus-summary-next-unread
 601      gnus-summary-next-unread-article t "Next unread article"]
 602     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 603     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 604     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 605     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 606     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 607     [gnus-summary-caesar-message
 608      gnus-summary-caesar-message t "Rot 13"]
 609     [gnus-uu-decode-uu
 610      gnus-uu-decode-uu t "Decode uuencoded articles"]
 611     [gnus-summary-save-article-file
 612      gnus-summary-save-article-file t "Save article in file"]
 613     [gnus-summary-save-article
 614      gnus-summary-save-article t "Save article"]
 615     [gnus-summary-catchup
 616      gnus-summary-catchup t "Catchup"]
 617     [gnus-summary-catchup-and-exit
 618      gnus-summary-catchup-and-exit t "Catchup and exit"]
 619     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 620   "The summary buffer mail toolbar.")
 621
 622 (defun gnus-xmas-setup-group-toolbar ()
 623   (and gnus-use-toolbar
 624        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 625        (set-specifier (symbol-value gnus-use-toolbar)
 626                       (cons (current-buffer) gnus-group-toolbar))))
 627
 628 (defun gnus-xmas-setup-summary-toolbar ()
 629   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 630                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 631     (and gnus-use-toolbar
 632          (message-xmas-setup-toolbar bar nil "gnus")
 633          (set-specifier (symbol-value gnus-use-toolbar)
 634                         (cons (current-buffer) bar)))))
 635
 636 (defun gnus-xmas-mail-strip-quoted-names (address)
 637   "Protect mail-strip-quoted-names from nil input.
 638 XEmacs compatibility workaround."
 639   (if (null address)
 640       nil
 641     (mail-strip-quoted-names address)))
 642
 643 (defun gnus-xmas-call-region (command &rest args)
 644   (apply
 645    'call-process-region (point-min) (point-max) command t '(t nil) nil
 646    args))
 647
 648 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 649   "Face to show X face"
 650   :group 'gnus-xmas)
 651
 652 (defun gnus-xmas-article-display-xface (data)
 653   "Display the XFace in DATA."
 654   (save-excursion
 655     (let ((xface-glyph
 656            (cond
 657             ((featurep 'xface)
 658              (make-glyph (vector 'xface :data
 659                                  (concat "X-Face: " data))))
 660             ((featurep 'xpm)
 661              (let ((cur (current-buffer)))
 662                (save-excursion
 663                  (gnus-set-work-buffer)
 664                  (insert data)
 665                  (let ((coding-system-for-read 'binary)
 666                        (coding-system-for-write 'binary))
 667                    (gnus-xmas-call-region "uncompface")
 668                    (goto-char (point-min))
 669                    (insert "/* Width=48, Height=48 */\n")
 670                    (gnus-xmas-call-region "icontopbm")
 671                    (gnus-xmas-call-region "ppmtoxpm")
 672                    (make-glyph
 673                     (vector 'xpm :data (buffer-string)))))))
 674             (t
 675              (make-glyph [nothing])))))
 676       ;;(set-glyph-face xface-glyph 'gnus-x-face)
 677
 678       (gnus-article-goto-header "from")
 679       (gnus-put-image xface-glyph " ")
 680       (gnus-add-wash-type 'xface)
 681       (gnus-add-image 'xface xface-glyph))))
 682
 683 (defvar gnus-xmas-modeline-left-extent
 684   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 685     ext))
 686
 687 (defvar gnus-xmas-modeline-right-extent
 688   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 689     ext))
 690
 691 (defvar gnus-xmas-modeline-glyph
 692   (progn
 693     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 694                                        gnus-xmas-glyph-directory))
 695            (file-xbm (expand-file-name "gnus-pointer.xbm"
 696                                        gnus-xmas-glyph-directory))
 697            (glyph (make-glyph
 698                    ;; Gag gag gag.
 699                    (cond ((featurep 'xpm)
 700                           ;; Let's try a nifty XPM
 701                           `[xpm :file ,file-xpm])
 702                          ((featurep 'xbm)
 703                           ;; Then a not-so-nifty XBM
 704                           `[xbm :file ,file-xbm])
 705                          ;; Then the simple string
 706                          (t [string :data "Gnus:"])))))
 707       (set-glyph-face glyph 'modeline-buffer-id)
 708       glyph)))
 709
 710 (defun gnus-xmas-mode-line-buffer-identification (line)
 711   (let ((line (car line))
 712         chop)
 713     (cond
 714      ;; This is some weird type of id.
 715      ((not (stringp line))
 716       (list line))
 717      ;; This is non-standard, so we just pass it through.
 718      ((not (string-match "^Gnus:" line))
 719       (list line))
 720      ;; We have a standard line, so we colorize and glyphize it a bit.
 721      (t
 722       (setq chop (match-end 0))
 723       (list
 724        (if gnus-xmas-modeline-glyph
 725            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 726          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 727        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 728
 729 (defun gnus-xmas-splash ()
 730   (when (eq (device-type) 'x)
 731     (gnus-splash)))
 732
 733 (defun gnus-xmas-annotation-in-region-p (b e)
 734   (or (map-extents (lambda (e u) t) nil b e nil nil 'mm t)
 735       (if (= b e)
 736           (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 737         (text-property-any b e 'gnus-undeletable t))))
 738
 739 (defun gnus-xmas-mime-button-menu (event)
 740   "Construct a context-sensitive menu of MIME commands."
 741   (interactive "e")
 742   (let ((response (get-popup-menu-response
 743                    `("MIME Part"
 744                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 745                                gnus-mime-button-commands)))))
 746     (set-buffer (event-buffer event))
 747     (goto-char (event-point event))
 748     (funcall (event-function response) (event-object response))))
 749
 750 (defun gnus-group-add-icon ()
 751   "Add an icon to the current line according to `gnus-group-icon-list'."
 752   (let* ((p (point))
 753          (end (progn (end-of-line) (point)))
 754          ;; now find out where the line starts and leave point there.
 755          (beg (progn (beginning-of-line) (point))))
 756     (save-restriction
 757       (narrow-to-region beg end)
 758       (goto-char beg)
 759       (when (search-forward "==&&==" nil t)
 760         (let* ((group (gnus-group-group-name))
 761                (entry (gnus-group-entry group))
 762                (unread (if (numberp (car entry)) (car entry) 0))
 763                (active (gnus-active group))
 764                (total (if active (1+ (- (cdr active) (car active))) 0))
 765                (info (nth 2 entry))
 766                (method (gnus-server-get-method group (gnus-info-method info)))
 767                (marked (gnus-info-marks info))
 768                (mailp (memq 'mail (assoc (symbol-name
 769                                           (car (or method gnus-select-method)))
 770                                          gnus-valid-select-methods)))
 771                (level (or (gnus-info-level info) gnus-level-killed))
 772                (score (or (gnus-info-score info) 0))
 773                (ticked (gnus-range-length (cdr (assq 'tick marked))))
 774                (group-age (gnus-group-timestamp-delta group))
 775                (inhibit-read-only t)
 776                (list gnus-group-icon-list)
 777                (mystart (match-beginning 0))
 778                (myend (match-end 0)))
 779           (goto-char (point-min))
 780           (while (and list
 781                       (not (eval (caar list))))
 782             (setq list (cdr list)))
 783           (if list
 784               (let* ((file (cdar list))
 785                      (glyph (gnus-group-icon-create-glyph
 786                              (buffer-substring mystart myend)
 787                              file)))
 788                 (if glyph
 789                     (progn
 790                       (mapcar 'delete-annotation (annotations-at myend))
 791                       (let ((ext (make-extent mystart myend))
 792                             (ant (make-annotation glyph myend 'text)))
 793                         ;; set text extent params
 794                         (set-extent-property ext 'end-open t)
 795                         (set-extent-property ext 'start-open t)
 796                         (set-extent-property ext 'invisible t)))
 797                   (delete-region mystart myend)))
 798             (delete-region mystart myend))))
 799       (widen))
 800     (goto-char p)))
 801
 802 (defun gnus-group-icon-create-glyph (substring pixmap)
 803   "Create a glyph for insertion into a group line."
 804   (or
 805    (cdr-safe (assoc pixmap gnus-group-icon-cache))
 806    (let* ((glyph (make-glyph
 807                   (list
 808                    (cons 'x
 809                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 810                    (cons 'mswindows
 811                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 812                    (cons 'tty substring)))))
 813      (setq gnus-group-icon-cache
 814            (cons (cons pixmap glyph) gnus-group-icon-cache))
 815      (set-glyph-face glyph 'default)
 816      glyph)))
 817
 818 (defun gnus-xmas-mailing-list-menu-add ()
 819   (gnus-xmas-menu-add mailing-list
 820                       gnus-mailing-list-menu))
 821
 822 (defun gnus-xmas-image-type-available-p (type)
 823   (featurep type))
 824
 825 (defun gnus-xmas-create-image (file)
 826   (with-temp-buffer
 827     (insert-file-contents file)
 828     (mm-create-image-xemacs (car (last (split-string file "[.]"))))))
 829
 830 (defun gnus-xmas-put-image (glyph &optional string)
 831   (let ((begin (point))
 832         extent)
 833     (insert " ")
 834     (setq extent (make-extent begin (point)))
 835     (set-extent-property extent 'gnus-image t)
 836     (set-extent-property extent 'duplicable t)
 837     (set-extent-property extent 'begin-glyph glyph)))
 838
 839 (defun gnus-xmas-remove-image (image)
 840   (map-extents
 841    (lambda (ext unused)
 842      (when (equal (extent-begin-glyph ext) image)
 843        (set-extent-property ext 'begin-glyph nil))
 844      nil)
 845    nil nil nil nil nil 'gnus-image))
 846
 847 (provide 'gnus-xmas)
 848
 849 ;;; gnus-xmas.el ends here