cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'text-props)
  31 (defvar menu-bar-mode (featurep 'menubar))
  32 (require 'messagexmas)
  33 (require 'wid-edit)
  34
  35 (defgroup gnus-xmas nil
  36   "XEmacsoid support for Gnus"
  37   :group 'gnus)
  38
  39 (defcustom gnus-xmas-glyph-directory nil
  40   "Directory where Gnus logos and icons are located.
  41 If this variable is nil, Gnus will try to locate the directory
  42 automatically."
  43   :type '(choice (const :tag "autodetect" nil)
  44                  directory)
  45   :group 'gnus-xmas)
  46
  47 (unless gnus-xmas-glyph-directory
  48   (unless (setq gnus-xmas-glyph-directory
  49                 (message-xmas-find-glyph-directory "gnus"))
  50     (error "Can't find glyph directory. \
  51 Possibly the `etc' directory has not been installed.")))
  52
  53 ;;; Internal variables.
  54
  55 ;; Don't warn about these undefined variables.
  56
  57 ;;defined in gnus.el
  58 (defvar gnus-active-hashtb)
  59 (defvar gnus-article-buffer)
  60 (defvar gnus-auto-center-summary)
  61 (defvar gnus-current-headers)
  62 (defvar gnus-level-killed)
  63 (defvar gnus-level-zombie)
  64 (defvar gnus-newsgroup-bookmarks)
  65 (defvar gnus-newsgroup-dependencies)
  66 (defvar gnus-newsgroup-selected-overlay)
  67 (defvar gnus-newsrc-hashtb)
  68 (defvar gnus-read-mark)
  69 (defvar gnus-refer-article-method)
  70 (defvar gnus-reffed-article-number)
  71 (defvar gnus-unread-mark)
  72 (defvar gnus-version)
  73 (defvar gnus-view-pseudos)
  74 (defvar gnus-view-pseudos-separately)
  75 (defvar gnus-visual)
  76 (defvar gnus-zombie-list)
  77 ;;defined in gnus-msg.el
  78 (defvar gnus-article-copy)
  79 (defvar gnus-check-before-posting)
  80 ;;defined in gnus-vis.el
  81 (defvar gnus-article-button-face)
  82 (defvar gnus-article-mouse-face)
  83 (defvar gnus-summary-selected-face)
  84 (defvar gnus-group-reading-menu)
  85 (defvar gnus-group-group-menu)
  86 (defvar gnus-group-misc-menu)
  87 (defvar gnus-summary-article-menu)
  88 (defvar gnus-summary-thread-menu)
  89 (defvar gnus-summary-misc-menu)
  90 (defvar gnus-summary-post-menu)
  91 (defvar gnus-summary-kill-menu)
  92 (defvar gnus-article-article-menu)
  93 (defvar gnus-article-treatment-menu)
  94 (defvar gnus-mouse-2)
  95 (defvar standard-display-table)
  96 (defvar gnus-tree-minimize-window)
  97
  98 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
  99   "You should NEVER use this function.  It is ideologically blasphemous.
 100 It is provided only to ease porting of broken FSF Emacs programs."
 101   (if (stringp buffer)
 102       nil
 103     (map-extents (lambda (extent ignored)
 104                    (remove-text-properties
 105                     start end
 106                     (list (extent-property extent 'text-prop) nil)
 107                     buffer)
 108                    nil)
 109                  buffer start end nil nil 'text-prop)
 110     (gnus-add-text-properties start end props buffer)))
 111
 112 (defun gnus-xmas-highlight-selected-summary ()
 113   ;; Highlight selected article in summary buffer
 114   (when gnus-summary-selected-face
 115     (when gnus-newsgroup-selected-overlay
 116       (delete-extent gnus-newsgroup-selected-overlay))
 117     (setq gnus-newsgroup-selected-overlay
 118           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 119     (set-extent-face gnus-newsgroup-selected-overlay
 120                      gnus-summary-selected-face)))
 121
 122 (defcustom gnus-xmas-force-redisplay nil
 123   "*If non-nil, force a redisplay before recentering the summary buffer.
 124 This is ugly, but it works around a bug in `window-displayed-height'."
 125   :type 'boolean
 126   :group 'gnus-xmas)
 127
 128 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 129   (when (featurep 'scrollbar)
 130     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 131
 132 (defun gnus-xmas-summary-recenter ()
 133   "\"Center\" point in the summary window.
 134 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 135 displayed, no centering will be performed."
 136   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 137   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 138   ;; Force redisplay to get properly computed window height.
 139   (when gnus-xmas-force-redisplay
 140     (sit-for 0))
 141   (when gnus-auto-center-summary
 142     (let* ((height (if (fboundp 'window-displayed-height)
 143                        (window-displayed-height)
 144                      (- (window-height) 2)))
 145            (top (cond ((< height 4) 0)
 146                       ((< height 7) 1)
 147                       (t (if (numberp gnus-auto-center-summary)
 148                              gnus-auto-center-summary
 149                            2))))
 150            (bottom (save-excursion (goto-char (point-max))
 151                                    (forward-line (- height))
 152                                    (point)))
 153            (window (get-buffer-window (current-buffer))))
 154       (when (get-buffer-window gnus-article-buffer)
 155         ;; Only do recentering when the article buffer is displayed,
 156         ;; Set the window start to either `bottom', which is the biggest
 157         ;; possible valid number, or the second line from the top,
 158         ;; whichever is the least.
 159         ;; NOFORCE parameter suggested by Daniel Pittman <daniel@danann.net>.
 160         (set-window-start
 161          window (min bottom (save-excursion (forward-line (- top)) (point)))
 162          t))
 163       ;; Do horizontal recentering while we're at it.
 164       (when (and (get-buffer-window (current-buffer) t)
 165                  (not (eq gnus-auto-center-summary 'vertical)))
 166         (let ((selected (selected-window)))
 167           (select-window (get-buffer-window (current-buffer) t))
 168           (gnus-summary-position-point)
 169           (gnus-horizontal-recenter)
 170           (select-window selected))))))
 171
 172 (defun gnus-xmas-summary-set-display-table ()
 173   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 174   ;; but done in an XEmacsish way.
 175   (let ((table (make-display-table))
 176         (i 32))
 177     ;; Nix out all the control chars...
 178     (while (>= (setq i (1- i)) 0)
 179       (aset table i [??]))
 180     ;; ... but not newline and cr, of course.  (cr is necessary for the
 181     ;; selective display).
 182     (aset table ?\n nil)
 183     (aset table ?\r nil)
 184     ;; We keep TAB as well.
 185     (aset table ?\t nil)
 186     ;; We nix out any glyphs over 126 below ctl-arrow.
 187     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 188       (while (>= (setq i (1- i)) 127)
 189         (unless (aref table i)
 190           (aset table i [??]))))
 191     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 192     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 193
 194 (defun gnus-xmas-add-text-properties (start end props &optional object)
 195   (add-text-properties start end props object)
 196   (put-text-property start end 'start-closed nil object))
 197
 198 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 199   (put-text-property start end prop value object)
 200   (put-text-property start end 'start-closed nil object))
 201
 202 (defun gnus-xmas-extent-start-open (point)
 203   (map-extents (lambda (extent arg)
 204                  (set-extent-property extent 'start-open t))
 205                nil point (min (1+ (point)) (point-max))))
 206
 207 (defun gnus-xmas-article-push-button (event)
 208   "Check text under the mouse pointer for a callback function.
 209 If the text under the mouse pointer has a `gnus-callback' property,
 210 call it with the value of the `gnus-data' text property."
 211   (interactive "e")
 212   (set-buffer (window-buffer (event-window event)))
 213   (let* ((pos (event-closest-point event))
 214          (data (get-text-property pos 'gnus-data))
 215          (fun (get-text-property pos 'gnus-callback)))
 216     (goto-char pos)
 217     (when fun
 218       (funcall fun data))))
 219
 220 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 221   (set-extent-endpoints extent start end buffer))
 222
 223 (defun gnus-xmas-kill-all-overlays ()
 224   "Delete all extents in the current buffer."
 225   (map-extents (lambda (extent ignore)
 226                  (delete-extent extent)
 227                  nil)))
 228
 229 (defun gnus-xmas-window-top-edge (&optional window)
 230   (nth 1 (window-pixel-edges window)))
 231
 232 (defun gnus-xmas-tree-minimize ()
 233   (when (and gnus-tree-minimize-window
 234              (not (one-window-p)))
 235     (let* ((window-min-height 2)
 236            (height (1+ (count-lines (point-min) (point-max))))
 237            (min (max (1- window-min-height) height))
 238            (tot (if (numberp gnus-tree-minimize-window)
 239                     (min gnus-tree-minimize-window min)
 240                   min))
 241            (win (get-buffer-window (current-buffer)))
 242            (wh (and win (1- (window-height win)))))
 243       (when (and win
 244                  (not (eq tot wh)))
 245         (let ((selected (selected-window)))
 246           (select-window win)
 247           (enlarge-window (- tot wh))
 248           (select-window selected))))))
 249
 250 ;; Select the lowest window on the frame.
 251 (defun gnus-xmas-appt-select-lowest-window ()
 252   (let* ((lowest-window (selected-window))
 253          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 254          (last-window (previous-window))
 255          (window-search t))
 256     (while window-search
 257       (let* ((this-window (next-window))
 258              (next-bottom-edge (car (cdr (cdr (cdr
 259                                                (window-pixel-edges
 260                                                 this-window)))))))
 261         (when (< bottom-edge next-bottom-edge)
 262           (setq bottom-edge next-bottom-edge)
 263           (setq lowest-window this-window))
 264
 265         (select-window this-window)
 266         (when (eq last-window this-window)
 267           (select-window lowest-window)
 268           (setq window-search nil))))))
 269
 270 (defmacro gnus-xmas-menu-add (type &rest menus)
 271   `(gnus-xmas-menu-add-1 ',type ',menus))
 272 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 273
 274 (defun gnus-xmas-menu-add-1 (type menus)
 275   (when (and menu-bar-mode
 276              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 277     (while menus
 278       (easy-menu-add (symbol-value (pop menus))))))
 279
 280 (defun gnus-xmas-group-menu-add ()
 281   (gnus-xmas-menu-add group
 282     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 283
 284 (defun gnus-xmas-summary-menu-add ()
 285   (gnus-xmas-menu-add summary
 286     gnus-summary-misc-menu gnus-summary-kill-menu
 287     gnus-summary-article-menu gnus-summary-thread-menu
 288     gnus-summary-post-menu ))
 289
 290 (defun gnus-xmas-article-menu-add ()
 291   (gnus-xmas-menu-add article
 292     gnus-article-article-menu gnus-article-treatment-menu
 293     gnus-article-post-menu gnus-article-commands-menu))
 294
 295 (defun gnus-xmas-score-menu-add ()
 296   (gnus-xmas-menu-add score
 297     gnus-score-menu))
 298
 299 (defun gnus-xmas-pick-menu-add ()
 300   (gnus-xmas-menu-add pick
 301     gnus-pick-menu))
 302
 303 (defun gnus-xmas-topic-menu-add ()
 304   (gnus-xmas-menu-add topic
 305     gnus-topic-menu))
 306
 307 (defun gnus-xmas-binary-menu-add ()
 308   (gnus-xmas-menu-add binary
 309     gnus-binary-menu))
 310
 311 (defun gnus-xmas-agent-summary-menu-add ()
 312   (gnus-xmas-menu-add agent-summary
 313     gnus-agent-summary-menu))
 314
 315 (defun gnus-xmas-agent-group-menu-add ()
 316   (gnus-xmas-menu-add agent-group
 317     gnus-agent-group-menu))
 318
 319 (defun gnus-xmas-agent-server-menu-add ()
 320   (gnus-xmas-menu-add agent-server
 321     gnus-agent-server-menu))
 322
 323 (defun gnus-xmas-tree-menu-add ()
 324   (gnus-xmas-menu-add tree
 325     gnus-tree-menu))
 326
 327 (defun gnus-xmas-draft-menu-add ()
 328   (gnus-xmas-menu-add draft
 329     gnus-draft-menu))
 330
 331 (defun gnus-xmas-server-menu-add ()
 332   (gnus-xmas-menu-add menu
 333     gnus-server-server-menu gnus-server-connections-menu))
 334
 335 (defun gnus-xmas-browse-menu-add ()
 336   (gnus-xmas-menu-add browse
 337     gnus-browse-menu))
 338
 339 (defun gnus-xmas-grouplens-menu-add ()
 340   (gnus-xmas-menu-add grouplens
 341     gnus-grouplens-menu))
 342
 343 (defun gnus-xmas-read-event-char (&optional prompt)
 344   "Get the next event."
 345   (when prompt
 346     (message "%s" prompt))
 347   (let ((event (next-command-event)))
 348     (sit-for 0)
 349     ;; We junk all non-key events.  Is this naughty?
 350     (while (not (or (key-press-event-p event)
 351                     (button-press-event-p event)))
 352       (dispatch-event event)
 353       (setq event (next-command-event)))
 354     (cons (and (key-press-event-p event)
 355                (event-to-character event))
 356           event)))
 357
 358 (defun gnus-xmas-define ()
 359   (setq gnus-mouse-2 [button2])
 360   (setq gnus-mouse-3 [button3])
 361   (setq gnus-widget-button-keymap widget-button-keymap)
 362
 363   (unless (memq 'underline (face-list))
 364     (and (fboundp 'make-face)
 365          (funcall (intern "make-face") 'underline)))
 366   ;; Must avoid calling set-face-underline-p directly, because it
 367   ;; is a defsubst in emacs19, and will make the .elc files non
 368   ;; portable!
 369   (unless (face-differs-from-default-p 'underline)
 370     (funcall (intern "set-face-underline-p") 'underline t))
 371
 372   (cond
 373    ((fboundp 'char-or-char-int-p)
 374     ;; Handle both types of marks for XEmacs-20.x.
 375     (defalias 'gnus-characterp 'char-or-char-int-p))
 376    ;; V19 of XEmacs, probably.
 377    (t
 378     (defalias 'gnus-characterp 'characterp)))
 379
 380   (defalias 'gnus-make-overlay 'make-extent)
 381   (defalias 'gnus-delete-overlay 'delete-extent)
 382   (defalias 'gnus-overlay-put 'set-extent-property)
 383   (defalias 'gnus-move-overlay 'gnus-xmas-move-overlay)
 384   (defalias 'gnus-overlay-buffer 'extent-object)
 385   (defalias 'gnus-overlay-start 'extent-start-position)
 386   (defalias 'gnus-overlay-end 'extent-end-position)
 387   (defalias 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 388   (defalias 'gnus-extent-detached-p 'extent-detached-p)
 389   (defalias 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 390   (defalias 'gnus-put-text-property 'gnus-xmas-put-text-property)
 391   (defalias 'gnus-deactivate-mark 'ignore)
 392   (defalias 'gnus-window-edges 'window-pixel-edges)
 393   (defalias 'gnus-assq-delete-all 'gnus-xmas-assq-delete-all)
 394
 395   (if (and (<= emacs-major-version 19)
 396            (< emacs-minor-version 14))
 397       (defalias 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 398
 399   (unless (boundp 'standard-display-table)
 400     (setq standard-display-table nil))
 401
 402   (defvar gnus-mouse-face-prop 'highlight)
 403
 404   (defun gnus-byte-code (func)
 405     "Return a form that can be `eval'ed based on FUNC."
 406     (let ((fval (indirect-function func)))
 407       (if (compiled-function-p fval)
 408           (list 'funcall fval)
 409         (cons 'progn (cdr (cdr fval))))))
 410
 411   (unless (fboundp 'match-string-no-properties)
 412     (defalias 'match-string-no-properties 'match-string))
 413
 414   (defalias 'gnus-x-color-values
 415         (if (fboundp 'x-color-values)
 416             'x-color-values
 417           (lambda (color)
 418             (color-instance-rgb-components
 419              (make-color-instance color))))))
 420
 421 (defun gnus-xmas-redefine ()
 422   "Redefine lots of Gnus functions for XEmacs."
 423   (defalias 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 424   (defalias 'gnus-visual-turn-off-edit-menu 'identity)
 425   (defalias 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 426   (defalias 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 427   (defalias 'gnus-article-push-button 'gnus-xmas-article-push-button)
 428   (defalias 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 429   (defalias 'gnus-read-event-char 'gnus-xmas-read-event-char)
 430   (defalias 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 431   (defalias 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 432   (defalias 'gnus-appt-select-lowest-window
 433     'gnus-xmas-appt-select-lowest-window)
 434   (defalias 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 435   (defalias 'gnus-character-to-event 'character-to-event)
 436   (defalias 'gnus-mode-line-buffer-identification
 437     'gnus-xmas-mode-line-buffer-identification)
 438   (defalias 'gnus-key-press-event-p 'key-press-event-p)
 439   (defalias 'gnus-region-active-p 'region-active-p)
 440   (defalias 'gnus-mark-active-p 'region-exists-p)
 441   (defalias 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 442   (defalias 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 443   (defalias 'gnus-image-type-available-p 'gnus-xmas-image-type-available-p)
 444   (defalias 'gnus-put-image 'gnus-xmas-put-image)
 445   (defalias 'gnus-create-image 'gnus-xmas-create-image)
 446   (defalias 'gnus-remove-image 'gnus-xmas-remove-image)
 447
 448   (when (or (< emacs-major-version 21)
 449             (and (= emacs-major-version 21)
 450                  (< emacs-minor-version 3)))
 451     (defalias 'gnus-completing-read 'gnus-xmas-completing-read))
 452
 453   ;; These ones are not defcutom'ed, sometimes not even defvar'ed. They
 454   ;; probably should. If that is done, the code below should then be moved
 455   ;; where each variable is defined, in order not to mess with user settings.
 456   ;; -- didier
 457   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 458   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 459   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 460   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 461   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 462   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 463   (add-hook 'gnus-mailing-list-mode-hook 'gnus-xmas-mailing-list-menu-add))
 464
 465
 466 ;;; XEmacs logo and toolbar.
 467
 468 (defun gnus-xmas-group-startup-message (&optional x y)
 469   "Insert startup message in current buffer."
 470   ;; Insert the message.
 471   (erase-buffer)
 472   (cond
 473    ((and (console-on-window-system-p)
 474          (or (featurep 'xpm)
 475              (featurep 'xbm)))
 476     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 477            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 478            (glyph (make-glyph
 479                    (cond ((featurep 'xpm)
 480                           `[xpm
 481                             :file ,logo-xpm
 482                             :color-symbols
 483                             (("thing" . ,(car gnus-logo-colors))
 484                              ("shadow" . ,(cadr gnus-logo-colors))
 485                              ("oort" . "#eeeeee")
 486                              ("background" . ,(face-background 'default)))])
 487                          ((featurep 'xbm)
 488                           `[xbm :file ,logo-xbm])
 489                          (t [nothing])))))
 490       (insert " ")
 491       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 492       (goto-char (point-min))
 493       (while (not (eobp))
 494         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 495                              ?\ ))
 496         (forward-line 1))
 497       (setq gnus-simple-splash nil))
 498     (goto-char (point-min))
 499     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 500            (wheight (window-height))
 501            (rest (- wheight pheight)))
 502       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 503    (t
 504     (insert
 505      (format "              %s
 506           _    ___ _             _
 507           _ ___ __ ___  __    _ ___
 508           __   _     ___    __  ___
 509               _           ___     _
 510              _  _ __             _
 511              ___   __            _
 512                    __           _
 513                     _      _   _
 514                    _      _    _
 515                       _  _    _
 516                   __  ___
 517                  _   _ _     _
 518                 _   _
 519               _    _
 520              _    _
 521             _
 522           __
 523
 524 "
 525              ""))
 526     ;; And then hack it.
 527     (gnus-indent-rigidly (point-min) (point-max)
 528                          (/ (max (- (window-width) (or x 46)) 0) 2))
 529     (goto-char (point-min))
 530     (forward-line 1)
 531     (let* ((pheight (count-lines (point-min) (point-max)))
 532            (wheight (window-height))
 533            (rest (- wheight pheight)))
 534       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 535     ;; Paint it.
 536     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 537   (setq modeline-buffer-identification
 538         (list (concat gnus-version ": *Group*")))
 539   (set-buffer-modified-p t))
 540
 541
 542 ;;; The toolbar.
 543
 544 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 545                                 'default-toolbar
 546                               nil)
 547   "*If nil, do not use a toolbar.
 548 If it is non-nil, it must be a toolbar.  The five valid values are
 549 `default-toolbar', `top-toolbar', `bottom-toolbar',
 550 `right-toolbar', and `left-toolbar'."
 551   :type '(choice (const default-toolbar)
 552                  (const top-toolbar) (const bottom-toolbar)
 553                  (const left-toolbar) (const right-toolbar)
 554                  (const :tag "no toolbar" nil))
 555   :group 'gnus-xmas)
 556
 557 (defvar gnus-group-toolbar
 558   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 559     [gnus-group-get-new-news-this-group
 560      gnus-group-get-new-news-this-group t "Get new news in this group"]
 561     [gnus-group-catchup-current
 562      gnus-group-catchup-current t "Catchup group"]
 563     [gnus-group-describe-group
 564      gnus-group-describe-group t "Describe group"]
 565     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 566     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 567     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 568     [gnus-summary-mail-save
 569      gnus-group-save-newsrc t "Save .newsrc files"] ; borrowed icon.
 570     [gnus-group-exit gnus-group-exit t "Exit Gnus"])
 571   "The group buffer toolbar.")
 572
 573 (defvar gnus-summary-toolbar
 574   '([gnus-summary-prev-unread
 575      gnus-summary-prev-page-or-article t "Page up"]
 576     [gnus-summary-next-unread
 577      gnus-summary-next-page t "Page down"]
 578     [gnus-summary-post-news
 579      gnus-summary-post-news t "Post an article"]
 580     [gnus-summary-followup-with-original
 581      gnus-summary-followup-with-original t
 582      "Post a followup and yank the original"]
 583     [gnus-summary-followup
 584      gnus-summary-followup t "Post a followup"]
 585     [gnus-summary-reply-with-original
 586      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 587     [gnus-summary-reply
 588      gnus-summary-reply t "Mail a reply"]
 589     [gnus-summary-caesar-message
 590      gnus-summary-caesar-message t "Rot 13"]
 591     [gnus-uu-decode-uu
 592      gnus-uu-decode-uu t "Decode uuencoded articles"]
 593     [gnus-summary-save-article-file
 594      gnus-summary-save-article-file t "Save article in file"]
 595     [gnus-summary-save-article
 596      gnus-summary-save-article t "Save article"]
 597     [gnus-uu-post-news
 598      gnus-uu-post-news t "Post a uuencoded article"]
 599     [gnus-summary-cancel-article
 600      gnus-summary-cancel-article t "Cancel article"]
 601     [gnus-summary-catchup
 602      gnus-summary-catchup t "Catchup"]
 603     [gnus-summary-catchup-and-exit
 604      gnus-summary-catchup-and-exit t "Catchup and exit"]
 605     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 606   "The summary buffer toolbar.")
 607
 608 (defvar gnus-summary-mail-toolbar
 609   '(
 610     [gnus-summary-prev-unread
 611      gnus-summary-prev-unread-article t "Prev unread article"]
 612     [gnus-summary-next-unread
 613      gnus-summary-next-unread-article t "Next unread article"]
 614     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 615     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 616     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 617     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 618     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 619     [gnus-summary-caesar-message
 620      gnus-summary-caesar-message t "Rot 13"]
 621     [gnus-uu-decode-uu
 622      gnus-uu-decode-uu t "Decode uuencoded articles"]
 623     [gnus-summary-save-article-file
 624      gnus-summary-save-article-file t "Save article in file"]
 625     [gnus-summary-save-article
 626      gnus-summary-save-article t "Save article"]
 627     [gnus-summary-cancel-article ; usenet : cancellation :: mail : deletion.
 628      gnus-summary-delete-article t "Delete message"]
 629     [gnus-summary-catchup
 630      gnus-summary-catchup t "Catchup"]
 631     [gnus-summary-catchup-and-exit
 632      gnus-summary-catchup-and-exit t "Catchup and exit"]
 633     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 634   "The summary buffer mail toolbar.")
 635
 636 (defun gnus-xmas-setup-group-toolbar ()
 637   (and gnus-use-toolbar
 638        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 639        (set-specifier (symbol-value gnus-use-toolbar)
 640                       (cons (current-buffer) gnus-group-toolbar))))
 641
 642 (defun gnus-xmas-setup-summary-toolbar ()
 643   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 644                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 645     (and gnus-use-toolbar
 646          (message-xmas-setup-toolbar bar nil "gnus")
 647          (set-specifier (symbol-value gnus-use-toolbar)
 648                         (cons (current-buffer) bar)))))
 649
 650 (defun gnus-xmas-mail-strip-quoted-names (address)
 651   "Protect mail-strip-quoted-names from nil input.
 652 XEmacs compatibility workaround."
 653   (if (null address)
 654       nil
 655     (mail-strip-quoted-names address)))
 656
 657 (defun gnus-xmas-call-region (command &rest args)
 658   (apply
 659    'call-process-region (point-min) (point-max) command t '(t nil) nil
 660    args))
 661
 662 (defvar gnus-xmas-modeline-left-extent
 663   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 664     ext))
 665
 666 (defvar gnus-xmas-modeline-right-extent
 667   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 668     ext))
 669
 670 (defvar gnus-xmas-modeline-glyph
 671   (progn
 672     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 673                                        gnus-xmas-glyph-directory))
 674            (file-xbm (expand-file-name "gnus-pointer.xbm"
 675                                        gnus-xmas-glyph-directory))
 676            (glyph (make-glyph
 677                    ;; Gag gag gag.
 678                    (cond ((featurep 'xpm)
 679                           ;; Let's try a nifty XPM
 680                           `[xpm :file ,file-xpm])
 681                          ((featurep 'xbm)
 682                           ;; Then a not-so-nifty XBM
 683                           `[xbm :file ,file-xbm])
 684                          ;; Then the simple string
 685                          (t [string :data "Gnus:"])))))
 686       (set-glyph-face glyph 'modeline-buffer-id)
 687       glyph)))
 688
 689 (defun gnus-xmas-mode-line-buffer-identification (line)
 690   (let ((line (car line))
 691         chop)
 692     (cond
 693      ;; This is some weird type of id.
 694      ((not (stringp line))
 695       (list line))
 696      ;; This is non-standard, so we just pass it through.
 697      ((not (string-match "^Gnus:" line))
 698       (list line))
 699      ;; We have a standard line, so we colorize and glyphize it a bit.
 700      (t
 701       (setq chop (match-end 0))
 702       (list
 703        (if gnus-xmas-modeline-glyph
 704            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 705          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 706        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 707
 708 (defun gnus-xmas-splash ()
 709   (when (eq (device-type) 'x)
 710     (gnus-splash)))
 711
 712 (defun gnus-xmas-annotation-in-region-p (b e)
 713   (or (map-extents (lambda (e u) t) nil b e nil nil 'mm t)
 714       (if (= b e)
 715           (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 716         (text-property-any b e 'gnus-undeletable t))))
 717
 718 (defun gnus-xmas-mime-button-menu (event prefix)
 719   "Construct a context-sensitive menu of MIME commands."
 720   (interactive "e\nP")
 721   (let ((response (get-popup-menu-response
 722                    `("MIME Part"
 723                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 724                                gnus-mime-button-commands)))))
 725     (set-buffer (event-buffer event))
 726     (goto-char (event-point event))
 727     (funcall (event-function response) (event-object response))))
 728
 729 (defun gnus-group-add-icon ()
 730   "Add an icon to the current line according to `gnus-group-icon-list'."
 731   (let* ((p (point))
 732          (end (gnus-point-at-eol))
 733          ;; now find out where the line starts and leave point there.
 734          (beg (progn (beginning-of-line) (point))))
 735     (save-restriction
 736       (narrow-to-region beg end)
 737       (goto-char beg)
 738       (when (search-forward "==&&==" nil t)
 739         (let* ((group (gnus-group-group-name))
 740                (entry (gnus-group-entry group))
 741                (unread (if (numberp (car entry)) (car entry) 0))
 742                (active (gnus-active group))
 743                (total (if active (1+ (- (cdr active) (car active))) 0))
 744                (info (nth 2 entry))
 745                (method (gnus-server-get-method group (gnus-info-method info)))
 746                (marked (gnus-info-marks info))
 747                (mailp (memq 'mail (assoc (symbol-name
 748                                           (car (or method gnus-select-method)))
 749                                          gnus-valid-select-methods)))
 750                (level (or (gnus-info-level info) gnus-level-killed))
 751                (score (or (gnus-info-score info) 0))
 752                (ticked (gnus-range-length (cdr (assq 'tick marked))))
 753                (group-age (gnus-group-timestamp-delta group))
 754                (inhibit-read-only t)
 755                (list gnus-group-icon-list)
 756                (mystart (match-beginning 0))
 757                (myend (match-end 0)))
 758           (goto-char (point-min))
 759           (while (and list
 760                       (not (eval (caar list))))
 761             (setq list (cdr list)))
 762           (if list
 763               (let* ((file (cdar list))
 764                      (glyph (gnus-group-icon-create-glyph
 765                              (buffer-substring mystart myend)
 766                              file)))
 767                 (if glyph
 768                     (progn
 769                       (mapcar 'delete-annotation (annotations-at myend))
 770                       (let ((ext (make-extent mystart myend))
 771                             (ant (make-annotation glyph myend 'text)))
 772                         ;; set text extent params
 773                         (set-extent-property ext 'end-open t)
 774                         (set-extent-property ext 'start-open t)
 775                         (set-extent-property ext 'invisible t)))
 776                   (delete-region mystart myend)))
 777             (delete-region mystart myend))))
 778       (widen))
 779     (goto-char p)))
 780
 781 (defun gnus-group-icon-create-glyph (substring pixmap)
 782   "Create a glyph for insertion into a group line."
 783   (or
 784    (cdr-safe (assoc pixmap gnus-group-icon-cache))
 785    (let* ((glyph (make-glyph
 786                   (list
 787                    (cons 'x
 788                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 789                    (cons 'mswindows
 790                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 791                    (cons 'tty substring)))))
 792      (setq gnus-group-icon-cache
 793            (cons (cons pixmap glyph) gnus-group-icon-cache))
 794      (set-glyph-face glyph 'default)
 795      glyph)))
 796
 797 (defun gnus-xmas-mailing-list-menu-add ()
 798   (gnus-xmas-menu-add mailing-list
 799                       gnus-mailing-list-menu))
 800
 801 (defun gnus-xmas-image-type-available-p (type)
 802   (and window-system
 803        (featurep (if (eq type 'pbm) 'xbm type))))
 804
 805 (defun gnus-xmas-create-image (file &optional type data-p &rest props)
 806   (let ((type (if type
 807                   (symbol-name type)
 808                 (car (last (split-string file "[.]")))))
 809         (face (plist-get props :face))
 810         glyph)
 811     (when (equal type "pbm")
 812       (with-temp-buffer
 813         (if data-p
 814             (insert file)
 815           (insert-file-contents-literally file))
 816         (shell-command-on-region (point-min) (point-max)
 817                                  "ppmtoxpm 2>/dev/null" t)
 818         (setq file (buffer-string)
 819               type "xpm"
 820               data-p t)))
 821     (setq glyph
 822           (if (equal type "xbm")
 823               (make-glyph (list (cons 'x file)))
 824             (with-temp-buffer
 825               (if data-p
 826                   (insert file)
 827                 (insert-file-contents-literally file))
 828               (make-glyph
 829                (vector
 830                 (or (intern type)
 831                     (mm-image-type-from-buffer))
 832                 :data (buffer-string))))))
 833     (when face
 834       (set-glyph-face glyph face))
 835     glyph))
 836
 837 (defun gnus-xmas-put-image (glyph &optional string category)
 838   "Insert STRING, but display GLYPH.
 839 Warning: Don't insert text immediately after the image."
 840   (let ((begin (point))
 841         extent)
 842     (if (and (bobp) (not string))
 843         (setq string " "))
 844     (if string
 845         (insert string)
 846       (setq begin (1- begin)))
 847     (setq extent (make-extent begin (point)))
 848     (set-extent-property extent 'gnus-image category)
 849     (set-extent-property extent 'duplicable t)
 850     (if string
 851         (set-extent-property extent 'invisible t))
 852     (set-extent-property extent 'end-glyph glyph))
 853   glyph)
 854
 855 (defun gnus-xmas-remove-image (image &optional category)
 856   (map-extents
 857    (lambda (ext unused)
 858      (when (equal (extent-end-glyph ext) image)
 859        (set-extent-property ext 'invisible nil)
 860        (set-extent-property ext 'end-glyph nil))
 861      nil)
 862    nil nil nil nil nil 'gnus-image category))
 863
 864 (defun gnus-xmas-completing-read (prompt table &optional
 865                                          predicate require-match history)
 866   (when (and history
 867              (not (boundp history)))
 868     (set history nil))
 869   (completing-read
 870    (if (symbol-value history)
 871        (concat prompt " (" (car (symbol-value history)) "): ")
 872      (concat prompt ": "))
 873    table
 874    predicate
 875    require-match
 876    nil
 877    history))
 878
 879 ;; This macro is because XEmacs versions prior to 21.2 do not have the
 880 ;; PROTOCOL argument to `open-network-stream'.
 881 (defmacro gnus-xmas-open-network-stream (name buffer host service &optional protocol)
 882   "Like `open-network-stream' but take into account older XEmacs versions."
 883   (if (and (featurep 'xemacs)
 884            (fboundp 'open-network-stream)
 885            (emacs-version>= 21 2))
 886       `(open-network-stream ,name ,buffer ,host ,service ,protocol)
 887     `(open-network-stream ,name ,buffer ,host ,service)))
 888
 889 (defun gnus-xmas-assq-delete-all (key alist)
 890   (let ((elem nil))
 891     (while (setq elem (assq key alist))
 892       (setq alist (delq elem alist)))
 893     alist))
 894
 895 (provide 'gnus-xmas)
 896
 897 ;;; gnus-xmas.el ends here