cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (eval-when-compile (require 'cl))
  30
  31 (defvar gnus-server-mode-hook nil
  32   "Hook run in `gnus-server-mode' buffers.")
  33
  34 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  35   "Format of server lines.
  36 It works along the same lines as a normal formatting string,
  37 with some simple extensions.")
  38
  39 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  40   "The format specification for the server mode line.")
  41
  42 (defvar gnus-server-exit-hook nil
  43   "*Hook run when exiting the server buffer.")
  44
  45 ;;; Internal variables.
  46
  47 (defvar gnus-inserted-opened-servers nil)
  48
  49 (defvar gnus-server-line-format-alist
  50   `((?h how ?s)
  51     (?n name ?s)
  52     (?w where ?s)
  53     (?s status ?s)))
  54
  55 (defvar gnus-server-mode-line-format-alist
  56   `((?S news-server ?s)
  57     (?M news-method ?s)
  58     (?u user-defined ?s)))
  59
  60 (defvar gnus-server-line-format-spec nil)
  61 (defvar gnus-server-mode-line-format-spec nil)
  62 (defvar gnus-server-killed-servers nil)
  63
  64 (defvar gnus-server-mode-map)
  65
  66 (defvar gnus-server-menu-hook nil
  67   "*Hook run after the creation of the server mode menu.")
  68
  69 (defun gnus-server-make-menu-bar ()
  70   (gnus-visual-turn-off-edit-menu 'server)
  71   (unless (boundp 'gnus-server-server-menu)
  72     (easy-menu-define
  73      gnus-server-server-menu gnus-server-mode-map ""
  74      '("Server"
  75        ["Add" gnus-server-add-server t]
  76        ["Browse" gnus-server-read-server t]
  77        ["List" gnus-server-list-servers t]
  78        ["Kill" gnus-server-kill-server t]
  79        ["Yank" gnus-server-yank-server t]
  80        ["Copy" gnus-server-copy-server t]
  81        ["Edit" gnus-server-edit-server t]
  82        ["Exit" gnus-server-exit t]
  83        ))
  84
  85     (easy-menu-define
  86      gnus-server-connections-menu gnus-server-mode-map ""
  87      '("Connections"
  88        ["Open" gnus-server-open-server t]
  89        ["Close" gnus-server-close-server t]
  90        ["Deny" gnus-server-deny-server t]
  91        ["Reset" gnus-server-remove-denials t]
  92        ))
  93
  94     (run-hooks 'gnus-server-menu-hook)))
  95
  96 (defvar gnus-server-mode-map nil)
  97 (put 'gnus-server-mode 'mode-class 'special)
  98
  99 (unless gnus-server-mode-map
 100   (setq gnus-server-mode-map (make-sparse-keymap))
 101   (suppress-keymap gnus-server-mode-map)
 102
 103   (gnus-define-keys
 104    gnus-server-mode-map
 105    " " gnus-server-read-server
 106    "\r" gnus-server-read-server
 107    gnus-mouse-2 gnus-server-pick-server
 108    "q" gnus-server-exit
 109    "l" gnus-server-list-servers
 110    "k" gnus-server-kill-server
 111    "y" gnus-server-yank-server
 112    "c" gnus-server-copy-server
 113    "a" gnus-server-add-server
 114    "e" gnus-server-edit-server
 115
 116    "O" gnus-server-open-server
 117    "C" gnus-server-close-server
 118    "D" gnus-server-deny-server
 119    "R" gnus-server-remove-denials))
 120
 121 (defun gnus-server-mode ()
 122   "Major mode for listing and editing servers.
 123
 124 All normal editing commands are switched off.
 125 \\<gnus-server-mode-map>
 126 For more in-depth information on this mode, read the manual
 127 (`\\[gnus-info-find-node]').
 128
 129 The following commands are available:
 130
 131 \\{gnus-server-mode-map}"
 132   (interactive)
 133   (when (and menu-bar-mode
 134              (gnus-visual-p 'server-menu 'menu))
 135     (gnus-server-make-menu-bar))
 136   (kill-all-local-variables)
 137   (gnus-simplify-mode-line)
 138   (setq major-mode 'gnus-server-mode)
 139   (setq mode-name "Server")
 140                                         ;  (gnus-group-set-mode-line)
 141   (setq mode-line-process nil)
 142   (use-local-map gnus-server-mode-map)
 143   (buffer-disable-undo (current-buffer))
 144   (setq truncate-lines t)
 145   (setq buffer-read-only t)
 146   (run-hooks 'gnus-server-mode-hook))
 147
 148 (defun gnus-server-insert-server-line (name method)
 149   (let* ((how (car method))
 150          (where (nth 1 method))
 151          (elem (assoc method gnus-opened-servers))
 152          (status (cond ((eq (nth 1 elem) 'denied)
 153                         "(denied)")
 154                        ((or (gnus-server-opened method)
 155                             (eq (nth 1 elem) 'ok))
 156                         "(opened)")
 157                        (t
 158                         "(closed)"))))
 159     (beginning-of-line)
 160     (gnus-add-text-properties
 161      (point)
 162      (prog1 (1+ (point))
 163        ;; Insert the text.
 164        (eval gnus-server-line-format-spec))
 165      (list 'gnus-server (intern name)))))
 166
 167 (defun gnus-enter-server-buffer ()
 168   "Set up the server buffer."
 169   (gnus-server-setup-buffer)
 170   (gnus-configure-windows 'server)
 171   (gnus-server-prepare))
 172
 173 (defun gnus-server-setup-buffer ()
 174   "Initialize the server buffer."
 175   (unless (get-buffer gnus-server-buffer)
 176     (save-excursion
 177       (set-buffer (get-buffer-create gnus-server-buffer))
 178       (gnus-server-mode)
 179       (when gnus-carpal
 180         (gnus-carpal-setup-buffer 'server)))))
 181
 182 (defun gnus-server-prepare ()
 183   (setq gnus-server-mode-line-format-spec
 184         (gnus-parse-format gnus-server-mode-line-format
 185                            gnus-server-mode-line-format-alist))
 186   (setq gnus-server-line-format-spec
 187         (gnus-parse-format gnus-server-line-format
 188                            gnus-server-line-format-alist t))
 189   (let ((alist gnus-server-alist)
 190         (buffer-read-only nil)
 191         (opened gnus-opened-servers)
 192         done server op-ser)
 193     (erase-buffer)
 194     (setq gnus-inserted-opened-servers nil)
 195     ;; First we do the real list of servers.
 196     (while alist
 197       (push (cdr (setq server (pop alist))) done)
 198       (when (and server (car server) (cdr server))
 199         (gnus-server-insert-server-line (car server) (cdr server))))
 200     ;; Then we insert the list of servers that have been opened in
 201     ;; this session.
 202     (while opened
 203       (unless (member (caar opened) done)
 204         (gnus-server-insert-server-line
 205          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 206          (caar opened))
 207         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 208       (setq opened (cdr opened))))
 209   (goto-char (point-min))
 210   (gnus-server-position-point))
 211
 212 (defun gnus-server-server-name ()
 213   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 214     (and server (symbol-name server))))
 215
 216 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 217
 218 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 219
 220 (defun gnus-server-update-server (server)
 221   (save-excursion
 222     (set-buffer gnus-server-buffer)
 223     (let* ((buffer-read-only nil)
 224            (entry (assoc server gnus-server-alist))
 225            (oentry (assoc (gnus-server-to-method server)
 226                           gnus-opened-servers)))
 227       (when entry
 228         (gnus-dribble-enter
 229          (concat "(gnus-server-set-info \"" server "\" '"
 230                  (prin1-to-string (cdr entry)) ")")))
 231       (when (or entry oentry)
 232         ;; Buffer may be narrowed.
 233         (save-restriction
 234           (widen)
 235           (when (gnus-server-goto-server server)
 236             (gnus-delete-line))
 237           (if entry
 238               (gnus-server-insert-server-line (car entry) (cdr entry))
 239             (gnus-server-insert-server-line
 240              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 241              (car oentry)))
 242           (gnus-server-position-point))))))
 243
 244 (defun gnus-server-set-info (server info)
 245   ;; Enter a select method into the virtual server alist.
 246   (when (and server info)
 247     (gnus-dribble-enter
 248      (concat "(gnus-server-set-info \"" server "\" '"
 249              (prin1-to-string info) ")"))
 250     (let* ((server (nth 1 info))
 251            (entry (assoc server gnus-server-alist)))
 252       (if entry (setcdr entry info)
 253         (setq gnus-server-alist
 254               (nconc gnus-server-alist (list (cons server info))))))))
 255
 256 ;;; Interactive server functions.
 257
 258 (defun gnus-server-kill-server (server)
 259   "Kill the server on the current line."
 260   (interactive (list (gnus-server-server-name)))
 261   (unless (gnus-server-goto-server server)
 262     (if server (error "No such server: %s" server)
 263       (error "No server on the current line")))
 264   (unless (assoc server gnus-server-alist)
 265     (error "Read-only server %s" server))
 266   (gnus-dribble-enter "")
 267   (let ((buffer-read-only nil))
 268     (gnus-delete-line))
 269   (setq gnus-server-killed-servers
 270         (cons (assoc server gnus-server-alist) gnus-server-killed-servers))
 271   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 272                                 gnus-server-alist))
 273   (gnus-server-position-point))
 274
 275 (defun gnus-server-yank-server ()
 276   "Yank the previously killed server."
 277   (interactive)
 278   (or gnus-server-killed-servers
 279       (error "No killed servers to be yanked"))
 280   (let ((alist gnus-server-alist)
 281         (server (gnus-server-server-name))
 282         (killed (car gnus-server-killed-servers)))
 283     (if (not server)
 284         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 285       (if (string= server (caar gnus-server-alist))
 286           (setq gnus-server-alist (cons killed gnus-server-alist))
 287         (while (and (cdr alist)
 288                     (not (string= server (caadr alist))))
 289           (setq alist (cdr alist)))
 290         (if alist
 291             (setcdr alist (cons killed (cdr alist)))
 292           (setq gnus-server-alist (list killed)))))
 293     (gnus-server-update-server (car killed))
 294     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 295     (gnus-server-position-point)))
 296
 297 (defun gnus-server-exit ()
 298   "Return to the group buffer."
 299   (interactive)
 300   (kill-buffer (current-buffer))
 301   (switch-to-buffer gnus-group-buffer)
 302   (run-hooks 'gnus-server-exit-hook))
 303
 304 (defun gnus-server-list-servers ()
 305   "List all available servers."
 306   (interactive)
 307   (let ((cur (gnus-server-server-name)))
 308     (gnus-server-prepare)
 309     (if cur (gnus-server-goto-server cur)
 310       (goto-char (point-max))
 311       (forward-line -1))
 312     (gnus-server-position-point)))
 313
 314 (defun gnus-server-set-status (method status)
 315   "Make METHOD have STATUS."
 316   (let ((entry (assoc method gnus-opened-servers)))
 317     (if entry
 318         (setcar (cdr entry) status)
 319       (push (list method status) gnus-opened-servers))))
 320
 321 (defun gnus-opened-servers-remove (method)
 322   "Remove METHOD from the list of opened servers."
 323   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 324                                   gnus-opened-servers)))
 325
 326 (defun gnus-server-open-server (server)
 327   "Force an open of SERVER."
 328   (interactive (list (gnus-server-server-name)))
 329   (let ((method (gnus-server-to-method server)))
 330     (or method (error "No such server: %s" server))
 331     (gnus-server-set-status method 'ok)
 332     (prog1
 333         (or (gnus-open-server method)
 334             (progn (message "Couldn't open %s" server) nil))
 335       (gnus-server-update-server server)
 336       (gnus-server-position-point))))
 337
 338 (defun gnus-server-close-server (server)
 339   "Close SERVER."
 340   (interactive (list (gnus-server-server-name)))
 341   (let ((method (gnus-server-to-method server)))
 342     (or method (error "No such server: %s" server))
 343     (gnus-server-set-status method 'closed)
 344     (prog1
 345         (gnus-close-server method)
 346       (gnus-server-update-server server)
 347       (gnus-server-position-point))))
 348
 349 (defun gnus-server-deny-server (server)
 350   "Make sure SERVER will never be attempted opened."
 351   (interactive (list (gnus-server-server-name)))
 352   (let ((method (gnus-server-to-method server)))
 353     (or method (error "No such server: %s" server))
 354     (gnus-server-set-status method 'denied))
 355   (gnus-server-update-server server)
 356   (gnus-server-position-point)
 357   t)
 358
 359 (defun gnus-server-remove-denials ()
 360   "Make all denied servers into closed servers."
 361   (interactive)
 362   (let ((servers gnus-opened-servers))
 363     (while servers
 364       (when (eq (nth 1 (car servers)) 'denied)
 365         (setcar (nthcdr 1 (car servers)) 'closed))
 366       (setq servers (cdr servers))))
 367   (gnus-server-list-servers))
 368
 369 (defun gnus-server-copy-server (from to)
 370   (interactive
 371    (list
 372     (or (gnus-server-server-name)
 373         (error "No server on the current line"))
 374     (read-string "Copy to: ")))
 375   (or from (error "No server on current line"))
 376   (or (and to (not (string= to ""))) (error "No name to copy to"))
 377   (and (assoc to gnus-server-alist) (error "%s already exists" to))
 378   (or (assoc from gnus-server-alist)
 379       (error "%s: no such server" from))
 380   (let ((to-entry (gnus-copy-sequence (assoc from gnus-server-alist))))
 381     (setcar to-entry to)
 382     (setcar (nthcdr 2 to-entry) to)
 383     (setq gnus-server-killed-servers
 384           (cons to-entry gnus-server-killed-servers))
 385     (gnus-server-yank-server)))
 386
 387 (defun gnus-server-add-server (how where)
 388   (interactive
 389    (list (intern (completing-read "Server method: "
 390                                   gnus-valid-select-methods nil t))
 391          (read-string "Server name: ")))
 392   (setq gnus-server-killed-servers
 393         (cons (list where how where) gnus-server-killed-servers))
 394   (gnus-server-yank-server))
 395
 396 (defun gnus-server-goto-server (server)
 397   "Jump to a server line."
 398   (interactive
 399    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 400   (let ((to (text-property-any (point-min) (point-max)
 401                                'gnus-server (intern server))))
 402     (and to
 403          (progn
 404            (goto-char to)
 405            (gnus-server-position-point)))))
 406
 407 (defun gnus-server-edit-server (server)
 408   "Edit the server on the current line."
 409   (interactive (list (gnus-server-server-name)))
 410   (unless server
 411     (error "No server on current line"))
 412   (unless (assoc server gnus-server-alist)
 413     (error "This server can't be edited"))
 414   (let ((winconf (current-window-configuration))
 415         (info (cdr (assoc server gnus-server-alist))))
 416     (gnus-close-server info)
 417     (get-buffer-create gnus-server-edit-buffer)
 418     (gnus-configure-windows 'edit-server)
 419     (gnus-add-current-to-buffer-list)
 420     (emacs-lisp-mode)
 421     (make-local-variable 'gnus-prev-winconf)
 422     (setq gnus-prev-winconf winconf)
 423     (use-local-map (copy-keymap (current-local-map)))
 424     (let ((done-func '(lambda ()
 425                         "Exit editing mode and update the information."
 426                         (interactive)
 427                         (gnus-server-edit-server-done 'group))))
 428       (setcar (cdr (nth 4 done-func)) server)
 429       (local-set-key "\C-c\C-c" done-func))
 430     (erase-buffer)
 431     (insert ";; Type `C-c C-c' after you have edited the server.\n\n")
 432     (insert (pp-to-string info))))
 433
 434 (defun gnus-server-edit-server-done (server)
 435   (interactive)
 436   (set-buffer (get-buffer-create gnus-server-edit-buffer))
 437   (goto-char (point-min))
 438   (let ((form (read (current-buffer)))
 439         (winconf gnus-prev-winconf))
 440     (gnus-server-set-info server form)
 441     (kill-buffer (current-buffer))
 442     (and winconf (set-window-configuration winconf))
 443     (set-buffer gnus-server-buffer)
 444     (gnus-server-update-server server)
 445     (gnus-server-list-servers)
 446     (gnus-server-position-point)))
 447
 448 (defun gnus-server-read-server (server)
 449   "Browse a server."
 450   (interactive (list (gnus-server-server-name)))
 451   (let ((buf (current-buffer)))
 452     (prog1
 453         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 454       (save-excursion
 455         (set-buffer buf)
 456         (gnus-server-update-server (gnus-server-server-name))
 457         (gnus-server-position-point)))))
 458
 459 (defun gnus-server-pick-server (e)
 460   (interactive "e")
 461   (mouse-set-point e)
 462   (gnus-server-read-server (gnus-server-server-name)))
 463
 464 \f
 465 ;;;
 466 ;;; Browse Server Mode
 467 ;;;
 468
 469 (defvar gnus-browse-menu-hook nil
 470   "*Hook run after the creation of the browse mode menu.")
 471
 472 (defvar gnus-browse-mode-hook nil)
 473 (defvar gnus-browse-mode-map nil)
 474 (put 'gnus-browse-mode 'mode-class 'special)
 475
 476 (unless gnus-browse-mode-map
 477   (setq gnus-browse-mode-map (make-keymap))
 478   (suppress-keymap gnus-browse-mode-map)
 479
 480   (gnus-define-keys
 481    gnus-browse-mode-map
 482    " " gnus-browse-read-group
 483    "=" gnus-browse-select-group
 484    "n" gnus-browse-next-group
 485    "p" gnus-browse-prev-group
 486    "\177" gnus-browse-prev-group
 487    "N" gnus-browse-next-group
 488    "P" gnus-browse-prev-group
 489    "\M-n" gnus-browse-next-group
 490    "\M-p" gnus-browse-prev-group
 491    "\r" gnus-browse-select-group
 492    "u" gnus-browse-unsubscribe-current-group
 493    "l" gnus-browse-exit
 494    "L" gnus-browse-exit
 495    "q" gnus-browse-exit
 496    "Q" gnus-browse-exit
 497    "\C-c\C-c" gnus-browse-exit
 498    "?" gnus-browse-describe-briefly
 499    "\C-c\C-i" gnus-info-find-node))
 500
 501 (defun gnus-browse-make-menu-bar ()
 502   (gnus-visual-turn-off-edit-menu 'browse)
 503   (or
 504    (boundp 'gnus-browse-menu)
 505    (progn
 506      (easy-menu-define
 507       gnus-browse-menu gnus-browse-mode-map ""
 508       '("Browse"
 509         ["Subscribe" gnus-browse-unsubscribe-current-group t]
 510         ["Read" gnus-browse-read-group t]
 511         ["Select" gnus-browse-read-group t]
 512         ["Next" gnus-browse-next-group t]
 513         ["Prev" gnus-browse-next-group t]
 514         ["Exit" gnus-browse-exit t]
 515         ))
 516       (run-hooks 'gnus-browse-menu-hook))))
 517
 518 (defvar gnus-browse-current-method nil)
 519 (defvar gnus-browse-return-buffer nil)
 520
 521 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 522
 523 (defun gnus-browse-foreign-server (method &optional return-buffer)
 524   "Browse the server METHOD."
 525   (setq gnus-browse-current-method method)
 526   (setq gnus-browse-return-buffer return-buffer)
 527   (let ((gnus-select-method method)
 528         groups group)
 529     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 530     (cond
 531      ((not (gnus-check-server method))
 532       (gnus-message
 533        1 "Unable to contact server: %s" (gnus-status-message method))
 534       nil)
 535      ((not (gnus-request-list method))
 536       (gnus-message
 537        1 "Couldn't request list: %s" (gnus-status-message method))
 538       nil)
 539      (t
 540       (get-buffer-create gnus-browse-buffer)
 541       (gnus-add-current-to-buffer-list)
 542       (and gnus-carpal (gnus-carpal-setup-buffer 'browse))
 543       (gnus-configure-windows 'browse)
 544       (buffer-disable-undo (current-buffer))
 545       (let ((buffer-read-only nil))
 546         (erase-buffer))
 547       (gnus-browse-mode)
 548       (setq mode-line-buffer-identification
 549             (list
 550              (format
 551               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 552       (save-excursion
 553         (set-buffer nntp-server-buffer)
 554         (let ((cur (current-buffer)))
 555           (goto-char (point-min))
 556           (or (string= gnus-ignored-newsgroups "")
 557               (delete-matching-lines gnus-ignored-newsgroups))
 558           (while (re-search-forward
 559                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 560             (goto-char (match-end 1))
 561             (setq groups (cons (cons (match-string 1)
 562                                      (max 0 (- (1+ (read cur)) (read cur))))
 563                                groups)))))
 564       (setq groups (sort groups
 565                          (lambda (l1 l2)
 566                            (string< (car l1) (car l2)))))
 567       (let ((buffer-read-only nil))
 568         (while groups
 569           (setq group (car groups))
 570           (insert
 571            (format "K%7d: %s\n" (cdr group) (car group)))
 572           (setq groups (cdr groups))))
 573       (switch-to-buffer (current-buffer))
 574       (goto-char (point-min))
 575       (gnus-group-position-point)
 576       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 577       t))))
 578
 579 (defun gnus-browse-mode ()
 580   "Major mode for browsing a foreign server.
 581
 582 All normal editing commands are switched off.
 583
 584 \\<gnus-browse-mode-map>
 585 The only things you can do in this buffer is
 586
 587 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 588 The group will be inserted into the group buffer upon exit from this
 589 buffer.
 590
 591 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 592
 593 3) `\\[gnus-browse-exit]' to return to the group buffer."
 594   (interactive)
 595   (kill-all-local-variables)
 596   (when (and menu-bar-mode
 597              (gnus-visual-p 'browse-menu 'menu))
 598     (gnus-browse-make-menu-bar))
 599   (gnus-simplify-mode-line)
 600   (setq major-mode 'gnus-browse-mode)
 601   (setq mode-name "Browse Server")
 602   (setq mode-line-process nil)
 603   (use-local-map gnus-browse-mode-map)
 604   (buffer-disable-undo (current-buffer))
 605   (setq truncate-lines t)
 606   (setq buffer-read-only t)
 607   (run-hooks 'gnus-browse-mode-hook))
 608
 609 (defun gnus-browse-read-group (&optional no-article)
 610   "Enter the group at the current line."
 611   (interactive)
 612   (let ((group (gnus-browse-group-name)))
 613     (or (gnus-group-read-ephemeral-group
 614          group gnus-browse-current-method nil
 615          (cons (current-buffer) 'browse))
 616         (error "Couldn't enter %s" group))))
 617
 618 (defun gnus-browse-select-group ()
 619   "Select the current group."
 620   (interactive)
 621   (gnus-browse-read-group 'no))
 622
 623 (defun gnus-browse-next-group (n)
 624   "Go to the next group."
 625   (interactive "p")
 626   (prog1
 627       (forward-line n)
 628     (gnus-group-position-point)))
 629
 630 (defun gnus-browse-prev-group (n)
 631   "Go to the next group."
 632   (interactive "p")
 633   (gnus-browse-next-group (- n)))
 634
 635 (defun gnus-browse-unsubscribe-current-group (arg)
 636   "(Un)subscribe to the next ARG groups."
 637   (interactive "p")
 638   (when (eobp)
 639     (error "No group at current line."))
 640   (let ((ward (if (< arg 0) -1 1))
 641         (arg (abs arg)))
 642     (while (and (> arg 0)
 643                 (not (eobp))
 644                 (gnus-browse-unsubscribe-group)
 645                 (zerop (gnus-browse-next-group ward)))
 646       (decf arg))
 647     (gnus-group-position-point)
 648     (if (/= 0 arg) (gnus-message 7 "No more newsgroups"))
 649     arg))
 650
 651 (defun gnus-browse-group-name ()
 652   (save-excursion
 653     (beginning-of-line)
 654     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 655       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 656
 657 (defun gnus-browse-unsubscribe-group ()
 658   "Toggle subscription of the current group in the browse buffer."
 659   (let ((sub nil)
 660         (buffer-read-only nil)
 661         group)
 662     (save-excursion
 663       (beginning-of-line)
 664       ;; If this group it killed, then we want to subscribe it.
 665       (if (= (following-char) ?K) (setq sub t))
 666       (setq group (gnus-browse-group-name))
 667       (delete-char 1)
 668       (if sub
 669           (progn
 670             (gnus-group-change-level
 671              (list t group gnus-level-default-subscribed
 672                    nil nil gnus-browse-current-method)
 673              gnus-level-default-subscribed gnus-level-killed
 674              (and (car (nth 1 gnus-newsrc-alist))
 675                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 676                                 gnus-newsrc-hashtb))
 677              t)
 678             (insert ? ))
 679         (gnus-group-change-level
 680          group gnus-level-killed gnus-level-default-subscribed)
 681         (insert ?K)))
 682     t))
 683
 684 (defun gnus-browse-exit ()
 685   "Quit browsing and return to the group buffer."
 686   (interactive)
 687   (when (eq major-mode 'gnus-browse-mode)
 688     (kill-buffer (current-buffer)))
 689   ;; Insert the newly subscribed groups in the group buffer.
 690   (save-excursion
 691     (set-buffer gnus-group-buffer)
 692     (gnus-group-list-groups nil))
 693   (if gnus-browse-return-buffer
 694       (gnus-configure-windows 'server 'force)
 695     (gnus-configure-windows 'group 'force)))
 696
 697 (defun gnus-browse-describe-briefly ()
 698   "Give a one line description of the group mode commands."
 699   (interactive)
 700   (gnus-message 6
 701                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 702
 703 (provide 'gnus-srvr)
 704
 705 ;;; gnus-srvr.el ends here.