cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defgroup gnus-xmas nil
  33   "XEmacsoid support for Gnus"
  34   :group 'gnus)
  35
  36 (defcustom gnus-xmas-glyph-directory nil
  37   "*Directory where Gnus logos and icons are located.
  38 If this variable is nil, Gnus will try to locate the directory
  39 automatically."
  40   :type '(choice (const :tag "autodetect" nil)
  41                  directory)
  42   :group 'gnus-xmas)
  43
  44 (defvar gnus-xmas-logo-color-alist
  45   '((flame "#cc3300" "#ff2200")
  46     (pine "#c0cc93" "#f8ffb8")
  47     (moss "#a1cc93" "#d2ffb8")
  48     (irish "#04cc90" "#05ff97")
  49     (sky "#049acc" "#05deff")
  50     (tin "#6886cc" "#82b6ff")
  51     (velvet "#7c68cc" "#8c82ff")
  52     (grape "#b264cc" "#cf7df")
  53     (labia "#cc64c2" "#fd7dff")
  54     (berry "#cc6485" "#ff7db5")
  55     (neutral "#b4b4b4" "#878787")
  56     (september "#bf9900" "#ffcc00"))
  57   "Color alist used for the Gnus logo.")
  58
  59 (defcustom gnus-xmas-logo-color-style 'moss
  60   "Color styles used for the Gnus logo."
  61   :type '(choice (const flame) (const pine) (const moss)
  62                  (const irish) (const sky) (const tin)
  63                  (const velvet) (const grape) (const labia)
  64                  (const berry) (const neutral) (const september))
  65   :group 'gnus-xmas)
  66
  67 (defvar gnus-xmas-logo-colors
  68   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  69   "Colors used for the Gnus logo.")
  70
  71 (defcustom gnus-article-x-face-command
  72   (if (or (featurep 'xface)
  73           (featurep 'xpm))
  74       'gnus-xmas-article-display-xface
  75     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  76   "String or function to be executed to display an X-Face header.
  77 If it is a string, the command will be executed in a sub-shell
  78 asynchronously.  The compressed face will be piped to this command."
  79   :type '(choice string function))
  80
  81 ;;; Internal variables.
  82
  83 ;; Don't warn about these undefined variables.
  84
  85 (defvar gnus-group-mode-hook)
  86 (defvar gnus-summary-mode-hook)
  87 (defvar gnus-article-mode-hook)
  88
  89 ;;defined in gnus.el
  90 (defvar gnus-active-hashtb)
  91 (defvar gnus-article-buffer)
  92 (defvar gnus-auto-center-summary)
  93 (defvar gnus-buffer-list)
  94 (defvar gnus-current-headers)
  95 (defvar gnus-level-killed)
  96 (defvar gnus-level-zombie)
  97 (defvar gnus-newsgroup-bookmarks)
  98 (defvar gnus-newsgroup-dependencies)
  99 (defvar gnus-newsgroup-selected-overlay)
 100 (defvar gnus-newsrc-hashtb)
 101 (defvar gnus-read-mark)
 102 (defvar gnus-refer-article-method)
 103 (defvar gnus-reffed-article-number)
 104 (defvar gnus-unread-mark)
 105 (defvar gnus-version)
 106 (defvar gnus-view-pseudos)
 107 (defvar gnus-view-pseudos-separately)
 108 (defvar gnus-visual)
 109 (defvar gnus-zombie-list)
 110 ;;defined in gnus-msg.el
 111 (defvar gnus-article-copy)
 112 (defvar gnus-check-before-posting)
 113 ;;defined in gnus-vis.el
 114 (defvar gnus-article-button-face)
 115 (defvar gnus-article-mouse-face)
 116 (defvar gnus-summary-selected-face)
 117 (defvar gnus-group-reading-menu)
 118 (defvar gnus-group-group-menu)
 119 (defvar gnus-group-misc-menu)
 120 (defvar gnus-summary-article-menu)
 121 (defvar gnus-summary-thread-menu)
 122 (defvar gnus-summary-misc-menu)
 123 (defvar gnus-summary-post-menu)
 124 (defvar gnus-summary-kill-menu)
 125 (defvar gnus-article-article-menu)
 126 (defvar gnus-article-treatment-menu)
 127 (defvar gnus-mouse-2)
 128 (defvar standard-display-table)
 129 (defvar gnus-tree-minimize-window)
 130
 131 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 132   "You should NEVER use this function.  It is ideologically blasphemous.
 133 It is provided only to ease porting of broken FSF Emacs programs."
 134   (if (stringp buffer)
 135       nil
 136     (map-extents (lambda (extent ignored)
 137                    (remove-text-properties
 138                     start end
 139                     (list (extent-property extent 'text-prop) nil)
 140                     buffer)
 141                    nil)
 142                  buffer start end nil nil 'text-prop)
 143     (gnus-add-text-properties start end props buffer)))
 144
 145 (defun gnus-xmas-highlight-selected-summary ()
 146   ;; Highlight selected article in summary buffer
 147   (when gnus-summary-selected-face
 148     (when gnus-newsgroup-selected-overlay
 149       (delete-extent gnus-newsgroup-selected-overlay))
 150     (setq gnus-newsgroup-selected-overlay
 151           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 152     (set-extent-face gnus-newsgroup-selected-overlay
 153                      gnus-summary-selected-face)))
 154
 155 (defcustom gnus-xmas-force-redisplay nil
 156   "If non-nil, force a redisplay before recentering the summary buffer.
 157 This is ugly, but it works around a bug in `window-displayed-height'."
 158   :type 'boolean
 159   :group 'gnus-xmas)
 160
 161 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 162   (when (featurep 'scrollbar)
 163     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 164
 165 (defun gnus-xmas-summary-recenter ()
 166   "\"Center\" point in the summary window.
 167 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 168 displayed, no centering will be performed."
 169   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 170   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 171   ;; Force redisplay to get properly computed window height.
 172   (when gnus-xmas-force-redisplay
 173     (sit-for 0))
 174   (when gnus-auto-center-summary
 175     (let* ((height (if (fboundp 'window-displayed-height)
 176                        (window-displayed-height)
 177                      (- (window-height) 2)))
 178            (top (cond ((< height 4) 0)
 179                       ((< height 7) 1)
 180                       (t 2)))
 181            (bottom (save-excursion (goto-char (point-max))
 182                                    (forward-line (- height))
 183                                    (point)))
 184            (window (get-buffer-window (current-buffer))))
 185       (when (get-buffer-window gnus-article-buffer)
 186         ;; Only do recentering when the article buffer is displayed,
 187         ;; Set the window start to either `bottom', which is the biggest
 188         ;; possible valid number, or the second line from the top,
 189         ;; whichever is the least.
 190         (set-window-start
 191          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 192       ;; Do horizontal recentering while we're at it.
 193       (when (and (get-buffer-window (current-buffer) t)
 194                  (not (eq gnus-auto-center-summary 'vertical)))
 195         (let ((selected (selected-window)))
 196           (select-window (get-buffer-window (current-buffer) t))
 197           (gnus-summary-position-point)
 198           (gnus-horizontal-recenter)
 199           (select-window selected))))))
 200
 201 (defun gnus-xmas-summary-set-display-table ()
 202   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 203   ;; but done in an XEmacsish way.
 204   (let ((table (make-display-table))
 205         (i 32))
 206     ;; Nix out all the control chars...
 207     (while (>= (setq i (1- i)) 0)
 208       (aset table i [??]))
 209     ;; ... but not newline and cr, of course.  (cr is necessary for the
 210     ;; selective display).
 211     (aset table ?\n nil)
 212     (aset table ?\r nil)
 213     ;; We nix out any glyphs over 126 below ctl-arrow.
 214     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 215       (while (>= (setq i (1- i)) 127)
 216         (unless (aref table i)
 217           (aset table i [??]))))
 218     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 219     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 220
 221 (defun gnus-xmas-add-text-properties (start end props &optional object)
 222   (add-text-properties start end props object)
 223   (put-text-property start end 'start-closed nil object))
 224
 225 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 226   (put-text-property start end prop value object)
 227   (put-text-property start end 'start-closed nil object))
 228
 229 (defun gnus-xmas-extent-start-open (point)
 230   (map-extents (lambda (extent arg)
 231                  (set-extent-property extent 'start-open t))
 232                nil point (min (1+ (point)) (point-max))))
 233
 234 (defun gnus-xmas-article-push-button (event)
 235   "Check text under the mouse pointer for a callback function.
 236 If the text under the mouse pointer has a `gnus-callback' property,
 237 call it with the value of the `gnus-data' text property."
 238   (interactive "e")
 239   (set-buffer (window-buffer (event-window event)))
 240   (let* ((pos (event-closest-point event))
 241          (data (get-text-property pos 'gnus-data))
 242          (fun (get-text-property pos 'gnus-callback)))
 243     (when fun
 244       (funcall fun data))))
 245
 246 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 247   (set-extent-endpoints extent start end buffer))
 248
 249 (defun gnus-xmas-kill-all-overlays ()
 250   "Delete all extents in the current buffer."
 251   (map-extents (lambda (extent ignore)
 252                  (delete-extent extent)
 253                  nil)))
 254
 255 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 256 (defun gnus-xmas-article-add-button (from to fun &optional data)
 257   "Create a button between FROM and TO with callback FUN and data DATA."
 258   (when gnus-article-button-face
 259     (gnus-overlay-put (gnus-make-overlay from to)
 260                       'face gnus-article-button-face))
 261   (gnus-add-text-properties
 262    from to
 263    (nconc
 264     (and gnus-article-mouse-face
 265          (list 'mouse-face gnus-article-mouse-face))
 266     (list 'gnus-callback fun)
 267     (and data (list 'gnus-data data))
 268     (list 'highlight t))))
 269
 270 (defun gnus-xmas-window-top-edge (&optional window)
 271   (nth 1 (window-pixel-edges window)))
 272
 273 (defun gnus-xmas-tree-minimize ()
 274   (when (and gnus-tree-minimize-window
 275              (not (one-window-p)))
 276     (let* ((window-min-height 2)
 277            (height (1+ (count-lines (point-min) (point-max))))
 278            (min (max (1- window-min-height) height))
 279            (tot (if (numberp gnus-tree-minimize-window)
 280                     (min gnus-tree-minimize-window min)
 281                   min))
 282            (win (get-buffer-window (current-buffer)))
 283            (wh (and win (1- (window-height win)))))
 284       (when (and win
 285                  (not (eq tot wh)))
 286         (let ((selected (selected-window)))
 287           (select-window win)
 288           (enlarge-window (- tot wh))
 289           (select-window selected))))))
 290
 291 ;; Select the lowest window on the frame.
 292 (defun gnus-xmas-appt-select-lowest-window ()
 293   (let* ((lowest-window (selected-window))
 294          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 295          (last-window (previous-window))
 296          (window-search t))
 297     (while window-search
 298       (let* ((this-window (next-window))
 299              (next-bottom-edge (car (cdr (cdr (cdr
 300                                                (window-pixel-edges
 301                                                 this-window)))))))
 302         (when (< bottom-edge next-bottom-edge)
 303           (setq bottom-edge next-bottom-edge)
 304           (setq lowest-window this-window))
 305
 306         (select-window this-window)
 307         (when (eq last-window this-window)
 308           (select-window lowest-window)
 309           (setq window-search nil))))))
 310
 311 (defmacro gnus-xmas-menu-add (type &rest menus)
 312   `(gnus-xmas-menu-add-1 ',type ',menus))
 313 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 314
 315 (defun gnus-xmas-menu-add-1 (type menus)
 316   (when (and menu-bar-mode
 317              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 318     (while menus
 319       (easy-menu-add (symbol-value (pop menus))))))
 320
 321 (defun gnus-xmas-group-menu-add ()
 322   (gnus-xmas-menu-add group
 323     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 324
 325 (defun gnus-xmas-summary-menu-add ()
 326   (gnus-xmas-menu-add summary
 327     gnus-summary-misc-menu gnus-summary-kill-menu
 328     gnus-summary-article-menu gnus-summary-thread-menu
 329     gnus-summary-post-menu ))
 330
 331 (defun gnus-xmas-article-menu-add ()
 332   (gnus-xmas-menu-add article
 333     gnus-article-article-menu gnus-article-treatment-menu))
 334
 335 (defun gnus-xmas-score-menu-add ()
 336   (gnus-xmas-menu-add score
 337     gnus-score-menu))
 338
 339 (defun gnus-xmas-pick-menu-add ()
 340   (gnus-xmas-menu-add pick
 341     gnus-pick-menu))
 342
 343 (defun gnus-xmas-topic-menu-add ()
 344   (gnus-xmas-menu-add topic
 345     gnus-topic-menu))
 346
 347 (defun gnus-xmas-binary-menu-add ()
 348   (gnus-xmas-menu-add binary
 349     gnus-binary-menu))
 350
 351 (defun gnus-xmas-agent-summary-menu-add ()
 352   (gnus-xmas-menu-add agent-summary
 353     gnus-agent-summary-menu))
 354
 355 (defun gnus-xmas-agent-group-menu-add ()
 356   (gnus-xmas-menu-add agent-group
 357     gnus-agent-group-menu))
 358
 359 (defun gnus-xmas-agent-server-menu-add ()
 360   (gnus-xmas-menu-add agent-server
 361     gnus-agent-server-menu))
 362
 363 (defun gnus-xmas-tree-menu-add ()
 364   (gnus-xmas-menu-add tree
 365     gnus-tree-menu))
 366
 367 (defun gnus-xmas-server-menu-add ()
 368   (gnus-xmas-menu-add menu
 369     gnus-server-server-menu gnus-server-connections-menu))
 370
 371 (defun gnus-xmas-browse-menu-add ()
 372   (gnus-xmas-menu-add browse
 373     gnus-browse-menu))
 374
 375 (defun gnus-xmas-grouplens-menu-add ()
 376   (gnus-xmas-menu-add grouplens
 377     gnus-grouplens-menu))
 378
 379 (defun gnus-xmas-read-event-char ()
 380   "Get the next event."
 381   (let ((event (next-command-event)))
 382     (sit-for 0)
 383     ;; We junk all non-key events.  Is this naughty?
 384     (while (not (or (key-press-event-p event)
 385                     (button-press-event-p event)))
 386       (dispatch-event event)
 387       (setq event (next-command-event)))
 388     (cons (and (key-press-event-p event)
 389                (event-to-character event))
 390           event)))
 391
 392 (defun gnus-xmas-seconds-since-epoch (date)
 393   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 394   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 395                         (timezone-parse-date date)))
 396          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 397                         (timezone-parse-time
 398                          (aref (timezone-parse-date date) 3))))
 399          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 400                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 401          (tday (- (timezone-absolute-from-gregorian
 402                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 403                   (timezone-absolute-from-gregorian
 404                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 405     (+ (nth 2 ttime)
 406        (* (nth 1 ttime) 60)
 407        (* (float (nth 0 ttime)) 60 60)
 408        (* (float tday) 60 60 24))))
 409
 410 (defun gnus-xmas-define ()
 411   (setq gnus-mouse-2 [button2])
 412
 413   (unless (memq 'underline (face-list))
 414     (and (fboundp 'make-face)
 415          (funcall (intern "make-face") 'underline)))
 416   ;; Must avoid calling set-face-underline-p directly, because it
 417   ;; is a defsubst in emacs19, and will make the .elc files non
 418   ;; portable!
 419   (unless (face-differs-from-default-p 'underline)
 420     (funcall (intern "set-face-underline-p") 'underline t))
 421
 422   (cond
 423    ((fboundp 'char-or-char-int-p)
 424     ;; Handle both types of marks for XEmacs-20.x.
 425     (fset 'gnus-characterp 'char-or-char-int-p))
 426    ;; V19 of XEmacs, probably.
 427    (t
 428     (fset 'gnus-characterp 'characterp)))
 429
 430   (fset 'gnus-make-overlay 'make-extent)
 431   (fset 'gnus-delete-overlay 'delete-extent)
 432   (fset 'gnus-overlay-put 'set-extent-property)
 433   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 434   (fset 'gnus-overlay-end 'extent-end-position)
 435   (fset 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 436   (fset 'gnus-extent-detached-p 'extent-detached-p)
 437   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 438   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 439   (fset 'gnus-deactivate-mark 'ignore)
 440   (fset 'gnus-window-edges 'window-pixel-edges)
 441
 442   (if (and (<= emacs-major-version 19)
 443            (< emacs-minor-version 14))
 444       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 445
 446   (when (fboundp 'turn-off-scroll-in-place)
 447     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 448
 449   (unless (boundp 'standard-display-table)
 450     (setq standard-display-table nil))
 451
 452   (defvar gnus-mouse-face-prop 'highlight)
 453
 454   (unless (fboundp 'encode-time)
 455     (defun encode-time (sec minute hour day month year &optional zone)
 456       (let ((seconds
 457              (gnus-xmas-seconds-since-epoch
 458               (timezone-make-arpa-date
 459                year month day (timezone-make-time-string hour minute sec)
 460                zone))))
 461         (list (floor (/ seconds (expt 2 16)))
 462               (round (mod seconds (expt 2 16)))))))
 463
 464   (defun gnus-byte-code (func)
 465     "Return a form that can be `eval'ed based on FUNC."
 466     (let ((fval (indirect-function func)))
 467       (if (compiled-function-p fval)
 468           (list 'funcall fval)
 469         (cons 'progn (cdr (cdr fval))))))
 470
 471   (fset 'gnus-x-color-values
 472         (if (fboundp 'x-color-values)
 473             'x-color-values
 474           (lambda (color)
 475             (color-instance-rgb-components
 476              (make-color-instance color))))))
 477
 478 (defun gnus-xmas-redefine ()
 479   "Redefine lots of Gnus functions for XEmacs."
 480   (fset 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 481   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 482   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 483   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 484   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 485   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 486   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 487   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 488   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 489   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 490   (fset 'gnus-appt-select-lowest-window
 491         'gnus-xmas-appt-select-lowest-window)
 492   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 493   (fset 'gnus-character-to-event 'character-to-event)
 494   (fset 'gnus-mode-line-buffer-identification
 495         'gnus-xmas-mode-line-buffer-identification)
 496   (fset 'gnus-key-press-event-p 'key-press-event-p)
 497   (fset 'gnus-region-active-p 'region-active-p)
 498
 499   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 500   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 501   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 502   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 503
 504   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 505   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 506   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 507   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 508   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 509   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 510   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 511
 512   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 513   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 514
 515   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add)
 516   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add)
 517   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add)
 518
 519   (add-hook 'gnus-summary-mode-hook
 520             'gnus-xmas-switch-horizontal-scrollbar-off)
 521   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off))
 522
 523
 524 ;;; XEmacs logo and toolbar.
 525
 526 (defun gnus-xmas-group-startup-message (&optional x y)
 527   "Insert startup message in current buffer."
 528   ;; Insert the message.
 529   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 530   (erase-buffer)
 531   (cond
 532    ((and (console-on-window-system-p)
 533          (or (featurep 'xpm)
 534              (featurep 'xbm)))
 535     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 536            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 537            (glyph (make-glyph
 538                    (cond ((featurep 'xpm)
 539                           `[xpm
 540                             :file ,logo-xpm
 541                             :color-symbols
 542                             (("thing" . ,(car gnus-xmas-logo-colors))
 543                              ("shadow" . ,(cadr gnus-xmas-logo-colors))
 544                              ("background" . ,(face-background 'default)))])
 545                          ((featurep 'xbm)
 546                           `[xbm :file ,logo-xbm])
 547                          (t [nothing])))))
 548       (insert " ")
 549       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 550       (goto-char (point-min))
 551       (while (not (eobp))
 552         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 553                              ?\ ))
 554         (forward-line 1)))
 555     (goto-char (point-min))
 556     (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 557            (wheight (window-height))
 558            (rest (- wheight pheight)))
 559       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 560    (t
 561     (insert
 562      (format "              %s
 563           _    ___ _             _
 564           _ ___ __ ___  __    _ ___
 565           __   _     ___    __  ___
 566               _           ___     _
 567              _  _ __             _
 568              ___   __            _
 569                    __           _
 570                     _      _   _
 571                    _      _    _
 572                       _  _    _
 573                   __  ___
 574                  _   _ _     _
 575                 _   _
 576               _    _
 577              _    _
 578             _
 579           __
 580
 581 "
 582              ""))
 583     ;; And then hack it.
 584     (gnus-indent-rigidly (point-min) (point-max)
 585                          (/ (max (- (window-width) (or x 46)) 0) 2))
 586     (goto-char (point-min))
 587     (forward-line 1)
 588     (let* ((pheight (count-lines (point-min) (point-max)))
 589            (wheight (window-height))
 590            (rest (- wheight pheight)))
 591       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 592     ;; Paint it.
 593     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 594   (setq modeline-buffer-identification
 595         (list (concat gnus-version ": *Group*")))
 596   (set-buffer-modified-p t))
 597
 598
 599 ;;; The toolbar.
 600
 601 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 602                                 'default-toolbar
 603                               nil)
 604   "*If nil, do not use a toolbar.
 605 If it is non-nil, it must be a toolbar.  The five legal values are
 606 `default-toolbar', `top-toolbar', `bottom-toolbar',
 607 `right-toolbar', and `left-toolbar'."
 608   :type '(choice (const default-toolbar)
 609                  (const top-toolbar) (const bottom-toolbar)
 610                  (const left-toolbar) (const right-toolbar)
 611                  (const :tag "no toolbar" nil))
 612   :group 'gnus-xmas)
 613
 614 (defvar gnus-group-toolbar
 615   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 616     [gnus-group-get-new-news-this-group
 617      gnus-group-get-new-news-this-group t "Get new news in this group"]
 618     [gnus-group-catchup-current
 619      gnus-group-catchup-current t "Catchup group"]
 620     [gnus-group-describe-group
 621      gnus-group-describe-group t "Describe group"]
 622     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 623     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 624     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 625     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 626     )
 627   "The group buffer toolbar.")
 628
 629 (defvar gnus-summary-toolbar
 630   '([gnus-summary-prev-unread
 631      gnus-summary-prev-page-or-article t "Page up"]
 632     [gnus-summary-next-unread
 633      gnus-summary-next-page t "Page down"]
 634     [gnus-summary-post-news
 635      gnus-summary-post-news t "Post an article"]
 636     [gnus-summary-followup-with-original
 637      gnus-summary-followup-with-original t
 638      "Post a followup and yank the original"]
 639     [gnus-summary-followup
 640      gnus-summary-followup t "Post a followup"]
 641     [gnus-summary-reply-with-original
 642      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 643     [gnus-summary-reply
 644      gnus-summary-reply t "Mail a reply"]
 645     [gnus-summary-caesar-message
 646      gnus-summary-caesar-message t "Rot 13"]
 647     [gnus-uu-decode-uu
 648      gnus-uu-decode-uu t "Decode uuencoded articles"]
 649     [gnus-summary-save-article-file
 650      gnus-summary-save-article-file t "Save article in file"]
 651     [gnus-summary-save-article
 652      gnus-summary-save-article t "Save article"]
 653     [gnus-uu-post-news
 654      gnus-uu-post-news t "Post a uuencoded article"]
 655     [gnus-summary-cancel-article
 656      gnus-summary-cancel-article t "Cancel article"]
 657     [gnus-summary-catchup
 658      gnus-summary-catchup t "Catchup"]
 659     [gnus-summary-catchup-and-exit
 660      gnus-summary-catchup-and-exit t "Catchup and exit"]
 661     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 662     )
 663   "The summary buffer toolbar.")
 664
 665 (defvar gnus-summary-mail-toolbar
 666   '(
 667     [gnus-summary-prev-unread
 668      gnus-summary-prev-unread-article t "Prev unread article"]
 669     [gnus-summary-next-unread
 670      gnus-summary-next-unread-article t "Next unread article"]
 671     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 672 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 673     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 674     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 675     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 676 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 677     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 678 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 679 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 680     [gnus-summary-caesar-message
 681      gnus-summary-caesar-message t "Rot 13"]
 682     [gnus-uu-decode-uu
 683      gnus-uu-decode-uu t "Decode uuencoded articles"]
 684     [gnus-summary-save-article-file
 685      gnus-summary-save-article-file t "Save article in file"]
 686     [gnus-summary-save-article
 687      gnus-summary-save-article t "Save article"]
 688     [gnus-summary-catchup
 689      gnus-summary-catchup t "Catchup"]
 690     [gnus-summary-catchup-and-exit
 691      gnus-summary-catchup-and-exit t "Catchup and exit"]
 692     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 693     )
 694   "The summary buffer mail toolbar.")
 695
 696 (defun gnus-xmas-setup-group-toolbar ()
 697   (and gnus-use-toolbar
 698        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 699        (set-specifier (symbol-value gnus-use-toolbar)
 700                       (cons (current-buffer) gnus-group-toolbar))))
 701
 702 (defun gnus-xmas-setup-summary-toolbar ()
 703   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 704                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 705     (and gnus-use-toolbar
 706          (message-xmas-setup-toolbar bar nil "gnus")
 707          (set-specifier (symbol-value gnus-use-toolbar)
 708                         (cons (current-buffer) bar)))))
 709
 710 (defun gnus-xmas-mail-strip-quoted-names (address)
 711   "Protect mail-strip-quoted-names from NIL input.
 712 XEmacs compatibility workaround."
 713   (if (null address)
 714       nil
 715     (mail-strip-quoted-names address)))
 716
 717 (defun gnus-xmas-call-region (command &rest args)
 718   (apply
 719    'call-process-region (point-min) (point-max) command t '(t nil) nil
 720    args))
 721
 722 (defface gnus-x-face '((t (:foreground "black" :background "white")))
 723   "Face to show X face"
 724   :group 'gnus-xmas)
 725
 726 (defun gnus-xmas-article-display-xface (beg end)
 727   "Display any XFace headers in the current article."
 728   (save-excursion
 729     (let ((xface-glyph
 730            (cond ((featurep 'xface)
 731                   (make-glyph (vector 'xface :data
 732                                       (concat "X-Face: "
 733                                               (buffer-substring beg end)))))
 734                  ((featurep 'xpm)
 735                   (let ((cur (current-buffer)))
 736                     (save-excursion
 737                       (gnus-set-work-buffer)
 738                       (insert (format "%s" (buffer-substring beg end cur)))
 739                       (gnus-xmas-call-region "uncompface")
 740                       (goto-char (point-min))
 741                       (insert "/* Width=48, Height=48 */\n")
 742                       (gnus-xmas-call-region "icontopbm")
 743                       (gnus-xmas-call-region "ppmtoxpm")
 744                       (make-glyph
 745                        (vector 'xpm :data (buffer-string))))))
 746                  (t
 747                   (make-glyph [nothing])))))
 748       (set-glyph-face xface-glyph 'gnus-x-face)
 749       (goto-char (point-min))
 750       (re-search-forward "^From:" nil t)
 751       (set-extent-begin-glyph
 752        (make-extent (point) (1+ (point))) xface-glyph))))
 753
 754 ;;(defvar gnus-xmas-pointer-glyph
 755 ;;  (progn
 756 ;;    (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory
 757 ;;                                     "gnus"))
 758 ;;    (let ((file-xpm (expand-file-name "gnus-pointer.xpm"
 759 ;;                                    gnus-xmas-glyph-directory))
 760 ;;        (file-xbm (expand-file-name "gnus-pointer.xbm"
 761 ;;                                    gnus-xmas-glyph-directory)))
 762 ;;      (make-pointer-glyph
 763 ;;       (list (vector 'xpm ':file file-xpm)
 764 ;;           (vector 'xbm ':file file-xbm))))))
 765
 766 (defvar gnus-xmas-modeline-left-extent
 767   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 768 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 769     ext))
 770
 771 (defvar gnus-xmas-modeline-right-extent
 772   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 773 ;    (set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 774     ext))
 775
 776 (defvar gnus-xmas-modeline-glyph
 777   (progn
 778     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 779     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 780                                        gnus-xmas-glyph-directory))
 781            (file-xbm (expand-file-name "gnus-pointer.xbm"
 782                                        gnus-xmas-glyph-directory))
 783            (glyph (make-glyph
 784                    ;; Gag gag gag.
 785                    (cond ((featurep 'xpm)
 786                           ;; Let's try a nifty XPM
 787                           `[xpm :file ,file-xpm])
 788                          ((featurep 'xbm)
 789                           ;; Then a not-so-nifty XBM
 790                           [xbm :file ,file-xbm])
 791                          ;; Then the simple string
 792                          (t [string :data "Gnus:"])))))
 793       (set-glyph-face glyph 'modeline-buffer-id)
 794       glyph)))
 795
 796 (defun gnus-xmas-mode-line-buffer-identification (line)
 797   (let ((line (car line))
 798         chop)
 799     (cond
 800      ;; This is some weird type of id.
 801      ((not (stringp line))
 802       (list line))
 803      ;; This is non-standard, so we just pass it through.
 804      ((not (string-match "^Gnus:" line))
 805       (list line))
 806      ;; We have a standard line, so we colorize and glyphize it a bit.
 807      (t
 808       (setq chop (match-end 0))
 809       (list
 810        (if gnus-xmas-modeline-glyph
 811            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 812          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 813        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 814
 815 (defun gnus-xmas-splash ()
 816   (when (eq (device-type) 'x)
 817     (gnus-splash)))
 818
 819 (provide 'gnus-xmas)
 820
 821 ;;; gnus-xmas.el ends here