cgit.sxemacs.org Git - gnus/blob - lisp/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-spec)
  30 (require 'gnus)
  31 (require 'gnus-group)
  32 (require 'gnus-int)
  33 (require 'gnus-range)
  34
  35 (defvar gnus-server-mode-hook nil
  36   "Hook run in `gnus-server-mode' buffers.")
  37
  38 (defconst gnus-server-line-format "     {%(%h:%w%)} %s\n"
  39   "Format of server lines.
  40 It works along the same lines as a normal formatting string,
  41 with some simple extensions.")
  42
  43 (defvar gnus-server-mode-line-format "Gnus  List of servers"
  44   "The format specification for the server mode line.")
  45
  46 (defvar gnus-server-exit-hook nil
  47   "*Hook run when exiting the server buffer.")
  48
  49 ;;; Internal variables.
  50
  51 (defvar gnus-inserted-opened-servers nil)
  52
  53 (defvar gnus-server-line-format-alist
  54   `((?h how ?s)
  55     (?n name ?s)
  56     (?w where ?s)
  57     (?s status ?s)))
  58
  59 (defvar gnus-server-mode-line-format-alist
  60   `((?S news-server ?s)
  61     (?M news-method ?s)
  62     (?u user-defined ?s)))
  63
  64 (defvar gnus-server-line-format-spec nil)
  65 (defvar gnus-server-mode-line-format-spec nil)
  66 (defvar gnus-server-killed-servers nil)
  67
  68 (defvar gnus-server-mode-map)
  69
  70 (defvar gnus-server-menu-hook nil
  71   "*Hook run after the creation of the server mode menu.")
  72
  73 (defun gnus-server-make-menu-bar ()
  74   (gnus-turn-off-edit-menu 'server)
  75   (unless (boundp 'gnus-server-server-menu)
  76     (easy-menu-define
  77      gnus-server-server-menu gnus-server-mode-map ""
  78      '("Server"
  79        ["Add" gnus-server-add-server t]
  80        ["Browse" gnus-server-read-server t]
  81        ["Scan" gnus-server-scan-server t]
  82        ["List" gnus-server-list-servers t]
  83        ["Kill" gnus-server-kill-server t]
  84        ["Yank" gnus-server-yank-server t]
  85        ["Copy" gnus-server-copy-server t]
  86        ["Edit" gnus-server-edit-server t]
  87        ["Exit" gnus-server-exit t]
  88        ))
  89
  90     (easy-menu-define
  91      gnus-server-connections-menu gnus-server-mode-map ""
  92      '("Connections"
  93        ["Open" gnus-server-open-server t]
  94        ["Close" gnus-server-close-server t]
  95        ["Deny" gnus-server-deny-server t]
  96        "---"
  97        ["Open All" gnus-server-open-all-servers t]
  98        ["Close All" gnus-server-close-all-servers t]
  99        ["Reset All" gnus-server-remove-denials t]
 100        ))
 101
 102     (run-hooks 'gnus-server-menu-hook)))
 103
 104 (defvar gnus-server-mode-map nil)
 105 (put 'gnus-server-mode 'mode-class 'special)
 106
 107 (unless gnus-server-mode-map
 108   (setq gnus-server-mode-map (make-sparse-keymap))
 109   (suppress-keymap gnus-server-mode-map)
 110
 111   (gnus-define-keys
 112    gnus-server-mode-map
 113    " " gnus-server-read-server
 114    "\r" gnus-server-read-server
 115    gnus-mouse-2 gnus-server-pick-server
 116    "q" gnus-server-exit
 117    "l" gnus-server-list-servers
 118    "k" gnus-server-kill-server
 119    "y" gnus-server-yank-server
 120    "c" gnus-server-copy-server
 121    "a" gnus-server-add-server
 122    "e" gnus-server-edit-server
 123    "s" gnus-server-scan-server
 124
 125    "O" gnus-server-open-server
 126    "\M-o" gnus-server-open-all-servers
 127    "C" gnus-server-close-server
 128    "\M-c" gnus-server-close-all-servers
 129    "D" gnus-server-deny-server
 130    "R" gnus-server-remove-denials
 131
 132     "\C-c\C-i" gnus-info-find-node))
 133
 134 (defun gnus-server-mode ()
 135   "Major mode for listing and editing servers.
 136
 137 All normal editing commands are switched off.
 138 \\<gnus-server-mode-map>
 139 For more in-depth information on this mode, read the manual
 140 (`\\[gnus-info-find-node]').
 141
 142 The following commands are available:
 143
 144 \\{gnus-server-mode-map}"
 145   (interactive)
 146   (when (and menu-bar-mode
 147              (gnus-visual-p 'server-menu 'menu))
 148     (gnus-server-make-menu-bar))
 149   (kill-all-local-variables)
 150   (gnus-simplify-mode-line)
 151   (setq major-mode 'gnus-server-mode)
 152   (setq mode-name "Server")
 153   (gnus-set-default-directory)
 154   (setq mode-line-process nil)
 155   (use-local-map gnus-server-mode-map)
 156   (buffer-disable-undo (current-buffer))
 157   (setq truncate-lines t)
 158   (setq buffer-read-only t)
 159   (run-hooks 'gnus-server-mode-hook))
 160
 161 (defun gnus-server-insert-server-line (name method)
 162   (let* ((how (car method))
 163          (where (nth 1 method))
 164          (elem (assoc method gnus-opened-servers))
 165          (status (cond ((eq (nth 1 elem) 'denied)
 166                         "(denied)")
 167                        ((or (gnus-server-opened method)
 168                             (eq (nth 1 elem) 'ok))
 169                         "(opened)")
 170                        (t
 171                         "(closed)"))))
 172     (beginning-of-line)
 173     (gnus-add-text-properties
 174      (point)
 175      (prog1 (1+ (point))
 176        ;; Insert the text.
 177        (eval gnus-server-line-format-spec))
 178      (list 'gnus-server (intern name)))))
 179
 180 (defun gnus-enter-server-buffer ()
 181   "Set up the server buffer."
 182   (gnus-server-setup-buffer)
 183   (gnus-configure-windows 'server)
 184   (gnus-server-prepare))
 185
 186 (defun gnus-server-setup-buffer ()
 187   "Initialize the server buffer."
 188   (unless (get-buffer gnus-server-buffer)
 189     (save-excursion
 190       (set-buffer (get-buffer-create gnus-server-buffer))
 191       (gnus-server-mode)
 192       (when gnus-carpal
 193         (gnus-carpal-setup-buffer 'server)))))
 194
 195 (defun gnus-server-prepare ()
 196   (setq gnus-server-mode-line-format-spec
 197         (gnus-parse-format gnus-server-mode-line-format
 198                            gnus-server-mode-line-format-alist))
 199   (setq gnus-server-line-format-spec
 200         (gnus-parse-format gnus-server-line-format
 201                            gnus-server-line-format-alist t))
 202   (let ((alist gnus-server-alist)
 203         (buffer-read-only nil)
 204         (opened gnus-opened-servers)
 205         done server op-ser)
 206     (erase-buffer)
 207     (setq gnus-inserted-opened-servers nil)
 208     ;; First we do the real list of servers.
 209     (while alist
 210       (push (cdr (setq server (pop alist))) done)
 211       (when (and server (car server) (cdr server))
 212         (gnus-server-insert-server-line (car server) (cdr server))))
 213     ;; Then we insert the list of servers that have been opened in
 214     ;; this session.
 215     (while opened
 216       (unless (member (caar opened) done)
 217         (gnus-server-insert-server-line
 218          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 219          (caar opened))
 220         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 221       (setq opened (cdr opened))))
 222   (goto-char (point-min))
 223   (gnus-server-position-point))
 224
 225 (defun gnus-server-server-name ()
 226   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 227     (and server (symbol-name server))))
 228
 229 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 230
 231 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 232
 233 (defun gnus-server-update-server (server)
 234   (save-excursion
 235     (set-buffer gnus-server-buffer)
 236     (let* ((buffer-read-only nil)
 237            (entry (assoc server gnus-server-alist))
 238            (oentry (assoc (gnus-server-to-method server)
 239                           gnus-opened-servers)))
 240       (when entry
 241         (gnus-dribble-enter
 242          (concat "(gnus-server-set-info \"" server "\" '"
 243                  (prin1-to-string (cdr entry)) ")")))
 244       (when (or entry oentry)
 245         ;; Buffer may be narrowed.
 246         (save-restriction
 247           (widen)
 248           (when (gnus-server-goto-server server)
 249             (gnus-delete-line))
 250           (if entry
 251               (gnus-server-insert-server-line (car entry) (cdr entry))
 252             (gnus-server-insert-server-line
 253              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 254              (car oentry)))
 255           (gnus-server-position-point))))))
 256
 257 (defun gnus-server-set-info (server info)
 258   ;; Enter a select method into the virtual server alist.
 259   (when (and server info)
 260     (gnus-dribble-enter
 261      (concat "(gnus-server-set-info \"" server "\" '"
 262              (prin1-to-string info) ")"))
 263     (let* ((server (nth 1 info))
 264            (entry (assoc server gnus-server-alist)))
 265       (if entry (setcdr entry info)
 266         (setq gnus-server-alist
 267               (nconc gnus-server-alist (list (cons server info))))))))
 268
 269 ;;; Interactive server functions.
 270
 271 (defun gnus-server-kill-server (server)
 272   "Kill the server on the current line."
 273   (interactive (list (gnus-server-server-name)))
 274   (unless (gnus-server-goto-server server)
 275     (if server (error "No such server: %s" server)
 276       (error "No server on the current line")))
 277   (unless (assoc server gnus-server-alist)
 278     (error "Read-only server %s" server))
 279   (gnus-dribble-enter "")
 280   (let ((buffer-read-only nil))
 281     (gnus-delete-line))
 282   (setq gnus-server-killed-servers
 283         (cons (assoc server gnus-server-alist) gnus-server-killed-servers))
 284   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 285                                 gnus-server-alist))
 286   (gnus-server-position-point))
 287
 288 (defun gnus-server-yank-server ()
 289   "Yank the previously killed server."
 290   (interactive)
 291   (or gnus-server-killed-servers
 292       (error "No killed servers to be yanked"))
 293   (let ((alist gnus-server-alist)
 294         (server (gnus-server-server-name))
 295         (killed (car gnus-server-killed-servers)))
 296     (if (not server)
 297         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 298       (if (string= server (caar gnus-server-alist))
 299           (setq gnus-server-alist (cons killed gnus-server-alist))
 300         (while (and (cdr alist)
 301                     (not (string= server (caadr alist))))
 302           (setq alist (cdr alist)))
 303         (if alist
 304             (setcdr alist (cons killed (cdr alist)))
 305           (setq gnus-server-alist (list killed)))))
 306     (gnus-server-update-server (car killed))
 307     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 308     (gnus-server-position-point)))
 309
 310 (defun gnus-server-exit ()
 311   "Return to the group buffer."
 312   (interactive)
 313   (kill-buffer (current-buffer))
 314   (switch-to-buffer gnus-group-buffer)
 315   (run-hooks 'gnus-server-exit-hook))
 316
 317 (defun gnus-server-list-servers ()
 318   "List all available servers."
 319   (interactive)
 320   (let ((cur (gnus-server-server-name)))
 321     (gnus-server-prepare)
 322     (if cur (gnus-server-goto-server cur)
 323       (goto-char (point-max))
 324       (forward-line -1))
 325     (gnus-server-position-point)))
 326
 327 (defun gnus-server-set-status (method status)
 328   "Make METHOD have STATUS."
 329   (let ((entry (assoc method gnus-opened-servers)))
 330     (if entry
 331         (setcar (cdr entry) status)
 332       (push (list method status) gnus-opened-servers))))
 333
 334 (defun gnus-opened-servers-remove (method)
 335   "Remove METHOD from the list of opened servers."
 336   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 337                                   gnus-opened-servers)))
 338
 339 (defun gnus-server-open-server (server)
 340   "Force an open of SERVER."
 341   (interactive (list (gnus-server-server-name)))
 342   (let ((method (gnus-server-to-method server)))
 343     (or method (error "No such server: %s" server))
 344     (gnus-server-set-status method 'ok)
 345     (prog1
 346         (or (gnus-open-server method)
 347             (progn (message "Couldn't open %s" server) nil))
 348       (gnus-server-update-server server)
 349       (gnus-server-position-point))))
 350
 351 (defun gnus-server-open-all-servers ()
 352   "Open all servers."
 353   (interactive)
 354   (let ((servers gnus-inserted-opened-servers))
 355     (while servers
 356       (gnus-server-open-server (car (pop servers))))))
 357
 358 (defun gnus-server-close-server (server)
 359   "Close SERVER."
 360   (interactive (list (gnus-server-server-name)))
 361   (let ((method (gnus-server-to-method server)))
 362     (or method (error "No such server: %s" server))
 363     (gnus-server-set-status method 'closed)
 364     (prog1
 365         (gnus-close-server method)
 366       (gnus-server-update-server server)
 367       (gnus-server-position-point))))
 368
 369 (defun gnus-server-close-all-servers ()
 370   "Close all servers."
 371   (interactive)
 372   (let ((servers gnus-inserted-opened-servers))
 373     (while servers
 374       (gnus-server-close-server (car (pop servers))))))
 375
 376 (defun gnus-server-deny-server (server)
 377   "Make sure SERVER will never be attempted opened."
 378   (interactive (list (gnus-server-server-name)))
 379   (let ((method (gnus-server-to-method server)))
 380     (or method (error "No such server: %s" server))
 381     (gnus-server-set-status method 'denied))
 382   (gnus-server-update-server server)
 383   (gnus-server-position-point)
 384   t)
 385
 386 (defun gnus-server-remove-denials ()
 387   "Make all denied servers into closed servers."
 388   (interactive)
 389   (let ((servers gnus-opened-servers))
 390     (while servers
 391       (when (eq (nth 1 (car servers)) 'denied)
 392         (setcar (nthcdr 1 (car servers)) 'closed))
 393       (setq servers (cdr servers))))
 394   (gnus-server-list-servers))
 395
 396 (defun gnus-server-copy-server (from to)
 397   (interactive
 398    (list
 399     (or (gnus-server-server-name)
 400         (error "No server on the current line"))
 401     (read-string "Copy to: ")))
 402   (or from (error "No server on current line"))
 403   (or (and to (not (string= to ""))) (error "No name to copy to"))
 404   (and (assoc to gnus-server-alist) (error "%s already exists" to))
 405   (or (assoc from gnus-server-alist)
 406       (error "%s: no such server" from))
 407   (let ((to-entry (gnus-copy-sequence (assoc from gnus-server-alist))))
 408     (setcar to-entry to)
 409     (setcar (nthcdr 2 to-entry) to)
 410     (setq gnus-server-killed-servers
 411           (cons to-entry gnus-server-killed-servers))
 412     (gnus-server-yank-server)))
 413
 414 (defun gnus-server-add-server (how where)
 415   (interactive
 416    (list (intern (completing-read "Server method: "
 417                                   gnus-valid-select-methods nil t))
 418          (read-string "Server name: ")))
 419   (setq gnus-server-killed-servers
 420         (cons (list where how where) gnus-server-killed-servers))
 421   (gnus-server-yank-server))
 422
 423 (defun gnus-server-goto-server (server)
 424   "Jump to a server line."
 425   (interactive
 426    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 427   (let ((to (text-property-any (point-min) (point-max)
 428                                'gnus-server (intern server))))
 429     (and to
 430          (progn
 431            (goto-char to)
 432            (gnus-server-position-point)))))
 433
 434 (defun gnus-server-edit-server (server)
 435   "Edit the server on the current line."
 436   (interactive (list (gnus-server-server-name)))
 437   (unless server
 438     (error "No server on current line"))
 439   (unless (assoc server gnus-server-alist)
 440     (error "This server can't be edited"))
 441   (let ((info (cdr (assoc server gnus-server-alist))))
 442     (gnus-close-server info)
 443     (gnus-edit-form
 444      info "Editing the server."
 445      `(lambda (form)
 446         (gnus-server-set-info ,server form)
 447         (gnus-server-list-servers)
 448         (gnus-server-position-point)))))
 449
 450 (defun gnus-server-scan-server (server)
 451   "Request a scan from the current server."
 452   (interactive (list (gnus-server-server-name)))
 453   (gnus-message 3 "Scanning %s...done" server)
 454   (gnus-request-scan nil (gnus-server-to-method server))
 455   (gnus-message 3 "Scanning %s...done" server))
 456
 457 (defun gnus-server-read-server (server)
 458   "Browse a server."
 459   (interactive (list (gnus-server-server-name)))
 460   (let ((buf (current-buffer)))
 461     (prog1
 462         (gnus-browse-foreign-server (gnus-server-to-method server) buf)
 463       (save-excursion
 464         (set-buffer buf)
 465         (gnus-server-update-server (gnus-server-server-name))
 466         (gnus-server-position-point)))))
 467
 468 (defun gnus-server-pick-server (e)
 469   (interactive "e")
 470   (mouse-set-point e)
 471   (gnus-server-read-server (gnus-server-server-name)))
 472
 473 \f
 474 ;;;
 475 ;;; Browse Server Mode
 476 ;;;
 477
 478 (defvar gnus-browse-menu-hook nil
 479   "*Hook run after the creation of the browse mode menu.")
 480
 481 (defvar gnus-browse-mode-hook nil)
 482 (defvar gnus-browse-mode-map nil)
 483 (put 'gnus-browse-mode 'mode-class 'special)
 484
 485 (unless gnus-browse-mode-map
 486   (setq gnus-browse-mode-map (make-keymap))
 487   (suppress-keymap gnus-browse-mode-map)
 488
 489   (gnus-define-keys
 490    gnus-browse-mode-map
 491    " " gnus-browse-read-group
 492    "=" gnus-browse-select-group
 493    "n" gnus-browse-next-group
 494    "p" gnus-browse-prev-group
 495    "\177" gnus-browse-prev-group
 496    "N" gnus-browse-next-group
 497    "P" gnus-browse-prev-group
 498    "\M-n" gnus-browse-next-group
 499    "\M-p" gnus-browse-prev-group
 500    "\r" gnus-browse-select-group
 501    "u" gnus-browse-unsubscribe-current-group
 502    "l" gnus-browse-exit
 503    "L" gnus-browse-exit
 504    "q" gnus-browse-exit
 505    "Q" gnus-browse-exit
 506    "\C-c\C-c" gnus-browse-exit
 507    "?" gnus-browse-describe-briefly
 508
 509    "\C-c\C-i" gnus-info-find-node))
 510
 511 (defun gnus-browse-make-menu-bar ()
 512   (gnus-turn-off-edit-menu 'browse)
 513   (unless (boundp 'gnus-browse-menu)
 514     (easy-menu-define
 515      gnus-browse-menu gnus-browse-mode-map ""
 516      '("Browse"
 517        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 518        ["Read" gnus-browse-read-group t]
 519        ["Select" gnus-browse-read-group t]
 520        ["Next" gnus-browse-next-group t]
 521        ["Prev" gnus-browse-next-group t]
 522        ["Exit" gnus-browse-exit t]
 523        ))
 524     (run-hooks 'gnus-browse-menu-hook)))
 525
 526 (defvar gnus-browse-current-method nil)
 527 (defvar gnus-browse-return-buffer nil)
 528
 529 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 530
 531 (defun gnus-browse-foreign-server (method &optional return-buffer)
 532   "Browse the server METHOD."
 533   (setq gnus-browse-current-method method)
 534   (setq gnus-browse-return-buffer return-buffer)
 535   (let ((gnus-select-method method)
 536         groups group)
 537     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 538     (cond
 539      ((not (gnus-check-server method))
 540       (gnus-message
 541        1 "Unable to contact server: %s" (gnus-status-message method))
 542       nil)
 543      ((not (gnus-request-list method))
 544       (gnus-message
 545        1 "Couldn't request list: %s" (gnus-status-message method))
 546       nil)
 547      (t
 548       (get-buffer-create gnus-browse-buffer)
 549       (gnus-add-current-to-buffer-list)
 550       (and gnus-carpal (gnus-carpal-setup-buffer 'browse))
 551       (gnus-configure-windows 'browse)
 552       (buffer-disable-undo (current-buffer))
 553       (let ((buffer-read-only nil))
 554         (erase-buffer))
 555       (gnus-browse-mode)
 556       (setq mode-line-buffer-identification
 557             (list
 558              (format
 559               "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 560       (save-excursion
 561         (set-buffer nntp-server-buffer)
 562         (let ((cur (current-buffer)))
 563           (goto-char (point-min))
 564           (or (string= gnus-ignored-newsgroups "")
 565               (delete-matching-lines gnus-ignored-newsgroups))
 566           (while (re-search-forward
 567                   "\\(^[^ \t]+\\)[ \t]+[0-9]+[ \t]+[0-9]+" nil t)
 568             (goto-char (match-end 1))
 569             (setq groups (cons (cons (match-string 1)
 570                                      (max 0 (- (1+ (read cur)) (read cur))))
 571                                groups)))))
 572       (setq groups (sort groups
 573                          (lambda (l1 l2)
 574                            (string< (car l1) (car l2)))))
 575       (let ((buffer-read-only nil))
 576         (while groups
 577           (setq group (car groups))
 578           (insert
 579            (format "K%7d: %s\n" (cdr group) (car group)))
 580           (setq groups (cdr groups))))
 581       (switch-to-buffer (current-buffer))
 582       (goto-char (point-min))
 583       (gnus-group-position-point)
 584       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 585       t))))
 586
 587 (defun gnus-browse-mode ()
 588   "Major mode for browsing a foreign server.
 589
 590 All normal editing commands are switched off.
 591
 592 \\<gnus-browse-mode-map>
 593 The only things you can do in this buffer is
 594
 595 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 596 The group will be inserted into the group buffer upon exit from this
 597 buffer.
 598
 599 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 600
 601 3) `\\[gnus-browse-exit]' to return to the group buffer."
 602   (interactive)
 603   (kill-all-local-variables)
 604   (when (and menu-bar-mode
 605              (gnus-visual-p 'browse-menu 'menu))
 606     (gnus-browse-make-menu-bar))
 607   (gnus-simplify-mode-line)
 608   (setq major-mode 'gnus-browse-mode)
 609   (setq mode-name "Browse Server")
 610   (setq mode-line-process nil)
 611   (use-local-map gnus-browse-mode-map)
 612   (buffer-disable-undo (current-buffer))
 613   (setq truncate-lines t)
 614   (gnus-set-default-directory)
 615   (setq buffer-read-only t)
 616   (run-hooks 'gnus-browse-mode-hook))
 617
 618 (defun gnus-browse-read-group (&optional no-article)
 619   "Enter the group at the current line."
 620   (interactive)
 621   (let ((group (gnus-browse-group-name)))
 622     (unless (gnus-group-read-ephemeral-group
 623              group gnus-browse-current-method nil
 624              (cons (current-buffer) 'browse))
 625       (error "Couldn't enter %s" group))))
 626
 627 (defun gnus-browse-select-group ()
 628   "Select the current group."
 629   (interactive)
 630   (gnus-browse-read-group 'no))
 631
 632 (defun gnus-browse-next-group (n)
 633   "Go to the next group."
 634   (interactive "p")
 635   (prog1
 636       (forward-line n)
 637     (gnus-group-position-point)))
 638
 639 (defun gnus-browse-prev-group (n)
 640   "Go to the next group."
 641   (interactive "p")
 642   (gnus-browse-next-group (- n)))
 643
 644 (defun gnus-browse-unsubscribe-current-group (arg)
 645   "(Un)subscribe to the next ARG groups."
 646   (interactive "p")
 647   (when (eobp)
 648     (error "No group at current line."))
 649   (let ((ward (if (< arg 0) -1 1))
 650         (arg (abs arg)))
 651     (while (and (> arg 0)
 652                 (not (eobp))
 653                 (gnus-browse-unsubscribe-group)
 654                 (zerop (gnus-browse-next-group ward)))
 655       (decf arg))
 656     (gnus-group-position-point)
 657     (if (/= 0 arg) (gnus-message 7 "No more newsgroups"))
 658     arg))
 659
 660 (defun gnus-browse-group-name ()
 661   (save-excursion
 662     (beginning-of-line)
 663     (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 664       (gnus-group-prefixed-name (match-string 1) gnus-browse-current-method))))
 665
 666 (defun gnus-browse-unsubscribe-group ()
 667   "Toggle subscription of the current group in the browse buffer."
 668   (let ((sub nil)
 669         (buffer-read-only nil)
 670         group)
 671     (save-excursion
 672       (beginning-of-line)
 673       ;; If this group it killed, then we want to subscribe it.
 674       (if (= (following-char) ?K) (setq sub t))
 675       (setq group (gnus-browse-group-name))
 676       ;; Make sure the group has been properly removed before we
 677       ;; subscribe to it.
 678       (gnus-kill-ephemeral-group group)
 679       (delete-char 1)
 680       (if sub
 681           (progn
 682             (gnus-group-change-level
 683              (list t group gnus-level-default-subscribed
 684                    nil nil gnus-browse-current-method)
 685              gnus-level-default-subscribed gnus-level-killed
 686              (and (car (nth 1 gnus-newsrc-alist))
 687                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 688                                 gnus-newsrc-hashtb))
 689              t)
 690             (insert ? ))
 691         (gnus-group-change-level
 692          group gnus-level-killed gnus-level-default-subscribed)
 693         (insert ?K)))
 694     t))
 695
 696 (defun gnus-browse-exit ()
 697   "Quit browsing and return to the group buffer."
 698   (interactive)
 699   (when (eq major-mode 'gnus-browse-mode)
 700     (kill-buffer (current-buffer)))
 701   ;; Insert the newly subscribed groups in the group buffer.
 702   (save-excursion
 703     (set-buffer gnus-group-buffer)
 704     (gnus-group-list-groups nil))
 705   (if gnus-browse-return-buffer
 706       (gnus-configure-windows 'server 'force)
 707     (gnus-configure-windows 'group 'force)))
 708
 709 (defun gnus-browse-describe-briefly ()
 710   "Give a one line description of the group mode commands."
 711   (interactive)
 712   (gnus-message 6
 713                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 714
 715 (provide 'gnus-srvr)
 716
 717 ;;; gnus-srvr.el ends here.