cgit.sxemacs.org Git - gnus/blob - lisp/gnus-sync.el

   1 ;;; gnus-sync.el --- synchronization facility for Gnus
   2
   3 ;; Copyright (C) 2010-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news synchronization nntp nnrss
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the gnus-sync.el package.
  26
  27 ;; Put this in your startup file (~/.gnus.el for instance)
  28
  29 ;; possibilities for gnus-sync-backend:
  30 ;; Tramp over SSH: /ssh:user@host:/path/to/filename
  31 ;; ...or any other file Tramp and Emacs can handle...
  32
  33 ;; (setq gnus-sync-backend "/remote:/path.gpg" ; will use Tramp+EPA if loaded
  34 ;;       gnus-sync-global-vars '(gnus-newsrc-last-checked-date)
  35 ;;       gnus-sync-newsrc-groups '("nntp" "nnrss"))
  36 ;;       gnus-sync-newsrc-offsets '(2 3))
  37 ;; against a LeSync server (beware the vampire LeSync, who knows your newsrc)
  38
  39 ;; (setq gnus-sync-backend '(lesync "http://lesync.info:5984/tzz")
  40 ;;       gnus-sync-newsrc-groups '("nntp" "nnrss"))
  41
  42 ;; What's a LeSync server?
  43
  44 ;; 1. install CouchDB, set up a real server admin user, and create a
  45 ;; database, e.g. "tzz" and save the URL,
  46 ;; e.g. http://lesync.info:5984/tzz
  47
  48 ;; 2. run `M-: (gnus-sync-lesync-setup "http://lesync.info:5984/tzz" "tzzadmin" "mypassword" "mysalt" t t)'
  49
  50 ;;    (If you run it more than once, you have to remove the entry from
  51 ;;    _users yourself.  This is intentional.  This sets up a database
  52 ;;    admin for the "tzz" database, distinct from the server admin
  53 ;;    user in (1) above.)
  54
  55 ;; That's it, you can start using http://lesync.info:5984/tzz in your
  56 ;; gnus-sync-backend as a LeSync backend.  Fan fiction about the
  57 ;; vampire LeSync is welcome.
  58
  59 ;; You may not want to expose a CouchDB install to the Big Bad
  60 ;; Internet, especially if your love of all things furry would be thus
  61 ;; revealed.  Make sure it's not accessible by unauthorized users and
  62 ;; guests, at least.
  63
  64 ;; If you want to try it out, I will create a test DB for you under
  65 ;; http://lesync.info:5984/yourfavoritedbname
  66
  67 ;; TODO:
  68
  69 ;; - after gnus-sync-read, the message counts look wrong until you do
  70 ;;   `g'.  So it's not run automatically, you have to call it with M-x
  71 ;;   gnus-sync-read
  72
  73 ;; - use gnus-after-set-mark-hook and gnus-before-update-mark-hook to
  74 ;;   catch the mark updates
  75
  76 ;; - repositioning of groups within topic after a LeSync sync is a
  77 ;;   weird sort of bubble sort ("buttle" sort: the old entry ends up
  78 ;;   at the rear of the list); you will eventually end up with the
  79 ;;   right order after calling `gnus-sync-read' a bunch of times.
  80
  81 ;; - installing topics and groups is inefficient and annoying, lots of
  82 ;;   prompts could be avoided
  83
  84 ;;; Code:
  85
  86 (eval-when-compile (require 'cl))
  87 (eval-and-compile
  88   (or (ignore-errors (progn
  89                        (require 'json)))
  90       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  91       (ignore-errors
  92         (let ((load-path (cons (expand-file-name
  93                                 "gnus-fallback-lib"
  94                                 (file-name-directory (locate-library "gnus")))
  95                                load-path)))
  96           (require 'json)))
  97       (error
  98        "json not found in `load-path' or gnus-fallback-lib/ directory.")))
  99 (require 'gnus)
 100 (require 'gnus-start)
 101 (require 'gnus-util)
 102
 103 (defvar gnus-topic-alist) ;; gnus-group.el
 104 (eval-when-compile
 105   (autoload 'gnus-group-topic "gnus-topic")
 106   (autoload 'gnus-topic-create-topic "gnus-topic" nil t)
 107   (autoload 'gnus-topic-enter-dribble "gnus-topic"))
 108
 109 (defgroup gnus-sync nil
 110   "The Gnus synchronization facility."
 111   :version "24.1"
 112   :group 'gnus)
 113
 114 (defcustom gnus-sync-newsrc-groups '("nntp" "nnrss")
 115   "List of groups to be synchronized in the gnus-newsrc-alist.
 116 The group names are matched, they don't have to be fully
 117 qualified.  Typically you would choose all of these.  That's the
 118 default because there is no active sync backend by default, so
 119 this setting is harmless until the user chooses a sync backend."
 120   :group 'gnus-sync
 121   :type '(repeat regexp))
 122
 123 (defcustom gnus-sync-global-vars nil
 124   "List of global variables to be synchronized.
 125 You may want to sync `gnus-newsrc-last-checked-date' but pretty
 126 much any symbol is fair game.  You could additionally sync
 127 `gnus-newsrc-alist', `gnus-server-alist', `gnus-topic-topology',
 128 and `gnus-topic-alist'.  Also see `gnus-variable-list'."
 129   :group 'gnus-sync
 130   :type '(repeat (choice (variable :tag "A known variable")
 131                          (symbol :tag "Any symbol"))))
 132
 133 (defcustom gnus-sync-backend nil
 134   "The synchronization backend."
 135   :group 'gnus-sync
 136   :type '(radio (const :format "None" nil)
 137                 (list :tag "Sync server"
 138                       (const :format "LeSync Server API" lesync)
 139                       (string :tag "URL of a CouchDB database for API access"))
 140                 (string :tag "Sync to a file")))
 141
 142 (defvar gnus-sync-newsrc-loader nil
 143   "Carrier for newsrc data")
 144
 145 (defcustom gnus-sync-lesync-name (system-name)
 146   "The LeSync name for this machine."
 147   :group 'gnus-sync
 148   :type 'string)
 149
 150 (defcustom  gnus-sync-lesync-install-topics 'ask
 151   "Should LeSync install the recorded topics?"
 152   :group 'gnus-sync
 153   :type '(choice (const :tag "Never Install" nil)
 154                  (const :tag "Always Install" t)
 155                  (const :tag "Ask Me Once" ask)))
 156
 157 (defvar gnus-sync-lesync-props-hash (make-hash-table :test 'equal)
 158   "LeSync props, keyed by group name")
 159
 160 (defvar gnus-sync-lesync-design-prefix "/_design/lesync"
 161   "The LeSync design prefix for CouchDB")
 162
 163 (defvar gnus-sync-lesync-security-object "/_security"
 164   "The LeSync security object for CouchDB")
 165
 166 (defun gnus-sync-lesync-parse ()
 167   "Parse the result of a LeSync request."
 168   (goto-char (point-min))
 169   (condition-case nil
 170       (when (search-forward-regexp "^$" nil t)
 171         (json-read))
 172     (error
 173      (gnus-message
 174       1
 175       "gnus-sync-lesync-parse: Could not read the LeSync response!")
 176      nil)))
 177
 178 (defun gnus-sync-lesync-call (url method headers &optional kvdata)
 179   "Make an access request to URL using KVDATA and METHOD.
 180 KVDATA must be an alist."
 181   (flet ((json-alist-p (list) (gnus-sync-json-alist-p list))) ; temp patch
 182     (let ((url-request-method method)
 183           (url-request-extra-headers headers)
 184           (url-request-data (if kvdata (json-encode kvdata) nil)))
 185       (with-current-buffer (url-retrieve-synchronously url)
 186         (let ((data (gnus-sync-lesync-parse)))
 187           (gnus-message 12 "gnus-sync-lesync-call: %s URL %s sent %S got %S"
 188                         method url `((headers . ,headers) (data ,kvdata)) data)
 189           (kill-buffer (current-buffer))
 190           data)))))
 191
 192 (defun gnus-sync-lesync-PUT (url headers &optional data)
 193   (gnus-sync-lesync-call url "PUT" headers data))
 194
 195 (defun gnus-sync-lesync-POST (url headers &optional data)
 196   (gnus-sync-lesync-call url "POST" headers data))
 197
 198 (defun gnus-sync-lesync-GET (url headers &optional data)
 199   (gnus-sync-lesync-call url "GET" headers data))
 200
 201 (defun gnus-sync-lesync-DELETE (url headers &optional data)
 202   (gnus-sync-lesync-call url "DELETE" headers data))
 203
 204 ;; this is not necessary with newer versions of json.el but 1.2 or older
 205 ;; (which are in Emacs 24.1 and earlier) need it
 206 (defun gnus-sync-json-alist-p (list)
 207   "Non-null if and only if LIST is an alist."
 208   (while (consp list)
 209     (setq list (if (consp (car list))
 210                    (cdr list)
 211                  'not-alist)))
 212   (null list))
 213
 214 ;; this is not necessary with newer versions of json.el but 1.2 or older
 215 ;; (which are in Emacs 24.1 and earlier) need it
 216 (defun gnus-sync-json-plist-p (list)
 217   "Non-null if and only if LIST is a plist."
 218   (while (consp list)
 219     (setq list (if (and (keywordp (car list))
 220                         (consp (cdr list)))
 221                    (cddr list)
 222                  'not-plist)))
 223   (null list))
 224
 225 ; (gnus-sync-lesync-setup "http://lesync.info:5984/tzz" "tzzadmin" "mypassword" "mysalt" t t)
 226 ; (gnus-sync-lesync-setup "http://lesync.info:5984/tzz")
 227
 228 (defun gnus-sync-lesync-setup (url &optional user password salt reader admin)
 229   (interactive "sEnter URL to set up: ")
 230   "Set up the LeSync database at URL.
 231 Install USER as a READER and/or an ADMIN in the security object
 232 under \"_security\", and in the CouchDB \"_users\" table using
 233 PASSWORD and SALT.  Only one USER is thus supported for now.
 234 When SALT is nil, a random one will be generated using `random'."
 235   (let* ((design-url (concat url gnus-sync-lesync-design-prefix))
 236          (security-object (concat url "/_security"))
 237          (user-record `((names . [,user]) (roles . [])))
 238          (couch-user-name (format "org.couchdb.user:%s" user))
 239          (salt (or salt (sha1 (format "%s" (random t)))))
 240          (couch-user-record
 241           `((_id . ,couch-user-name)
 242             (type . user)
 243             (name . ,(format "%s" user))
 244             (roles . [])
 245             (salt . ,salt)
 246             (password_sha . ,(when password
 247                                (sha1
 248                                 (format "%s%s" password salt))))))
 249          (rev (progn
 250                 (gnus-sync-lesync-find-prop 'rev design-url design-url)
 251                 (gnus-sync-lesync-get-prop 'rev design-url)))
 252          (latest-func "function(head,req)
 253 {
 254   var tosend = [];
 255   var row;
 256   var ftime = (req.query['ftime'] || 0);
 257   while (row = getRow())
 258   {
 259     if (row.value['float-time'] > ftime)
 260     {
 261       var s = row.value['_id'];
 262       if (s) tosend.push('\"'+s.replace('\"', '\\\"')+'\"');
 263     }
 264   }
 265   send('['+tosend.join(',') + ']');
 266 }")
 267 ;; <key>read</key>
 268 ;; <dict>
 269 ;;   <key>de.alt.fan.ipod</key>
 270 ;;   <array>
 271 ;;       <integer>1</integer>
 272 ;;       <integer>2</integer>
 273 ;;       <dict>
 274 ;;           <key>start</key>
 275 ;;           <integer>100</integer>
 276 ;;           <key>length</key>
 277 ;;           <integer>100</integer>
 278 ;;       </dict>
 279 ;;   </array>
 280 ;; </dict>
 281          (xmlplistread-func "function(head, req) {
 282   var row;
 283   start({ 'headers': { 'Content-Type': 'text/xml' } });
 284
 285   send('<dict>');
 286   send('<key>read</key>');
 287   send('<dict>');
 288   while(row = getRow())
 289   {
 290     var read = row.value.read;
 291     if (read && read[0] && read[0] == 'invlist')
 292     {
 293       send('<key>'+row.key+'</key>');
 294       //send('<invlist>'+read+'</invlist>');
 295       send('<array>');
 296
 297       var from = 0;
 298       var flip = false;
 299
 300       for (var i = 1; i < read.length && read[i]; i++)
 301       {
 302         var cur = read[i];
 303         if (flip)
 304         {
 305           if (from == cur-1)
 306           {
 307             send('<integer>'+read[i]+'</integer>');
 308           }
 309           else
 310           {
 311             send('<dict>');
 312             send('<key>start</key>');
 313             send('<integer>'+from+'</integer>');
 314             send('<key>end</key>');
 315             send('<integer>'+(cur-1)+'</integer>');
 316             send('</dict>');
 317           }
 318
 319         }
 320         flip = ! flip;
 321         from = cur;
 322       }
 323       send('</array>');
 324     }
 325   }
 326
 327   send('</dict>');
 328   send('</dict>');
 329 }
 330 ")
 331          (subs-func "function(doc){emit([doc._id, doc.source], doc._rev);}")
 332          (revs-func "function(doc){emit(doc._id, doc._rev);}")
 333          (bytimesubs-func "function(doc)
 334 {emit([(doc['float-time']||0), doc._id], doc._rev);}")
 335          (bytime-func "function(doc)
 336 {emit([(doc['float-time']||0), doc._id], doc);}")
 337          (groups-func "function(doc){emit(doc._id, doc);}"))
 338     (and (if user
 339              (and (assq 'ok (gnus-sync-lesync-PUT
 340                              security-object
 341                              nil
 342                              (append (and reader
 343                                           (list `(readers . ,user-record)))
 344                                      (and admin
 345                                           (list `(admins . ,user-record))))))
 346                   (assq 'ok (gnus-sync-lesync-PUT
 347                              (concat (file-name-directory url)
 348                                      "_users/"
 349                                      couch-user-name)
 350                              nil
 351                              couch-user-record)))
 352            t)
 353          (assq 'ok (gnus-sync-lesync-PUT
 354                     design-url
 355                     nil
 356                     `(,@(when rev (list (cons '_rev rev)))
 357                       (lists . ((latest . ,latest-func)
 358                                 (xmlplistread . ,xmlplistread-func)))
 359                       (views . ((subs . ((map . ,subs-func)))
 360                                 (revs . ((map . ,revs-func)))
 361                                 (bytimesubs . ((map . ,bytimesubs-func)))
 362                                 (bytime . ((map . ,bytime-func)))
 363                                 (groups . ((map . ,groups-func)))))))))))
 364
 365 (defun gnus-sync-lesync-find-prop (prop url key)
 366   "Retrieve a PROPerty of a document KEY at URL.
 367 Calls `gnus-sync-lesync-set-prop'.
 368 For the 'rev PROP, uses '_rev against the document."
 369   (gnus-sync-lesync-set-prop
 370    prop key (cdr (assq (if (eq prop 'rev) '_rev prop)
 371                        (gnus-sync-lesync-GET url nil)))))
 372
 373 (defun gnus-sync-lesync-set-prop (prop key val)
 374   "Update the PROPerty of document KEY at URL to VAL.
 375 Updates `gnus-sync-lesync-props-hash'."
 376     (puthash (format "%s.%s" key prop) val gnus-sync-lesync-props-hash))
 377
 378 (defun gnus-sync-lesync-get-prop (prop key)
 379   "Get the PROPerty of KEY from `gnus-sync-lesync-props-hash'."
 380     (gethash (format "%s.%s" key prop) gnus-sync-lesync-props-hash))
 381
 382 (defun gnus-sync-deep-print (data)
 383   (let* ((print-quoted t)
 384          (print-readably t)
 385          (print-escape-multibyte nil)
 386          (print-escape-nonascii t)
 387          (print-length nil)
 388          (print-level nil)
 389          (print-circle nil)
 390          (print-escape-newlines t))
 391     (format "%S" data)))
 392
 393 (defun gnus-sync-newsrc-loader-builder (&optional only-modified)
 394   (let* ((entries (cdr gnus-newsrc-alist))
 395          entry name ret)
 396     (while entries
 397       (setq entry (pop entries)
 398             name (car entry))
 399       (when (gnus-grep-in-list name gnus-sync-newsrc-groups)
 400         (if only-modified
 401             (when (not (equal (gnus-sync-deep-print entry)
 402                               (gnus-sync-lesync-get-prop 'checksum name)))
 403               (gnus-message 9 "%s: add %s, it's modified"
 404                             "gnus-sync-newsrc-loader-builder" name)
 405               (push entry ret))
 406           (push entry ret))))
 407     ret))
 408
 409 ; (json-encode (gnus-sync-range2invlist '((1 . 47137) (47139 . 47714) 48129 48211 49231 49281 49342 49473 49475 49502)))
 410 (defun gnus-sync-range2invlist (ranges)
 411   (append '(invlist)
 412           (let ((ranges (delq nil ranges))
 413                 ret range from to)
 414             (while ranges
 415               (setq range (pop ranges))
 416               (if (atom range)
 417                   (setq from range
 418                         to range)
 419                 (setq from (car range)
 420                       to (cdr range)))
 421               (push from ret)
 422               (push (1+ to) ret))
 423             (reverse ret))))
 424
 425 ; (let* ((d '((1 . 47137) (47139 . 47714) 48129 48211 49231 49281 49342 49473 49475 49502)) (j (format "%S" (gnus-sync-invlist2range (gnus-sync-range2invlist d))))) (or (equal (format "%S" d) j) j))
 426 (defun gnus-sync-invlist2range (inv)
 427   (setq inv (append inv nil))
 428   (if (equal (format "%s" (car inv)) "invlist")
 429       (let ((i (cdr inv))
 430             (start 0)
 431             ret cur top flip)
 432         (while i
 433           (setq cur (pop i))
 434           (when flip
 435             (setq top (1- cur))
 436             (if (= start top)
 437                 (push start ret)
 438               (push (cons start top) ret)))
 439           (setq flip (not flip))
 440           (setq start cur))
 441         (reverse ret))
 442     inv))
 443
 444 (defun gnus-sync-position (search list &optional test)
 445   "Find the position of SEARCH in LIST using TEST, defaulting to `eq'."
 446   (let ((pos 0)
 447         (test (or test 'eq)))
 448     (while (and list (not (funcall test (car list) search)))
 449       (pop list)
 450       (incf pos))
 451     (if (funcall test (car list) search) pos nil)))
 452
 453 (defun gnus-sync-topic-group-position (group topic-name)
 454   (gnus-sync-position
 455    group (cdr (assoc topic-name gnus-topic-alist)) 'equal))
 456
 457 (defun gnus-sync-fix-topic-group-position (group topic-name position)
 458   (unless (equal position (gnus-sync-topic-group-position group topic-name))
 459     (let* ((loc "gnus-sync-fix-topic-group-position")
 460            (groups (delete group (cdr (assoc topic-name gnus-topic-alist))))
 461            (position (min position (1- (length groups))))
 462            (old (nth position groups)))
 463       (when (and old (not (equal old group)))
 464         (setf (nth position groups) group)
 465         (setcdr (assoc topic-name gnus-topic-alist)
 466                 (append groups (list old)))
 467         (gnus-message 9 "%s: %s moved to %d, swap with %s"
 468                       loc group position old)))))
 469
 470 (defun gnus-sync-lesync-pre-save-group-entry (url nentry &rest passed-props)
 471   (let* ((loc "gnus-sync-lesync-save-group-entry")
 472          (k (car nentry))
 473          (revision (gnus-sync-lesync-get-prop 'rev k))
 474          (sname gnus-sync-lesync-name)
 475          (topic (gnus-group-topic k))
 476          (topic-offset (gnus-sync-topic-group-position k topic))
 477          (sources (gnus-sync-lesync-get-prop 'source k)))
 478     ;; set the revision so we don't have a conflict
 479     `(,@(when revision
 480           (list (cons '_rev revision)))
 481       (_id . ,k)
 482       ;; the time we saved
 483       ,@passed-props
 484       ;; add our name to the sources list for this key
 485       (source ,@(if (member gnus-sync-lesync-name sources)
 486                     sources
 487                   (cons gnus-sync-lesync-name sources)))
 488       ,(cons 'level (nth 1 nentry))
 489       ,@(if topic (list (cons 'topic topic)) nil)
 490       ,@(if topic-offset (list (cons 'topic-offset topic-offset)) nil)
 491       ;; the read marks
 492       ,(cons 'read (gnus-sync-range2invlist (nth 2 nentry)))
 493       ;; the other marks
 494       ,@(delq nil (mapcar (lambda (mark-entry)
 495                             (gnus-message 12 "%s: prep param %s in %s"
 496                                           loc
 497                                           (car mark-entry)
 498                                           (nth 3 nentry))
 499                             (if (listp (cdr mark-entry))
 500                                 (cons (car mark-entry)
 501                                       (gnus-sync-range2invlist
 502                                        (cdr mark-entry)))
 503                               (progn    ; else this is not a list
 504                                 (gnus-message 9 "%s: non-list param %s in %s"
 505                                               loc
 506                                               (car mark-entry)
 507                                               (nth 3 nentry))
 508                                 nil)))
 509                           (nth 3 nentry))))))
 510
 511 (defun gnus-sync-lesync-post-save-group-entry (url entry)
 512   (let* ((loc "gnus-sync-lesync-post-save-group-entry")
 513          (k (cdr (assq 'id entry))))
 514     (cond
 515      ;; success!
 516      ((and (assq 'rev entry) (assq 'id entry))
 517       (progn
 518         (gnus-sync-lesync-set-prop 'rev k (cdr (assq 'rev entry)))
 519         (gnus-sync-lesync-set-prop 'checksum
 520                                    k
 521                                    (gnus-sync-deep-print
 522                                     (assoc k gnus-newsrc-alist)))
 523         (gnus-message 9 "%s: successfully synced %s to %s"
 524                       loc k url)))
 525      ;; specifically check for document conflicts
 526      ((equal "conflict" (format "%s" (cdr-safe (assq 'error entry))))
 527       (gnus-error
 528        1
 529        "%s: use `%s' to resolve the conflict synchronizing %s to %s: %s"
 530        loc "gnus-sync-read" k url (cdr (assq 'reason entry))))
 531      ;; generic errors
 532      ((assq 'error entry)
 533       (gnus-error 1 "%s: got error while synchronizing %s to %s: %s"
 534                   loc k url (cdr (assq 'reason entry))))
 535
 536      (t
 537       (gnus-message 2 "%s: unknown sync status after %s to %s: %S"
 538                     loc k url entry)))
 539     (assoc 'error entry)))
 540
 541 (defun gnus-sync-lesync-groups-builder (url)
 542   (let ((u (concat url gnus-sync-lesync-design-prefix "/_view/groups")))
 543     (cdr (assq 'rows (gnus-sync-lesync-GET u nil)))))
 544
 545 (defun gnus-sync-subscribe-group (name)
 546   "Subscribe to group NAME.  Returns NAME on success, nil otherwise."
 547   (gnus-subscribe-newsgroup name))
 548
 549 (defun gnus-sync-lesync-read-group-entry (url name entry &rest passed-props)
 550   "Read ENTRY information for NAME.  Returns NAME if successful.
 551 Skips entries whose sources don't contain
 552 `gnus-sync-lesync-name'.  When the alist PASSED-PROPS has a
 553 `subscribe-all' element that evaluates to true, we attempt to
 554 subscribe to unknown groups.  The user is also allowed to delete
 555 unwanted groups via the LeSync URL."
 556   (let* ((loc "gnus-sync-lesync-read-group-entry")
 557          (entry (gnus-sync-lesync-normalize-group-entry entry passed-props))
 558          (subscribe-all (cdr (assq 'subscribe-all passed-props)))
 559          (sources (cdr (assq 'source entry)))
 560          (rev (cdr (assq 'rev entry)))
 561          (in-sources (member gnus-sync-lesync-name sources))
 562          (known (assoc name gnus-newsrc-alist))
 563          cell)
 564     (unless known
 565       (if (and subscribe-all
 566                (y-or-n-p (format "Subscribe to group %s?" name)))
 567           (setq known (gnus-sync-subscribe-group name)
 568                 in-sources t)
 569         ;; else...
 570         (when (y-or-n-p (format "Delete group %s from server?" name))
 571           (if (equal name (gnus-sync-lesync-delete-group url name))
 572               (gnus-message 1 "%s: removed group %s from server %s"
 573                             loc name url)
 574             (gnus-error 1 "%s: could not remove group %s from server %s"
 575                         loc name url)))))
 576     (when known
 577       (unless in-sources
 578         (setq in-sources
 579               (y-or-n-p
 580                (format "Read group %s even though %s is not in sources %S?"
 581                        name gnus-sync-lesync-name (or sources ""))))))
 582     (when rev
 583       (gnus-sync-lesync-set-prop 'rev name rev))
 584
 585     ;; if the source matches AND we have this group
 586     (if (and known in-sources)
 587         (progn
 588           (gnus-message 10 "%s: reading LeSync entry %s, sources %S"
 589                         loc name sources)
 590           (while entry
 591             (setq cell (pop entry))
 592             (let ((k (car cell))
 593                   (val (cdr cell)))
 594               (gnus-sync-lesync-set-prop k name val)))
 595           name)
 596       ;; else...
 597       (unless known
 598         (gnus-message 5 "%s: ignoring entry %s, it wasn't subscribed.  %s"
 599                         loc name "Call `gnus-sync-read' with C-u to force it."))
 600       (unless in-sources
 601         (gnus-message 5 "%s: ignoring entry %s, %s not in sources %S"
 602                       loc name gnus-sync-lesync-name (or sources "")))
 603       nil)))
 604
 605 (defun gnus-sync-lesync-install-group-entry (name)
 606   (let* ((master (assoc name gnus-newsrc-alist))
 607          (old-topic-name (gnus-group-topic name))
 608          (old-topic (assoc old-topic-name gnus-topic-alist))
 609          (target-topic-name (gnus-sync-lesync-get-prop 'topic name))
 610          (target-topic-offset (gnus-sync-lesync-get-prop 'topic-offset name))
 611          (target-topic (assoc target-topic-name gnus-topic-alist))
 612          (loc "gnus-sync-lesync-install-group-entry"))
 613     (if master
 614         (progn
 615           (when (eq 'ask gnus-sync-lesync-install-topics)
 616             (setq gnus-sync-lesync-install-topics
 617                   (y-or-n-p "Install topics from LeSync?")))
 618           (when (and (eq t gnus-sync-lesync-install-topics)
 619                      target-topic-name)
 620             (if (equal old-topic-name target-topic-name)
 621                 (gnus-message 12 "%s: %s is already in topic %s"
 622                               loc name target-topic-name)
 623               ;; see `gnus-topic-move-group'
 624               (when (and old-topic target-topic)
 625                 (setcdr old-topic (gnus-delete-first name (cdr old-topic)))
 626                 (gnus-message 5 "%s: removing %s from topic %s"
 627                               loc name old-topic-name))
 628               (unless target-topic
 629                 (when (y-or-n-p (format "Create missing topic %s?"
 630                                         target-topic-name))
 631                   (gnus-topic-create-topic target-topic-name nil)
 632                   (setq target-topic (assoc target-topic-name
 633                                             gnus-topic-alist))))
 634               (if target-topic
 635                   (prog1
 636                       (nconc target-topic (list name))
 637                     (gnus-message 5 "%s: adding %s to topic %s"
 638                                   loc name (car target-topic))
 639                     (gnus-topic-enter-dribble))
 640                 (gnus-error 2 "%s: LeSync group %s can't go in missing topic %s"
 641                             loc name target-topic-name)))
 642             (when (and target-topic-offset target-topic)
 643               (gnus-sync-fix-topic-group-position
 644                name target-topic-name target-topic-offset)))
 645           ;; install the subscription level
 646           (when (gnus-sync-lesync-get-prop 'level name)
 647             (setf (nth 1 master) (gnus-sync-lesync-get-prop 'level name)))
 648           ;; install the read and other marks
 649           (setf (nth 2 master) (gnus-sync-lesync-get-prop 'read name))
 650           (setf (nth 3 master) (gnus-sync-lesync-get-prop 'marks name))
 651           (gnus-sync-lesync-set-prop 'checksum
 652                                      name
 653                                      (gnus-sync-deep-print master))
 654           nil)
 655       (gnus-error 1 "%s: invalid LeSync group %s" loc name)
 656       'invalid-name)))
 657
 658 ; (gnus-sync-lesync-delete-group (cdr gnus-sync-backend) "nntp+Gmane:gwene.org.slashdot")
 659
 660 (defun gnus-sync-lesync-delete-group (url name)
 661   "Returns NAME if successful deleting it from URL, an error otherwise."
 662   (interactive "sEnter URL to set up: \rsEnter group name: ")
 663   (let* ((u (concat (cadr gnus-sync-backend) "/" (url-hexify-string name)))
 664          (del (gnus-sync-lesync-DELETE
 665                u
 666                `(,@(when (gnus-sync-lesync-get-prop 'rev name)
 667                      (list (cons "If-Match"
 668                                  (gnus-sync-lesync-get-prop 'rev name))))))))
 669     (or (cdr (assq 'id del)) del)))
 670
 671 ;;; (gnus-sync-lesync-normalize-group-entry '((subscribe . ["invlist"]) (read . ["invlist"]) (topic-offset . 20) (topic . "news") (level . 6) (source . ["a" "b"]) (float-time . 1319671237.099285) (_rev . "10-edf5107f41e5e6f7f6629d1c0ee172f7") (_id . "nntp+news.net:alt.movies")) '((read-time 1319672156.486414) (subscribe-all nil)))
 672
 673 (defun gnus-sync-lesync-normalize-group-entry (entry &optional passed-props)
 674   (let (ret
 675         marks
 676         cell)
 677     (setq entry (append passed-props entry))
 678     (while (setq cell (pop entry))
 679       (let ((k (car cell))
 680             (val (cdr cell)))
 681         (cond
 682          ((eq k 'read)
 683           (push (cons k (gnus-sync-invlist2range val)) ret))
 684          ;; we ignore these parameters
 685          ((member k '(_id subscribe-all _deleted_conflicts))
 686           nil)
 687          ((eq k '_rev)
 688           (push (cons 'rev val) ret))
 689          ((eq k 'source)
 690           (push (cons 'source (append val nil)) ret))
 691          ((or (eq k 'float-time)
 692               (eq k 'level)
 693               (eq k 'topic)
 694               (eq k 'topic-offset)
 695               (eq k 'read-time))
 696           (push (cons k val) ret))
 697 ;;; "How often have I said to you that when you have eliminated the
 698 ;;; impossible, whatever remains, however improbable, must be the
 699 ;;; truth?" --Sherlock Holmes
 700           ;; everything remaining must be a mark
 701           (t (push (cons k (gnus-sync-invlist2range val)) marks)))))
 702     (cons (cons 'marks marks) ret)))
 703
 704 (defun gnus-sync-save (&optional force)
 705 "Save the Gnus sync data to the backend.
 706 With a prefix, FORCE is set and all groups will be saved."
 707   (interactive "P")
 708   (cond
 709    ((and (listp gnus-sync-backend)
 710          (eq (nth 0 gnus-sync-backend) 'lesync)
 711          (stringp (nth 1 gnus-sync-backend)))
 712
 713     ;; refresh the revisions if we're forcing the save
 714     (when force
 715       (mapc (lambda (entry)
 716               (when (and (assq 'key entry)
 717                          (assq 'value entry))
 718                 (gnus-sync-lesync-set-prop
 719                  'rev
 720                  (cdr (assq 'key entry))
 721                  (cdr (assq 'value entry)))))
 722             ;; the revs view is key = name, value = rev
 723             (cdr (assq 'rows (gnus-sync-lesync-GET
 724                               (concat (nth 1 gnus-sync-backend)
 725                                       gnus-sync-lesync-design-prefix
 726                                       "/_view/revs")
 727                               nil)))))
 728
 729     (let* ((ftime (float-time))
 730            (url (nth 1 gnus-sync-backend))
 731            (entries
 732             (mapcar (lambda (entry)
 733                       (gnus-sync-lesync-pre-save-group-entry
 734                        (cadr gnus-sync-backend)
 735                        entry
 736                        (cons 'float-time ftime)))
 737                     (gnus-sync-newsrc-loader-builder (not force))))
 738            ;; when there are no entries, there's nothing to save
 739            (sync (if entries
 740                      (gnus-sync-lesync-POST
 741                       (concat url "/_bulk_docs")
 742                       '(("Content-Type" . "application/json"))
 743                       `((docs . ,(vconcat entries nil))))
 744                    (gnus-message
 745                     2 "gnus-sync-save: nothing to save to the LeSync backend")
 746                    nil)))
 747       (mapcar (lambda (e) (gnus-sync-lesync-post-save-group-entry url e))
 748               sync)))
 749    ((stringp gnus-sync-backend)
 750     (gnus-message 7 "gnus-sync-save: saving to backend %s" gnus-sync-backend)
 751     ;; populate gnus-sync-newsrc-loader from all but the first dummy
 752     ;; entry in gnus-newsrc-alist whose group matches any of the
 753     ;; gnus-sync-newsrc-groups
 754     ;; TODO: keep the old contents for groups we don't have!
 755     (let ((gnus-sync-newsrc-loader (gnus-sync-newsrc-loader-builder)))
 756       (with-temp-file gnus-sync-backend
 757         (progn
 758           (let ((coding-system-for-write gnus-ding-file-coding-system)
 759                 (standard-output (current-buffer)))
 760             (princ (format ";; -*- mode:emacs-lisp; coding: %s; -*-\n"
 761                            gnus-ding-file-coding-system))
 762             (princ ";; Gnus sync data v. 0.0.1\n")
 763             ;; TODO: replace with `gnus-sync-deep-print'
 764             (let* ((print-quoted t)
 765                    (print-readably t)
 766                    (print-escape-multibyte nil)
 767                    (print-escape-nonascii t)
 768                    (print-length nil)
 769                    (print-level nil)
 770                    (print-circle nil)
 771                    (print-escape-newlines t)
 772                    (variables (cons 'gnus-sync-newsrc-loader
 773                                     gnus-sync-global-vars))
 774                    variable)
 775               (while variables
 776                 (if (and (boundp (setq variable (pop variables)))
 777                            (symbol-value variable))
 778                     (progn
 779                       (princ "\n(setq ")
 780                       (princ (symbol-name variable))
 781                       (princ " '")
 782                       (prin1 (symbol-value variable))
 783                       (princ ")\n"))
 784                   (princ "\n;;; skipping empty variable ")
 785                   (princ (symbol-name variable)))))
 786             (gnus-message
 787              7
 788              "gnus-sync-save: stored variables %s and %d groups in %s"
 789              gnus-sync-global-vars
 790              (length gnus-sync-newsrc-loader)
 791              gnus-sync-backend)
 792
 793             ;; Idea from Dan Christensen <jdc@chow.mat.jhu.edu>
 794             ;; Save the .eld file with extra line breaks.
 795             (gnus-message 8 "gnus-sync-save: adding whitespace to %s"
 796                           gnus-sync-backend)
 797             (save-excursion
 798               (goto-char (point-min))
 799               (while (re-search-forward "^(\\|(\\\"" nil t)
 800                 (replace-match "\n\\&" t))
 801               (goto-char (point-min))
 802               (while (re-search-forward " $" nil t)
 803                 (replace-match "" t t))))))))
 804     ;; the pass-through case: gnus-sync-backend is not a known choice
 805     (nil)))
 806
 807 (defun gnus-sync-read (&optional subscribe-all)
 808   "Load the Gnus sync data from the backend.
 809 With a prefix, SUBSCRIBE-ALL is set and unknown groups will be subscribed."
 810   (interactive "P")
 811   (when gnus-sync-backend
 812     (gnus-message 7 "gnus-sync-read: loading from backend %s" gnus-sync-backend)
 813     (cond
 814      ((and (listp gnus-sync-backend)
 815            (eq (nth 0 gnus-sync-backend) 'lesync)
 816            (stringp (nth 1 gnus-sync-backend)))
 817       (let ((errored nil)
 818             name ftime)
 819         (mapc (lambda (entry)
 820                 (setq name (cdr (assq 'id entry)))
 821                 ;; set ftime the FIRST time through this loop, that
 822                 ;; way it reflects the time we FINISHED reading
 823                 (unless ftime (setq ftime (float-time)))
 824
 825                 (unless errored
 826                   (setq errored
 827                         (when (equal name
 828                                      (gnus-sync-lesync-read-group-entry
 829                                       (nth 1 gnus-sync-backend)
 830                                       name
 831                                       (cdr (assq 'value entry))
 832                                       `(read-time ,ftime)
 833                                       `(subscribe-all ,subscribe-all)))
 834                           (gnus-sync-lesync-install-group-entry
 835                            (cdr (assq 'id entry)))))))
 836               (gnus-sync-lesync-groups-builder (nth 1 gnus-sync-backend)))))
 837
 838      ((stringp gnus-sync-backend)
 839       ;; read data here...
 840       (if (or debug-on-error debug-on-quit)
 841           (load gnus-sync-backend nil t)
 842         (condition-case var
 843             (load gnus-sync-backend nil t)
 844           (error
 845            (error "Error in %s: %s" gnus-sync-backend (cadr var)))))
 846       (let ((valid-count 0)
 847             invalid-groups)
 848         (dolist (node gnus-sync-newsrc-loader)
 849           (if (gnus-gethash (car node) gnus-newsrc-hashtb)
 850               (progn
 851                 (incf valid-count)
 852                 (loop for store in (cdr node)
 853                       do (setf (nth (car store)
 854                                     (assoc (car node) gnus-newsrc-alist))
 855                                (cdr store))))
 856             (push (car node) invalid-groups)))
 857         (gnus-message
 858          7
 859          "gnus-sync-read: loaded %d groups (out of %d) from %s"
 860          valid-count (length gnus-sync-newsrc-loader)
 861          gnus-sync-backend)
 862         (when invalid-groups
 863           (gnus-message
 864            7
 865            "gnus-sync-read: skipped %d groups (out of %d) from %s"
 866            (length invalid-groups)
 867            (length gnus-sync-newsrc-loader)
 868            gnus-sync-backend)
 869           (gnus-message 9 "gnus-sync-read: skipped groups: %s"
 870                         (mapconcat 'identity invalid-groups ", ")))))
 871      (nil))
 872
 873     (gnus-message 9 "gnus-sync-read: remaking the newsrc hashtable")
 874     (gnus-make-hashtable-from-newsrc-alist)))
 875
 876 ;;;###autoload
 877 (defun gnus-sync-initialize ()
 878 "Initialize the Gnus sync facility."
 879   (interactive)
 880   (gnus-message 5 "Initializing the sync facility")
 881   (gnus-sync-install-hooks))
 882
 883 ;;;###autoload
 884 (defun gnus-sync-install-hooks ()
 885   "Install the sync hooks."
 886   (interactive)
 887   ;; (add-hook 'gnus-get-new-news-hook 'gnus-sync-read)
 888   ;; (add-hook 'gnus-read-newsrc-el-hook 'gnus-sync-read)
 889   (add-hook 'gnus-save-newsrc-hook 'gnus-sync-save))
 890
 891 (defun gnus-sync-unload-hook ()
 892   "Uninstall the sync hooks."
 893   (interactive)
 894   (remove-hook 'gnus-save-newsrc-hook 'gnus-sync-save))
 895
 896 (add-hook 'gnus-sync-unload-hook 'gnus-sync-unload-hook)
 897
 898 (when gnus-sync-backend (gnus-sync-initialize))
 899
 900 (provide 'gnus-sync)
 901
 902 ;;; gnus-sync.el ends here