cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (eval-when-compile (require 'cl))
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 ;;; Internal variables.
  44
  45 (defvar gnus-pick-mode-map nil)
  46
  47 (unless gnus-pick-mode-map
  48   (setq gnus-pick-mode-map (make-sparse-keymap))
  49
  50   (gnus-define-keys
  51    gnus-pick-mode-map
  52    "t" gnus-uu-mark-thread
  53    "T" gnus-uu-unmark-thread
  54    " " gnus-summary-mark-as-processable
  55    "u" gnus-summary-unmark-as-processable
  56    "U" gnus-summary-unmark-all-processable
  57    "v" gnus-uu-mark-over
  58    "r" gnus-uu-mark-region
  59    "R" gnus-uu-unmark-region
  60    "e" gnus-uu-mark-by-regexp
  61    "E" gnus-uu-mark-by-regexp
  62    "b" gnus-uu-mark-buffer
  63    "B" gnus-uu-unmark-buffer
  64    "\r" gnus-pick-start-reading))
  65
  66 (defun gnus-pick-make-menu-bar ()
  67   (unless (boundp 'gnus-pick-menu)
  68     (easy-menu-define
  69      gnus-pick-menu gnus-pick-mode-map ""
  70      '("Pick"
  71        ("Pick"
  72         ["Article" gnus-summary-mark-as-processable t]
  73         ["Thread" gnus-uu-mark-thread t]
  74         ["Region" gnus-uu-mark-region t]
  75         ["Regexp" gnus-uu-mark-regexp t]
  76         ["Buffer" gnus-uu-mark-buffer t])
  77        ("Unpick"
  78         ["Article" gnus-summary-unmark-as-processable t]
  79         ["Thread" gnus-uu-unmark-thread t]
  80         ["Region" gnus-uu-unmark-region t]
  81         ["Regexp" gnus-uu-unmark-regexp t]
  82         ["Buffer" gnus-uu-unmark-buffer t])
  83        ["Start reading" gnus-pick-start-reading t]
  84        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  85
  86 (defun gnus-pick-mode (&optional arg)
  87   "Minor mode for providing a pick-and-read interface in Gnus summary buffers."
  88   (interactive "P")
  89   (when (eq major-mode 'gnus-summary-mode)
  90     (make-local-variable 'gnus-pick-mode)
  91     (setq gnus-pick-mode
  92           (if (null arg) (not gnus-pick-mode)
  93             (> (prefix-numeric-value arg) 0)))
  94     (when gnus-pick-mode
  95       ;; Make sure that we don't select any articles upon group entry.
  96       (make-local-variable 'gnus-auto-select-first)
  97       (setq gnus-auto-select-first nil)
  98       ;; Set up the menu.
  99       (when (and menu-bar-mode
 100                  (gnus-visual-p 'pick-menu 'menu))
 101         (gnus-pick-make-menu-bar))
 102       (unless (assq 'gnus-pick-mode minor-mode-alist)
 103         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 104       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 105         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 106               minor-mode-map-alist))
 107       (run-hooks 'gnus-pick-mode-hook))))
 108
 109 (defun gnus-pick-start-reading (&optional catch-up)
 110   "Start reading the picked articles.
 111 If given a prefix, mark all unpicked articles as read."
 112   (interactive "P")
 113   (unless gnus-newsgroup-processable
 114     (error "No articles have been picked"))
 115   (gnus-summary-limit-to-articles nil)
 116   (when catch-up
 117     (gnus-summary-limit-mark-excluded-as-read))
 118   (gnus-configure-windows (if gnus-pick-display-summary 'summary 'pick) t))
 119
 120
 121 ;;;
 122 ;;; gnus-binary-mode
 123 ;;;
 124
 125 (defvar gnus-binary-mode nil
 126   "Minor mode for provind a binary group interface in Gnus summary buffers.")
 127
 128 (defvar gnus-binary-mode-hook nil
 129   "Hook run in summary binary mode buffers.")
 130
 131 (defvar gnus-binary-mode-map nil)
 132
 133 (unless gnus-binary-mode-map
 134   (setq gnus-binary-mode-map (make-sparse-keymap))
 135
 136   (gnus-define-keys
 137    gnus-binary-mode-map
 138    "g" gnus-binary-show-article))
 139
 140 (defun gnus-binary-make-menu-bar ()
 141   (unless (boundp 'gnus-binary-menu)
 142     (easy-menu-define
 143      gnus-binary-menu gnus-binary-mode-map ""
 144      '("Pick"
 145        ["Switch binary mode off" gnus-binary-mode t]))))
 146
 147 (defun gnus-binary-mode (&optional arg)
 148   "Minor mode for providing a binary group interface in Gnus summary buffers."
 149   (interactive "P")
 150   (when (eq major-mode 'gnus-summary-mode)
 151     (make-local-variable 'gnus-binary-mode)
 152     (setq gnus-binary-mode
 153           (if (null arg) (not gnus-binary-mode)
 154             (> (prefix-numeric-value arg) 0)))
 155     (when gnus-binary-mode
 156       ;; Make sure that we don't select any articles upon group entry.
 157       (make-local-variable 'gnus-auto-select-first)
 158       (setq gnus-auto-select-first nil)
 159       (make-local-variable 'gnus-summary-display-article-function)
 160       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 161       ;; Set up the menu.
 162       (when (and menu-bar-mode
 163                  (gnus-visual-p 'binary-menu 'menu))
 164         (gnus-binary-make-menu-bar))
 165       (unless (assq 'gnus-binary-mode minor-mode-alist)
 166         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 167       (unless (assq 'gnus-topic-mode minor-mode-map-alist)
 168         (push (cons 'gnus-topic-mode gnus-binary-mode-map)
 169               minor-mode-map-alist))
 170       (run-hooks 'gnus-binary-mode-hook))))
 171
 172 (defun gnus-binary-display-article (article &optional all-header)
 173   "Run ARTICLE through the binary decode functions."
 174   (when (gnus-summary-goto-subject article)
 175     (let ((gnus-view-pseudos 'automatic))
 176       (gnus-uu-decode-uu))))
 177
 178 (defun gnus-binary-show-article (&optional arg)
 179   "Bypass the binary functions and show the article."
 180   (interactive "P")
 181   (let (gnus-summary-display-article-function)
 182     (gnus-summary-show-article arg)))
 183
 184 ;;;
 185 ;;; gnus-tree-mode
 186 ;;;
 187
 188 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 189   "Format of tree elements.")
 190
 191 (defvar gnus-tree-minimize-window t
 192   "If non-nil, minimize the tree buffer window.
 193 If a number, never let the tree buffer grow taller than that number of
 194 lines.")
 195
 196 (defvar gnus-selected-tree-face 'modeline
 197   "*Face used for highlighting selected articles in the thread tree.")
 198
 199 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\))
 200                              (?\{ . ?\}) (?< . ?>))
 201   "Brackets used in tree nodes.")
 202
 203 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 204   "Charaters used to connect parents with children.")
 205
 206 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 207   "*The format specification for the tree mode line.")
 208
 209 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 210   "*Function for generating a thread tree.
 211 Two predefined functions are available:
 212 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 213
 214 (defvar gnus-tree-mode-hook nil
 215   "*Hook run in tree mode buffers.")
 216
 217 (defvar gnus-tree-buffer "*Tree*"
 218   "Buffer where Gnus thread trees are displayed.")
 219
 220 ;;; Internal variables.
 221
 222 (defvar gnus-tree-line-format-alist
 223   `((?n gnus-tmp-name ?s)
 224     (?f gnus-tmp-from ?s)
 225     (?N gnus-tmp-number ?d)
 226     (?\[ gnus-tmp-open-bracket ?c)
 227     (?\] gnus-tmp-close-bracket ?c)
 228     (?s gnus-tmp-subject ?s)))
 229
 230 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 231
 232 (defvar gnus-tree-mode-line-format-spec nil)
 233 (defvar gnus-tree-line-format-spec nil)
 234
 235 (defvar gnus-tree-node-length nil)
 236 (defvar gnus-selected-tree-overlay nil)
 237
 238 (defvar gnus-tree-displayed-thread nil)
 239
 240 (defvar gnus-tree-mode-map nil)
 241 (put 'gnus-tree-mode 'mode-class 'special)
 242
 243 (unless gnus-tree-mode-map
 244   (setq gnus-tree-mode-map (make-keymap))
 245   (suppress-keymap gnus-tree-mode-map)
 246   (gnus-define-keys
 247    gnus-tree-mode-map
 248    "\r" gnus-tree-select-article
 249    gnus-mouse-2 gnus-tree-pick-article
 250    "\C-?" gnus-tree-read-summary-keys)
 251
 252   (substitute-key-definition
 253    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 254
 255 (defun gnus-tree-make-menu-bar ()
 256   )
 257
 258 (defun gnus-tree-mode ()
 259   "Major mode for displaying thread trees."
 260   (interactive)
 261   (setq gnus-tree-mode-line-format-spec
 262         (gnus-parse-format gnus-tree-mode-line-format
 263                            gnus-summary-mode-line-format-alist))
 264   (setq gnus-tree-line-format-spec
 265         (gnus-parse-format gnus-tree-line-format
 266                            gnus-tree-line-format-alist t))
 267   (when (and menu-bar-mode
 268              (gnus-visual-p 'tree-menu 'menu))
 269     (gnus-tree-make-menu-bar))
 270   (kill-all-local-variables)
 271   (gnus-simplify-mode-line)
 272   (setq mode-name "Tree")
 273   (setq major-mode 'gnus-tree-mode)
 274   (use-local-map gnus-tree-mode-map)
 275   (buffer-disable-undo (current-buffer))
 276   (setq buffer-read-only t)
 277   (setq truncate-lines t)
 278   (save-excursion
 279     (gnus-set-work-buffer)
 280     (gnus-tree-node-insert (make-mail-header "") nil)
 281     (setq gnus-tree-node-length (1- (point))))
 282   (run-hooks 'gnus-tree-mode-hook))
 283
 284 (defun gnus-tree-read-summary-keys (&optional arg)
 285   "Read a summary buffer key sequence and execute it."
 286   (interactive "P")
 287   (let ((buf (current-buffer))
 288         win)
 289     (gnus-article-read-summary-keys arg nil t)
 290     (when (setq win (get-buffer-window buf))
 291       (select-window win)
 292       (when gnus-selected-tree-overlay
 293         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 294       (gnus-tree-minimize))))
 295
 296 (defun gnus-tree-select-article (article)
 297   "Select the article under point, if any."
 298   (interactive (list (gnus-tree-article-number)))
 299   (let ((buf (current-buffer)))
 300     (when article
 301       (save-excursion
 302         (set-buffer gnus-summary-buffer)
 303         (gnus-summary-goto-article article))
 304       (select-window (get-buffer-window buf)))))
 305
 306 (defun gnus-tree-pick-article (e)
 307   "Select the article under the mouse pointer."
 308   (interactive "e")
 309   (mouse-set-point e)
 310   (gnus-tree-select-article (gnus-tree-article-number)))
 311
 312 (defun gnus-tree-article-number ()
 313   (get-text-property (point) 'gnus-number))
 314
 315 (defun gnus-tree-article-region (article)
 316   "Return a cons with BEG and END of the article region."
 317   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 318     (when pos
 319       (cons pos (next-single-property-change pos 'gnus-number)))))
 320
 321 (defun gnus-tree-goto-article (article)
 322   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 323     (when pos
 324       (goto-char pos))))
 325
 326 (defun gnus-tree-recenter ()
 327   "Center point in the tree window."
 328   (let ((selected (selected-window))
 329         (tree-window (get-buffer-window gnus-tree-buffer t)))
 330     (when tree-window
 331       (select-window tree-window)
 332       (when gnus-selected-tree-overlay
 333         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 334       (let* ((top (cond ((< (window-height) 4) 0)
 335                         ((< (window-height) 7) 1)
 336                         (t 2)))
 337              (height (1- (window-height)))
 338              (bottom (save-excursion (goto-char (point-max))
 339                                      (forward-line (- height))
 340                                      (point))))
 341         ;; Set the window start to either `bottom', which is the biggest
 342         ;; possible valid number, or the second line from the top,
 343         ;; whichever is the least.
 344         (set-window-start
 345          tree-window (min bottom (save-excursion
 346                                    (forward-line (- top)) (point)))))
 347       (select-window selected))))
 348
 349 (defun gnus-get-tree-buffer ()
 350   "Return the tree buffer properly initialized."
 351   (save-excursion
 352     (set-buffer (get-buffer-create gnus-tree-buffer))
 353     (unless (eq major-mode 'gnus-tree-mode)
 354       (gnus-add-current-to-buffer-list)
 355       (gnus-tree-mode))
 356     (current-buffer)))
 357
 358 (defun gnus-tree-minimize ()
 359   (when (and gnus-tree-minimize-window
 360              (not (one-window-p)))
 361     (let* ((window-min-height 2)
 362            (height (count-lines (point-min) (point-max)))
 363            (min (max (1- window-min-height) height))
 364            (tot (if (numberp gnus-tree-minimize-window)
 365                     (min gnus-tree-minimize-window min)
 366                   min))
 367            (win (get-buffer-window (current-buffer)))
 368            (wh (and win (1- (window-height win)))))
 369       (when (and win
 370                  (not (eq tot wh)))
 371         (let ((selected (selected-window)))
 372           (select-window win)
 373           (enlarge-window (- tot wh))
 374           (select-window selected))))))
 375
 376 ;;; Generating the tree.
 377
 378 (defun gnus-tree-node-insert (header sparse &optional adopted)
 379   (let* ((dummy (stringp header))
 380          (header (if (vectorp header) header
 381                    (progn
 382                      (setq header (make-mail-header "*****"))
 383                      (mail-header-set-number header 0)
 384                      (mail-header-set-lines header 0)
 385                      (mail-header-set-chars header 0)
 386                      header)))
 387          (gnus-tmp-from (mail-header-from header))
 388          (gnus-tmp-subject (mail-header-subject header))
 389          (gnus-tmp-number (mail-header-number header))
 390          (gnus-tmp-name
 391           (cond
 392            ((string-match "(.+)" gnus-tmp-from)
 393             (substring gnus-tmp-from
 394                        (1+ (match-beginning 0)) (1- (match-end 0))))
 395            ((string-match "<[^>]+> *$" gnus-tmp-from)
 396             (let ((beg (match-beginning 0)))
 397               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 398                        (substring gnus-tmp-from (1+ (match-beginning 0))
 399                                   (1- (match-end 0))))
 400                   (substring gnus-tmp-from 0 beg))))
 401            ((memq gnus-tmp-number sparse)
 402             "***")
 403            (t gnus-tmp-from)))
 404          (gnus-tmp-open-bracket
 405           (cond ((memq gnus-tmp-number sparse)
 406                  (caadr gnus-tree-brackets))
 407                 (dummy (caaddr gnus-tree-brackets))
 408                 (adopted (car (nth 3 gnus-tree-brackets)))
 409                 (t (caar gnus-tree-brackets))))
 410          (gnus-tmp-close-bracket
 411           (cond ((memq gnus-tmp-number sparse)
 412                  (cdadr gnus-tree-brackets))
 413                 (adopted (cdr (nth 3 gnus-tree-brackets)))
 414                 (dummy
 415                  (cdaddr gnus-tree-brackets))
 416                 (t (cdar gnus-tree-brackets))))
 417          (buffer-read-only nil)
 418          beg end)
 419     (add-text-properties
 420      (setq beg (point))
 421      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 422      (list 'gnus-number gnus-tmp-number))
 423     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 424       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 425
 426 (defun gnus-tree-highlight-node (article beg end)
 427   "Highlight current line according to `gnus-summary-highlight'."
 428   (let ((list gnus-summary-highlight)
 429         face)
 430     (save-excursion
 431       (set-buffer gnus-summary-buffer)
 432       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 433                         gnus-summary-default-score 0))
 434              (default gnus-summary-default-score)
 435              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 436         ;; Eval the cars of the lists until we find a match.
 437         (while (and list
 438                     (not (eval (caar list))))
 439           (setq list (cdr list)))))
 440     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 441       (put-text-property
 442        beg end 'face
 443        (if (boundp face) (symbol-value face) face)))))
 444
 445 (defun gnus-tree-indent (level)
 446   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 447
 448 (defvar gnus-tmp-limit)
 449 (defvar gnus-tmp-sparse)
 450 (defvar gnus-tmp-indent)
 451
 452 (defun gnus-generate-tree (thread)
 453   "Generate a thread tree for THREAD."
 454   (save-excursion
 455     (set-buffer (gnus-get-tree-buffer))
 456     (let ((buffer-read-only nil)
 457           (gnus-tmp-indent 0))
 458       (erase-buffer)
 459       (funcall gnus-generate-tree-function thread 0)
 460       (gnus-set-mode-line 'tree)
 461       (goto-char (point-min))
 462       (gnus-tree-minimize)
 463       (gnus-tree-recenter)
 464       (let ((selected (selected-window)))
 465         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 466           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 467           (gnus-horizontal-recenter)
 468           (select-window selected))))))
 469
 470 (defun gnus-generate-horizontal-tree (thread level &optional dummyp adopted)
 471   "Generate a horizontal tree."
 472   (let* ((dummy (stringp (car thread)))
 473          (do (or dummy
 474                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 475          col beg)
 476     (if (not do)
 477         ;; We don't want this article.
 478         (setq thread (cdr thread))
 479       (if (not (bolp))
 480           ;; Not the first article on the line, so we insert a "-".
 481           (insert (car gnus-tree-parent-child-edges))
 482         ;; If the level isn't zero, then we insert some indentation.
 483         (unless (zerop level)
 484           (gnus-tree-indent level)
 485           (insert (cadr gnus-tree-parent-child-edges))
 486           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 487           ;; Draw "|" lines upwards.
 488           (while (progn
 489                    (forward-line -1)
 490                    (forward-char col)
 491                    (= (following-char) ? ))
 492             (delete-char 1)
 493             (insert (caddr gnus-tree-parent-child-edges)))
 494           (goto-char beg)))
 495       (setq dummyp nil)
 496       ;; Insert the article node.
 497       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted))
 498     (if (null thread)
 499         ;; End of the thread, so we go to the next line.
 500         (unless (bolp)
 501           (insert "\n"))
 502       ;; Recurse downwards in all children of this article.
 503       (while thread
 504         (gnus-generate-horizontal-tree
 505          (pop thread) (if do (1+ level) level)
 506          (or dummyp dummy) dummy)))))
 507
 508 (defsubst gnus-tree-indent-vertical ()
 509   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 510                 (- (point) (gnus-point-at-bol)))))
 511     (when (> len 0)
 512       (insert (make-string len ? )))))
 513
 514 (defsubst gnus-tree-forward-line (n)
 515   (while (>= (decf n) 0)
 516     (unless (zerop (forward-line 1))
 517       (end-of-line)
 518       (insert "\n")))
 519   (end-of-line))
 520
 521 (defun gnus-generate-vertical-tree (thread level &optional dummyp adopted)
 522   "Generate a vertical tree."
 523   (let* ((dummy (stringp (car thread)))
 524          (do (or dummy
 525                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 526          col beg)
 527     (if (not do)
 528         ;; We don't want this article.
 529         (setq thread (cdr thread))
 530       (if (not (save-excursion (beginning-of-line) (bobp)))
 531           ;; Not the first article on the line, so we insert a "-".
 532           (progn
 533             (gnus-tree-indent-vertical)
 534             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 535             (insert (caddr gnus-tree-parent-child-edges))
 536             (gnus-tree-forward-line 1))
 537         ;; If the level isn't zero, then we insert some indentation.
 538         (unless (zerop gnus-tmp-indent)
 539           (gnus-tree-forward-line (1- (* 2 level)))
 540           (gnus-tree-indent-vertical)
 541           (delete-char -1)
 542           (insert (cadr gnus-tree-parent-child-edges))
 543           (setq beg (point))
 544           ;; Draw "-" lines leftwards.
 545           (while (progn
 546                    (forward-char -2)
 547                    (= (following-char) ? ))
 548             (delete-char 1)
 549             (insert (car gnus-tree-parent-child-edges)))
 550           (goto-char beg)
 551           (gnus-tree-forward-line 1)))
 552       (setq dummyp nil)
 553       ;; Insert the article node.
 554       (gnus-tree-indent-vertical)
 555       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted)
 556       (gnus-tree-forward-line 1))
 557     (if (null thread)
 558         ;; End of the thread, so we go to the next line.
 559         (progn
 560           (goto-char (point-min))
 561           (end-of-line)
 562           (incf gnus-tmp-indent))
 563       ;; Recurse downwards in all children of this article.
 564       (while thread
 565         (gnus-generate-vertical-tree
 566          (pop thread) (if do (1+ level) level)
 567          (or dummyp dummy) dummy)))))
 568
 569 ;;; Interface functions.
 570
 571 (defun gnus-possibly-generate-tree (article &optional force)
 572   "Generate the thread tree for ARTICLE if it isn't displayed already."
 573   (when (save-excursion
 574           (set-buffer gnus-summary-buffer)
 575           (and gnus-use-trees
 576                (vectorp (gnus-summary-article-header article))))
 577     (save-excursion
 578       (let ((top (save-excursion
 579                    (set-buffer gnus-summary-buffer)
 580                    (gnus-cut-thread
 581                     (gnus-remove-thread
 582                      (mail-header-id
 583                       (gnus-summary-article-header article)) t))))
 584             (gnus-tmp-limit gnus-newsgroup-limit)
 585             (gnus-tmp-sparse gnus-newsgroup-sparse))
 586         (when (or force
 587                   (not (eq top gnus-tree-displayed-thread)))
 588           (gnus-generate-tree top)
 589           (setq gnus-tree-displayed-thread top))))))
 590
 591 (defun gnus-tree-open (group)
 592   (gnus-get-tree-buffer))
 593
 594 (defun gnus-tree-close (group)
 595   ;(gnus-kill-buffer gnus-tree-buffer)
 596   )
 597
 598 (defun gnus-highlight-selected-tree (article)
 599   "Highlight the selected article in the tree."
 600   (let ((buf (current-buffer))
 601         region)
 602     (set-buffer gnus-tree-buffer)
 603     (when (setq region (gnus-tree-article-region article))
 604       (when (or (not gnus-selected-tree-overlay)
 605                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 606         ;; Create a new overlay.
 607         (gnus-overlay-put
 608          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 609          'face gnus-selected-tree-face))
 610       ;; Move the overlay to the article.
 611       (gnus-move-overlay
 612        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 613       (gnus-tree-minimize)
 614       (gnus-tree-recenter)
 615       (let ((selected (selected-window)))
 616         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 617           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 618           (gnus-horizontal-recenter)
 619           (select-window selected))))
 620     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 621     (save-excursion
 622       (set-buffer gnus-tree-buffer)
 623       (gnus-set-mode-line 'tree))
 624     (set-buffer buf)))
 625
 626 (defun gnus-tree-highlight-article (article face)
 627   (save-excursion
 628     (set-buffer (gnus-get-tree-buffer))
 629     (let (region)
 630       (when (setq region (gnus-tree-article-region article))
 631         (put-text-property (car region) (cdr region) 'face face)
 632         (set-window-point
 633          (get-buffer-window (current-buffer) t) (cdr region))))))
 634
 635 ;;; Allow redefinition of functions.
 636 (gnus-ems-redefine)
 637
 638 (provide 'gnus-salt)
 639
 640 ;;; gnus-salt.el ends here