cgit.sxemacs.org Git - gnus/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'text-props)
  29 (defvar menu-bar-mode (featurep 'menubar))
  30 (require 'messagexmas)
  31
  32 (defvar gnus-xmas-glyph-directory nil
  33   "*Directory where Gnus logos and icons are located.
  34 If this variable is nil, Gnus will try to locate the directory
  35 automatically.")
  36
  37 (defvar gnus-xmas-logo-color-alist
  38   '((flame "#cc3300" "#ff2200")
  39     (pine "#c0cc93" "#f8ffb8")
  40     (moss "#a1cc93" "#d2ffb8")
  41     (irish "#04cc90" "#05ff97")
  42     (sky "#049acc" "#05deff")
  43     (tin "#6886cc" "#82b6ff")
  44     (velvet "#7c68cc" "#8c82ff")
  45     (grape "#b264cc" "#cf7df")
  46     (labia "#cc64c2" "#fd7dff")
  47     (berry "#cc6485" "#ff7db5")
  48     (neutral "#b4b4b4" "#878787")
  49     (september "#bf9900" "#ffcc00"))
  50   "Color alist used for the Gnus logo.")
  51
  52 (defvar gnus-xmas-logo-color-style 'flame
  53   "Color styles used for the Gnus logo.")
  54
  55 (defvar gnus-xmas-logo-colors
  56   (cdr (assq gnus-xmas-logo-color-style gnus-xmas-logo-color-alist))
  57   "Colors used for the Gnus logo.")
  58
  59 (defvar gnus-article-x-face-command
  60   (if (featurep 'xface)
  61       'gnus-xmas-article-display-xface
  62     "{ echo '/* Width=48, Height=48 */'; uncompface; } | icontopbm | xv -quit -")
  63   "String or function to be executed to display an X-Face header.
  64 If it is a string, the command will be executed in a sub-shell
  65 asynchronously.  The compressed face will be piped to this command.")
  66
  67 ;;; Internal variables.
  68
  69 ;; Don't warn about these undefined variables.
  70
  71 (defvar gnus-group-mode-hook)
  72 (defvar gnus-summary-mode-hook)
  73 (defvar gnus-article-mode-hook)
  74
  75 ;;defined in gnus.el
  76 (defvar gnus-active-hashtb)
  77 (defvar gnus-article-buffer)
  78 (defvar gnus-auto-center-summary)
  79 (defvar gnus-buffer-list)
  80 (defvar gnus-current-headers)
  81 (defvar gnus-level-killed)
  82 (defvar gnus-level-zombie)
  83 (defvar gnus-newsgroup-bookmarks)
  84 (defvar gnus-newsgroup-dependencies)
  85 (defvar gnus-newsgroup-selected-overlay)
  86 (defvar gnus-newsrc-hashtb)
  87 (defvar gnus-read-mark)
  88 (defvar gnus-refer-article-method)
  89 (defvar gnus-reffed-article-number)
  90 (defvar gnus-unread-mark)
  91 (defvar gnus-version)
  92 (defvar gnus-view-pseudos)
  93 (defvar gnus-view-pseudos-separately)
  94 (defvar gnus-visual)
  95 (defvar gnus-zombie-list)
  96 ;;defined in gnus-msg.el
  97 (defvar gnus-article-copy)
  98 (defvar gnus-check-before-posting)
  99 ;;defined in gnus-vis.el
 100 (defvar gnus-article-button-face)
 101 (defvar gnus-article-mouse-face)
 102 (defvar gnus-summary-selected-face)
 103 (defvar gnus-group-reading-menu)
 104 (defvar gnus-group-group-menu)
 105 (defvar gnus-group-misc-menu)
 106 (defvar gnus-summary-article-menu)
 107 (defvar gnus-summary-thread-menu)
 108 (defvar gnus-summary-misc-menu)
 109 (defvar gnus-summary-post-menu)
 110 (defvar gnus-summary-kill-menu)
 111 (defvar gnus-article-article-menu)
 112 (defvar gnus-article-treatment-menu)
 113 (defvar gnus-mouse-2)
 114 (defvar standard-display-table)
 115 (defvar gnus-tree-minimize-window)
 116
 117 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 118   "You should NEVER use this function.  It is ideologically blasphemous.
 119 It is provided only to ease porting of broken FSF Emacs programs."
 120   (if (stringp buffer)
 121       nil
 122     (map-extents (lambda (extent ignored)
 123                    (remove-text-properties
 124                     start end
 125                     (list (extent-property extent 'text-prop) nil)
 126                     buffer))
 127                  buffer start end nil nil 'text-prop)
 128     (gnus-add-text-properties start end props buffer)))
 129
 130 (defun gnus-xmas-highlight-selected-summary ()
 131   ;; Highlight selected article in summary buffer
 132   (when gnus-summary-selected-face
 133     (when gnus-newsgroup-selected-overlay
 134       (delete-extent gnus-newsgroup-selected-overlay))
 135     (setq gnus-newsgroup-selected-overlay
 136           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 137     (set-extent-face gnus-newsgroup-selected-overlay
 138                      gnus-summary-selected-face)))
 139
 140 (defvar gnus-xmas-force-redisplay nil
 141   "If non-nil, force a redisplay before recentering the summary buffer.
 142 This is ugly, but it works around a bug in `window-displayed-height'.")
 143
 144 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 145   (set-specifier scrollbar-height (cons (current-buffer) 0)))
 146
 147 (defun gnus-xmas-summary-recenter ()
 148   "\"Center\" point in the summary window.
 149 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 150 displayed, no centering will be performed."
 151   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 152   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 153   ;; Force redisplay to get properly computed window height.
 154   (when gnus-xmas-force-redisplay
 155     (sit-for 0))
 156   (when gnus-auto-center-summary
 157     (let* ((height (if (fboundp 'window-displayed-height)
 158                        (window-displayed-height)
 159                      (- (window-height) 2)))
 160            (top (cond ((< height 4) 0)
 161                       ((< height 7) 1)
 162                       (t 2)))
 163            (bottom (save-excursion (goto-char (point-max))
 164                                    (forward-line (- height))
 165                                    (point)))
 166            (window (get-buffer-window (current-buffer))))
 167       (when (get-buffer-window gnus-article-buffer)
 168         ;; Only do recentering when the article buffer is displayed,
 169         ;; Set the window start to either `bottom', which is the biggest
 170         ;; possible valid number, or the second line from the top,
 171         ;; whichever is the least.
 172         (set-window-start
 173          window (min bottom (save-excursion (forward-line (- top)) (point)))))
 174       ;; Do horizontal recentering while we're at it.
 175       (when (and (get-buffer-window (current-buffer) t)
 176                  (not (eq gnus-auto-center-summary 'vertical)))
 177         (let ((selected (selected-window)))
 178           (select-window (get-buffer-window (current-buffer) t))
 179           (gnus-summary-position-point)
 180           (gnus-horizontal-recenter)
 181           (select-window selected))))))
 182
 183 (defun gnus-xmas-add-hook (hook function &optional append local)
 184   (add-hook hook function))
 185
 186 (defun gnus-xmas-add-text-properties (start end props &optional object)
 187   (add-text-properties start end props object)
 188   (put-text-property start end 'start-closed nil object))
 189
 190 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 191   (put-text-property start end prop value object)
 192   (put-text-property start end 'start-closed nil object))
 193
 194 (defun gnus-xmas-extent-start-open (point)
 195   (map-extents (lambda (extent arg)
 196                  (set-extent-property extent 'start-open t))
 197                nil point (min (1+ (point)) (point-max))))
 198
 199 (defun gnus-xmas-article-push-button (event)
 200   "Check text under the mouse pointer for a callback function.
 201 If the text under the mouse pointer has a `gnus-callback' property,
 202 call it with the value of the `gnus-data' text property."
 203   (interactive "e")
 204   (set-buffer (window-buffer (event-window event)))
 205   (let* ((pos (event-closest-point event))
 206          (data (get-text-property pos 'gnus-data))
 207          (fun (get-text-property pos 'gnus-callback)))
 208     (when fun
 209       (funcall fun data))))
 210
 211 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 212   (set-extent-endpoints extent start end))
 213
 214 ;; Fixed by Christopher Davis <ckd@loiosh.kei.com>.
 215 (defun gnus-xmas-article-add-button (from to fun &optional data)
 216   "Create a button between FROM and TO with callback FUN and data DATA."
 217   (when gnus-article-button-face
 218     (gnus-overlay-put (gnus-make-overlay from to)
 219                       'face gnus-article-button-face))
 220   (gnus-add-text-properties
 221    from to
 222    (nconc
 223     (and gnus-article-mouse-face
 224          (list 'mouse-face gnus-article-mouse-face))
 225     (list 'gnus-callback fun)
 226     (and data (list 'gnus-data data))
 227     (list 'highlight t))))
 228
 229 (defun gnus-xmas-window-top-edge (&optional window)
 230   (nth 1 (window-pixel-edges window)))
 231
 232 (defun gnus-xmas-tree-minimize ()
 233   (when (and gnus-tree-minimize-window
 234              (not (one-window-p)))
 235     (let* ((window-min-height 2)
 236            (height (1+ (count-lines (point-min) (point-max))))
 237            (min (max (1- window-min-height) height))
 238            (tot (if (numberp gnus-tree-minimize-window)
 239                     (min gnus-tree-minimize-window min)
 240                   min))
 241            (win (get-buffer-window (current-buffer)))
 242            (wh (and win (1- (window-height win)))))
 243       (when (and win
 244                  (not (eq tot wh)))
 245         (let ((selected (selected-window)))
 246           (select-window win)
 247           (enlarge-window (- tot wh))
 248           (select-window selected))))))
 249
 250 ;; Select the lowest window on the frame.
 251 (defun gnus-xmas-appt-select-lowest-window ()
 252   (let* ((lowest-window (selected-window))
 253          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 254          (last-window (previous-window))
 255          (window-search t))
 256     (while window-search
 257       (let* ((this-window (next-window))
 258              (next-bottom-edge (car (cdr (cdr (cdr
 259                                                (window-pixel-edges
 260                                                 this-window)))))))
 261         (when (< bottom-edge next-bottom-edge)
 262           (setq bottom-edge next-bottom-edge)
 263           (setq lowest-window this-window))
 264
 265         (select-window this-window)
 266         (when (eq last-window this-window)
 267           (select-window lowest-window)
 268           (setq window-search nil))))))
 269
 270 (defmacro gnus-xmas-menu-add (type &rest menus)
 271   `(gnus-xmas-menu-add-1 ',type ',menus))
 272 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 273
 274 (defun gnus-xmas-menu-add-1 (type menus)
 275   (when (and menu-bar-mode
 276              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 277     (while menus
 278       (easy-menu-add (symbol-value (pop menus))))))
 279
 280 (defun gnus-xmas-group-menu-add ()
 281   (gnus-xmas-menu-add group
 282     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 283
 284 (defun gnus-xmas-summary-menu-add ()
 285   (gnus-xmas-menu-add summary
 286     gnus-summary-misc-menu gnus-summary-kill-menu
 287     gnus-summary-article-menu gnus-summary-thread-menu
 288     gnus-summary-post-menu ))
 289
 290 (defun gnus-xmas-article-menu-add ()
 291   (gnus-xmas-menu-add article
 292     gnus-article-article-menu gnus-article-treatment-menu))
 293
 294 (defun gnus-xmas-score-menu-add ()
 295   (gnus-xmas-menu-add score
 296     gnus-score-menu))
 297
 298 (defun gnus-xmas-pick-menu-add ()
 299   (gnus-xmas-menu-add pick
 300     gnus-pick-menu))
 301
 302 (defun gnus-xmas-topic-menu-add ()
 303   (gnus-xmas-menu-add topic
 304     gnus-topic-menu))
 305
 306 (defun gnus-xmas-binary-menu-add ()
 307   (gnus-xmas-menu-add binary
 308     gnus-binary-menu))
 309
 310 (defun gnus-xmas-tree-menu-add ()
 311   (gnus-xmas-menu-add tree
 312     gnus-tree-menu))
 313
 314 (defun gnus-xmas-server-menu-add ()
 315   (gnus-xmas-menu-add menu
 316     gnus-server-server-menu gnus-server-connections-menu))
 317
 318 (defun gnus-xmas-browse-menu-add ()
 319   (gnus-xmas-menu-add browse
 320     gnus-browse-menu))
 321
 322 (defun gnus-xmas-grouplens-menu-add ()
 323   (gnus-xmas-menu-add grouplens
 324     gnus-grouplens-menu))
 325
 326 (defun gnus-xmas-read-event-char ()
 327   "Get the next event."
 328   (let ((event (next-command-event)))
 329     (sit-for 0)
 330     ;; We junk all non-key events.  Is this naughty?
 331     (while (not (or (key-press-event-p event)
 332                     (button-press-event-p event)))
 333       (dispatch-event event)
 334       (setq event (next-command-event)))
 335     (cons (and (key-press-event-p event)
 336                (event-to-character event))
 337           event)))
 338
 339 (defun gnus-xmas-group-remove-excess-properties ()
 340   (let ((end (point))
 341         (beg (progn (forward-line -1) (point))))
 342     (remove-text-properties (1+ beg) end '(gnus-group nil))
 343     (remove-text-properties
 344      beg end
 345      '(gnus-topic nil gnus-topic-level nil gnus-topic-visible nil))
 346     (goto-char end)
 347     (map-extents
 348      (lambda (e ma)
 349        (set-extent-property e 'start-closed t))
 350      (current-buffer) beg end)))
 351
 352 (defun gnus-xmas-topic-remove-excess-properties ()
 353   (let ((end (point))
 354         (beg (progn (forward-line -1) (point))))
 355     (remove-text-properties beg end '(gnus-group nil gnus-unread nil))
 356     (remove-text-properties (1+ beg) end '(gnus-topic nil))
 357     (goto-char end)))
 358
 359 (defun gnus-xmas-seconds-since-epoch (date)
 360   "Return a floating point number that says how many seconds have lapsed between Jan 1 12:00:00 1970 and DATE."
 361   (let* ((tdate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 362                         (timezone-parse-date date)))
 363          (ttime (mapcar (lambda (ti) (and ti (string-to-int ti)))
 364                         (timezone-parse-time
 365                          (aref (timezone-parse-date date) 3))))
 366          (edate (mapcar (lambda (ti) (and ti (string-to-int ti)))
 367                         (timezone-parse-date "Jan 1 12:00:00 1970")))
 368          (tday (- (timezone-absolute-from-gregorian
 369                    (nth 1 tdate) (nth 2 tdate) (nth 0 tdate))
 370                   (timezone-absolute-from-gregorian
 371                    (nth 1 edate) (nth 2 edate) (nth 0 edate)))))
 372     (+ (nth 2 ttime)
 373        (* (nth 1 ttime) 60)
 374        (* (float (nth 0 ttime)) 60 60)
 375        (* (float tday) 60 60 24))))
 376
 377 (defun gnus-xmas-define ()
 378   (setq gnus-mouse-2 [button2])
 379
 380   (unless (memq 'underline (face-list))
 381     (and (fboundp 'make-face)
 382          (funcall (intern "make-face") 'underline)))
 383   ;; Must avoid calling set-face-underline-p directly, because it
 384   ;; is a defsubst in emacs19, and will make the .elc files non
 385   ;; portable!
 386   (unless (face-differs-from-default-p 'underline)
 387     (funcall (intern "set-face-underline-p") 'underline t))
 388
 389   (cond
 390    ((fboundp 'char-or-char-int-p)
 391     ;; Handle both types of marks for XEmacs-20.x.
 392     (fset 'gnus-characterp 'char-or-char-int-p))
 393    ;; V19 of XEmacs, probably.
 394    (t
 395     (fset 'gnus-characterp 'characterp)))
 396
 397   (fset 'gnus-make-overlay 'make-extent)
 398   (fset 'gnus-overlay-put 'set-extent-property)
 399   (fset 'gnus-move-overlay 'gnus-xmas-move-overlay)
 400   (fset 'gnus-overlay-end 'extent-end-position)
 401   (fset 'gnus-extent-detached-p 'extent-detached-p)
 402   (fset 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 403   (fset 'gnus-put-text-property 'gnus-xmas-put-text-property)
 404
 405   (require 'text-props)
 406   (if (and (<= emacs-major-version 19)
 407            (< emacs-minor-version 14))
 408       (fset 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 409
 410   (when (fboundp 'turn-off-scroll-in-place)
 411     (add-hook 'gnus-article-mode-hook 'turn-off-scroll-in-place))
 412
 413   (unless (boundp 'standard-display-table)
 414     (setq standard-display-table nil))
 415
 416   (defvar gnus-mouse-face-prop 'highlight)
 417
 418   (unless (fboundp 'encode-time)
 419     (defun encode-time (sec minute hour day month year &optional zone)
 420       (let ((seconds
 421              (gnus-xmas-seconds-since-epoch
 422               (timezone-make-arpa-date
 423                year month day (timezone-make-time-string hour minute sec)
 424                zone))))
 425         (list (floor (/ seconds (expt 2 16)))
 426               (round (mod seconds (expt 2 16)))))))
 427
 428   (defun gnus-byte-code (func)
 429     "Return a form that can be `eval'ed based on FUNC."
 430     (let ((fval (symbol-function func)))
 431       (if (compiled-function-p fval)
 432           (list 'funcall fval)
 433         (cons 'progn (cdr (cdr fval))))))
 434
 435   (fset 'gnus-x-color-values
 436         (if (fboundp 'x-color-values)
 437             'x-color-values
 438           (lambda (color)
 439             (color-instance-rgb-components
 440              (make-color-instance color))))))
 441
 442 (defun gnus-xmas-redefine ()
 443   "Redefine lots of Gnus functions for XEmacs."
 444   (fset 'gnus-summary-make-display-table 'ignore)
 445   (fset 'gnus-visual-turn-off-edit-menu 'identity)
 446   (fset 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 447   (fset 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 448   (fset 'gnus-article-push-button 'gnus-xmas-article-push-button)
 449   (fset 'gnus-article-add-button 'gnus-xmas-article-add-button)
 450   (fset 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 451   (fset 'gnus-read-event-char 'gnus-xmas-read-event-char)
 452   (fset 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 453   (fset 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 454   (fset 'gnus-appt-select-lowest-window
 455         'gnus-xmas-appt-select-lowest-window)
 456   (fset 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 457   (fset 'gnus-add-hook 'gnus-xmas-add-hook)
 458   (fset 'gnus-character-to-event 'character-to-event)
 459   (fset 'gnus-mode-line-buffer-identification
 460         'gnus-xmas-mode-line-buffer-identification)
 461   (fset 'gnus-key-press-event-p 'key-press-event-p)
 462   (fset 'gnus-region-active-p 'region-active-p)
 463
 464   (add-hook 'gnus-group-mode-hook 'gnus-xmas-group-menu-add)
 465   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-summary-menu-add)
 466   (add-hook 'gnus-article-mode-hook 'gnus-xmas-article-menu-add)
 467   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 468
 469   (add-hook 'gnus-pick-mode-hook 'gnus-xmas-pick-menu-add)
 470   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add)
 471   (add-hook 'gnus-tree-mode-hook 'gnus-xmas-tree-menu-add)
 472   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 473   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 474   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 475   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 476
 477   (add-hook 'gnus-group-mode-hook 'gnus-xmas-setup-group-toolbar)
 478   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-setup-summary-toolbar)
 479
 480   (add-hook 'gnus-summary-mode-hook 'gnus-xmas-switch-horizontal-scrollbar-off)
 481
 482   (when (and (<= emacs-major-version 19)
 483              (<= emacs-minor-version 13))
 484     (setq gnus-article-x-face-too-ugly (when (eq (device-type) 'tty)
 485                                          "."))
 486     (fset 'gnus-highlight-selected-summary
 487           'gnus-xmas-highlight-selected-summary)
 488     (fset 'gnus-group-remove-excess-properties
 489           'gnus-xmas-group-remove-excess-properties)
 490     (fset 'gnus-topic-remove-excess-properties
 491           'gnus-xmas-topic-remove-excess-properties)
 492     (fset 'gnus-mode-line-buffer-identification 'identity)
 493     (unless (boundp 'shell-command-switch)
 494       (setq shell-command-switch "-c"))))
 495
 496
 497 ;;; XEmacs logo and toolbar.
 498
 499 (defun gnus-xmas-group-startup-message (&optional x y)
 500   "Insert startup message in current buffer."
 501   ;; Insert the message.
 502   (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 503   (erase-buffer)
 504   (let ((logo (and gnus-xmas-glyph-directory
 505                    (concat
 506                     (file-name-as-directory gnus-xmas-glyph-directory)
 507                     "gnus."
 508                     (if (featurep 'xpm) "xpm" "xbm"))))
 509         (xpm-color-symbols
 510          (and (featurep 'xpm)
 511               (append `(("thing" ,(car gnus-xmas-logo-colors))
 512                         ("shadow" ,(cadr gnus-xmas-logo-colors)))
 513                       xpm-color-symbols))))
 514     (if (and (featurep 'xpm)
 515              (not (equal (device-type) 'tty))
 516              logo
 517              (file-exists-p logo))
 518         (progn
 519           (setq logo (make-glyph logo))
 520           (insert " ")
 521           (set-extent-begin-glyph (make-extent (point) (point)) logo)
 522           (goto-char (point-min))
 523           (while (not (eobp))
 524             (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 525                                  ? ))
 526             (forward-line 1))
 527           (goto-char (point-min))
 528           (let* ((pheight (+ 20 (count-lines (point-min) (point-max))))
 529                  (wheight (window-height))
 530                  (rest (- wheight pheight)))
 531             (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 532
 533       (insert
 534        (format "              %s
 535           _    ___ _             _
 536           _ ___ __ ___  __    _ ___
 537           __   _     ___    __  ___
 538               _           ___     _
 539              _  _ __             _
 540              ___   __            _
 541                    __           _
 542                     _      _   _
 543                    _      _    _
 544                       _  _    _
 545                   __  ___
 546                  _   _ _     _
 547                 _   _
 548               _    _
 549              _    _
 550             _
 551           __
 552
 553 "
 554                ""))
 555       ;; And then hack it.
 556       (gnus-indent-rigidly (point-min) (point-max)
 557                            (/ (max (- (window-width) (or x 46)) 0) 2))
 558       (goto-char (point-min))
 559       (forward-line 1)
 560       (let* ((pheight (count-lines (point-min) (point-max)))
 561              (wheight (window-height))
 562              (rest (- wheight pheight)))
 563         (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n))))
 564     ;; Fontify some.
 565     (goto-char (point-min))
 566     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)
 567     (goto-char (point-min))
 568     (setq modeline-buffer-identification
 569           (list (concat gnus-version ": *Group*")))
 570     (set-buffer-modified-p t)))
 571
 572
 573 ;;; The toolbar.
 574
 575 (defvar gnus-use-toolbar (if (featurep 'toolbar)
 576                              'default-toolbar
 577                            nil)
 578   "*If nil, do not use a toolbar.
 579 If it is non-nil, it must be a toolbar.  The five legal values are
 580 `default-toolbar', `top-toolbar', `bottom-toolbar',
 581 `right-toolbar', and `left-toolbar'.")
 582
 583 (defvar gnus-group-toolbar
 584   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 585     [gnus-group-get-new-news-this-group
 586      gnus-group-get-new-news-this-group t "Get new news in this group"]
 587     [gnus-group-catchup-current
 588      gnus-group-catchup-current t "Catchup group"]
 589     [gnus-group-describe-group
 590      gnus-group-describe-group t "Describe group"]
 591     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 592     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 593     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 594     [gnus-group-exit gnus-group-exit t "Exit Gnus"]
 595     )
 596   "The group buffer toolbar.")
 597
 598 (defvar gnus-summary-toolbar
 599   '([gnus-summary-prev-unread
 600      gnus-summary-prev-unread-article t "Prev unread article"]
 601     [gnus-summary-next-unread
 602      gnus-summary-next-unread-article t "Next unread article"]
 603     [gnus-summary-post-news
 604      gnus-summary-post-news t "Post an article"]
 605     [gnus-summary-followup-with-original
 606      gnus-summary-followup-with-original t
 607      "Post a followup and yank the original"]
 608     [gnus-summary-followup
 609      gnus-summary-followup t "Post a followup"]
 610     [gnus-summary-reply-with-original
 611      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 612     [gnus-summary-reply
 613      gnus-summary-reply t "Mail a reply"]
 614     [gnus-summary-caesar-message
 615      gnus-summary-caesar-message t "Rot 13"]
 616     [gnus-uu-decode-uu
 617      gnus-uu-decode-uu t "Decode uuencoded articles"]
 618     [gnus-summary-save-article-file
 619      gnus-summary-save-article-file t "Save article in file"]
 620     [gnus-summary-save-article
 621      gnus-summary-save-article t "Save article"]
 622     [gnus-uu-post-news
 623      gnus-uu-post-news t "Post an uuencoded article"]
 624     [gnus-summary-cancel-article
 625      gnus-summary-cancel-article t "Cancel article"]
 626     [gnus-summary-catchup
 627      gnus-summary-catchup t "Catchup"]
 628     [gnus-summary-catchup-and-exit
 629      gnus-summary-catchup-and-exit t "Catchup and exit"]
 630     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 631     )
 632   "The summary buffer toolbar.")
 633
 634 (defvar gnus-summary-mail-toolbar
 635   '(
 636     [gnus-summary-prev-unread
 637      gnus-summary-prev-unread-article t "Prev unread article"]
 638     [gnus-summary-next-unread
 639      gnus-summary-next-unread-article t "Next unread article"]
 640     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 641 ;    [gnus-summary-mail-get gnus-mail-get t "Message get"]
 642     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 643     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 644     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 645 ;    [gnus-summary-mail-delete gnus-summary-delete-article t "Delete message"]
 646     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 647 ;    [gnus-summary-mail-spell gnus-mail-spell t "Spell"]
 648 ;    [gnus-summary-mail-help gnus-mail-help  t "Message help"]
 649     [gnus-summary-caesar-message
 650      gnus-summary-caesar-message t "Rot 13"]
 651     [gnus-uu-decode-uu
 652      gnus-uu-decode-uu t "Decode uuencoded articles"]
 653     [gnus-summary-save-article-file
 654      gnus-summary-save-article-file t "Save article in file"]
 655     [gnus-summary-save-article
 656      gnus-summary-save-article t "Save article"]
 657     [gnus-summary-catchup
 658      gnus-summary-catchup t "Catchup"]
 659     [gnus-summary-catchup-and-exit
 660      gnus-summary-catchup-and-exit t "Catchup and exit"]
 661     [gnus-summary-exit gnus-summary-exit t "Exit this summary"]
 662     )
 663   "The summary buffer mail toolbar.")
 664
 665 (defun gnus-xmas-setup-group-toolbar ()
 666   (and gnus-use-toolbar
 667        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 668        (set-specifier (symbol-value gnus-use-toolbar)
 669                       (cons (current-buffer) gnus-group-toolbar))))
 670
 671 (defun gnus-xmas-setup-summary-toolbar ()
 672   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 673                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 674     (and gnus-use-toolbar
 675          (message-xmas-setup-toolbar bar nil "gnus")
 676          (set-specifier (symbol-value gnus-use-toolbar)
 677                         (cons (current-buffer) bar)))))
 678
 679 (defun gnus-xmas-mail-strip-quoted-names (address)
 680   "Protect mail-strip-quoted-names from NIL input.
 681 XEmacs compatibility workaround."
 682   (if (null address)
 683       nil
 684     (mail-strip-quoted-names address)))
 685
 686 (defun gnus-xmas-call-region (command &rest args)
 687   (apply
 688    'call-process-region (point-min) (point-max) command t '(t nil) nil
 689    args))
 690
 691 (unless (find-face 'gnus-x-face)
 692   (copy-face 'default 'gnus-x-face)
 693   (set-face-foreground 'gnus-x-face "black")
 694   (set-face-background 'gnus-x-face "white"))
 695
 696 (defun gnus-xmas-article-display-xface (beg end)
 697   "Display any XFace headers in the current article."
 698   (save-excursion
 699     (let (xface-glyph)
 700       (if (featurep 'xface)
 701           (setq xface-glyph
 702                 (make-glyph (vector 'xface :data
 703                                     (concat "X-Face: "
 704                                             (buffer-substring beg end)))))
 705         (let ((cur (current-buffer)))
 706           (save-excursion
 707             (gnus-set-work-buffer)
 708             (insert (format "%s" (buffer-substring beg end cur)))
 709             (gnus-xmas-call-region "uncompface")
 710             (goto-char (point-min))
 711             (insert "/* Width=48, Height=48 */\n")
 712             (gnus-xmas-call-region "icontopbm")
 713             (gnus-xmas-call-region "ppmtoxpm")
 714             (setq xface-glyph
 715                   (make-glyph
 716                    (vector 'xpm :data (buffer-string )))))))
 717       (set-glyph-face xface-glyph 'gnus-x-face)
 718       (goto-char (point-min))
 719       (re-search-forward "^From:" nil t)
 720       (set-extent-begin-glyph
 721        (make-extent (point) (1+ (point))) xface-glyph))))
 722
 723 (defvar gnus-xmas-pointer-glyph
 724   (progn
 725     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 726     (make-pointer-glyph (concat gnus-xmas-glyph-directory "gnus-pointer."
 727                                 (if (featurep 'xpm) "xpm" "xbm")))))
 728
 729 (defvar gnus-xmas-modeline-left-extent
 730   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 731     ;(set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 732     ext))
 733
 734 (defvar gnus-xmas-modeline-right-extent
 735   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 736     ;(set-extent-property ext 'pointer gnus-xmas-pointer-glyph)
 737     ext))
 738
 739 (defvar gnus-xmas-modeline-glyph
 740   (progn
 741     (setq gnus-xmas-glyph-directory (message-xmas-find-glyph-directory "gnus"))
 742     (let* ((file (concat gnus-xmas-glyph-directory "gnus-pointer."
 743                          (if (featurep 'xpm) "xpm" "xbm")))
 744            (glyph (make-glyph file)))
 745       (when (and (featurep 'x)
 746                  (file-exists-p file))
 747         (set-glyph-face glyph 'modeline-buffer-id)
 748         (set-glyph-property glyph 'image (cons 'tty "Gnus:"))
 749         glyph))))
 750
 751 (defun gnus-xmas-mode-line-buffer-identification (line)
 752   (let ((line (car line))
 753         chop)
 754     (cond
 755      ;; This is some weird type of id.
 756      ((not (stringp line))
 757       (list line))
 758      ;; This is non-standard, so we just pass it through.
 759      ((not (string-match "^Gnus:" line))
 760       (list line))
 761      ;; We have a standard line, so we colorize and glyphize it a bit.
 762      (t
 763       (setq chop (match-end 0))
 764       (list
 765        (if gnus-xmas-modeline-glyph
 766            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 767          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 768        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 769
 770 (defun gnus-xmas-splash ()
 771   (when (eq (device-type) 'x)
 772     (gnus-splash)))
 773
 774 (provide 'gnus-xmas)
 775
 776 ;;; gnus-xmas.el ends here