cgit.sxemacs.org Git - gnus/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus  -*- coding: iso-latin-1 -*-
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32
  33 (defcustom gnus-use-correct-string-widths t
  34   "*If non-nil, use correct functions for dealing with wide characters."
  35   :group 'gnus-format
  36   :type 'boolean)
  37
  38 ;;; Internal variables.
  39
  40 (defvar gnus-summary-mark-positions nil)
  41 (defvar gnus-group-mark-positions nil)
  42 (defvar gnus-group-indentation "")
  43
  44 ;; Format specs.  The chunks below are the machine-generated forms
  45 ;; that are to be evaled as the result of the default format strings.
  46 ;; We write them in here to get them byte-compiled.  That way the
  47 ;; default actions will be quite fast, while still retaining the full
  48 ;; flexibility of the user-defined format specs.
  49
  50 ;; First we have lots of dummy defvars to let the compiler know these
  51 ;; are really dynamic variables.
  52
  53 (defvar gnus-tmp-unread)
  54 (defvar gnus-tmp-replied)
  55 (defvar gnus-tmp-score-char)
  56 (defvar gnus-tmp-indentation)
  57 (defvar gnus-tmp-opening-bracket)
  58 (defvar gnus-tmp-lines)
  59 (defvar gnus-tmp-name)
  60 (defvar gnus-tmp-closing-bracket)
  61 (defvar gnus-tmp-subject-or-nil)
  62 (defvar gnus-tmp-subject)
  63 (defvar gnus-tmp-marked)
  64 (defvar gnus-tmp-marked-mark)
  65 (defvar gnus-tmp-subscribed)
  66 (defvar gnus-tmp-process-marked)
  67 (defvar gnus-tmp-number-of-unread)
  68 (defvar gnus-tmp-group-name)
  69 (defvar gnus-tmp-group)
  70 (defvar gnus-tmp-article-number)
  71 (defvar gnus-tmp-unread-and-unselected)
  72 (defvar gnus-tmp-news-method)
  73 (defvar gnus-tmp-news-server)
  74 (defvar gnus-tmp-article-number)
  75 (defvar gnus-mouse-face)
  76 (defvar gnus-mouse-face-prop)
  77
  78 (defun gnus-summary-line-format-spec ()
  79   (insert gnus-tmp-unread gnus-tmp-replied
  80           gnus-tmp-score-char gnus-tmp-indentation)
  81   (gnus-put-text-property
  82    (point)
  83    (progn
  84      (insert
  85       gnus-tmp-opening-bracket
  86       (format "%4d: %-20s"
  87               gnus-tmp-lines
  88               (if (> (length gnus-tmp-name) 20)
  89                   (substring gnus-tmp-name 0 20)
  90                 gnus-tmp-name))
  91       gnus-tmp-closing-bracket)
  92      (point))
  93    gnus-mouse-face-prop gnus-mouse-face)
  94   (insert " " gnus-tmp-subject-or-nil "\n"))
  95
  96 (defvar gnus-summary-line-format-spec
  97   (gnus-byte-code 'gnus-summary-line-format-spec))
  98
  99 (defun gnus-summary-dummy-line-format-spec ()
 100   (insert "*  ")
 101   (gnus-put-text-property
 102    (point)
 103    (progn
 104      (insert ":                          :")
 105      (point))
 106    gnus-mouse-face-prop gnus-mouse-face)
 107   (insert " " gnus-tmp-subject "\n"))
 108
 109 (defvar gnus-summary-dummy-line-format-spec
 110   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 111
 112 (defun gnus-group-line-format-spec ()
 113   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 114           gnus-tmp-process-marked
 115           gnus-group-indentation
 116           (format "%5s: " gnus-tmp-number-of-unread))
 117   (gnus-put-text-property
 118    (point)
 119    (progn
 120      (insert gnus-tmp-group "\n")
 121      (1- (point)))
 122    gnus-mouse-face-prop gnus-mouse-face))
 123 (defvar gnus-group-line-format-spec
 124   (gnus-byte-code 'gnus-group-line-format-spec))
 125
 126 (defvar gnus-format-specs
 127   `((version . ,emacs-version)
 128     (gnus-version . ,(gnus-continuum-version))
 129     (group "%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec)
 130     (summary-dummy "*  %(:                          :%) %S\n"
 131                    ,gnus-summary-dummy-line-format-spec)
 132     (summary "%U\%R\%z\%I\%(%[%4L: %-23,23n%]%) %s\n"
 133              ,gnus-summary-line-format-spec))
 134   "Alist of format specs.")
 135
 136 (defvar gnus-article-mode-line-format-spec nil)
 137 (defvar gnus-summary-mode-line-format-spec nil)
 138 (defvar gnus-group-mode-line-format-spec nil)
 139
 140 ;;; Phew.  All that gruft is over with, fortunately.
 141
 142 ;;;###autoload
 143 (defun gnus-update-format (var)
 144   "Update the format specification near point."
 145   (interactive
 146    (list
 147     (save-excursion
 148       (eval-defun nil)
 149       ;; Find the end of the current word.
 150       (re-search-forward "[ \t\n]" nil t)
 151       ;; Search backward.
 152       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 153         (match-string 1)))))
 154   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 155                               (match-string 1 var))))
 156          (entry (assq type gnus-format-specs))
 157          value spec)
 158     (when entry
 159       (setq gnus-format-specs (delq entry gnus-format-specs)))
 160     (set
 161      (intern (format "%s-spec" var))
 162      (gnus-parse-format (setq value (symbol-value (intern var)))
 163                         (symbol-value (intern (format "%s-alist" var)))
 164                         (not (string-match "mode" var))))
 165     (setq spec (symbol-value (intern (format "%s-spec" var))))
 166     (push (list type value spec) gnus-format-specs)
 167
 168     (pop-to-buffer "*Gnus Format*")
 169     (erase-buffer)
 170     (lisp-interaction-mode)
 171     (insert (pp-to-string spec))))
 172
 173 (defun gnus-update-format-specifications (&optional force &rest types)
 174   "Update all (necessary) format specifications."
 175   ;; Make the indentation array.
 176   ;; See whether all the stored info needs to be flushed.
 177   (when (or force
 178             (not (equal (gnus-continuum-version)
 179                         (cdr (assq 'gnus-version gnus-format-specs))))
 180             (not (equal emacs-version
 181                         (cdr (assq 'version gnus-format-specs)))))
 182     (setq gnus-format-specs nil))
 183
 184   ;; Go through all the formats and see whether they need updating.
 185   (let (new-format entry type val)
 186     (while (setq type (pop types))
 187       ;; Jump to the proper buffer to find out the value of the
 188       ;; variable, if possible.  (It may be buffer-local.)
 189       (save-excursion
 190         (let ((buffer (intern (format "gnus-%s-buffer" type)))
 191               val)
 192           (when (and (boundp buffer)
 193                      (setq val (symbol-value buffer))
 194                      (gnus-buffer-exists-p val))
 195             (set-buffer val))
 196           (setq new-format (symbol-value
 197                             (intern (format "gnus-%s-line-format" type)))))
 198         (setq entry (cdr (assq type gnus-format-specs)))
 199         (if (and (car entry)
 200                  (equal (car entry) new-format))
 201             ;; Use the old format.
 202             (set (intern (format "gnus-%s-line-format-spec" type))
 203                  (cadr entry))
 204           ;; This is a new format.
 205           (setq val
 206                 (if (not (stringp new-format))
 207                     ;; This is a function call or something.
 208                     new-format
 209                   ;; This is a "real" format.
 210                   (gnus-parse-format
 211                    new-format
 212                    (symbol-value
 213                     (intern (format "gnus-%s-line-format-alist" type)))
 214                    (not (string-match "mode$" (symbol-name type))))))
 215           ;; Enter the new format spec into the list.
 216           (if entry
 217               (progn
 218                 (setcar (cdr entry) val)
 219                 (setcar entry new-format))
 220             (push (list type new-format val) gnus-format-specs))
 221           (set (intern (format "gnus-%s-line-format-spec" type)) val)))))
 222
 223   (unless (assq 'version gnus-format-specs)
 224     (push (cons 'version emacs-version) gnus-format-specs)))
 225
 226 (defvar gnus-mouse-face-0 'highlight)
 227 (defvar gnus-mouse-face-1 'highlight)
 228 (defvar gnus-mouse-face-2 'highlight)
 229 (defvar gnus-mouse-face-3 'highlight)
 230 (defvar gnus-mouse-face-4 'highlight)
 231
 232 (defun gnus-mouse-face-function (form type)
 233   `(gnus-put-text-property
 234     (point) (progn ,@form (point))
 235     gnus-mouse-face-prop
 236     ,(if (equal type 0)
 237          'gnus-mouse-face
 238        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 239
 240 (defvar gnus-face-0 'bold)
 241 (defvar gnus-face-1 'italic)
 242 (defvar gnus-face-2 'bold-italic)
 243 (defvar gnus-face-3 'bold)
 244 (defvar gnus-face-4 'bold)
 245
 246 (defun gnus-face-face-function (form type)
 247   `(gnus-add-text-properties
 248     (point) (progn ,@form (point))
 249     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 250
 251 (defun gnus-balloon-face-function (form type)
 252   `(gnus-put-text-property
 253     (point) (progn ,@form (point))
 254     'balloon-help
 255     ,(intern (format "gnus-balloon-face-%d" type))))
 256
 257 (defun gnus-spec-tab (column)
 258   (if (> column 0)
 259       `(insert (make-string (max (- ,column (current-column)) 0) ? ))
 260     `(progn
 261        (if (> (current-column) ,(abs column))
 262            (delete-region (point)
 263                           (- (point) (- (current-column) ,(abs column))))
 264          (insert (make-string (max (- ,(abs column) (current-column)) 0)
 265                               ? ))))))
 266
 267 (defun gnus-correct-length (string)
 268   "Return the correct width of STRING."
 269   (let ((length 0))
 270     (mapcar (lambda (char) (incf length (gnus-char-width char))) string)
 271     length))
 272
 273 (defun gnus-correct-substring (string start &optional end)
 274   (let ((wstart 0)
 275         (wend 0)
 276         (seek 0)
 277         (length (length string)))
 278     ;; Find the start position.
 279     (while (and (< seek length)
 280                 (< wstart start))
 281       (incf wstart (gnus-char-width (aref string seek)))
 282       (incf seek))
 283     (setq wend wstart
 284           wstart seek)
 285     ;; Find the end position.
 286     (while (and (< seek length)
 287                 (or (not end)
 288                     (<= wend end)))
 289       (incf wend (gnus-char-width (aref string seek)))
 290       (incf seek))
 291     (setq wend seek)
 292     (substring string wstart (1- wend))))
 293
 294 (defun gnus-tilde-max-form (el max-width)
 295   "Return a form that limits EL to MAX-WIDTH."
 296   (let ((max (abs max-width)))
 297     (if (symbolp el)
 298         `(if (> (,(if gnus-use-correct-string-widths
 299                       'gnus-correct-length
 300                     'length) ,el)
 301                 ,max)
 302              ,(if (< max-width 0)
 303                   `(,(if gnus-use-correct-string-widths
 304                          'gnus-correct-substring
 305                        'substring)
 306                     ,el (- (,(if gnus-use-correct-string-widths
 307                                  'gnus-correct-length
 308                                'length)
 309                             el) ,max))
 310                 `(,(if gnus-use-correct-string-widths
 311                        'gnus-correct-substring
 312                      'substring)
 313                   ,el 0 ,max))
 314            ,el)
 315       `(let ((val (eval ,el)))
 316          (if (> (,(if gnus-use-correct-string-widths
 317                       'gnus-correct-length
 318                     'length) val) ,max)
 319              ,(if (< max-width 0)
 320                   `(,(if gnus-use-correct-string-widths
 321                          'gnus-correct-substring
 322                        'substring)
 323                     val (- (,(if gnus-use-correct-string-widths
 324                                  'gnus-correct-length
 325                                'length) val) ,max))
 326                 `(,(if gnus-use-correct-string-widths
 327                        'gnus-correct-substring
 328                      'substring)
 329                   val 0 ,max))
 330            val)))))
 331
 332 (defun gnus-tilde-cut-form (el cut-width)
 333   "Return a form that cuts CUT-WIDTH off of EL."
 334   (let ((cut (abs cut-width)))
 335     (if (symbolp el)
 336         `(if (> (,(if gnus-use-correct-string-widths
 337                       'gnus-correct-length
 338                     'length) ,el) ,cut)
 339              ,(if (< cut-width 0)
 340                   `(,(if gnus-use-correct-string-widths
 341                          'gnus-correct-substring
 342                        'substring) ,el 0
 343                        (- (,(if gnus-use-correct-string-widths
 344                                 'gnus-correct-length
 345                               'length) el) ,cut))
 346                 `(,(if gnus-use-correct-string-widths
 347                        'gnus-correct-substring
 348                      'substring) ,el ,cut))
 349            ,el)
 350       `(let ((val (eval ,el)))
 351          (if (> (,(if gnus-use-correct-string-widths
 352                       'gnus-correct-length
 353                     'length) val) ,cut)
 354              ,(if (< cut-width 0)
 355                   `(,(if gnus-use-correct-string-widths
 356                          'gnus-correct-substring
 357                        'substring) val 0
 358                        (- (,(if gnus-use-correct-string-widths
 359                                 'gnus-correct-length
 360                               'length) val) ,cut))
 361                 `(,(if gnus-use-correct-string-widths
 362                        'gnus-correct-substring
 363                      'substring) val ,cut))
 364            val)))))
 365
 366 (defun gnus-tilde-ignore-form (el ignore-value)
 367   "Return a form that is blank when EL is IGNORE-VALUE."
 368   (if (symbolp el)
 369       `(if (equal ,el ,ignore-value)
 370            "" ,el)
 371     `(let ((val (eval ,el)))
 372        (if (equal val ,ignore-value)
 373            "" val))))
 374
 375 (defun gnus-parse-format (format spec-alist &optional insert)
 376   ;; This function parses the FORMAT string with the help of the
 377   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 378   ;; string.  If the FORMAT string contains the specifiers %( and %)
 379   ;; the text between them will have the mouse-face text property.
 380   ;; If the FORMAT string contains the specifiers %[ and %], the text between
 381   ;; them will have the balloon-help text property.
 382   (if (string-match
 383        "\\`\\(.*\\)%[0-9]?[{(«]\\(.*\\)%[0-9]?[»})]\\(.*\n?\\)\\'"
 384        format)
 385       (gnus-parse-complex-format format spec-alist)
 386     ;; This is a simple format.
 387     (gnus-parse-simple-format format spec-alist insert)))
 388
 389 (defun gnus-parse-complex-format (format spec-alist)
 390   (save-excursion
 391     (gnus-set-work-buffer)
 392     (insert format)
 393     (goto-char (point-min))
 394     (while (re-search-forward "\"" nil t)
 395       (replace-match "\\\"" nil t))
 396     (goto-char (point-min))
 397     (insert "(\"")
 398     ;; Convert all font specs into font spec lists.
 399     (while (re-search-forward "%\\([0-9]+\\)?\\([«»{}()]\\)" nil t)
 400       (let ((number (if (match-beginning 1)
 401                         (match-string 1) "0"))
 402             (delim (aref (match-string 2) 0)))
 403         (if (or (= delim ?\()
 404                 (= delim ?\{)
 405                 (= delim ?\«))
 406             (replace-match (concat "\"("
 407                                    (cond ((= delim ?\() "mouse")
 408                                          ((= delim ?\{) "face")
 409                                          (t "balloon"))
 410                                    " " number " \"")
 411                            t t)
 412           (replace-match "\")\""))))
 413     (goto-char (point-max))
 414     (insert "\")")
 415     ;; Convert point position commands.
 416     (goto-char (point-min))
 417     (while (re-search-forward "%\\([-0-9]+\\)?C" nil t)
 418       (replace-match "\"(point)\"" t t))
 419     ;; Convert TAB commands.
 420     (goto-char (point-min))
 421     (while (re-search-forward "%\\([-0-9]+\\)=" nil t)
 422       (replace-match (format "\"(tab %s)\"" (match-string 1)) t t))
 423     ;; Convert the buffer into the spec.
 424     (goto-char (point-min))
 425     (let ((form (read (current-buffer))))
 426       ;; If the first element is '(point), we just remove it.
 427       (when (equal (car form) '(point))
 428         (pop form))
 429       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 430
 431 (defun gnus-complex-form-to-spec (form spec-alist)
 432   (delq nil
 433         (mapcar
 434          (lambda (sform)
 435            (cond
 436             ((stringp sform)
 437              (gnus-parse-simple-format sform spec-alist t))
 438             ((eq (car sform) 'point)
 439              `(gnus-put-text-property (1- (point)) (point) 'gnus-position t))
 440             ((eq (car sform) 'tab)
 441              (gnus-spec-tab (cadr sform)))
 442             (t
 443              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 444                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 445                       (nth 1 sform)))))
 446          form)))
 447
 448 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 449   ;; This function parses the FORMAT string with the help of the
 450   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 451   ;; string.
 452   (let ((max-width 0)
 453         spec flist fstring elem result dontinsert user-defined
 454         type value pad-width spec-beg cut-width ignore-value
 455         tilde-form tilde elem-type)
 456     (save-excursion
 457       (gnus-set-work-buffer)
 458       (insert format)
 459       (goto-char (point-min))
 460       (while (re-search-forward "%" nil t)
 461         (setq user-defined nil
 462               spec-beg nil
 463               pad-width nil
 464               max-width nil
 465               cut-width nil
 466               ignore-value nil
 467               tilde-form nil)
 468         (setq spec-beg (1- (point)))
 469
 470         ;; Parse this spec fully.
 471         (while
 472             (cond
 473              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 474               (setq pad-width (string-to-number (match-string 1)))
 475               (when (match-beginning 2)
 476                 (setq max-width (string-to-number (buffer-substring
 477                                                    (1+ (match-beginning 2))
 478                                                    (match-end 2)))))
 479               (goto-char (match-end 0)))
 480              ((looking-at "~")
 481               (forward-char 1)
 482               (setq tilde (read (current-buffer))
 483                     type (car tilde)
 484                     value (cadr tilde))
 485               (cond
 486                ((memq type '(pad pad-left))
 487                 (setq pad-width value))
 488                ((eq type 'pad-right)
 489                 (setq pad-width (- value)))
 490                ((memq type '(max-right max))
 491                 (setq max-width value))
 492                ((eq type 'max-left)
 493                 (setq max-width (- value)))
 494                ((memq type '(cut cut-left))
 495                 (setq cut-width value))
 496                ((eq type 'cut-right)
 497                 (setq cut-width (- value)))
 498                ((eq type 'ignore)
 499                 (setq ignore-value
 500                       (if (stringp value) value (format "%s" value))))
 501                ((eq type 'form)
 502                 (setq tilde-form value))
 503                (t
 504                 (error "Unknown tilde type: %s" tilde)))
 505               t)
 506              (t
 507               nil)))
 508         ;; User-defined spec -- find the spec name.
 509         (when (eq (setq spec (char-after)) ?u)
 510           (forward-char 1)
 511           (setq user-defined (char-after)))
 512         (forward-char 1)
 513         (delete-region spec-beg (point))
 514
 515         ;; Now we have all the relevant data on this spec, so
 516         ;; we start doing stuff.
 517         (insert "%")
 518         (if (eq spec ?%)
 519             ;; "%%" just results in a "%".
 520             (insert "%")
 521           (cond
 522            ;; Do tilde forms.
 523            ((eq spec ?@)
 524             (setq elem (list tilde-form ?s)))
 525            ;; Treat user defined format specifiers specially.
 526            (user-defined
 527             (setq elem
 528                   (list
 529                    (list (intern (format "gnus-user-format-function-%c"
 530                                          user-defined))
 531                          'gnus-tmp-header)
 532                    ?s)))
 533            ;; Find the specification from `spec-alist'.
 534            ((setq elem (cdr (assq spec spec-alist))))
 535            (t
 536             (setq elem '("*" ?s))))
 537           (setq elem-type (cadr elem))
 538           ;; Insert the new format elements.
 539           (when pad-width
 540             (insert (number-to-string pad-width)))
 541           ;; Create the form to be evaled.
 542           (if (or max-width cut-width ignore-value)
 543               (progn
 544                 (insert ?s)
 545                 (let ((el (car elem)))
 546                   (cond ((= (cadr elem) ?c)
 547                          (setq el (list 'char-to-string el)))
 548                         ((= (cadr elem) ?d)
 549                          (setq el (list 'int-to-string el))))
 550                   (when ignore-value
 551                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 552                   (when cut-width
 553                     (setq el (gnus-tilde-cut-form el cut-width)))
 554                   (when max-width
 555                     (setq el (gnus-tilde-max-form el max-width)))
 556                   (push el flist)))
 557             (insert elem-type)
 558             (push (car elem) flist))))
 559       (setq fstring (buffer-string)))
 560
 561     ;; Do some postprocessing to increase efficiency.
 562     (setq
 563      result
 564      (cond
 565       ;; Emptyness.
 566       ((string= fstring "")
 567        nil)
 568       ;; Not a format string.
 569       ((not (string-match "%" fstring))
 570        (list fstring))
 571       ;; A format string with just a single string spec.
 572       ((string= fstring "%s")
 573        (list (car flist)))
 574       ;; A single character.
 575       ((string= fstring "%c")
 576        (list (car flist)))
 577       ;; A single number.
 578       ((string= fstring "%d")
 579        (setq dontinsert)
 580        (if insert
 581            (list `(princ ,(car flist)))
 582          (list `(int-to-string ,(car flist)))))
 583       ;; Just lots of chars and strings.
 584       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 585        (nreverse flist))
 586       ;; A single string spec at the beginning of the spec.
 587       ((string-match "\\`%[sc][^%]+\\'" fstring)
 588        (list (car flist) (substring fstring 2)))
 589       ;; A single string spec in the middle of the spec.
 590       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 591        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 592       ;; A single string spec in the end of the spec.
 593       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 594        (list (match-string 1 fstring) (car flist)))
 595       ;; A more complex spec.
 596       (t
 597        (list (cons 'format (cons fstring (nreverse flist)))))))
 598
 599     (if insert
 600         (when result
 601           (if dontinsert
 602               result
 603             (cons 'insert result)))
 604       (cond ((stringp result)
 605              result)
 606             ((consp result)
 607              (cons 'concat result))
 608             (t "")))))
 609
 610 (defun gnus-eval-format (format &optional alist props)
 611   "Eval the format variable FORMAT, using ALIST.
 612 If PROPS, insert the result."
 613   (let ((form (gnus-parse-format format alist props)))
 614     (if props
 615         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 616       (eval form))))
 617
 618 (defun gnus-compile ()
 619   "Byte-compile the user-defined format specs."
 620   (interactive)
 621   (require 'bytecomp)
 622   (let ((entries gnus-format-specs)
 623         (byte-compile-warnings '(unresolved callargs redefine))
 624         entry gnus-tmp-func)
 625     (save-excursion
 626       (gnus-message 7 "Compiling format specs...")
 627
 628       (while entries
 629         (setq entry (pop entries))
 630         (if (eq (car entry) 'version)
 631             (setq gnus-format-specs (delq entry gnus-format-specs))
 632           (let ((form (caddr entry)))
 633             (when (and (listp form)
 634                        ;; Under GNU Emacs, it's (byte-code ...)
 635                        (not (eq 'byte-code (car form)))
 636                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 637                        (not (and (eq 'funcall (car form))
 638                                  (byte-code-function-p (cadr form)))))
 639               (defalias 'gnus-tmp-func `(lambda () ,form))
 640               (byte-compile 'gnus-tmp-func)
 641               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 642
 643       (push (cons 'version emacs-version) gnus-format-specs)
 644       ;; Mark the .newsrc.eld file as "dirty".
 645       (gnus-dribble-touch)
 646       (gnus-message 7 "Compiling user specs...done"))))
 647
 648 (defun gnus-set-format (type &optional insertable)
 649   (set (intern (format "gnus-%s-line-format-spec" type))
 650        (gnus-parse-format
 651         (symbol-value (intern (format "gnus-%s-line-format" type)))
 652         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 653         insertable)))
 654
 655 (provide 'gnus-spec)
 656
 657 ;; Local Variables:
 658 ;; coding: iso-8859-1
 659 ;; End:
 660
 661 ;;; gnus-spec.el ends here