cgit.sxemacs.org Git - gnus/blob - lisp/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Nothing in this file depends on any other parts of Gnus -- all
  28 ;; functions and macros in this file are utility functions that are
  29 ;; used by Gnus and may be used by any other package without loading
  30 ;; Gnus first.
  31
  32 ;;; Code:
  33
  34 (require 'custom)
  35 (eval-when-compile
  36   (require 'cl)
  37   ;; Fixme: this should be a gnus variable, not nnmail-.
  38   (defvar nnmail-pathname-coding-system))
  39 (require 'nnheader)
  40 (require 'time-date)
  41 (require 'netrc)
  42
  43 (eval-and-compile
  44   (autoload 'message-fetch-field "message")
  45   (autoload 'gnus-get-buffer-window "gnus-win")
  46   (autoload 'rmail-insert-rmail-file-header "rmail")
  47   (autoload 'rmail-count-new-messages "rmail")
  48   (autoload 'rmail-show-message "rmail"))
  49
  50 (eval-and-compile
  51   (cond
  52    ((fboundp 'replace-in-string)
  53     (defalias 'gnus-replace-in-string 'replace-in-string))
  54    ((fboundp 'replace-regexp-in-string)
  55     (defun gnus-replace-in-string  (string regexp newtext &optional literal)
  56       (replace-regexp-in-string regexp newtext string nil literal)))
  57    (t
  58     (defun gnus-replace-in-string (string regexp newtext &optional literal)
  59       (let ((start 0) tail)
  60         (while (string-match regexp string start)
  61           (setq tail (- (length string) (match-end 0)))
  62           (setq string (replace-match newtext nil literal string))
  63           (setq start (- (length string) tail))))
  64       string))))
  65
  66 ;;; bring in the netrc functions as aliases
  67 (defalias 'gnus-netrc-get 'netrc-get)
  68 (defalias 'gnus-netrc-machine 'netrc-machine)
  69 (defalias 'gnus-parse-netrc 'netrc-parse)
  70
  71 (defun gnus-boundp (variable)
  72   "Return non-nil if VARIABLE is bound and non-nil."
  73   (and (boundp variable)
  74        (symbol-value variable)))
  75
  76 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  77   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  78   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  79         (w (make-symbol "w"))
  80         (buf (make-symbol "buf")))
  81     `(let* ((,tempvar (selected-window))
  82             (,buf ,buffer)
  83             (,w (gnus-get-buffer-window ,buf 'visible)))
  84        (unwind-protect
  85            (progn
  86              (if ,w
  87                  (progn
  88                    (select-window ,w)
  89                    (set-buffer (window-buffer ,w)))
  90                (pop-to-buffer ,buf))
  91              ,@forms)
  92          (select-window ,tempvar)))))
  93
  94 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  95 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
  96
  97 (defmacro gnus-intern-safe (string hashtable)
  98   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
  99   `(let ((symbol (intern ,string ,hashtable)))
 100      (or (boundp symbol)
 101          (set symbol nil))
 102      symbol))
 103
 104 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
 105 ;; to limit the length of a string.  This function is necessary since
 106 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
 107 (defsubst gnus-limit-string (str width)
 108   (if (> (length str) width)
 109       (substring str 0 width)
 110     str))
 111
 112 (defsubst gnus-functionp (form)
 113   "Return non-nil if FORM is funcallable."
 114   (or (and (symbolp form) (fboundp form))
 115       (and (listp form) (eq (car form) 'lambda))
 116       (byte-code-function-p form)))
 117
 118 (defsubst gnus-goto-char (point)
 119   (and point (goto-char point)))
 120
 121 (defmacro gnus-buffer-exists-p (buffer)
 122   `(let ((buffer ,buffer))
 123      (when buffer
 124        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 125                 buffer))))
 126
 127 (defalias 'gnus-point-at-bol
 128   (if (fboundp 'point-at-bol)
 129       'point-at-bol
 130     'line-beginning-position))
 131
 132 (defalias 'gnus-point-at-eol
 133   (if (fboundp 'point-at-eol)
 134       'point-at-eol
 135     'line-end-position))
 136
 137 (defun gnus-delete-first (elt list)
 138   "Delete by side effect the first occurrence of ELT as a member of LIST."
 139   (if (equal (car list) elt)
 140       (cdr list)
 141     (let ((total list))
 142       (while (and (cdr list)
 143                   (not (equal (cadr list) elt)))
 144         (setq list (cdr list)))
 145       (when (cdr list)
 146         (setcdr list (cddr list)))
 147       total)))
 148
 149 ;; Delete the current line (and the next N lines).
 150 (defmacro gnus-delete-line (&optional n)
 151   `(delete-region (gnus-point-at-bol)
 152                   (progn (forward-line ,(or n 1)) (point))))
 153
 154 (defun gnus-byte-code (func)
 155   "Return a form that can be `eval'ed based on FUNC."
 156   (let ((fval (indirect-function func)))
 157     (if (byte-code-function-p fval)
 158         (let ((flist (append fval nil)))
 159           (setcar flist 'byte-code)
 160           flist)
 161       (cons 'progn (cddr fval)))))
 162
 163 (defun gnus-extract-address-components (from)
 164   (let (name address)
 165     ;; First find the address - the thing with the @ in it.  This may
 166     ;; not be accurate in mail addresses, but does the trick most of
 167     ;; the time in news messages.
 168     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 169       (setq address (substring from (match-beginning 0) (match-end 0))))
 170     ;; Then we check whether the "name <address>" format is used.
 171     (and address
 172          ;; Linear white space is not required.
 173          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 174          (and (setq name (substring from 0 (match-beginning 0)))
 175               ;; Strip any quotes from the name.
 176               (string-match "^\".*\"$" name)
 177               (setq name (substring name 1 (1- (match-end 0))))))
 178     ;; If not, then "address (name)" is used.
 179     (or name
 180         (and (string-match "(.+)" from)
 181              (setq name (substring from (1+ (match-beginning 0))
 182                                    (1- (match-end 0)))))
 183         (and (string-match "()" from)
 184              (setq name address))
 185         ;; XOVER might not support folded From headers.
 186         (and (string-match "(.*" from)
 187              (setq name (substring from (1+ (match-beginning 0))
 188                                    (match-end 0)))))
 189     (list (if (string= name "") nil name) (or address from))))
 190
 191
 192 (defun gnus-fetch-field (field)
 193   "Return the value of the header FIELD of current article."
 194   (save-excursion
 195     (save-restriction
 196       (let ((case-fold-search t)
 197             (inhibit-point-motion-hooks t))
 198         (nnheader-narrow-to-headers)
 199         (message-fetch-field field)))))
 200
 201 (defun gnus-fetch-original-field (field)
 202   "Fetch FIELD from the original version of the current article."
 203   (with-current-buffer gnus-original-article-buffer
 204     (gnus-fetch-field field)))
 205
 206
 207 (defun gnus-goto-colon ()
 208   (beginning-of-line)
 209   (let ((eol (gnus-point-at-eol)))
 210     (goto-char (or (text-property-any (point) eol 'gnus-position t)
 211                    (search-forward ":" eol t)
 212                    (point)))))
 213
 214 (defun gnus-decode-newsgroups (newsgroups group &optional method)
 215   (let ((method (or method (gnus-find-method-for-group group))))
 216     (mapconcat (lambda (group)
 217                  (gnus-group-name-decode group (gnus-group-name-charset
 218                                                 method group)))
 219                (message-tokenize-header newsgroups)
 220                ",")))
 221
 222 (defun gnus-remove-text-with-property (prop)
 223   "Delete all text in the current buffer with text property PROP."
 224   (save-excursion
 225     (goto-char (point-min))
 226     (while (not (eobp))
 227       (while (get-text-property (point) prop)
 228         (delete-char 1))
 229       (goto-char (next-single-property-change (point) prop nil (point-max))))))
 230
 231 (require 'nnheader)
 232 (defun gnus-newsgroup-directory-form (newsgroup)
 233   "Make hierarchical directory name from NEWSGROUP name."
 234   (let* ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 235          (idx (string-match ":" newsgroup)))
 236     (concat
 237      (if idx (substring newsgroup 0 idx))
 238      (if idx "/")
 239      (nnheader-replace-chars-in-string
 240       (if idx (substring newsgroup (1+ idx)) newsgroup)
 241       ?. ?/))))
 242
 243 (defun gnus-newsgroup-savable-name (group)
 244   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 245   ;; with dots.
 246   (nnheader-replace-chars-in-string group ?/ ?.))
 247
 248 (defun gnus-string> (s1 s2)
 249   (not (or (string< s1 s2)
 250            (string= s1 s2))))
 251
 252 ;;; Time functions.
 253
 254 (defun gnus-file-newer-than (file date)
 255   (let ((fdate (nth 5 (file-attributes file))))
 256     (or (> (car fdate) (car date))
 257         (and (= (car fdate) (car date))
 258              (> (nth 1 fdate) (nth 1 date))))))
 259
 260 ;;; Keymap macros.
 261
 262 (defmacro gnus-local-set-keys (&rest plist)
 263   "Set the keys in PLIST in the current keymap."
 264   `(gnus-define-keys-1 (current-local-map) ',plist))
 265
 266 (defmacro gnus-define-keys (keymap &rest plist)
 267   "Define all keys in PLIST in KEYMAP."
 268   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 269
 270 (defmacro gnus-define-keys-safe (keymap &rest plist)
 271   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 272   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 273
 274 (put 'gnus-define-keys 'lisp-indent-function 1)
 275 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 276 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 277
 278 (defmacro gnus-define-keymap (keymap &rest plist)
 279   "Define all keys in PLIST in KEYMAP."
 280   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 281
 282 (put 'gnus-define-keymap 'lisp-indent-function 1)
 283
 284 (defun gnus-define-keys-1 (keymap plist &optional safe)
 285   (when (null keymap)
 286     (error "Can't set keys in a null keymap"))
 287   (cond ((symbolp keymap)
 288          (setq keymap (symbol-value keymap)))
 289         ((keymapp keymap))
 290         ((listp keymap)
 291          (set (car keymap) nil)
 292          (define-prefix-command (car keymap))
 293          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 294          (setq keymap (symbol-value (car keymap)))))
 295   (let (key)
 296     (while plist
 297       (when (symbolp (setq key (pop plist)))
 298         (setq key (symbol-value key)))
 299       (if (or (not safe)
 300               (eq (lookup-key keymap key) 'undefined))
 301           (define-key keymap key (pop plist))
 302         (pop plist)))))
 303
 304 (defun gnus-completing-read-with-default (default prompt &rest args)
 305   ;; Like `completing-read', except that DEFAULT is the default argument.
 306   (let* ((prompt (if default
 307                      (concat prompt " (default " default ") ")
 308                    (concat prompt " ")))
 309          (answer (apply 'completing-read prompt args)))
 310     (if (or (null answer) (zerop (length answer)))
 311         default
 312       answer)))
 313
 314 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 315 ;; the echo area.
 316 (defun gnus-y-or-n-p (prompt)
 317   (prog1
 318       (y-or-n-p prompt)
 319     (message "")))
 320
 321 (defun gnus-yes-or-no-p (prompt)
 322   (prog1
 323       (yes-or-no-p prompt)
 324     (message "")))
 325
 326 ;; By Frank Schmitt <ich@Frank-Schmitt.net>. Allows to have
 327 ;; age-depending date representations. (e.g. just the time if it's
 328 ;; from today, the day of the week if it's within the last 7 days and
 329 ;; the full date if it's older)
 330 (defun gnus-seconds-today ()
 331   "Returns the number of seconds passed today"
 332   (let ((now (decode-time (current-time))))
 333     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600))))
 334
 335 (defun gnus-seconds-month ()
 336   "Returns the number of seconds passed this month"
 337   (let ((now (decode-time (current-time))))
 338     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 339        (* (- (car (nthcdr 3 now)) 1) 3600 24))))
 340
 341 (defun gnus-seconds-year ()
 342   "Returns the number of seconds passed this year"
 343   (let ((now (decode-time (current-time)))
 344         (days (format-time-string "%j" (current-time))))
 345     (+ (car now) (* (car (cdr now)) 60) (* (car (nthcdr 2 now)) 3600)
 346        (* (- (string-to-number days) 1) 3600 24))))
 347
 348 (defvar gnus-user-date-format-alist
 349   '(((gnus-seconds-today) . "%k:%M")
 350     (604800 . "%a %k:%M")                   ;;that's one week
 351     ((gnus-seconds-month) . "%a %d")
 352     ((gnus-seconds-year) . "%b %d")
 353     (t . "%b %d '%y"))                      ;;this one is used when no
 354                                             ;;other does match
 355   "Specifies date format depending on age of article.
 356 This is an alist of items (AGE . FORMAT).  AGE can be a number (of
 357 seconds) or a Lisp expression evaluating to a number.  When the age of
 358 the article is less than this number, then use `format-time-string'
 359 with the corresponding FORMAT for displaying the date of the article.
 360 If AGE is not a number or a Lisp expression evaluating to a
 361 non-number, then the corresponding FORMAT is used as a default value.
 362
 363 Note that the list is processed from the beginning, so it should be
 364 sorted by ascending AGE.  Also note that items following the first
 365 non-number AGE will be ignored.
 366
 367 You can use the functions `gnus-seconds-today', `gnus-seconds-month'
 368 and `gnus-seconds-year' in the AGE spec.  They return the number of
 369 seconds passed since the start of today, of this month, of this year,
 370 respectively.")
 371
 372 (defun gnus-user-date (messy-date)
 373   "Format the messy-date acording to gnus-user-date-format-alist.
 374 Returns \"  ?  \" if there's bad input or if an other error occurs.
 375 Input should look like this: \"Sun, 14 Oct 2001 13:34:39 +0200\"."
 376   (condition-case ()
 377       (let* ((messy-date (safe-date-to-time messy-date))
 378              (now (current-time))
 379              ;;If we don't find something suitable we'll use this one
 380              (my-format "%b %m '%y")
 381              (high (lsh (- (car now) (car messy-date)) 16)))
 382         (if (and (> high -1) (= (logand high 65535) 0))
 383             ;;overflow and bad input
 384             (let* ((difference (+ high (- (car (cdr now))
 385                                           (car (cdr messy-date)))))
 386                    (templist gnus-user-date-format-alist)
 387                    (top (eval (caar templist))))
 388               (while (if (numberp top) (< top difference) (not top))
 389                 (progn
 390                   (setq templist (cdr templist))
 391                   (setq top (eval (caar templist)))))
 392               (if (stringp (cdr (car templist)))
 393                   (setq my-format (cdr (car templist))))))
 394         (format-time-string (eval my-format) messy-date))
 395     (error "  ?   ")))
 396 ;;end of Frank's code
 397
 398 (defun gnus-dd-mmm (messy-date)
 399   "Return a string like DD-MMM from a big messy string."
 400   (condition-case ()
 401       (format-time-string "%d-%b" (safe-date-to-time messy-date))
 402     (error "  -   ")))
 403
 404 (defmacro gnus-date-get-time (date)
 405   "Convert DATE string to Emacs time.
 406 Cache the result as a text property stored in DATE."
 407   ;; Either return the cached value...
 408   `(let ((d ,date))
 409      (if (equal "" d)
 410          '(0 0)
 411        (or (get-text-property 0 'gnus-time d)
 412            ;; or compute the value...
 413            (let ((time (safe-date-to-time d)))
 414              ;; and store it back in the string.
 415              (put-text-property 0 1 'gnus-time time d)
 416              time)))))
 417
 418 (defsubst gnus-time-iso8601 (time)
 419   "Return a string of TIME in YYYYMMDDTHHMMSS format."
 420   (format-time-string "%Y%m%dT%H%M%S" time))
 421
 422 (defun gnus-date-iso8601 (date)
 423   "Convert the DATE to YYYYMMDDTHHMMSS."
 424   (condition-case ()
 425       (gnus-time-iso8601 (gnus-date-get-time date))
 426     (error "")))
 427
 428 (defun gnus-mode-string-quote (string)
 429   "Quote all \"%\"'s in STRING."
 430   (gnus-replace-in-string string "%" "%%"))
 431
 432 ;; Make a hash table (default and minimum size is 256).
 433 ;; Optional argument HASHSIZE specifies the table size.
 434 (defun gnus-make-hashtable (&optional hashsize)
 435   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 436
 437 ;; Make a number that is suitable for hashing; bigger than MIN and
 438 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 439 ;; hardware modulo operation, so they implement it in software.  On
 440 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 441 ;; Yes, it's slower than actually computing the hash from the string!
 442 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 443 (defun gnus-create-hash-size (min)
 444   (let ((i 1))
 445     (while (< i min)
 446       (setq i (* 2 i)))
 447     i))
 448
 449 (defcustom gnus-verbose 7
 450   "*Integer that says how verbose Gnus should be.
 451 The higher the number, the more messages Gnus will flash to say what
 452 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 453 display most important messages; and at ten, Gnus will keep on
 454 jabbering all the time."
 455   :group 'gnus-start
 456   :type 'integer)
 457
 458 (defun gnus-message (level &rest args)
 459   "If LEVEL is lower than `gnus-verbose' print ARGS using `message'.
 460
 461 Guideline for numbers:
 462 1 - error messages, 3 - non-serious error messages, 5 - messages for things
 463 that take a long time, 7 - not very important messages on stuff, 9 - messages
 464 inside loops."
 465   (if (<= level gnus-verbose)
 466       (apply 'message args)
 467     ;; We have to do this format thingy here even if the result isn't
 468     ;; shown - the return value has to be the same as the return value
 469     ;; from `message'.
 470     (apply 'format args)))
 471
 472 (defun gnus-error (level &rest args)
 473   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 474   (when (<= (floor level) gnus-verbose)
 475     (apply 'message args)
 476     (ding)
 477     (let (duration)
 478       (when (and (floatp level)
 479                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 480         (sit-for duration))))
 481   nil)
 482
 483 (defun gnus-split-references (references)
 484   "Return a list of Message-IDs in REFERENCES."
 485   (let ((beg 0)
 486         ids)
 487     (while (string-match "<[^<]+[^< \t]" references beg)
 488       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 489             ids))
 490     (nreverse ids)))
 491
 492 (defsubst gnus-parent-id (references &optional n)
 493   "Return the last Message-ID in REFERENCES.
 494 If N, return the Nth ancestor instead."
 495   (when (and references
 496              (not (zerop (length references))))
 497     (if n
 498         (let ((ids (inline (gnus-split-references references))))
 499           (while (nthcdr n ids)
 500             (setq ids (cdr ids)))
 501           (car ids))
 502       (when (string-match "\\(<[^<]+>\\)[ \t]*\\'" references)
 503         (match-string 1 references)))))
 504
 505 (defun gnus-buffer-live-p (buffer)
 506   "Say whether BUFFER is alive or not."
 507   (and buffer
 508        (get-buffer buffer)
 509        (buffer-name (get-buffer buffer))))
 510
 511 (defun gnus-horizontal-recenter ()
 512   "Recenter the current buffer horizontally."
 513   (if (< (current-column) (/ (window-width) 2))
 514       (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0)
 515     (let* ((orig (point))
 516            (end (window-end (gnus-get-buffer-window (current-buffer) t)))
 517            (max 0))
 518       (when end
 519         ;; Find the longest line currently displayed in the window.
 520         (goto-char (window-start))
 521         (while (and (not (eobp))
 522                     (< (point) end))
 523           (end-of-line)
 524           (setq max (max max (current-column)))
 525           (forward-line 1))
 526         (goto-char orig)
 527         ;; Scroll horizontally to center (sort of) the point.
 528         (if (> max (window-width))
 529             (set-window-hscroll
 530              (gnus-get-buffer-window (current-buffer) t)
 531              (min (- (current-column) (/ (window-width) 3))
 532                   (+ 2 (- max (window-width)))))
 533           (set-window-hscroll (gnus-get-buffer-window (current-buffer) t) 0))
 534         max))))
 535
 536 (defun gnus-read-event-char (&optional prompt)
 537   "Get the next event."
 538   (let ((event (read-event prompt)))
 539     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 540     (cons (and (numberp event) event) event)))
 541
 542 (defun gnus-sortable-date (date)
 543   "Make string suitable for sorting from DATE."
 544   (gnus-time-iso8601 (date-to-time date)))
 545
 546 (defun gnus-copy-file (file &optional to)
 547   "Copy FILE to TO."
 548   (interactive
 549    (list (read-file-name "Copy file: " default-directory)
 550          (read-file-name "Copy file to: " default-directory)))
 551   (unless to
 552     (setq to (read-file-name "Copy file to: " default-directory)))
 553   (when (file-directory-p to)
 554     (setq to (concat (file-name-as-directory to)
 555                      (file-name-nondirectory file))))
 556   (copy-file file to))
 557
 558 (defvar gnus-work-buffer " *gnus work*")
 559
 560 (defun gnus-set-work-buffer ()
 561   "Put point in the empty Gnus work buffer."
 562   (if (get-buffer gnus-work-buffer)
 563       (progn
 564         (set-buffer gnus-work-buffer)
 565         (erase-buffer))
 566     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 567     (kill-all-local-variables)
 568     (mm-enable-multibyte)))
 569
 570 (defmacro gnus-group-real-name (group)
 571   "Find the real name of a foreign newsgroup."
 572   `(let ((gname ,group))
 573      (if (string-match "^[^:]+:" gname)
 574          (substring gname (match-end 0))
 575        gname)))
 576
 577 (defun gnus-make-sort-function (funs)
 578   "Return a composite sort condition based on the functions in FUNC."
 579   (cond
 580    ;; Just a simple function.
 581    ((gnus-functionp funs) funs)
 582    ;; No functions at all.
 583    ((null funs) funs)
 584    ;; A list of functions.
 585    ((or (cdr funs)
 586         (listp (car funs)))
 587     (gnus-byte-compile
 588      `(lambda (t1 t2)
 589         ,(gnus-make-sort-function-1 (reverse funs)))))
 590    ;; A list containing just one function.
 591    (t
 592     (car funs))))
 593
 594 (defun gnus-make-sort-function-1 (funs)
 595   "Return a composite sort condition based on the functions in FUNC."
 596   (let ((function (car funs))
 597         (first 't1)
 598         (last 't2))
 599     (when (consp function)
 600       (cond
 601        ;; Reversed spec.
 602        ((eq (car function) 'not)
 603         (setq function (cadr function)
 604               first 't2
 605               last 't1))
 606        ((gnus-functionp function)
 607         ;; Do nothing.
 608         )
 609        (t
 610         (error "Invalid sort spec: %s" function))))
 611     (if (cdr funs)
 612         `(or (,function ,first ,last)
 613              (and (not (,function ,last ,first))
 614                   ,(gnus-make-sort-function-1 (cdr funs))))
 615       `(,function ,first ,last))))
 616
 617 (defun gnus-turn-off-edit-menu (type)
 618   "Turn off edit menu in `gnus-TYPE-mode-map'."
 619   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 620     [menu-bar edit] 'undefined))
 621
 622 (defun gnus-prin1 (form)
 623   "Use `prin1' on FORM in the current buffer.
 624 Bind `print-quoted' and `print-readably' to t while printing."
 625   (let ((print-quoted t)
 626         (print-readably t)
 627         (print-escape-multibyte nil)
 628         print-level print-length)
 629     (prin1 form (current-buffer))))
 630
 631 (defun gnus-prin1-to-string (form)
 632   "The same as `prin1'.
 633 Bind `print-quoted' and `print-readably' to t, and `print-length'
 634 and `print-level' to nil."
 635   (let ((print-quoted t)
 636         (print-readably t)
 637         (print-length nil)
 638         (print-level nil))
 639     (prin1-to-string form)))
 640
 641 (defun gnus-make-directory (directory)
 642   "Make DIRECTORY (and all its parents) if it doesn't exist."
 643   (require 'nnmail)
 644   (let ((file-name-coding-system nnmail-pathname-coding-system))
 645     (when (and directory
 646                (not (file-exists-p directory)))
 647       (make-directory directory t)))
 648   t)
 649
 650 (defun gnus-write-buffer (file)
 651   "Write the current buffer's contents to FILE."
 652   ;; Make sure the directory exists.
 653   (gnus-make-directory (file-name-directory file))
 654   (let ((file-name-coding-system nnmail-pathname-coding-system))
 655     ;; Write the buffer.
 656     (write-region (point-min) (point-max) file nil 'quietly)))
 657
 658 (defun gnus-delete-file (file)
 659   "Delete FILE if it exists."
 660   (when (file-exists-p file)
 661     (delete-file file)))
 662
 663 (defun gnus-strip-whitespace (string)
 664   "Return STRING stripped of all whitespace."
 665   (while (string-match "[\r\n\t ]+" string)
 666     (setq string (replace-match "" t t string)))
 667   string)
 668
 669 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 670   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 671   (save-match-data
 672     (save-excursion
 673       (save-restriction
 674         (goto-char beg)
 675         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 676           (gnus-put-text-property beg (match-beginning 0) prop val)
 677           (setq beg (point)))
 678         (gnus-put-text-property beg (point) prop val)))))
 679
 680 (defsubst gnus-put-overlay-excluding-newlines (beg end prop val)
 681   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 682   (save-match-data
 683     (save-excursion
 684       (save-restriction
 685         (goto-char beg)
 686         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 687           (gnus-overlay-put
 688            (gnus-make-overlay beg (match-beginning 0))
 689            prop val)
 690           (setq beg (point)))
 691         (gnus-overlay-put (gnus-make-overlay beg (point)) prop val)))))
 692
 693 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 694                                                                    prop val)
 695   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 696   (let ((b beg))
 697     (while (/= b end)
 698       (when (get-text-property b 'gnus-face)
 699         (setq b (next-single-property-change b 'gnus-face nil end)))
 700       (when (/= b end)
 701         (inline
 702           (gnus-put-text-property
 703            b (setq b (next-single-property-change b 'gnus-face nil end))
 704            prop val))))))
 705
 706 (defmacro gnus-faces-at (position)
 707   "Return a list of faces at POSITION."
 708   (if (featurep 'xemacs)
 709       `(let ((pos ,position))
 710          (mapcar-extents 'extent-face
 711                          nil (current-buffer) pos pos nil 'face))
 712     `(let ((pos ,position))
 713        (delq nil (cons (get-text-property pos 'face)
 714                        (mapcar
 715                         (lambda (overlay)
 716                           (overlay-get overlay 'face))
 717                         (overlays-at pos)))))))
 718
 719 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 720 ;;; The primary idea here is to try to protect internal datastructures
 721 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 722 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 723 ;;; updated at the same time, or information can be lost.
 724
 725 (defvar gnus-atomic-be-safe t
 726   "If t, certain operations will be protected from interruption by C-g.")
 727
 728 (defmacro gnus-atomic-progn (&rest forms)
 729   "Evaluate FORMS atomically, which means to protect the evaluation
 730 from being interrupted by the user.  An error from the forms themselves
 731 will return without finishing the operation.  Since interrupts from
 732 the user are disabled, it is recommended that only the most minimal
 733 operations are performed by FORMS.  If you wish to assign many
 734 complicated values atomically, compute the results into temporary
 735 variables and then do only the assignment atomically."
 736   `(let ((inhibit-quit gnus-atomic-be-safe))
 737      ,@forms))
 738
 739 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 740
 741 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 742   "Evaluate FORMS, but insure that the variables listed in PROTECT
 743 are not changed if anything in FORMS signals an error or otherwise
 744 non-locally exits.  The variables listed in PROTECT are updated atomically.
 745 It is safe to use gnus-atomic-progn-assign with long computations.
 746
 747 Note that if any of the symbols in PROTECT were unbound, they will be
 748 set to nil on a successful assignment.  In case of an error or other
 749 non-local exit, it will still be unbound."
 750   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 751                                                   (concat (symbol-name x)
 752                                                           "-tmp"))
 753                                                  x))
 754                                protect))
 755          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 756                                temp-sym-map))
 757          (temp-sym-let (mapcar (lambda (x) (list (car x)
 758                                                  `(and (boundp ',(cadr x))
 759                                                        ,(cadr x))))
 760                                temp-sym-map))
 761          (sym-temp-let sym-temp-map)
 762          (temp-sym-assign (apply 'append temp-sym-map))
 763          (sym-temp-assign (apply 'append sym-temp-map))
 764          (result (make-symbol "result-tmp")))
 765     `(let (,@temp-sym-let
 766            ,result)
 767        (let ,sym-temp-let
 768          (setq ,result (progn ,@forms))
 769          (setq ,@temp-sym-assign))
 770        (let ((inhibit-quit gnus-atomic-be-safe))
 771          (setq ,@sym-temp-assign))
 772        ,result)))
 773
 774 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 775 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 776
 777 (defmacro gnus-atomic-setq (&rest pairs)
 778   "Similar to setq, except that the real symbols are only assigned when
 779 there are no errors.  And when the real symbols are assigned, they are
 780 done so atomically.  If other variables might be changed via side-effect,
 781 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 782 with potentially long computations."
 783   (let ((tpairs pairs)
 784         syms)
 785     (while tpairs
 786       (push (car tpairs) syms)
 787       (setq tpairs (cddr tpairs)))
 788     `(gnus-atomic-progn-assign ,syms
 789        (setq ,@pairs))))
 790
 791 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 792
 793
 794 ;;; Functions for saving to babyl/mail files.
 795
 796 (defvar rmail-default-rmail-file)
 797 (defun gnus-output-to-rmail (filename &optional ask)
 798   "Append the current article to an Rmail file named FILENAME."
 799   (require 'rmail)
 800   ;; Most of these codes are borrowed from rmailout.el.
 801   (setq filename (expand-file-name filename))
 802   (setq rmail-default-rmail-file filename)
 803   (let ((artbuf (current-buffer))
 804         (tmpbuf (get-buffer-create " *Gnus-output*")))
 805     (save-excursion
 806       (or (get-file-buffer filename)
 807           (file-exists-p filename)
 808           (if (or (not ask)
 809                   (gnus-yes-or-no-p
 810                    (concat "\"" filename "\" does not exist, create it? ")))
 811               (let ((file-buffer (create-file-buffer filename)))
 812                 (save-excursion
 813                   (set-buffer file-buffer)
 814                   (rmail-insert-rmail-file-header)
 815                   (let ((require-final-newline nil)
 816                         (coding-system-for-write mm-text-coding-system))
 817                     (gnus-write-buffer filename)))
 818                 (kill-buffer file-buffer))
 819             (error "Output file does not exist")))
 820       (set-buffer tmpbuf)
 821       (erase-buffer)
 822       (insert-buffer-substring artbuf)
 823       (gnus-convert-article-to-rmail)
 824       ;; Decide whether to append to a file or to an Emacs buffer.
 825       (let ((outbuf (get-file-buffer filename)))
 826         (if (not outbuf)
 827             (let ((file-name-coding-system nnmail-pathname-coding-system))
 828               (mm-append-to-file (point-min) (point-max) filename))
 829           ;; File has been visited, in buffer OUTBUF.
 830           (set-buffer outbuf)
 831           (let ((buffer-read-only nil)
 832                 (msg (and (boundp 'rmail-current-message)
 833                           (symbol-value 'rmail-current-message))))
 834             ;; If MSG is non-nil, buffer is in RMAIL mode.
 835             (when msg
 836               (widen)
 837               (narrow-to-region (point-max) (point-max)))
 838             (insert-buffer-substring tmpbuf)
 839             (when msg
 840               (goto-char (point-min))
 841               (widen)
 842               (search-backward "\n\^_")
 843               (narrow-to-region (point) (point-max))
 844               (rmail-count-new-messages t)
 845               (when (rmail-summary-exists)
 846                 (rmail-select-summary
 847                  (rmail-update-summary)))
 848               (rmail-count-new-messages t)
 849               (rmail-show-message msg))
 850             (save-buffer)))))
 851     (kill-buffer tmpbuf)))
 852
 853 (defun gnus-output-to-mail (filename &optional ask)
 854   "Append the current article to a mail file named FILENAME."
 855   (setq filename (expand-file-name filename))
 856   (let ((artbuf (current-buffer))
 857         (tmpbuf (get-buffer-create " *Gnus-output*")))
 858     (save-excursion
 859       ;; Create the file, if it doesn't exist.
 860       (when (and (not (get-file-buffer filename))
 861                  (not (file-exists-p filename)))
 862         (if (or (not ask)
 863                 (gnus-y-or-n-p
 864                  (concat "\"" filename "\" does not exist, create it? ")))
 865             (let ((file-buffer (create-file-buffer filename)))
 866               (save-excursion
 867                 (set-buffer file-buffer)
 868                 (let ((require-final-newline nil)
 869                       (coding-system-for-write mm-text-coding-system))
 870                   (gnus-write-buffer filename)))
 871               (kill-buffer file-buffer))
 872           (error "Output file does not exist")))
 873       (set-buffer tmpbuf)
 874       (erase-buffer)
 875       (insert-buffer-substring artbuf)
 876       (goto-char (point-min))
 877       (if (looking-at "From ")
 878           (forward-line 1)
 879         (insert "From nobody " (current-time-string) "\n"))
 880       (let (case-fold-search)
 881         (while (re-search-forward "^From " nil t)
 882           (beginning-of-line)
 883           (insert ">")))
 884       ;; Decide whether to append to a file or to an Emacs buffer.
 885       (let ((outbuf (get-file-buffer filename)))
 886         (if (not outbuf)
 887             (let ((buffer-read-only nil))
 888               (save-excursion
 889                 (goto-char (point-max))
 890                 (forward-char -2)
 891                 (unless (looking-at "\n\n")
 892                   (goto-char (point-max))
 893                   (unless (bolp)
 894                     (insert "\n"))
 895                   (insert "\n"))
 896                 (goto-char (point-max))
 897                 (let ((file-name-coding-system nnmail-pathname-coding-system))
 898                   (mm-append-to-file (point-min) (point-max) filename))))
 899           ;; File has been visited, in buffer OUTBUF.
 900           (set-buffer outbuf)
 901           (let ((buffer-read-only nil))
 902             (goto-char (point-max))
 903             (unless (eobp)
 904               (insert "\n"))
 905             (insert "\n")
 906             (insert-buffer-substring tmpbuf)))))
 907     (kill-buffer tmpbuf)))
 908
 909 (defun gnus-convert-article-to-rmail ()
 910   "Convert article in current buffer to Rmail message format."
 911   (let ((buffer-read-only nil))
 912     ;; Convert article directly into Babyl format.
 913     (goto-char (point-min))
 914     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 915     (while (search-forward "\n\^_" nil t) ;single char
 916       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 917     (goto-char (point-max))
 918     (insert "\^_")))
 919
 920 (defun gnus-map-function (funs arg)
 921   "Applies the result of the first function in FUNS to the second, and so on.
 922 ARG is passed to the first function."
 923   (while funs
 924     (setq arg (funcall (pop funs) arg)))
 925   arg)
 926
 927 (defun gnus-run-hooks (&rest funcs)
 928   "Does the same as `run-hooks', but saves the current buffer."
 929   (save-current-buffer
 930     (apply 'run-hooks funcs)))
 931
 932 ;;; Various
 933
 934 (defvar gnus-group-buffer)              ; Compiler directive
 935 (defun gnus-alive-p ()
 936   "Say whether Gnus is running or not."
 937   (and (boundp 'gnus-group-buffer)
 938        (get-buffer gnus-group-buffer)
 939        (save-excursion
 940          (set-buffer gnus-group-buffer)
 941          (eq major-mode 'gnus-group-mode))))
 942
 943 (defun gnus-remove-duplicates (list)
 944   (let (new)
 945     (while list
 946       (or (member (car list) new)
 947           (setq new (cons (car list) new)))
 948       (setq list (cdr list)))
 949     (nreverse new)))
 950
 951 (defun gnus-remove-if (predicate list)
 952   "Return a copy of LIST with all items satisfying PREDICATE removed."
 953   (let (out)
 954     (while list
 955       (unless (funcall predicate (car list))
 956         (push (car list) out))
 957       (setq list (cdr list)))
 958     (nreverse out)))
 959
 960 (if (fboundp 'assq-delete-all)
 961     (defalias 'gnus-delete-alist 'assq-delete-all)
 962   (defun gnus-delete-alist (key alist)
 963     "Delete from ALIST all elements whose car is KEY.
 964 Return the modified alist."
 965     (let (entry)
 966       (while (setq entry (assq key alist))
 967         (setq alist (delq entry alist)))
 968       alist)))
 969
 970 (defmacro gnus-pull (key alist &optional assoc-p)
 971   "Modify ALIST to be without KEY."
 972   (unless (symbolp alist)
 973     (error "Not a symbol: %s" alist))
 974   (let ((fun (if assoc-p 'assoc 'assq)))
 975     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
 976
 977 (defun gnus-globalify-regexp (re)
 978   "Returns a regexp that matches a whole line, iff RE matches a part of it."
 979   (concat (unless (string-match "^\\^" re) "^.*")
 980           re
 981           (unless (string-match "\\$$" re) ".*$")))
 982
 983 (defun gnus-set-window-start (&optional point)
 984   "Set the window start to POINT, or (point) if nil."
 985   (let ((win (gnus-get-buffer-window (current-buffer) t)))
 986     (when win
 987       (set-window-start win (or point (point))))))
 988
 989 (defun gnus-annotation-in-region-p (b e)
 990   (if (= b e)
 991       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 992     (text-property-any b e 'gnus-undeletable t)))
 993
 994 (defun gnus-or (&rest elems)
 995   "Return non-nil if any of the elements are non-nil."
 996   (catch 'found
 997     (while elems
 998       (when (pop elems)
 999         (throw 'found t)))))
1000
1001 (defun gnus-and (&rest elems)
1002   "Return non-nil if all of the elements are non-nil."
1003   (catch 'found
1004     (while elems
1005       (unless (pop elems)
1006         (throw 'found nil)))
1007     t))
1008
1009 (defun gnus-write-active-file (file hashtb &optional full-names)
1010   (let ((coding-system-for-write nnmail-active-file-coding-system))
1011     (with-temp-file file
1012       (mapatoms
1013        (lambda (sym)
1014          (when (and sym
1015                     (boundp sym)
1016                     (symbol-value sym))
1017            (insert (format "%S %d %d y\n"
1018                            (if full-names
1019                                sym
1020                              (intern (gnus-group-real-name (symbol-name sym))))
1021                            (or (cdr (symbol-value sym))
1022                                (car (symbol-value sym)))
1023                            (car (symbol-value sym))))))
1024        hashtb)
1025       (goto-char (point-max))
1026       (while (search-backward "\\." nil t)
1027         (delete-char 1)))))
1028
1029 (defmacro gnus-with-output-to-file (file &rest body)
1030   (let ((buffer (make-symbol "output-buffer"))
1031         (size (make-symbol "output-buffer-size"))
1032         (leng (make-symbol "output-buffer-length"))
1033         (append (make-symbol "output-buffer-append")))
1034     `(let* ((,size 131072)
1035             (,buffer (make-string ,size 0))
1036             (,leng 0)
1037             (,append nil)
1038             (standard-output
1039              (lambda (c)
1040                (aset ,buffer ,leng c)
1041
1042                (if (= ,size (setq ,leng (1+ ,leng)))
1043                    (progn (write-region ,buffer nil ,file ,append 'no-msg)
1044                           (setq ,leng 0
1045                                 ,append t))))))
1046        ,@body
1047        (when (> ,leng 0)
1048          (let ((coding-system-for-write 'no-conversion))
1049          (write-region (substring ,buffer 0 ,leng) nil ,file
1050                        ,append 'no-msg))))))
1051
1052 (put 'gnus-with-output-to-file 'lisp-indent-function 1)
1053 (put 'gnus-with-output-to-file 'edebug-form-spec '(form body))
1054
1055 (if (fboundp 'union)
1056     (defalias 'gnus-union 'union)
1057   (defun gnus-union (l1 l2)
1058     "Set union of lists L1 and L2."
1059     (cond ((null l1) l2)
1060           ((null l2) l1)
1061           ((equal l1 l2) l1)
1062           (t
1063            (or (>= (length l1) (length l2))
1064                (setq l1 (prog1 l2 (setq l2 l1))))
1065            (while l2
1066              (or (member (car l2) l1)
1067                  (push (car l2) l1))
1068              (pop l2))
1069            l1))))
1070
1071 (defun gnus-add-text-properties-when
1072   (property value start end properties &optional object)
1073   "Like `gnus-add-text-properties', only applied on where PROPERTY is VALUE."
1074   (let (point)
1075     (while (and start
1076                 (< start end) ;; XEmacs will loop for every when start=end.
1077                 (setq point (text-property-not-all start end property value)))
1078       (gnus-add-text-properties start point properties object)
1079       (setq start (text-property-any point end property value)))
1080     (if start
1081         (gnus-add-text-properties start end properties object))))
1082
1083 (defun gnus-remove-text-properties-when
1084   (property value start end properties &optional object)
1085   "Like `remove-text-properties', only applied on where PROPERTY is VALUE."
1086   (let (point)
1087     (while (and start
1088                 (< start end)
1089                 (setq point (text-property-not-all start end property value)))
1090       (remove-text-properties start point properties object)
1091       (setq start (text-property-any point end property value)))
1092     (if start
1093         (remove-text-properties start end properties object))
1094     t))
1095
1096 ;; This might use `compare-strings' to reduce consing in the
1097 ;; case-insensitive case, but it has to cope with null args.
1098 ;; (`string-equal' uses symbol print names.)
1099 (defun gnus-string-equal (x y)
1100   "Like `string-equal', except it compares case-insensitively."
1101   (and (= (length x) (length y))
1102        (or (string-equal x y)
1103            (string-equal (downcase x) (downcase y)))))
1104
1105 (defcustom gnus-use-byte-compile t
1106   "If non-nil, byte-compile crucial run-time codes.
1107 Setting it to nil has no effect after first time running
1108 `gnus-byte-compile'."
1109   :type 'boolean
1110   :version "21.1"
1111   :group 'gnus-various)
1112
1113 (defun gnus-byte-compile (form)
1114   "Byte-compile FORM if `gnus-use-byte-compile' is non-nil."
1115   (if gnus-use-byte-compile
1116       (progn
1117         (condition-case nil
1118             ;; Work around a bug in XEmacs 21.4
1119             (require 'byte-optimize)
1120           (error))
1121         (require 'bytecomp)
1122         (defalias 'gnus-byte-compile
1123           (lambda (form)
1124             (let ((byte-compile-warnings '(unresolved callargs redefine)))
1125               (byte-compile form))))
1126         (gnus-byte-compile form))
1127     form))
1128
1129 (defun gnus-remassoc (key alist)
1130   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1131 The modified LIST is returned.  If the first member
1132 of LIST has a car that is `equal' to KEY, there is no way to remove it
1133 by side effect; therefore, write `(setq foo (remassoc key foo))' to be
1134 sure of changing the value of `foo'."
1135   (when alist
1136     (if (equal key (caar alist))
1137         (cdr alist)
1138       (setcdr alist (gnus-remassoc key (cdr alist)))
1139       alist)))
1140
1141 (defun gnus-update-alist-soft (key value alist)
1142   (if value
1143       (cons (cons key value) (gnus-remassoc key alist))
1144     (gnus-remassoc key alist)))
1145
1146 (defun gnus-create-info-command (node)
1147   "Create a command that will go to info NODE."
1148   `(lambda ()
1149      (interactive)
1150      ,(concat "Enter the info system at node " node)
1151      (Info-goto-node ,node)
1152      (setq gnus-info-buffer (current-buffer))
1153      (gnus-configure-windows 'info)))
1154
1155 (defun gnus-not-ignore (&rest args)
1156   t)
1157
1158 (defvar gnus-directory-sep-char-regexp "/"
1159   "The regexp of directory separator character.
1160 If you find some problem with the directory separator character, try
1161 \"[/\\\\\]\" for some systems.")
1162
1163 (defun gnus-url-unhex (x)
1164   (if (> x ?9)
1165       (if (>= x ?a)
1166           (+ 10 (- x ?a))
1167         (+ 10 (- x ?A)))
1168     (- x ?0)))
1169
1170 (defun gnus-url-unhex-string (str &optional allow-newlines)
1171   "Remove %XXX embedded spaces, etc in a url.
1172 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
1173 decoding of carriage returns and line feeds in the string, which is normally
1174 forbidden in URL encoding."
1175   (setq str (or (mm-subst-char-in-string ?+ ?  str) ""))
1176   (let ((tmp "")
1177         (case-fold-search t))
1178     (while (string-match "%[0-9a-f][0-9a-f]" str)
1179       (let* ((start (match-beginning 0))
1180              (ch1 (gnus-url-unhex (elt str (+ start 1))))
1181              (code (+ (* 16 ch1)
1182                       (gnus-url-unhex (elt str (+ start 2))))))
1183         (setq tmp (concat
1184                    tmp (substring str 0 start)
1185                    (cond
1186                     (allow-newlines
1187                      (char-to-string code))
1188                     ((or (= code ?\n) (= code ?\r))
1189                      " ")
1190                     (t (char-to-string code))))
1191               str (substring str (match-end 0)))))
1192     (setq tmp (concat tmp str))
1193     tmp))
1194
1195 (defun gnus-make-predicate (spec)
1196   "Transform SPEC into a function that can be called.
1197 SPEC is a predicate specifier that contains stuff like `or', `and',
1198 `not', lists and functions.  The functions all take one parameter."
1199   `(lambda (elem) ,(gnus-make-predicate-1 spec)))
1200
1201 (defun gnus-make-predicate-1 (spec)
1202   (cond
1203    ((symbolp spec)
1204     `(,spec elem))
1205    ((listp spec)
1206     (if (memq (car spec) '(or and not))
1207         `(,(car spec) ,@(mapcar 'gnus-make-predicate-1 (cdr spec)))
1208       (error "Invalid predicate specifier: %s" spec)))))
1209
1210 (defun gnus-local-map-property (map)
1211   "Return a list suitable for a text property list specifying keymap MAP."
1212   (cond
1213    ((featurep 'xemacs)
1214     (list 'keymap map))
1215    ((>= emacs-major-version 21)
1216     (list 'keymap map))
1217    (t
1218     (list 'local-map map))))
1219
1220 (defun gnus-completing-read (prompt table &optional predicate require-match
1221                                     history)
1222   (when (and history
1223              (not (boundp history)))
1224     (set history nil))
1225   (completing-read
1226    (if (symbol-value history)
1227        (concat prompt " (" (car (symbol-value history)) "): ")
1228      (concat prompt ": "))
1229    table
1230    predicate
1231    require-match
1232    nil
1233    history
1234    (car (symbol-value history))))
1235
1236 (defun gnus-graphic-display-p ()
1237   (or (and (fboundp 'display-graphic-p)
1238            (display-graphic-p))
1239       ;;;!!!This is bogus.  Fixme!
1240       (and (featurep 'xemacs)
1241            t)))
1242
1243 (put 'gnus-parse-without-error 'lisp-indent-function 0)
1244 (put 'gnus-parse-without-error 'edebug-form-spec '(body))
1245
1246 (defmacro gnus-parse-without-error (&rest body)
1247   "Allow continuing onto the next line even if an error occurs."
1248   `(while (not (eobp))
1249      (condition-case ()
1250          (progn
1251            ,@body
1252            (goto-char (point-max)))
1253        (error
1254         (gnus-error 4 "Invalid data on line %d"
1255                     (count-lines (point-min) (point)))
1256         (forward-line 1)))))
1257
1258 (defun gnus-cache-file-contents (file variable function)
1259   "Cache the contents of FILE in VARIABLE.  The contents come from FUNCTION."
1260   (let ((time (nth 5 (file-attributes file)))
1261         contents value)
1262     (if (or (null (setq value (symbol-value variable)))
1263             (not (equal (car value) file))
1264             (not (equal (nth 1 value) time)))
1265         (progn
1266           (setq contents (funcall function file))
1267           (set variable (list file time contents))
1268           contents)
1269       (nth 2 value))))
1270
1271 (defun gnus-multiple-choice (prompt choice &optional idx)
1272   "Ask user a multiple choice question.
1273 CHOICE is a list of the choice char and help message at IDX."
1274   (let (tchar buf)
1275     (save-window-excursion
1276       (save-excursion
1277         (while (not tchar)
1278           (message "%s (%s): "
1279                    prompt
1280                    (mapconcat (lambda (s) (char-to-string (car s)))
1281                               choice ", "))
1282           (setq tchar (read-char))
1283           (when (not (assq tchar choice))
1284             (setq tchar nil)
1285             (setq buf (get-buffer-create "*Gnus Help*"))
1286             (pop-to-buffer buf)
1287             (fundamental-mode)          ; for Emacs 20.4+
1288             (buffer-disable-undo)
1289             (erase-buffer)
1290             (insert prompt ":\n\n")
1291             (let ((max -1)
1292                   (list choice)
1293                   (alist choice)
1294                   (idx (or idx 1))
1295                   (i 0)
1296                   n width pad format)
1297               ;; find the longest string to display
1298               (while list
1299                 (setq n (length (nth idx (car list))))
1300                 (unless (> max n)
1301                   (setq max n))
1302                 (setq list (cdr list)))
1303               (setq max (+ max 4))      ; %c, `:', SPACE, a SPACE at end
1304               (setq n (/ (1- (window-width)) max)) ; items per line
1305               (setq width (/ (1- (window-width)) n)) ; width of each item
1306               ;; insert `n' items, each in a field of width `width'
1307               (while alist
1308                 (if (< i n)
1309                     ()
1310                   (setq i 0)
1311                   (delete-char -1)              ; the `\n' takes a char
1312                   (insert "\n"))
1313                 (setq pad (- width 3))
1314                 (setq format (concat "%c: %-" (int-to-string pad) "s"))
1315                 (insert (format format (caar alist) (nth idx (car alist))))
1316                 (setq alist (cdr alist))
1317                 (setq i (1+ i))))))))
1318     (if (buffer-live-p buf)
1319         (kill-buffer buf))
1320     tchar))
1321
1322 (defun gnus-select-frame-set-input-focus (frame)
1323   "Select FRAME, raise it, and set input focus, if possible."
1324   (cond ((featurep 'xemacs)
1325          (raise-frame frame)
1326          (select-frame frame)
1327          (focus-frame frame))
1328         ;; The function `select-frame-set-input-focus' won't set
1329         ;; the input focus under Emacs 21.2 and X window system.
1330         ;;((fboundp 'select-frame-set-input-focus)
1331         ;; (defalias 'gnus-select-frame-set-input-focus
1332         ;;   'select-frame-set-input-focus)
1333         ;; (select-frame-set-input-focus frame))
1334         (t
1335          (raise-frame frame)
1336          (select-frame frame)
1337          (cond ((and (eq window-system 'x)
1338                      (fboundp 'x-focus-frame))
1339                 (x-focus-frame frame))
1340                ((eq window-system 'w32)
1341                 (w32-focus-frame frame)))
1342          (when focus-follows-mouse
1343            (set-mouse-position frame (1- (frame-width frame)) 0)))))
1344
1345 (defun gnus-frame-or-window-display-name (object)
1346   "Given a frame or window, return the associated display name.
1347 Return nil otherwise."
1348   (if (featurep 'xemacs)
1349       (device-connection (dfw-device object))
1350     (if (or (framep object)
1351             (and (windowp object)
1352                  (setq object (window-frame object))))
1353         (let ((display (frame-parameter object 'display)))
1354           (if (and (stringp display)
1355                    ;; Exclude invalid display names.
1356                    (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'"
1357                                  display))
1358               display)))))
1359
1360 (defmacro gnus-mapcar (function seq1 &rest seqs2_n)
1361   "Apply FUNCTION to each element of the sequences, and make a list of the results.
1362 If there are several sequences, FUNCTION is called with that many arguments,
1363 and mapping stops as soon as the shortest sequence runs out.  With just one
1364 sequence, this is like `mapcar'.  With several, it is like the Common Lisp
1365 `mapcar' function extended to arbitrary sequence types."
1366
1367   (if seqs2_n
1368       (let* ((seqs (cons seq1 seqs2_n))
1369              (cnt 0)
1370              (heads (mapcar (lambda (seq)
1371                               (make-symbol (concat "head"
1372                                                    (int-to-string
1373                                                     (setq cnt (1+ cnt))))))
1374                             seqs))
1375              (result (make-symbol "result"))
1376              (result-tail (make-symbol "result-tail")))
1377         `(let* ,(let* ((bindings (cons nil nil))
1378                        (heads heads))
1379                   (nconc bindings (list (list result '(cons nil nil))))
1380                   (nconc bindings (list (list result-tail result)))
1381                   (while heads
1382                     (nconc bindings (list (list (pop heads) (pop seqs)))))
1383                   (cdr bindings))
1384            (while (and ,@heads)
1385              (setcdr ,result-tail (cons (funcall ,function
1386                                                  ,@(mapcar (lambda (h) (list 'car h))
1387                                                            heads))
1388                                         nil))
1389              (setq ,result-tail (cdr ,result-tail)
1390                    ,@(apply 'nconc (mapcar (lambda (h) (list h (list 'cdr h))) heads))))
1391            (cdr ,result)))
1392     `(mapcar ,function ,seq1)))
1393
1394 (if (fboundp 'merge)
1395     (defalias 'gnus-merge 'merge)
1396   ;; Adapted from cl-seq.el
1397   (defun gnus-merge (list1 list2 pred)
1398     "Destructively merge lists LIST1 and LIST2 to produce a new list.
1399 Ordering of the elements is preserved according to PRED, a `less-than'
1400 predicate on the elements."
1401     (let ((res nil))
1402       (while (and list1 list2)
1403         (if (funcall pred (car list2) (car list1))
1404             (push (pop list2) res)
1405           (push (pop list1) res)))
1406       (nconc (nreverse res) list1 list2))))
1407
1408 (provide 'gnus-util)
1409
1410 ;;; gnus-util.el ends here