cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (eval-when-compile (require 'cl))
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 ;;; Internal variables.
  44
  45 (defvar gnus-pick-mode-map nil)
  46
  47 (unless gnus-pick-mode-map
  48   (setq gnus-pick-mode-map (make-sparse-keymap))
  49
  50   (gnus-define-keys
  51    gnus-pick-mode-map
  52    "t" gnus-uu-mark-thread
  53    "T" gnus-uu-unmark-thread
  54    " " gnus-summary-mark-as-processable
  55    "u" gnus-summary-unmark-as-processable
  56    "U" gnus-summary-unmark-all-processable
  57    "v" gnus-uu-mark-over
  58    "r" gnus-uu-mark-region
  59    "R" gnus-uu-unmark-region
  60    "e" gnus-uu-mark-by-regexp
  61    "E" gnus-uu-mark-by-regexp
  62    "b" gnus-uu-mark-buffer
  63    "B" gnus-uu-unmark-buffer
  64    "\r" gnus-pick-start-reading))
  65
  66 (defun gnus-pick-make-menu-bar ()
  67   (unless (boundp 'gnus-pick-menu)
  68     (easy-menu-define
  69      gnus-pick-menu gnus-pick-mode-map ""
  70      '("Pick"
  71        ("Pick"
  72         ["Article" gnus-summary-mark-as-processable t]
  73         ["Thread" gnus-uu-mark-thread t]
  74         ["Region" gnus-uu-mark-region t]
  75         ["Regexp" gnus-uu-mark-regexp t]
  76         ["Buffer" gnus-uu-mark-buffer t])
  77        ("Unpick"
  78         ["Article" gnus-summary-unmark-as-processable t]
  79         ["Thread" gnus-uu-unmark-thread t]
  80         ["Region" gnus-uu-unmark-region t]
  81         ["Regexp" gnus-uu-unmark-regexp t]
  82         ["Buffer" gnus-uu-unmark-buffer t])
  83        ["Start reading" gnus-pick-start-reading t]
  84        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  85
  86 (defun gnus-pick-mode (&optional arg)
  87   "Minor mode for providing a pick-and-read interface in Gnus summary buffers."
  88   (interactive "P")
  89   (when (eq major-mode 'gnus-summary-mode)
  90     (make-local-variable 'gnus-pick-mode)
  91     (setq gnus-pick-mode
  92           (if (null arg) (not gnus-pick-mode)
  93             (> (prefix-numeric-value arg) 0)))
  94     (when gnus-pick-mode
  95       ;; Make sure that we don't select any articles upon group entry.
  96       (make-local-variable 'gnus-auto-select-first)
  97       (setq gnus-auto-select-first nil)
  98       ;; Set up the menu.
  99       (when (and menu-bar-mode
 100                  (gnus-visual-p 'pick-menu 'menu))
 101         (gnus-pick-make-menu-bar))
 102       (unless (assq 'gnus-pick-mode minor-mode-alist)
 103         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 104       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 105         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 106               minor-mode-map-alist))
 107       (run-hooks 'gnus-pick-mode-hook))))
 108
 109 (defun gnus-pick-start-reading (&optional catch-up)
 110   "Start reading the picked articles.
 111 If given a prefix, mark all unpicked articles as read."
 112   (interactive "P")
 113   (unless gnus-newsgroup-processable
 114     (error "No articles have been picked"))
 115   (gnus-summary-limit-to-articles nil)
 116   (when catch-up
 117     (gnus-summary-limit-mark-excluded-as-read))
 118   (gnus-configure-windows (if gnus-pick-display-summary 'summary 'pick) t))
 119
 120
 121 ;;;
 122 ;;; gnus-binary-mode
 123 ;;;
 124
 125 (defvar gnus-binary-mode nil
 126   "Minor mode for provind a binary group interface in Gnus summary buffers.")
 127
 128 (defvar gnus-binary-mode-hook nil
 129   "Hook run in summary binary mode buffers.")
 130
 131 (defvar gnus-binary-mode-map nil)
 132
 133 (unless gnus-binary-mode-map
 134   (setq gnus-binary-mode-map (make-sparse-keymap))
 135
 136   (gnus-define-keys
 137    gnus-binary-mode-map
 138    "g" gnus-binary-show-article))
 139
 140 (defun gnus-binary-make-menu-bar ()
 141   (unless (boundp 'gnus-binary-menu)
 142     (easy-menu-define
 143      gnus-binary-menu gnus-binary-mode-map ""
 144      '("Pick"
 145        ["Switch binary mode off" gnus-binary-mode t]))))
 146
 147 (defun gnus-binary-mode (&optional arg)
 148   "Minor mode for providing a binary group interface in Gnus summary buffers."
 149   (interactive "P")
 150   (when (eq major-mode 'gnus-summary-mode)
 151     (make-local-variable 'gnus-binary-mode)
 152     (setq gnus-binary-mode
 153           (if (null arg) (not gnus-binary-mode)
 154             (> (prefix-numeric-value arg) 0)))
 155     (when gnus-binary-mode
 156       ;; Make sure that we don't select any articles upon group entry.
 157       (make-local-variable 'gnus-auto-select-first)
 158       (setq gnus-auto-select-first nil)
 159       (make-local-variable 'gnus-summary-display-article-function)
 160       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 161       ;; Set up the menu.
 162       (when (and menu-bar-mode
 163                  (gnus-visual-p 'binary-menu 'menu))
 164         (gnus-binary-make-menu-bar))
 165       (unless (assq 'gnus-binary-mode minor-mode-alist)
 166         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 167       (unless (assq 'gnus-topic-mode minor-mode-map-alist)
 168         (push (cons 'gnus-topic-mode gnus-binary-mode-map)
 169               minor-mode-map-alist))
 170       (run-hooks 'gnus-binary-mode-hook))))
 171
 172 (defun gnus-binary-display-article (article &optional all-header)
 173   "Run ARTICLE through the binary decode functions."
 174   (when (gnus-summary-goto-subject article)
 175     (let ((gnus-view-pseudos 'automatic))
 176       (gnus-uu-decode-uu))))
 177
 178 (defun gnus-binary-show-article (&optional arg)
 179   "Bypass the binary functions and show the article."
 180   (interactive "P")
 181   (let (gnus-summary-display-article-function)
 182     (gnus-summary-show-article arg)))
 183
 184 ;;;
 185 ;;; gnus-tree-mode
 186 ;;;
 187
 188 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 189   "Format of tree elements.")
 190
 191 (defvar gnus-tree-minimize-window t
 192   "If non-nil, minimize the tree buffer window.
 193 If a number, never let the tree buffer grow taller than that number of
 194 lines.")
 195
 196 (defvar gnus-selected-tree-face 'modeline
 197   "*Face used for highlighting selected articles in the thread tree.")
 198
 199 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\)) (?\{ . ?\}))
 200   "Brackets used in tree nodes.")
 201
 202 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 203   "Charaters used to connect parents with children.")
 204
 205 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 206   "*The format specification for the tree mode line.")
 207
 208 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 209   "*Function for generating a thread tree.
 210 Two predefined functions are available:
 211 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 212
 213 (defvar gnus-tree-mode-hook nil
 214   "*Hook run in tree mode buffers.")
 215
 216 (defvar gnus-tree-buffer "*Tree*"
 217   "Buffer where Gnus thread trees are displayed.")
 218
 219 ;;; Internal variables.
 220
 221 (defvar gnus-tree-line-format-alist
 222   `((?n gnus-tmp-name ?s)
 223     (?f gnus-tmp-from ?s)
 224     (?N gnus-tmp-number ?d)
 225     (?\[ gnus-tmp-open-bracket ?c)
 226     (?\] gnus-tmp-close-bracket ?c)
 227     (?s gnus-tmp-subject ?s)))
 228
 229 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 230
 231 (defvar gnus-tree-mode-line-format-spec nil)
 232 (defvar gnus-tree-line-format-spec nil)
 233
 234 (defvar gnus-tree-node-length nil)
 235 (defvar gnus-selected-tree-overlay nil)
 236
 237 (defvar gnus-tree-displayed-thread nil)
 238
 239 (defvar gnus-tree-mode-map nil)
 240 (put 'gnus-tree-mode 'mode-class 'special)
 241
 242 (unless gnus-tree-mode-map
 243   (setq gnus-tree-mode-map (make-keymap))
 244   (suppress-keymap gnus-tree-mode-map)
 245   (gnus-define-keys
 246    gnus-tree-mode-map
 247    "\r" gnus-tree-select-article
 248    gnus-mouse-2 gnus-tree-pick-article
 249    "\C-?" gnus-tree-read-summary-keys)
 250
 251   (substitute-key-definition
 252    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 253
 254 (defun gnus-tree-make-menu-bar ()
 255   )
 256
 257 (defun gnus-tree-mode ()
 258   "Major mode for displaying thread trees."
 259   (interactive)
 260   (setq gnus-tree-mode-line-format-spec
 261         (gnus-parse-format gnus-tree-mode-line-format
 262                            gnus-summary-mode-line-format-alist))
 263   (setq gnus-tree-line-format-spec
 264         (gnus-parse-format gnus-tree-line-format
 265                            gnus-tree-line-format-alist t))
 266   (when (and menu-bar-mode
 267              (gnus-visual-p 'tree-menu 'menu))
 268     (gnus-tree-make-menu-bar))
 269   (kill-all-local-variables)
 270   (gnus-simplify-mode-line)
 271   (setq mode-name "Tree")
 272   (setq major-mode 'gnus-tree-mode)
 273   (use-local-map gnus-tree-mode-map)
 274   (buffer-disable-undo (current-buffer))
 275   (setq buffer-read-only t)
 276   (setq truncate-lines t)
 277   (save-excursion
 278     (gnus-set-work-buffer)
 279     (gnus-tree-node-insert (make-mail-header "") nil)
 280     (setq gnus-tree-node-length (1- (point))))
 281   (run-hooks 'gnus-tree-mode-hook))
 282
 283 (defun gnus-tree-read-summary-keys (&optional arg)
 284   "Read a summary buffer key sequence and execute it."
 285   (interactive "P")
 286   (let ((buf (current-buffer))
 287         win)
 288     (gnus-article-read-summary-keys arg nil t)
 289     (when (setq win (get-buffer-window buf))
 290       (select-window win)
 291       (when gnus-selected-tree-overlay
 292         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 293       (gnus-tree-minimize))))
 294
 295 (defun gnus-tree-select-article (article)
 296   "Select the article under point, if any."
 297   (interactive (list (gnus-tree-article-number)))
 298   (let ((buf (current-buffer)))
 299     (when article
 300       (save-excursion
 301         (set-buffer gnus-summary-buffer)
 302         (gnus-summary-goto-article article))
 303       (select-window (get-buffer-window buf)))))
 304
 305 (defun gnus-tree-pick-article (e)
 306   "Select the article under the mouse pointer."
 307   (interactive "e")
 308   (mouse-set-point e)
 309   (gnus-tree-select-article (gnus-tree-article-number)))
 310
 311 (defun gnus-tree-article-number ()
 312   (get-text-property (point) 'gnus-number))
 313
 314 (defun gnus-tree-article-region (article)
 315   "Return a cons with BEG and END of the article region."
 316   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 317     (when pos
 318       (cons pos (next-single-property-change pos 'gnus-number)))))
 319
 320 (defun gnus-tree-goto-article (article)
 321   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 322     (when pos
 323       (goto-char pos))))
 324
 325 (defun gnus-tree-recenter ()
 326   "Center point in the tree window."
 327   (let ((selected (selected-window))
 328         (tree-window (get-buffer-window gnus-tree-buffer t)))
 329     (when tree-window
 330       (select-window tree-window)
 331       (when gnus-selected-tree-overlay
 332         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 333       (let* ((top (cond ((< (window-height) 4) 0)
 334                         ((< (window-height) 7) 1)
 335                         (t 2)))
 336              (height (1- (window-height)))
 337              (bottom (save-excursion (goto-char (point-max))
 338                                      (forward-line (- height))
 339                                      (point))))
 340         ;; Set the window start to either `bottom', which is the biggest
 341         ;; possible valid number, or the second line from the top,
 342         ;; whichever is the least.
 343         (set-window-start
 344          tree-window (min bottom (save-excursion
 345                                    (forward-line (- top)) (point)))))
 346       (select-window selected))))
 347
 348 (defun gnus-get-tree-buffer ()
 349   "Return the tree buffer properly initialized."
 350   (save-excursion
 351     (set-buffer (get-buffer-create gnus-tree-buffer))
 352     (unless (eq major-mode 'gnus-tree-mode)
 353       (gnus-add-current-to-buffer-list)
 354       (gnus-tree-mode))
 355     (current-buffer)))
 356
 357 (defun gnus-tree-minimize ()
 358   (when (and gnus-tree-minimize-window
 359              (not (one-window-p)))
 360     (let* ((window-min-height 2)
 361            (height (count-lines (point-min) (point-max)))
 362            (min (max (1- window-min-height) height))
 363            (tot (if (numberp gnus-tree-minimize-window)
 364                     (min gnus-tree-minimize-window min)
 365                   min))
 366            (win (get-buffer-window (current-buffer)))
 367            (wh (and win (1- (window-height win)))))
 368       (when (and win
 369                  (not (eq tot wh)))
 370         (let ((selected (selected-window)))
 371           (select-window win)
 372           (enlarge-window (- tot wh))
 373           (select-window selected))))))
 374
 375 ;;; Generating the tree.
 376
 377 (defun gnus-tree-node-insert (header sparse)
 378   (let* ((dummy (stringp header))
 379          (header (if (vectorp header) header
 380                    (progn
 381                      (setq header (make-mail-header "*****"))
 382                      (mail-header-set-number header 0)
 383                      (mail-header-set-lines header 0)
 384                      (mail-header-set-chars header 0)
 385                      header)))
 386          (gnus-tmp-from (mail-header-from header))
 387          (gnus-tmp-subject (mail-header-subject header))
 388          (gnus-tmp-number (mail-header-number header))
 389          (gnus-tmp-name
 390           (cond
 391            ((string-match "(.+)" gnus-tmp-from)
 392             (substring gnus-tmp-from
 393                        (1+ (match-beginning 0)) (1- (match-end 0))))
 394            ((string-match "<[^>]+> *$" gnus-tmp-from)
 395             (let ((beg (match-beginning 0)))
 396               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 397                        (substring gnus-tmp-from (1+ (match-beginning 0))
 398                                   (1- (match-end 0))))
 399                   (substring gnus-tmp-from 0 beg))))
 400            ((memq gnus-tmp-number sparse)
 401             "***")
 402            (t gnus-tmp-from)))
 403          (gnus-tmp-open-bracket
 404           (cond ((memq gnus-tmp-number sparse)
 405                  (caadr gnus-tree-brackets))
 406                 (dummy (caaddr gnus-tree-brackets))
 407                 (t (caar gnus-tree-brackets))))
 408          (gnus-tmp-close-bracket
 409           (cond ((memq gnus-tmp-number sparse)
 410                  (cdadr gnus-tree-brackets))
 411                 (dummy
 412                  (cdaddr gnus-tree-brackets))
 413                 (t (cdar gnus-tree-brackets))))
 414          (buffer-read-only nil)
 415          beg end)
 416     (add-text-properties
 417      (setq beg (point))
 418      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 419      (list 'gnus-number gnus-tmp-number))
 420     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 421       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 422
 423 (defun gnus-tree-highlight-node (article beg end)
 424   "Highlight current line according to `gnus-summary-highlight'."
 425   (let ((list gnus-summary-highlight)
 426         face)
 427     (save-excursion
 428       (set-buffer gnus-summary-buffer)
 429       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 430                         gnus-summary-default-score 0))
 431              (default gnus-summary-default-score)
 432              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 433         ;; Eval the cars of the lists until we find a match.
 434         (while (and list
 435                     (not (eval (caar list))))
 436           (setq list (cdr list)))))
 437     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 438       (put-text-property
 439        beg end 'face
 440        (if (boundp face) (symbol-value face) face)))))
 441
 442 (defun gnus-tree-indent (level)
 443   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 444
 445 (defvar gnus-tmp-limit)
 446 (defvar gnus-tmp-sparse)
 447 (defvar gnus-tmp-indent)
 448
 449 (defun gnus-generate-tree (thread)
 450   "Generate a thread tree for THREAD."
 451   (save-excursion
 452     (set-buffer (gnus-get-tree-buffer))
 453     (let ((buffer-read-only nil)
 454           (gnus-tmp-indent 0))
 455       (erase-buffer)
 456       (funcall gnus-generate-tree-function thread 0)
 457       (gnus-set-mode-line 'tree)
 458       (goto-char (point-min))
 459       (gnus-tree-minimize)
 460       (gnus-tree-recenter)
 461       (let ((selected (selected-window)))
 462         (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 463         (gnus-horizontal-recenter)
 464         (select-window selected)))))
 465
 466 (defun gnus-generate-horizontal-tree (thread level &optional dummyp)
 467   "Generate a horizontal tree."
 468   (let* ((dummy (stringp (car thread)))
 469          (do (or dummy
 470                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 471          col beg)
 472     (if (not do)
 473         ;; We don't want this article.
 474         (setq thread (cdr thread))
 475       (if (not (bolp))
 476           ;; Not the first article on the line, so we insert a "-".
 477           (insert (car gnus-tree-parent-child-edges))
 478         ;; If the level isn't zero, then we insert some indentation.
 479         (unless (zerop level)
 480           (gnus-tree-indent level)
 481           (insert (cadr gnus-tree-parent-child-edges))
 482           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 483           ;; Draw "|" lines upwards.
 484           (while (progn
 485                    (forward-line -1)
 486                    (forward-char col)
 487                    (= (following-char) ? ))
 488             (delete-char 1)
 489             (insert (caddr gnus-tree-parent-child-edges)))
 490           (goto-char beg)))
 491       (setq dummyp nil)
 492       ;; Insert the article node.
 493       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse))
 494     (if (null thread)
 495         ;; End of the thread, so we go to the next line.
 496         (unless (bolp)
 497           (insert "\n"))
 498       ;; Recurse downwards in all children of this article.
 499       (while thread
 500         (gnus-generate-horizontal-tree
 501          (pop thread) (if do (1+ level) level)
 502          (or dummyp dummy))))))
 503
 504 (defsubst gnus-tree-indent-vertical ()
 505   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 506                 (- (point) (gnus-point-at-bol)))))
 507     (when (> len 0)
 508       (insert (make-string len ? )))))
 509
 510 (defsubst gnus-tree-forward-line (n)
 511   (while (>= (decf n) 0)
 512     (unless (zerop (forward-line 1))
 513       (end-of-line)
 514       (insert "\n")))
 515   (end-of-line))
 516
 517 (defun gnus-generate-vertical-tree (thread level &optional dummyp)
 518   "Generate a vertical tree."
 519   (let* ((dummy (stringp (car thread)))
 520          (do (or dummy
 521                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 522          col beg)
 523     (if (not do)
 524         ;; We don't want this article.
 525         (setq thread (cdr thread))
 526       (if (not (save-excursion (beginning-of-line) (bobp)))
 527           ;; Not the first article on the line, so we insert a "-".
 528           (progn
 529             (gnus-tree-indent-vertical)
 530             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 531             (insert (caddr gnus-tree-parent-child-edges))
 532             (gnus-tree-forward-line 1))
 533         ;; If the level isn't zero, then we insert some indentation.
 534         (unless (zerop gnus-tmp-indent)
 535           (gnus-tree-forward-line (1- (* 2 level)))
 536           (gnus-tree-indent-vertical)
 537           (delete-char -1)
 538           (insert (cadr gnus-tree-parent-child-edges))
 539           (setq beg (point))
 540           ;; Draw "-" lines leftwards.
 541           (while (progn
 542                    (forward-char -2)
 543                    (= (following-char) ? ))
 544             (delete-char 1)
 545             (insert (car gnus-tree-parent-child-edges)))
 546           (goto-char beg)
 547           (gnus-tree-forward-line 1)))
 548       (setq dummyp nil)
 549       ;; Insert the article node.
 550       (gnus-tree-indent-vertical)
 551       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse)
 552       (gnus-tree-forward-line 1))
 553     (if (null thread)
 554         ;; End of the thread, so we go to the next line.
 555         (progn
 556           (goto-char (point-min))
 557           (end-of-line)
 558           (incf gnus-tmp-indent))
 559       ;; Recurse downwards in all children of this article.
 560       (while thread
 561         (gnus-generate-vertical-tree
 562          (pop thread) (if do (1+ level) level)
 563          (or dummyp dummy))))))
 564
 565 ;;; Interface functions.
 566
 567 (defun gnus-possibly-generate-tree (article &optional force)
 568   "Generate the thread tree for ARTICLE if it isn't displayed already."
 569   (when (save-excursion
 570           (set-buffer gnus-summary-buffer)
 571           gnus-use-trees)
 572     (save-excursion
 573       (let ((top (save-excursion
 574                    (set-buffer gnus-summary-buffer)
 575                    (gnus-cut-thread
 576                     (gnus-remove-thread
 577                      (mail-header-id
 578                       (gnus-summary-article-header article)) t))))
 579             (gnus-tmp-limit gnus-newsgroup-limit)
 580             (gnus-tmp-sparse gnus-newsgroup-sparse))
 581         (when (or force
 582                   (not (eq top gnus-tree-displayed-thread)))
 583           (gnus-generate-tree top)
 584           (setq gnus-tree-displayed-thread top))))))
 585
 586 (defun gnus-tree-open (group)
 587   (gnus-get-tree-buffer))
 588
 589 (defun gnus-tree-close (group)
 590   ;(gnus-kill-buffer gnus-tree-buffer)
 591   )
 592
 593 (defun gnus-highlight-selected-tree (article)
 594   "Highlight the selected article in the tree."
 595   (let ((buf (current-buffer))
 596         region)
 597     (set-buffer gnus-tree-buffer)
 598     (when (setq region (gnus-tree-article-region article))
 599       (when (or (not gnus-selected-tree-overlay)
 600                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 601         ;; Create a new overlay.
 602         (gnus-overlay-put
 603          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 604          'face gnus-selected-tree-face))
 605       ;; Move the overlay to the article.
 606       (gnus-move-overlay
 607        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 608       (gnus-tree-minimize)
 609       (gnus-tree-recenter)
 610       (let ((selected (selected-window)))
 611         (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 612         (gnus-horizontal-recenter)
 613         (select-window selected)))
 614     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 615     (save-excursion
 616       (set-buffer gnus-tree-buffer)
 617       (gnus-set-mode-line 'tree))
 618     (set-buffer buf)))
 619
 620 (defun gnus-tree-highlight-article (article face)
 621   (save-excursion
 622     (set-buffer (gnus-get-tree-buffer))
 623     (let (region)
 624       (when (setq region (gnus-tree-article-region article))
 625         (put-text-property (car region) (cdr region) 'face face)
 626         (set-window-point
 627          (get-buffer-window (current-buffer) t) (cdr region))))))
 628
 629
 630 ;;; Allow redefinition of functions.
 631 (gnus-ems-redefine)
 632
 633 (provide 'gnus-salt)
 634
 635 ;;; gnus-salt.el ends here