cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h backend
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered"
  59   :group 'gnus-server-visual
  60   :type 'string)
  61
  62 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  63   "The format specification for the server mode line."
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-browse-in-group-buffer nil
  68   "Whether browse server in group buffer."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 ;;; Internal variables.
  73
  74 (defvar gnus-inserted-opened-servers nil)
  75
  76 (defvar gnus-server-line-format-alist
  77   `((?h gnus-tmp-how ?s)
  78     (?n gnus-tmp-name ?s)
  79     (?w gnus-tmp-where ?s)
  80     (?s gnus-tmp-status ?s)
  81     (?a gnus-tmp-agent ?s)))
  82
  83 (defvar gnus-server-mode-line-format-alist
  84   `((?S gnus-tmp-news-server ?s)
  85     (?M gnus-tmp-news-method ?s)
  86     (?u gnus-tmp-user-defined ?s)))
  87
  88 (defvar gnus-server-line-format-spec nil)
  89 (defvar gnus-server-mode-line-format-spec nil)
  90 (defvar gnus-server-killed-servers nil)
  91
  92 (defvar gnus-server-mode-map)
  93
  94 (defvar gnus-server-menu-hook nil
  95   "*Hook run after the creation of the server mode menu.")
  96
  97 (defun gnus-server-make-menu-bar ()
  98   (gnus-turn-off-edit-menu 'server)
  99   (unless (boundp 'gnus-server-server-menu)
 100     (easy-menu-define
 101      gnus-server-server-menu gnus-server-mode-map ""
 102      '("Server"
 103        ["Add" gnus-server-add-server t]
 104        ["Browse" gnus-server-read-server t]
 105        ["Scan" gnus-server-scan-server t]
 106        ["List" gnus-server-list-servers t]
 107        ["Kill" gnus-server-kill-server t]
 108        ["Yank" gnus-server-yank-server t]
 109        ["Copy" gnus-server-copy-server t]
 110        ["Edit" gnus-server-edit-server t]
 111        ["Regenerate" gnus-server-regenerate-server t]
 112        ["Exit" gnus-server-exit t]))
 113
 114     (easy-menu-define
 115      gnus-server-connections-menu gnus-server-mode-map ""
 116      '("Connections"
 117        ["Open" gnus-server-open-server t]
 118        ["Close" gnus-server-close-server t]
 119        ["Deny" gnus-server-deny-server t]
 120        "---"
 121        ["Open All" gnus-server-open-all-servers t]
 122        ["Close All" gnus-server-close-all-servers t]
 123        ["Reset All" gnus-server-remove-denials t]))
 124
 125     (gnus-run-hooks 'gnus-server-menu-hook)))
 126
 127 (defvar gnus-server-mode-map nil)
 128 (put 'gnus-server-mode 'mode-class 'special)
 129
 130 (unless gnus-server-mode-map
 131   (setq gnus-server-mode-map (make-sparse-keymap))
 132   (suppress-keymap gnus-server-mode-map)
 133
 134   (gnus-define-keys gnus-server-mode-map
 135     " " gnus-server-read-server-in-server-buffer
 136     "\r" gnus-server-read-server
 137     gnus-mouse-2 gnus-server-pick-server
 138     "q" gnus-server-exit
 139     "l" gnus-server-list-servers
 140     "k" gnus-server-kill-server
 141     "y" gnus-server-yank-server
 142     "c" gnus-server-copy-server
 143     "a" gnus-server-add-server
 144     "e" gnus-server-edit-server
 145     "s" gnus-server-scan-server
 146
 147     "O" gnus-server-open-server
 148     "\M-o" gnus-server-open-all-servers
 149     "C" gnus-server-close-server
 150     "\M-c" gnus-server-close-all-servers
 151     "D" gnus-server-deny-server
 152     "R" gnus-server-remove-denials
 153
 154     "n" next-line
 155     "p" previous-line
 156
 157     "g" gnus-server-regenerate-server
 158
 159     "\C-c\C-i" gnus-info-find-node
 160     "\C-c\C-b" gnus-bug))
 161
 162 (defface gnus-server-agent-face
 163   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 164     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 165     (t (:bold t)))
 166   "Face used for displaying AGENTIZED servers"
 167   :group 'gnus-server-visual)
 168
 169 (defface gnus-server-opened-face
 170   '((((class color) (background light)) (:foreground "Green3" :bold t))
 171     (((class color) (background dark)) (:foreground "Green1" :bold t))
 172     (t (:bold t)))
 173   "Face used for displaying OPENED servers"
 174   :group 'gnus-server-visual)
 175
 176 (defface gnus-server-closed-face
 177   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 178     (((class color) (background dark))
 179      (:foreground "Light Steel Blue" :italic t))
 180     (t (:italic t)))
 181   "Face used for displaying CLOSED servers"
 182   :group 'gnus-server-visual)
 183
 184 (defface gnus-server-denied-face
 185   '((((class color) (background light)) (:foreground "Red" :bold t))
 186     (((class color) (background dark)) (:foreground "Pink" :bold t))
 187     (t (:inverse-video t :bold t)))
 188   "Face used for displaying DENIED servers"
 189   :group 'gnus-server-visual)
 190
 191 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 192   "Face name to use on AGENTIZED servers."
 193   :group 'gnus-server-visual
 194   :type 'face)
 195
 196 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 197   "Face name to use on OPENED servers."
 198   :group 'gnus-server-visual
 199   :type 'face)
 200
 201 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 202   "Face name to use on CLOSED servers."
 203   :group 'gnus-server-visual
 204   :type 'face)
 205
 206 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 207   "Face name to use on DENIED servers."
 208   :group 'gnus-server-visual
 209   :type 'face)
 210
 211 (defvar gnus-server-font-lock-keywords
 212   (list
 213    '("(\\(agent\\))" 1 gnus-server-agent-face)
 214    '("(\\(opened\\))" 1 gnus-server-opened-face)
 215    '("(\\(closed\\))" 1 gnus-server-closed-face)
 216    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 217
 218 (defun gnus-server-mode ()
 219   "Major mode for listing and editing servers.
 220
 221 All normal editing commands are switched off.
 222 \\<gnus-server-mode-map>
 223 For more in-depth information on this mode, read the manual
 224 \(`\\[gnus-info-find-node]').
 225
 226 The following commands are available:
 227
 228 \\{gnus-server-mode-map}"
 229   (interactive)
 230   (when (gnus-visual-p 'server-menu 'menu)
 231     (gnus-server-make-menu-bar))
 232   (kill-all-local-variables)
 233   (gnus-simplify-mode-line)
 234   (setq major-mode 'gnus-server-mode)
 235   (setq mode-name "Server")
 236   (gnus-set-default-directory)
 237   (setq mode-line-process nil)
 238   (use-local-map gnus-server-mode-map)
 239   (buffer-disable-undo)
 240   (setq truncate-lines t)
 241   (setq buffer-read-only t)
 242   (if (featurep 'xemacs)
 243       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 244     (set (make-local-variable 'font-lock-defaults)
 245          '(gnus-server-font-lock-keywords t)))
 246   (gnus-run-hooks 'gnus-server-mode-hook))
 247
 248 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 249   (let* ((gnus-tmp-how (car method))
 250          (gnus-tmp-where (nth 1 method))
 251          (elem (assoc method gnus-opened-servers))
 252          (gnus-tmp-status
 253           (if (eq (nth 1 elem) 'denied)
 254               "(denied)"
 255             (condition-case nil
 256                 (if (or (gnus-server-opened method)
 257                         (eq (nth 1 elem) 'ok))
 258                     "(opened)"
 259                   "(closed)")
 260               ((error) "(error)"))))
 261          (gnus-tmp-agent (if (and gnus-agent
 262                                   (member method
 263                                           gnus-agent-covered-methods))
 264                              " (agent)"
 265                            "")))
 266     (beginning-of-line)
 267     (gnus-add-text-properties
 268      (point)
 269      (prog1 (1+ (point))
 270        ;; Insert the text.
 271        (eval gnus-server-line-format-spec))
 272      (list 'gnus-server (intern gnus-tmp-name)))))
 273
 274 (defun gnus-enter-server-buffer ()
 275   "Set up the server buffer."
 276   (gnus-server-setup-buffer)
 277   (gnus-configure-windows 'server)
 278   (gnus-server-prepare))
 279
 280 (defun gnus-server-setup-buffer ()
 281   "Initialize the server buffer."
 282   (unless (get-buffer gnus-server-buffer)
 283     (save-excursion
 284       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 285       (gnus-server-mode)
 286       (when gnus-carpal
 287         (gnus-carpal-setup-buffer 'server)))))
 288
 289 (defun gnus-server-prepare ()
 290   (gnus-set-format 'server-mode)
 291   (gnus-set-format 'server t)
 292   (let ((alist gnus-server-alist)
 293         (buffer-read-only nil)
 294         (opened gnus-opened-servers)
 295         done server op-ser)
 296     (erase-buffer)
 297     (setq gnus-inserted-opened-servers nil)
 298     ;; First we do the real list of servers.
 299     (while alist
 300       (unless (member (cdar alist) done)
 301         (push (cdar alist) done)
 302         (cdr (setq server (pop alist)))
 303         (when (and server (car server) (cdr server))
 304           (gnus-server-insert-server-line (car server) (cdr server))))
 305       (when (member (cdar alist) done)
 306         (pop alist)))
 307     ;; Then we insert the list of servers that have been opened in
 308     ;; this session.
 309     (while opened
 310       (when (and (not (member (caar opened) done))
 311                  ;; Just ignore ephemeral servers.
 312                  (not (member (caar opened) gnus-ephemeral-servers)))
 313         (push (caar opened) done)
 314         (gnus-server-insert-server-line
 315          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 316          (caar opened))
 317         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 318       (setq opened (cdr opened))))
 319   (goto-char (point-min))
 320   (gnus-server-position-point))
 321
 322 (defun gnus-server-server-name ()
 323   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 324     (and server (symbol-name server))))
 325
 326 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 327
 328 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 329
 330 (defun gnus-server-update-server (server)
 331   (save-excursion
 332     (set-buffer gnus-server-buffer)
 333     (let* ((buffer-read-only nil)
 334            (entry (assoc server gnus-server-alist))
 335            (oentry (assoc (gnus-server-to-method server)
 336                           gnus-opened-servers)))
 337       (when entry
 338         (gnus-dribble-enter
 339          (concat "(gnus-server-set-info \"" server "\" '"
 340                  (prin1-to-string (cdr entry)) ")\n")))
 341       (when (or entry oentry)
 342         ;; Buffer may be narrowed.
 343         (save-restriction
 344           (widen)
 345           (when (gnus-server-goto-server server)
 346             (gnus-delete-line))
 347           (if entry
 348               (gnus-server-insert-server-line (car entry) (cdr entry))
 349             (gnus-server-insert-server-line
 350              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 351              (car oentry)))
 352           (gnus-server-position-point))))))
 353
 354 (defun gnus-server-set-info (server info)
 355   ;; Enter a select method into the virtual server alist.
 356   (when (and server info)
 357     (gnus-dribble-enter
 358      (concat "(gnus-server-set-info \"" server "\" '"
 359              (prin1-to-string info) ")"))
 360     (let* ((server (nth 1 info))
 361            (entry (assoc server gnus-server-alist)))
 362       (if entry (setcdr entry info)
 363         (setq gnus-server-alist
 364               (nconc gnus-server-alist (list (cons server info))))))))
 365
 366 ;;; Interactive server functions.
 367
 368 (defun gnus-server-kill-server (server)
 369   "Kill the server on the current line."
 370   (interactive (list (gnus-server-server-name)))
 371   (unless (gnus-server-goto-server server)
 372     (if server (error "No such server: %s" server)
 373       (error "No server on the current line")))
 374   (unless (assoc server gnus-server-alist)
 375     (error "Read-only server %s" server))
 376   (gnus-dribble-touch)
 377   (let ((buffer-read-only nil))
 378     (gnus-delete-line))
 379   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 380   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 381                                 gnus-server-alist))
 382   (let ((groups (gnus-groups-from-server server)))
 383     (when (and groups
 384                (gnus-yes-or-no-p
 385                 (format "Kill all %s groups from this server? "
 386                         (length groups))))
 387       (dolist (group groups)
 388         (setq gnus-newsrc-alist
 389               (delq (assoc group gnus-newsrc-alist)
 390                     gnus-newsrc-alist))
 391         (when gnus-group-change-level-function
 392           (funcall gnus-group-change-level-function
 393                    group gnus-level-killed 3)))))
 394   (gnus-server-position-point))
 395
 396 (defun gnus-server-yank-server ()
 397   "Yank the previously killed server."
 398   (interactive)
 399   (unless gnus-server-killed-servers
 400     (error "No killed servers to be yanked"))
 401   (let ((alist gnus-server-alist)
 402         (server (gnus-server-server-name))
 403         (killed (car gnus-server-killed-servers)))
 404     (if (not server)
 405         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 406       (if (string= server (caar gnus-server-alist))
 407           (push killed gnus-server-alist)
 408         (while (and (cdr alist)
 409                     (not (string= server (caadr alist))))
 410           (setq alist (cdr alist)))
 411         (if alist
 412             (setcdr alist (cons killed (cdr alist)))
 413           (setq gnus-server-alist (list killed)))))
 414     (gnus-server-update-server (car killed))
 415     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 416     (gnus-server-position-point)))
 417
 418 (defun gnus-server-exit ()
 419   "Return to the group buffer."
 420   (interactive)
 421   (gnus-run-hooks 'gnus-server-exit-hook)
 422   (kill-buffer (current-buffer))
 423   (gnus-configure-windows 'group t))
 424
 425 (defun gnus-server-list-servers ()
 426   "List all available servers."
 427   (interactive)
 428   (let ((cur (gnus-server-server-name)))
 429     (gnus-server-prepare)
 430     (if cur (gnus-server-goto-server cur)
 431       (goto-char (point-max))
 432       (forward-line -1))
 433     (gnus-server-position-point)))
 434
 435 (defun gnus-server-set-status (method status)
 436   "Make METHOD have STATUS."
 437   (let ((entry (assoc method gnus-opened-servers)))
 438     (if entry
 439         (setcar (cdr entry) status)
 440       (push (list method status) gnus-opened-servers))))
 441
 442 (defun gnus-opened-servers-remove (method)
 443   "Remove METHOD from the list of opened servers."
 444   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 445                                   gnus-opened-servers)))
 446
 447 (defun gnus-server-open-server (server)
 448   "Force an open of SERVER."
 449   (interactive (list (gnus-server-server-name)))
 450   (let ((method (gnus-server-to-method server)))
 451     (unless method
 452       (error "No such server: %s" server))
 453     (gnus-server-set-status method 'ok)
 454     (prog1
 455         (or (gnus-open-server method)
 456             (progn (message "Couldn't open %s" server) nil))
 457       (gnus-server-update-server server)
 458       (gnus-server-position-point))))
 459
 460 (defun gnus-server-open-all-servers ()
 461   "Open all servers."
 462   (interactive)
 463   (let ((servers gnus-inserted-opened-servers))
 464     (while servers
 465       (gnus-server-open-server (car (pop servers))))))
 466
 467 (defun gnus-server-close-server (server)
 468   "Close SERVER."
 469   (interactive (list (gnus-server-server-name)))
 470   (let ((method (gnus-server-to-method server)))
 471     (unless method
 472       (error "No such server: %s" server))
 473     (gnus-server-set-status method 'closed)
 474     (prog1
 475         (gnus-close-server method)
 476       (gnus-server-update-server server)
 477       (gnus-server-position-point))))
 478
 479 (defun gnus-server-close-all-servers ()
 480   "Close all servers."
 481   (interactive)
 482   (dolist (server gnus-inserted-opened-servers)
 483     (gnus-server-close-server (car server))))
 484
 485 (defun gnus-server-deny-server (server)
 486   "Make sure SERVER will never be attempted opened."
 487   (interactive (list (gnus-server-server-name)))
 488   (let ((method (gnus-server-to-method server)))
 489     (unless method
 490       (error "No such server: %s" server))
 491     (gnus-server-set-status method 'denied))
 492   (gnus-server-update-server server)
 493   (gnus-server-position-point)
 494   t)
 495
 496 (defun gnus-server-remove-denials ()
 497   "Make all denied servers into closed servers."
 498   (interactive)
 499   (dolist (server gnus-opened-servers)
 500     (when (eq (nth 1 server) 'denied)
 501       (setcar (nthcdr 1 server) 'closed)))
 502   (gnus-server-list-servers))
 503
 504 (defun gnus-server-copy-server (from to)
 505   (interactive
 506    (list
 507     (or (gnus-server-server-name)
 508         (error "No server on the current line"))
 509     (read-string "Copy to: ")))
 510   (unless from
 511     (error "No server on current line"))
 512   (unless (and to (not (string= to "")))
 513     (error "No name to copy to"))
 514   (when (assoc to gnus-server-alist)
 515     (error "%s already exists" to))
 516   (unless (gnus-server-to-method from)
 517     (error "%s: no such server" from))
 518   (let ((to-entry (cons from (gnus-copy-sequence
 519                               (gnus-server-to-method from)))))
 520     (setcar to-entry to)
 521     (setcar (nthcdr 2 to-entry) to)
 522     (push to-entry gnus-server-killed-servers)
 523     (gnus-server-yank-server)))
 524
 525 (defun gnus-server-add-server (how where)
 526   (interactive
 527    (list (intern (completing-read "Server method: "
 528                                   gnus-valid-select-methods nil t))
 529          (read-string "Server name: ")))
 530   (when (assq where gnus-server-alist)
 531     (error "Server with that name already defined"))
 532   (push (list where how where) gnus-server-killed-servers)
 533   (gnus-server-yank-server))
 534
 535 (defun gnus-server-goto-server (server)
 536   "Jump to a server line."
 537   (interactive
 538    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 539   (let ((to (text-property-any (point-min) (point-max)
 540                                'gnus-server (intern server))))
 541     (when to
 542       (goto-char to)
 543       (gnus-server-position-point))))
 544
 545 (defun gnus-server-edit-server (server)
 546   "Edit the server on the current line."
 547   (interactive (list (gnus-server-server-name)))
 548   (unless server
 549     (error "No server on current line"))
 550   (unless (assoc server gnus-server-alist)
 551     (error "This server can't be edited"))
 552   (let ((info (cdr (assoc server gnus-server-alist))))
 553     (gnus-close-server info)
 554     (gnus-edit-form
 555      info "Editing the server."
 556      `(lambda (form)
 557         (gnus-server-set-info ,server form)
 558         (gnus-server-list-servers)
 559         (gnus-server-position-point)))))
 560
 561 (defun gnus-server-scan-server (server)
 562   "Request a scan from the current server."
 563   (interactive (list (gnus-server-server-name)))
 564   (let ((method (gnus-server-to-method server)))
 565     (if (not (gnus-get-function method 'request-scan))
 566         (error "Server %s can't scan" (car method))
 567       (gnus-message 3 "Scanning %s..." server)
 568       (gnus-request-scan nil method)
 569       (gnus-message 3 "Scanning %s...done" server))))
 570
 571 (defun gnus-server-read-server-in-server-buffer (server)
 572   "Browse a server in server buffer."
 573   (interactive (list (gnus-server-server-name)))
 574   (let (gnus-server-browse-in-group-buffer)
 575     (gnus-server-read-server server)))
 576
 577 (defun gnus-server-read-server (server)
 578   "Browse a server."
 579   (interactive (list (gnus-server-server-name)))
 580   (let ((buf (current-buffer)))
 581     (prog1
 582         (gnus-browse-foreign-server server buf)
 583       (save-excursion
 584         (set-buffer buf)
 585         (gnus-server-update-server (gnus-server-server-name))
 586         (gnus-server-position-point)))))
 587
 588 (defun gnus-server-pick-server (e)
 589   (interactive "e")
 590   (mouse-set-point e)
 591   (gnus-server-read-server (gnus-server-server-name)))
 592
 593 \f
 594 ;;;
 595 ;;; Browse Server Mode
 596 ;;;
 597
 598 (defvar gnus-browse-menu-hook nil
 599   "*Hook run after the creation of the browse mode menu.")
 600
 601 (defvar gnus-browse-mode-hook nil)
 602 (defvar gnus-browse-mode-map nil)
 603 (put 'gnus-browse-mode 'mode-class 'special)
 604
 605 (unless gnus-browse-mode-map
 606   (setq gnus-browse-mode-map (make-keymap))
 607   (suppress-keymap gnus-browse-mode-map)
 608
 609   (gnus-define-keys
 610       gnus-browse-mode-map
 611     " " gnus-browse-read-group
 612     "=" gnus-browse-select-group
 613     "n" gnus-browse-next-group
 614     "p" gnus-browse-prev-group
 615     "\177" gnus-browse-prev-group
 616     [delete] gnus-browse-prev-group
 617     "N" gnus-browse-next-group
 618     "P" gnus-browse-prev-group
 619     "\M-n" gnus-browse-next-group
 620     "\M-p" gnus-browse-prev-group
 621     "\r" gnus-browse-select-group
 622     "u" gnus-browse-unsubscribe-current-group
 623     "l" gnus-browse-exit
 624     "L" gnus-browse-exit
 625     "q" gnus-browse-exit
 626     "Q" gnus-browse-exit
 627     "\C-c\C-c" gnus-browse-exit
 628     "?" gnus-browse-describe-briefly
 629
 630     "\C-c\C-i" gnus-info-find-node
 631     "\C-c\C-b" gnus-bug))
 632
 633 (defun gnus-browse-make-menu-bar ()
 634   (gnus-turn-off-edit-menu 'browse)
 635   (unless (boundp 'gnus-browse-menu)
 636     (easy-menu-define
 637      gnus-browse-menu gnus-browse-mode-map ""
 638      '("Browse"
 639        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 640        ["Read" gnus-browse-read-group t]
 641        ["Select" gnus-browse-select-group t]
 642        ["Next" gnus-browse-next-group t]
 643        ["Prev" gnus-browse-prev-group t]
 644        ["Exit" gnus-browse-exit t]))
 645     (gnus-run-hooks 'gnus-browse-menu-hook)))
 646
 647 (defvar gnus-browse-current-method nil)
 648 (defvar gnus-browse-return-buffer nil)
 649
 650 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 651
 652 (defun gnus-browse-foreign-server (server &optional return-buffer)
 653   "Browse the server SERVER."
 654   (setq gnus-browse-current-method (gnus-server-to-method server))
 655   (setq gnus-browse-return-buffer return-buffer)
 656   (let* ((method gnus-browse-current-method)
 657          (orig-select-method gnus-select-method)
 658          (gnus-select-method method)
 659          groups group)
 660     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 661     (cond
 662      ((not (gnus-check-server method))
 663       (gnus-message
 664        1 "Unable to contact server %s: %s" (nth 1 method)
 665        (gnus-status-message method))
 666       nil)
 667      ((not
 668        (prog2
 669            (gnus-message 6 "Reading active file...")
 670            (gnus-request-list method)
 671          (gnus-message 6 "Reading active file...done")))
 672       (gnus-message
 673        1 "Couldn't request list: %s" (gnus-status-message method))
 674       nil)
 675      (t
 676       (save-excursion
 677         (set-buffer nntp-server-buffer)
 678         (let ((cur (current-buffer)))
 679           (goto-char (point-min))
 680           (unless (string= gnus-ignored-newsgroups "")
 681             (delete-matching-lines gnus-ignored-newsgroups))
 682           (while (not (eobp))
 683             (ignore-errors
 684               (push (cons
 685                      (if (eq (char-after) ?\")
 686                          (read cur)
 687                        (let ((p (point)) (name ""))
 688                          (skip-chars-forward "^ \t\\\\")
 689                          (setq name (buffer-substring p (point)))
 690                          (while (eq (char-after) ?\\)
 691                            (setq p (1+ (point)))
 692                            (forward-char 2)
 693                            (skip-chars-forward "^ \t\\\\")
 694                            (setq name (concat name (buffer-substring
 695                                                     p (point)))))
 696                          name))
 697                      (let ((last (read cur)))
 698                        (cons (read cur) last)))
 699                     groups))
 700             (forward-line))))
 701       (setq groups (sort groups
 702                          (lambda (l1 l2)
 703                            (string< (car l1) (car l2)))))
 704       (if gnus-server-browse-in-group-buffer
 705           (let* ((gnus-select-method orig-select-method)
 706                  (gnus-group-listed-groups
 707                   (mapcar (lambda (group)
 708                             (let ((name
 709                                    (gnus-group-prefixed-name
 710                                     (car group) method)))
 711                               (gnus-set-active name (cdr group))
 712                               name))
 713                           groups)))
 714             (gnus-configure-windows 'group)
 715             (funcall gnus-group-prepare-function
 716                      gnus-level-killed 'ignore 1 'ignore))
 717         (gnus-get-buffer-create gnus-browse-buffer)
 718         (when gnus-carpal
 719           (gnus-carpal-setup-buffer 'browse))
 720         (gnus-configure-windows 'browse)
 721         (buffer-disable-undo)
 722         (let ((buffer-read-only nil))
 723           (erase-buffer))
 724         (gnus-browse-mode)
 725         (setq mode-line-buffer-identification
 726               (list
 727                (format
 728                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 729         (let ((buffer-read-only nil) charset)
 730           (while groups
 731             (setq group (car groups))
 732             (setq charset (gnus-group-name-charset method (car group)))
 733             (gnus-add-text-properties
 734              (point)
 735              (prog1 (1+ (point))
 736                (insert
 737                 (format "%c%7d: %s\n"
 738                         (let ((level
 739                                (let ((gnus-select-method orig-select-method))
 740                                  (gnus-group-level
 741                                   (gnus-group-prefixed-name (car group)
 742                                                             method)))))
 743                               (cond
 744                                ((<= level gnus-level-subscribed) ? )
 745                                ((<= level gnus-level-unsubscribed) ?U)
 746                                ((= level gnus-level-zombie) ?Z)
 747                                (t ?K)))
 748                         (max 0 (- (1+ (cddr group)) (cadr group)))
 749                         (gnus-group-name-decode (car group) charset))))
 750              (list 'gnus-group (car group)))
 751             (setq groups (cdr groups))))
 752         (switch-to-buffer (current-buffer)))
 753       (goto-char (point-min))
 754       (gnus-group-position-point)
 755       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 756       t))))
 757
 758 (defun gnus-browse-mode ()
 759   "Major mode for browsing a foreign server.
 760
 761 All normal editing commands are switched off.
 762
 763 \\<gnus-browse-mode-map>
 764 The only things you can do in this buffer is
 765
 766 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 767 The group will be inserted into the group buffer upon exit from this
 768 buffer.
 769
 770 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 771
 772 3) `\\[gnus-browse-exit]' to return to the group buffer."
 773   (interactive)
 774   (kill-all-local-variables)
 775   (when (gnus-visual-p 'browse-menu 'menu)
 776     (gnus-browse-make-menu-bar))
 777   (gnus-simplify-mode-line)
 778   (setq major-mode 'gnus-browse-mode)
 779   (setq mode-name "Browse Server")
 780   (setq mode-line-process nil)
 781   (use-local-map gnus-browse-mode-map)
 782   (buffer-disable-undo)
 783   (setq truncate-lines t)
 784   (gnus-set-default-directory)
 785   (setq buffer-read-only t)
 786   (gnus-run-hooks 'gnus-browse-mode-hook))
 787
 788 (defun gnus-browse-read-group (&optional no-article)
 789   "Enter the group at the current line."
 790   (interactive)
 791   (let ((group (gnus-browse-group-name)))
 792     (if (or (not (gnus-get-info group))
 793             (gnus-ephemeral-group-p group))
 794         (unless (gnus-group-read-ephemeral-group
 795                  (gnus-group-real-name group) gnus-browse-current-method nil
 796                  (cons (current-buffer) 'browse))
 797           (error "Couldn't enter %s" group))
 798       (unless (gnus-group-read-group nil no-article group)
 799         (error "Couldn't enter %s" group)))))
 800
 801 (defun gnus-browse-select-group ()
 802   "Select the current group."
 803   (interactive)
 804   (gnus-browse-read-group 'no))
 805
 806 (defun gnus-browse-next-group (n)
 807   "Go to the next group."
 808   (interactive "p")
 809   (prog1
 810       (forward-line n)
 811     (gnus-group-position-point)))
 812
 813 (defun gnus-browse-prev-group (n)
 814   "Go to the next group."
 815   (interactive "p")
 816   (gnus-browse-next-group (- n)))
 817
 818 (defun gnus-browse-unsubscribe-current-group (arg)
 819   "(Un)subscribe to the next ARG groups."
 820   (interactive "p")
 821   (when (eobp)
 822     (error "No group at current line"))
 823   (let ((ward (if (< arg 0) -1 1))
 824         (arg (abs arg)))
 825     (while (and (> arg 0)
 826                 (not (eobp))
 827                 (gnus-browse-unsubscribe-group)
 828                 (zerop (gnus-browse-next-group ward)))
 829       (decf arg))
 830     (gnus-group-position-point)
 831     (when (/= 0 arg)
 832       (gnus-message 7 "No more newsgroups"))
 833     arg))
 834
 835 (defun gnus-browse-group-name ()
 836   (save-excursion
 837     (beginning-of-line)
 838     (let ((name (get-text-property (point) 'gnus-group)))
 839       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 840         (gnus-group-prefixed-name
 841          (or name
 842              (match-string-no-properties 1))
 843          gnus-browse-current-method)))))
 844
 845 (defun gnus-browse-unsubscribe-group ()
 846   "Toggle subscription of the current group in the browse buffer."
 847   (let ((sub nil)
 848         (buffer-read-only nil)
 849         group)
 850     (save-excursion
 851       (beginning-of-line)
 852       ;; If this group it killed, then we want to subscribe it.
 853       (unless (eq (char-after) ? )
 854         (setq sub t))
 855       (setq group (gnus-browse-group-name))
 856       ;;;;
 857       ;;(when (and sub
 858       ;;                 (cadr (gnus-gethash group gnus-newsrc-hashtb)))
 859       ;;(error "Group already subscribed"))
 860       (if sub
 861           (progn
 862             ;; Make sure the group has been properly removed before we
 863             ;; subscribe to it.
 864             (gnus-kill-ephemeral-group group)
 865             (gnus-group-change-level
 866              (list t group gnus-level-default-subscribed
 867                    nil nil (if (gnus-server-equal
 868                                 gnus-browse-current-method "native")
 869                                nil
 870                              (gnus-method-simplify
 871                               gnus-browse-current-method)))
 872              gnus-level-default-subscribed (gnus-group-level group)
 873              (and (car (nth 1 gnus-newsrc-alist))
 874                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 875                                 gnus-newsrc-hashtb))
 876              t)
 877             (delete-char 1)
 878             (insert ? ))
 879         (gnus-group-change-level
 880          group gnus-level-unsubscribed gnus-level-default-subscribed)
 881         (delete-char 1)
 882         (insert ?U)))
 883     t))
 884
 885 (defun gnus-browse-exit ()
 886   "Quit browsing and return to the group buffer."
 887   (interactive)
 888   (when (eq major-mode 'gnus-browse-mode)
 889     (kill-buffer (current-buffer)))
 890   ;; Insert the newly subscribed groups in the group buffer.
 891   (save-excursion
 892     (set-buffer gnus-group-buffer)
 893     (gnus-group-list-groups nil))
 894   (if gnus-browse-return-buffer
 895       (gnus-configure-windows 'server 'force)
 896     (gnus-configure-windows 'group 'force)))
 897
 898 (defun gnus-browse-describe-briefly ()
 899   "Give a one line description of the group mode commands."
 900   (interactive)
 901   (gnus-message 6
 902                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 903
 904 (defun gnus-server-regenerate-server ()
 905   "Issue a command to the server to regenerate all its data structures."
 906   (interactive)
 907   (let ((server (gnus-server-server-name)))
 908     (unless server
 909       (error "No server on the current line"))
 910     (condition-case ()
 911         (gnus-get-function (gnus-server-to-method server)
 912                            'request-regenerate)
 913       (error
 914         (error "This backend doesn't support regeneration")))
 915     (gnus-message 5 "Requesting regeneration of %s..." server)
 916     (unless (gnus-open-server server)
 917       (error "Couldn't open server"))
 918     (if (gnus-request-regenerate server)
 919         (gnus-message 5 "Requesting regeneration of %s...done" server)
 920       (gnus-message 5 "Couldn't regenerate %s" server))))
 921
 922 (provide 'gnus-srvr)
 923
 924 ;;; gnus-srvr.el ends here