cgit.sxemacs.org Git - gnus/blob - lisp/gnus-salt.el

   1 ;;; gnus-salt.el --- alternate summary mode interfaces for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (eval-when-compile (require 'cl))
  29
  30 ;;;
  31 ;;; gnus-pick-mode
  32 ;;;
  33
  34 (defvar gnus-pick-mode nil
  35   "Minor mode for providing a pick-and-read interface in Gnus summary buffers.")
  36
  37 (defvar gnus-pick-display-summary nil
  38   "*Display summary while reading.")
  39
  40 (defvar gnus-pick-mode-hook nil
  41   "Hook run in summary pick mode buffers.")
  42
  43 ;;; Internal variables.
  44
  45 (defvar gnus-pick-mode-map nil)
  46
  47 (unless gnus-pick-mode-map
  48   (setq gnus-pick-mode-map (make-sparse-keymap))
  49
  50   (gnus-define-keys
  51    gnus-pick-mode-map
  52    "t" gnus-uu-mark-thread
  53    "T" gnus-uu-unmark-thread
  54    " " gnus-summary-mark-as-processable
  55    "u" gnus-summary-unmark-as-processable
  56    "U" gnus-summary-unmark-all-processable
  57    "v" gnus-uu-mark-over
  58    "r" gnus-uu-mark-region
  59    "R" gnus-uu-unmark-region
  60    "e" gnus-uu-mark-by-regexp
  61    "E" gnus-uu-mark-by-regexp
  62    "b" gnus-uu-mark-buffer
  63    "B" gnus-uu-unmark-buffer
  64    "\r" gnus-pick-start-reading))
  65
  66 (defun gnus-pick-make-menu-bar ()
  67   (unless (boundp 'gnus-pick-menu)
  68     (easy-menu-define
  69      gnus-pick-menu gnus-pick-mode-map ""
  70      '("Pick"
  71        ("Pick"
  72         ["Article" gnus-summary-mark-as-processable t]
  73         ["Thread" gnus-uu-mark-thread t]
  74         ["Region" gnus-uu-mark-region t]
  75         ["Regexp" gnus-uu-mark-regexp t]
  76         ["Buffer" gnus-uu-mark-buffer t])
  77        ("Unpick"
  78         ["Article" gnus-summary-unmark-as-processable t]
  79         ["Thread" gnus-uu-unmark-thread t]
  80         ["Region" gnus-uu-unmark-region t]
  81         ["Regexp" gnus-uu-unmark-regexp t]
  82         ["Buffer" gnus-uu-unmark-buffer t])
  83        ["Start reading" gnus-pick-start-reading t]
  84        ["Switch pick mode off" gnus-pick-mode gnus-pick-mode]))))
  85
  86 (defun gnus-pick-mode (&optional arg)
  87   "Minor mode for providing a pick-and-read interface in Gnus summary buffers."
  88   (interactive "P")
  89   (when (eq major-mode 'gnus-summary-mode)
  90     (make-local-variable 'gnus-pick-mode)
  91     (setq gnus-pick-mode
  92           (if (null arg) (not gnus-pick-mode)
  93             (> (prefix-numeric-value arg) 0)))
  94     (when gnus-pick-mode
  95       ;; Make sure that we don't select any articles upon group entry.
  96       (make-local-variable 'gnus-auto-select-first)
  97       (setq gnus-auto-select-first nil)
  98       ;; Set up the menu.
  99       (when (and menu-bar-mode
 100                  (gnus-visual-p 'pick-menu 'menu))
 101         (gnus-pick-make-menu-bar))
 102       (unless (assq 'gnus-pick-mode minor-mode-alist)
 103         (push '(gnus-pick-mode " Pick") minor-mode-alist))
 104       (unless (assq 'gnus-pick-mode minor-mode-map-alist)
 105         (push (cons 'gnus-pick-mode gnus-pick-mode-map)
 106               minor-mode-map-alist))
 107       (run-hooks 'gnus-pick-mode-hook))))
 108
 109 (defun gnus-pick-start-reading (&optional catch-up)
 110   "Start reading the picked articles.
 111 If given a prefix, mark all unpicked articles as read."
 112   (interactive "P")
 113   (unless gnus-newsgroup-processable
 114     (error "No articles have been picked"))
 115   (gnus-summary-limit-to-articles nil)
 116   (when catch-up
 117     (gnus-summary-limit-mark-excluded-as-read))
 118   (gnus-configure-windows (if gnus-pick-display-summary 'summary 'pick) t))
 119
 120
 121 ;;;
 122 ;;; gnus-binary-mode
 123 ;;;
 124
 125 (defvar gnus-binary-mode nil
 126   "Minor mode for provind a binary group interface in Gnus summary buffers.")
 127
 128 (defvar gnus-binary-mode-hook nil
 129   "Hook run in summary binary mode buffers.")
 130
 131 (defvar gnus-binary-mode-map nil)
 132
 133 (unless gnus-binary-mode-map
 134   (setq gnus-binary-mode-map (make-sparse-keymap))
 135
 136   (gnus-define-keys
 137    gnus-binary-mode-map
 138    "g" gnus-binary-show-article))
 139
 140 (defun gnus-binary-make-menu-bar ()
 141   (unless (boundp 'gnus-binary-menu)
 142     (easy-menu-define
 143      gnus-binary-menu gnus-binary-mode-map ""
 144      '("Pick"
 145        ["Switch binary mode off" gnus-binary-mode t]))))
 146
 147 (defun gnus-binary-mode (&optional arg)
 148   "Minor mode for providing a binary group interface in Gnus summary buffers."
 149   (interactive "P")
 150   (when (eq major-mode 'gnus-summary-mode)
 151     (make-local-variable 'gnus-binary-mode)
 152     (setq gnus-binary-mode
 153           (if (null arg) (not gnus-binary-mode)
 154             (> (prefix-numeric-value arg) 0)))
 155     (when gnus-binary-mode
 156       ;; Make sure that we don't select any articles upon group entry.
 157       (make-local-variable 'gnus-auto-select-first)
 158       (setq gnus-auto-select-first nil)
 159       (make-local-variable 'gnus-summary-display-article-function)
 160       (setq gnus-summary-display-article-function 'gnus-binary-display-article)
 161       ;; Set up the menu.
 162       (when (and menu-bar-mode
 163                  (gnus-visual-p 'binary-menu 'menu))
 164         (gnus-binary-make-menu-bar))
 165       (unless (assq 'gnus-binary-mode minor-mode-alist)
 166         (push '(gnus-binary-mode " Binary") minor-mode-alist))
 167       (unless (assq 'gnus-topic-mode minor-mode-map-alist)
 168         (push (cons 'gnus-topic-mode gnus-binary-mode-map)
 169               minor-mode-map-alist))
 170       (run-hooks 'gnus-binary-mode-hook))))
 171
 172 (defun gnus-binary-display-article (article &optional all-header)
 173   "Run ARTICLE through the binary decode functions."
 174   (when (gnus-summary-goto-subject article)
 175     (let ((gnus-view-pseudos 'automatic))
 176       (gnus-uu-decode-uu))))
 177
 178 (defun gnus-binary-show-article (&optional arg)
 179   "Bypass the binary functions and show the article."
 180   (interactive "P")
 181   (let (gnus-summary-display-article-function)
 182     (gnus-summary-show-article arg)))
 183
 184 ;;;
 185 ;;; gnus-tree-mode
 186 ;;;
 187
 188 (defvar gnus-tree-line-format "%(%[%3,3n%]%)"
 189   "Format of tree elements.")
 190
 191 (defvar gnus-tree-minimize-window t
 192   "If non-nil, minimize the tree buffer window.
 193 If a number, never let the tree buffer grow taller than that number of
 194 lines.")
 195
 196 (defvar gnus-selected-tree-face 'modeline
 197   "*Face used for highlighting selected articles in the thread tree.")
 198
 199 (defvar gnus-tree-brackets '((?\[ . ?\]) (?\( . ?\))
 200                              (?\{ . ?\}) (?< . ?>))
 201   "Brackets used in tree nodes.")
 202
 203 (defvar gnus-tree-parent-child-edges '(?- ?\\ ?|)
 204   "Charaters used to connect parents with children.")
 205
 206 (defvar gnus-tree-mode-line-format "Gnus: %%b %S %Z"
 207   "*The format specification for the tree mode line.")
 208
 209 (defvar gnus-generate-tree-function 'gnus-generate-vertical-tree
 210   "*Function for generating a thread tree.
 211 Two predefined functions are available:
 212 `gnus-generate-horizontal-tree' and `gnus-generate-vertical-tree'.")
 213
 214 (defvar gnus-tree-mode-hook nil
 215   "*Hook run in tree mode buffers.")
 216
 217 (defvar gnus-tree-buffer "*Tree*"
 218   "Buffer where Gnus thread trees are displayed.")
 219
 220 ;;; Internal variables.
 221
 222 (defvar gnus-tree-line-format-alist
 223   `((?n gnus-tmp-name ?s)
 224     (?f gnus-tmp-from ?s)
 225     (?N gnus-tmp-number ?d)
 226     (?\[ gnus-tmp-open-bracket ?c)
 227     (?\] gnus-tmp-close-bracket ?c)
 228     (?s gnus-tmp-subject ?s)))
 229
 230 (defvar gnus-tree-mode-line-format-alist gnus-summary-mode-line-format-alist)
 231
 232 (defvar gnus-tree-mode-line-format-spec nil)
 233 (defvar gnus-tree-line-format-spec nil)
 234
 235 (defvar gnus-tree-node-length nil)
 236 (defvar gnus-selected-tree-overlay nil)
 237
 238 (defvar gnus-tree-displayed-thread nil)
 239
 240 (defvar gnus-tree-mode-map nil)
 241 (put 'gnus-tree-mode 'mode-class 'special)
 242
 243 (unless gnus-tree-mode-map
 244   (setq gnus-tree-mode-map (make-keymap))
 245   (suppress-keymap gnus-tree-mode-map)
 246   (gnus-define-keys
 247    gnus-tree-mode-map
 248    "\r" gnus-tree-select-article
 249    gnus-mouse-2 gnus-tree-pick-article
 250    "\C-?" gnus-tree-read-summary-keys)
 251
 252   (substitute-key-definition
 253    'undefined 'gnus-tree-read-summary-keys gnus-tree-mode-map))
 254
 255 (defun gnus-tree-make-menu-bar ()
 256   (unless (boundp 'gnus-tree-menu)
 257     (easy-menu-define
 258      gnus-tree-menu gnus-tree-mode-map ""
 259      '("Tree"
 260        ["Select article" gnus-tree-select-article t]))))
 261
 262 (defun gnus-tree-mode ()
 263   "Major mode for displaying thread trees."
 264   (interactive)
 265   (setq gnus-tree-mode-line-format-spec
 266         (gnus-parse-format gnus-tree-mode-line-format
 267                            gnus-summary-mode-line-format-alist))
 268   (setq gnus-tree-line-format-spec
 269         (gnus-parse-format gnus-tree-line-format
 270                            gnus-tree-line-format-alist t))
 271   (when (and menu-bar-mode
 272              (gnus-visual-p 'tree-menu 'menu))
 273     (gnus-tree-make-menu-bar))
 274   (kill-all-local-variables)
 275   (gnus-simplify-mode-line)
 276   (setq mode-name "Tree")
 277   (setq major-mode 'gnus-tree-mode)
 278   (use-local-map gnus-tree-mode-map)
 279   (buffer-disable-undo (current-buffer))
 280   (setq buffer-read-only t)
 281   (setq truncate-lines t)
 282   (save-excursion
 283     (gnus-set-work-buffer)
 284     (gnus-tree-node-insert (make-mail-header "") nil)
 285     (setq gnus-tree-node-length (1- (point))))
 286   (run-hooks 'gnus-tree-mode-hook))
 287
 288 (defun gnus-tree-read-summary-keys (&optional arg)
 289   "Read a summary buffer key sequence and execute it."
 290   (interactive "P")
 291   (let ((buf (current-buffer))
 292         win)
 293     (gnus-article-read-summary-keys arg nil t)
 294     (when (setq win (get-buffer-window buf))
 295       (select-window win)
 296       (when gnus-selected-tree-overlay
 297         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 298       (gnus-tree-minimize))))
 299
 300 (defun gnus-tree-select-article (article)
 301   "Select the article under point, if any."
 302   (interactive (list (gnus-tree-article-number)))
 303   (let ((buf (current-buffer)))
 304     (when article
 305       (save-excursion
 306         (set-buffer gnus-summary-buffer)
 307         (gnus-summary-goto-article article))
 308       (select-window (get-buffer-window buf)))))
 309
 310 (defun gnus-tree-pick-article (e)
 311   "Select the article under the mouse pointer."
 312   (interactive "e")
 313   (mouse-set-point e)
 314   (gnus-tree-select-article (gnus-tree-article-number)))
 315
 316 (defun gnus-tree-article-number ()
 317   (get-text-property (point) 'gnus-number))
 318
 319 (defun gnus-tree-article-region (article)
 320   "Return a cons with BEG and END of the article region."
 321   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 322     (when pos
 323       (cons pos (next-single-property-change pos 'gnus-number)))))
 324
 325 (defun gnus-tree-goto-article (article)
 326   (let ((pos (text-property-any (point-min) (point-max) 'gnus-number article)))
 327     (when pos
 328       (goto-char pos))))
 329
 330 (defun gnus-tree-recenter ()
 331   "Center point in the tree window."
 332   (let ((selected (selected-window))
 333         (tree-window (get-buffer-window gnus-tree-buffer t)))
 334     (when tree-window
 335       (select-window tree-window)
 336       (when gnus-selected-tree-overlay
 337         (goto-char (or (gnus-overlay-end gnus-selected-tree-overlay) 1)))
 338       (let* ((top (cond ((< (window-height) 4) 0)
 339                         ((< (window-height) 7) 1)
 340                         (t 2)))
 341              (height (1- (window-height)))
 342              (bottom (save-excursion (goto-char (point-max))
 343                                      (forward-line (- height))
 344                                      (point))))
 345         ;; Set the window start to either `bottom', which is the biggest
 346         ;; possible valid number, or the second line from the top,
 347         ;; whichever is the least.
 348         (set-window-start
 349          tree-window (min bottom (save-excursion
 350                                    (forward-line (- top)) (point)))))
 351       (select-window selected))))
 352
 353 (defun gnus-get-tree-buffer ()
 354   "Return the tree buffer properly initialized."
 355   (save-excursion
 356     (set-buffer (get-buffer-create gnus-tree-buffer))
 357     (unless (eq major-mode 'gnus-tree-mode)
 358       (gnus-add-current-to-buffer-list)
 359       (gnus-tree-mode))
 360     (current-buffer)))
 361
 362 (defun gnus-tree-minimize ()
 363   (when (and gnus-tree-minimize-window
 364              (not (one-window-p)))
 365     (let* ((window-min-height 2)
 366            (height (count-lines (point-min) (point-max)))
 367            (min (max (1- window-min-height) height))
 368            (tot (if (numberp gnus-tree-minimize-window)
 369                     (min gnus-tree-minimize-window min)
 370                   min))
 371            (win (get-buffer-window (current-buffer)))
 372            (wh (and win (1- (window-height win)))))
 373       (when (and win
 374                  (not (eq tot wh)))
 375         (let ((selected (selected-window)))
 376           (select-window win)
 377           (enlarge-window (- tot wh))
 378           (select-window selected))))))
 379
 380 ;;; Generating the tree.
 381
 382 (defun gnus-tree-node-insert (header sparse &optional adopted)
 383   (let* ((dummy (stringp header))
 384          (header (if (vectorp header) header
 385                    (progn
 386                      (setq header (make-mail-header "*****"))
 387                      (mail-header-set-number header 0)
 388                      (mail-header-set-lines header 0)
 389                      (mail-header-set-chars header 0)
 390                      header)))
 391          (gnus-tmp-from (mail-header-from header))
 392          (gnus-tmp-subject (mail-header-subject header))
 393          (gnus-tmp-number (mail-header-number header))
 394          (gnus-tmp-name
 395           (cond
 396            ((string-match "(.+)" gnus-tmp-from)
 397             (substring gnus-tmp-from
 398                        (1+ (match-beginning 0)) (1- (match-end 0))))
 399            ((string-match "<[^>]+> *$" gnus-tmp-from)
 400             (let ((beg (match-beginning 0)))
 401               (or (and (string-match "^\"[^\"]*\"" gnus-tmp-from)
 402                        (substring gnus-tmp-from (1+ (match-beginning 0))
 403                                   (1- (match-end 0))))
 404                   (substring gnus-tmp-from 0 beg))))
 405            ((memq gnus-tmp-number sparse)
 406             "***")
 407            (t gnus-tmp-from)))
 408          (gnus-tmp-open-bracket
 409           (cond ((memq gnus-tmp-number sparse)
 410                  (caadr gnus-tree-brackets))
 411                 (dummy (caaddr gnus-tree-brackets))
 412                 (adopted (car (nth 3 gnus-tree-brackets)))
 413                 (t (caar gnus-tree-brackets))))
 414          (gnus-tmp-close-bracket
 415           (cond ((memq gnus-tmp-number sparse)
 416                  (cdadr gnus-tree-brackets))
 417                 (adopted (cdr (nth 3 gnus-tree-brackets)))
 418                 (dummy
 419                  (cdaddr gnus-tree-brackets))
 420                 (t (cdar gnus-tree-brackets))))
 421          (buffer-read-only nil)
 422          beg end)
 423     (add-text-properties
 424      (setq beg (point))
 425      (setq end (progn (eval gnus-tree-line-format-spec) (point)))
 426      (list 'gnus-number gnus-tmp-number))
 427     (when (or t (gnus-visual-p 'tree-highlight 'highlight))
 428       (gnus-tree-highlight-node gnus-tmp-number beg end))))
 429
 430 (defun gnus-tree-highlight-node (article beg end)
 431   "Highlight current line according to `gnus-summary-highlight'."
 432   (let ((list gnus-summary-highlight)
 433         face)
 434     (save-excursion
 435       (set-buffer gnus-summary-buffer)
 436       (let* ((score (or (cdr (assq article gnus-newsgroup-scored))
 437                         gnus-summary-default-score 0))
 438              (default gnus-summary-default-score)
 439              (mark (or (gnus-summary-article-mark article) gnus-unread-mark)))
 440         ;; Eval the cars of the lists until we find a match.
 441         (while (and list
 442                     (not (eval (caar list))))
 443           (setq list (cdr list)))))
 444     (unless (eq (setq face (cdar list)) (get-text-property beg 'face))
 445       (put-text-property
 446        beg end 'face
 447        (if (boundp face) (symbol-value face) face)))))
 448
 449 (defun gnus-tree-indent (level)
 450   (insert (make-string (1- (* (1+ gnus-tree-node-length) level)) ? )))
 451
 452 (defvar gnus-tmp-limit)
 453 (defvar gnus-tmp-sparse)
 454 (defvar gnus-tmp-indent)
 455
 456 (defun gnus-generate-tree (thread)
 457   "Generate a thread tree for THREAD."
 458   (save-excursion
 459     (set-buffer (gnus-get-tree-buffer))
 460     (let ((buffer-read-only nil)
 461           (gnus-tmp-indent 0))
 462       (erase-buffer)
 463       (funcall gnus-generate-tree-function thread 0)
 464       (gnus-set-mode-line 'tree)
 465       (goto-char (point-min))
 466       (gnus-tree-minimize)
 467       (gnus-tree-recenter)
 468       (let ((selected (selected-window)))
 469         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 470           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 471           (gnus-horizontal-recenter)
 472           (select-window selected))))))
 473
 474 (defun gnus-generate-horizontal-tree (thread level &optional dummyp adopted)
 475   "Generate a horizontal tree."
 476   (let* ((dummy (stringp (car thread)))
 477          (do (or dummy
 478                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 479          col beg)
 480     (if (not do)
 481         ;; We don't want this article.
 482         (setq thread (cdr thread))
 483       (if (not (bolp))
 484           ;; Not the first article on the line, so we insert a "-".
 485           (insert (car gnus-tree-parent-child-edges))
 486         ;; If the level isn't zero, then we insert some indentation.
 487         (unless (zerop level)
 488           (gnus-tree-indent level)
 489           (insert (cadr gnus-tree-parent-child-edges))
 490           (setq col (- (setq beg (point)) (gnus-point-at-bol) 1))
 491           ;; Draw "|" lines upwards.
 492           (while (progn
 493                    (forward-line -1)
 494                    (forward-char col)
 495                    (= (following-char) ? ))
 496             (delete-char 1)
 497             (insert (caddr gnus-tree-parent-child-edges)))
 498           (goto-char beg)))
 499       (setq dummyp nil)
 500       ;; Insert the article node.
 501       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted))
 502     (if (null thread)
 503         ;; End of the thread, so we go to the next line.
 504         (unless (bolp)
 505           (insert "\n"))
 506       ;; Recurse downwards in all children of this article.
 507       (while thread
 508         (gnus-generate-horizontal-tree
 509          (pop thread) (if do (1+ level) level)
 510          (or dummyp dummy) dummy)))))
 511
 512 (defsubst gnus-tree-indent-vertical ()
 513   (let ((len (- (* (1+ gnus-tree-node-length) gnus-tmp-indent)
 514                 (- (point) (gnus-point-at-bol)))))
 515     (when (> len 0)
 516       (insert (make-string len ? )))))
 517
 518 (defsubst gnus-tree-forward-line (n)
 519   (while (>= (decf n) 0)
 520     (unless (zerop (forward-line 1))
 521       (end-of-line)
 522       (insert "\n")))
 523   (end-of-line))
 524
 525 (defun gnus-generate-vertical-tree (thread level &optional dummyp adopted)
 526   "Generate a vertical tree."
 527   (let* ((dummy (stringp (car thread)))
 528          (do (or dummy
 529                  (memq (mail-header-number (car thread)) gnus-tmp-limit)))
 530          beg)
 531     (if (not do)
 532         ;; We don't want this article.
 533         (setq thread (cdr thread))
 534       (if (not (save-excursion (beginning-of-line) (bobp)))
 535           ;; Not the first article on the line, so we insert a "-".
 536           (progn
 537             (gnus-tree-indent-vertical)
 538             (insert (make-string (/ gnus-tree-node-length 2) ? ))
 539             (insert (caddr gnus-tree-parent-child-edges))
 540             (gnus-tree-forward-line 1))
 541         ;; If the level isn't zero, then we insert some indentation.
 542         (unless (zerop gnus-tmp-indent)
 543           (gnus-tree-forward-line (1- (* 2 level)))
 544           (gnus-tree-indent-vertical)
 545           (delete-char -1)
 546           (insert (cadr gnus-tree-parent-child-edges))
 547           (setq beg (point))
 548           ;; Draw "-" lines leftwards.
 549           (while (progn
 550                    (forward-char -2)
 551                    (= (following-char) ? ))
 552             (delete-char 1)
 553             (insert (car gnus-tree-parent-child-edges)))
 554           (goto-char beg)
 555           (gnus-tree-forward-line 1)))
 556       (setq dummyp nil)
 557       ;; Insert the article node.
 558       (gnus-tree-indent-vertical)
 559       (gnus-tree-node-insert (pop thread) gnus-tmp-sparse adopted)
 560       (gnus-tree-forward-line 1))
 561     (if (null thread)
 562         ;; End of the thread, so we go to the next line.
 563         (progn
 564           (goto-char (point-min))
 565           (end-of-line)
 566           (incf gnus-tmp-indent))
 567       ;; Recurse downwards in all children of this article.
 568       (while thread
 569         (gnus-generate-vertical-tree
 570          (pop thread) (if do (1+ level) level)
 571          (or dummyp dummy) dummy)))))
 572
 573 ;;; Interface functions.
 574
 575 (defun gnus-possibly-generate-tree (article &optional force)
 576   "Generate the thread tree for ARTICLE if it isn't displayed already."
 577   (when (save-excursion
 578           (set-buffer gnus-summary-buffer)
 579           (and gnus-use-trees
 580                (vectorp (gnus-summary-article-header article))))
 581     (save-excursion
 582       (let ((top (save-excursion
 583                    (set-buffer gnus-summary-buffer)
 584                    (gnus-cut-thread
 585                     (gnus-remove-thread
 586                      (mail-header-id
 587                       (gnus-summary-article-header article)) t))))
 588             (gnus-tmp-limit gnus-newsgroup-limit)
 589             (gnus-tmp-sparse gnus-newsgroup-sparse))
 590         (when (or force
 591                   (not (eq top gnus-tree-displayed-thread)))
 592           (gnus-generate-tree top)
 593           (setq gnus-tree-displayed-thread top))))))
 594
 595 (defun gnus-tree-open (group)
 596   (gnus-get-tree-buffer))
 597
 598 (defun gnus-tree-close (group)
 599   ;(gnus-kill-buffer gnus-tree-buffer)
 600   )
 601
 602 (defun gnus-highlight-selected-tree (article)
 603   "Highlight the selected article in the tree."
 604   (let ((buf (current-buffer))
 605         region)
 606     (set-buffer gnus-tree-buffer)
 607     (when (setq region (gnus-tree-article-region article))
 608       (when (or (not gnus-selected-tree-overlay)
 609                 (gnus-extent-detached-p gnus-selected-tree-overlay))
 610         ;; Create a new overlay.
 611         (gnus-overlay-put
 612          (setq gnus-selected-tree-overlay (gnus-make-overlay 1 2))
 613          'face gnus-selected-tree-face))
 614       ;; Move the overlay to the article.
 615       (gnus-move-overlay
 616        gnus-selected-tree-overlay (goto-char (car region)) (cdr region))
 617       (gnus-tree-minimize)
 618       (gnus-tree-recenter)
 619       (let ((selected (selected-window)))
 620         (when (get-buffer-window (set-buffer gnus-tree-buffer) t)
 621           (select-window (get-buffer-window (set-buffer gnus-tree-buffer) t))
 622           (gnus-horizontal-recenter)
 623           (select-window selected))))
 624     ;; If we remove this save-excursion, it updates the wrong mode lines?!?
 625     (save-excursion
 626       (set-buffer gnus-tree-buffer)
 627       (gnus-set-mode-line 'tree))
 628     (set-buffer buf)))
 629
 630 (defun gnus-tree-highlight-article (article face)
 631   (save-excursion
 632     (set-buffer (gnus-get-tree-buffer))
 633     (let (region)
 634       (when (setq region (gnus-tree-article-region article))
 635         (put-text-property (car region) (cdr region) 'face face)
 636         (set-window-point
 637          (get-buffer-window (current-buffer) t) (cdr region))))))
 638
 639 ;;; Allow redefinition of functions.
 640 (gnus-ems-redefine)
 641
 642 (provide 'gnus-salt)
 643
 644 ;;; gnus-salt.el ends here