cgit.sxemacs.org Git - gnus/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   7 ;; Keywords: news xpm annotation glyph faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; There are three picon types relevant to Gnus:
  29 ;;
  30 ;; Persons: person@subdomain.dom
  31 ;;          users/dom/subdomain/person/face.gif
  32 ;;          usenix/dom/subdomain/person/face.gif
  33 ;;          misc/MISC/person/face.gif
  34 ;; Domains: subdomain.dom
  35 ;;          domain/dom/subdomain/unknown/face.gif
  36 ;; Groups:  comp.lang.lisp
  37 ;;          news/comp/lang/lisp/unknown/face.gif
  38
  39 ;;; Code:
  40
  41 (require 'gnus)
  42 (require 'custom)
  43 (require 'gnus-art)
  44
  45 ;;; User variables:
  46
  47 (defgroup picon nil
  48   "Show pictures of people, domains, and newsgroups."
  49   :group 'gnus-visual)
  50
  51 (defcustom gnus-picon-databases '("/usr/lib/picon" "/usr/local/faces")
  52   "*Defines the location of the faces database.
  53 For information on obtaining this database of pretty pictures, please
  54 see http://www.cs.indiana.edu/picons/ftp/index.html"
  55   :type 'directory
  56   :group 'picon)
  57
  58 (defcustom gnus-picon-news-directories '("news")
  59   "*List of directories to search for newsgroups faces."
  60   :type '(repeat string)
  61   :group 'picon)
  62
  63 (defcustom gnus-picon-user-directories '("users" "usenix" "local" "misc")
  64   "*List of directories to search for user faces."
  65   :type '(repeat string)
  66   :group 'picon)
  67
  68 (defcustom gnus-picon-domain-directories '("domains")
  69   "*List of directories to search for domain faces.
  70 Some people may want to add \"unknown\" to this list."
  71   :type '(repeat string)
  72   :group 'picon)
  73
  74 (defcustom gnus-picon-file-types
  75   (let ((types (list "xbm")))
  76     (when (gnus-image-type-available-p 'gif)
  77       (push "gif" types))
  78     (when (gnus-image-type-available-p 'xpm)
  79       (push "xpm" types))
  80     types)
  81   "*List of suffixes on picon file names to try."
  82   :type '(repeat string)
  83   :group 'picon)
  84
  85 (defface gnus-picon-xbm-face '((t (:foreground "black" :background "white")))
  86   "Face to show xbm picon in."
  87   :group 'picon)
  88
  89 (defface gnus-picon-face '((t (:foreground "black" :background "white")))
  90   "Face to show picon in."
  91   :group 'picon)
  92
  93 ;;; Internal variables:
  94
  95 (defvar gnus-picon-setup-p nil)
  96 (defvar gnus-picon-glyph-alist nil
  97   "Picon glyphs cache.
  98 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
  99 (defvar gnus-picon-cache nil)
 100
 101 ;;; Functions:
 102
 103 (defsubst gnus-picon-split-address (address)
 104   (setq address (split-string address "@"))
 105   (if (stringp (cadr address))
 106       (cons (car address) (split-string (cadr address) "\\."))
 107     (if (stringp (car address))
 108         (split-string (car address) "\\."))))
 109
 110 (defun gnus-picon-find-face (address directories &optional exact)
 111   (let* ((address (gnus-picon-split-address address))
 112          (user (pop address))
 113          (faddress address)
 114          database directory result instance base)
 115     (catch 'found
 116       (dolist (database gnus-picon-databases)
 117         (dolist (directory directories)
 118           (setq address faddress
 119                 base (expand-file-name directory database))
 120           (while address
 121             (when (setq result (gnus-picon-find-image
 122                                 (concat base "/" (mapconcat 'identity
 123                                                             (reverse address)
 124                                                             "/")
 125                                         "/" user "/")))
 126               (throw 'found result))
 127             (if exact
 128                 (setq address nil)
 129               (pop address)))
 130           ;; Kludge to search MISC as well.  But not in "news".
 131           (unless (string= directory "news")
 132             (when (setq result (gnus-picon-find-image
 133                                 (concat base "/MISC/" user "/")))
 134               (throw 'found result))))))))
 135
 136 (defun gnus-picon-find-image (directory)
 137   (let ((types gnus-picon-file-types)
 138         found type file)
 139     (while (and (not found)
 140                 (setq type (pop types)))
 141       (setq found (file-exists-p (setq file (concat directory "face." type)))))
 142     (if found
 143         file
 144       nil)))
 145
 146 (defun gnus-picon-insert-glyph (glyph category)
 147   "Insert GLYPH into the buffer.
 148 GLYPH can be either a glyph or a string."
 149   (if (stringp glyph)
 150       (insert glyph)
 151     (gnus-add-wash-type category)
 152     (gnus-add-image category (car glyph))
 153     (gnus-put-image (car glyph) (cdr glyph))))
 154
 155 (defun gnus-picon-create-glyph (file)
 156   (or (cdr (assoc file gnus-picon-glyph-alist))
 157       (cdar (push (cons file (gnus-create-image file))
 158                   gnus-picon-glyph-alist))))
 159
 160 ;;; Functions that does picon transformations:
 161
 162 (defun gnus-picon-transform-address (header category)
 163   (gnus-with-article-headers
 164     (let ((addresses
 165            (mail-header-parse-addresses (mail-fetch-field header)))
 166           spec file point cache)
 167       (dolist (address addresses)
 168         (setq address (car address))
 169         (when (and (stringp address)
 170                    (setq spec (gnus-picon-split-address address)))
 171           (if (setq cache (cdr (assoc address gnus-picon-cache)))
 172               (setq spec cache)
 173             (when (setq file (or (gnus-picon-find-face
 174                                   address gnus-picon-user-directories)
 175                                  (gnus-picon-find-face
 176                                   (concat "unknown@"
 177                                           (mapconcat
 178                                            'identity (cdr spec) "."))
 179                                   gnus-picon-user-directories)))
 180               (setcar spec (cons (gnus-picon-create-glyph file)
 181                                  (car spec))))
 182
 183             (dotimes (i (1- (length spec)))
 184               (when (setq file (gnus-picon-find-face
 185                                 (concat "unknown@"
 186                                         (mapconcat
 187                                          'identity (nthcdr (1+ i) spec) "."))
 188                                 gnus-picon-domain-directories t))
 189                 (setcar (nthcdr (1+ i) spec)
 190                         (cons (gnus-picon-create-glyph file)
 191                               (nth (1+ i) spec)))))
 192             (setq spec (nreverse spec))
 193             (push (cons address spec) gnus-picon-cache))
 194
 195           (gnus-article-goto-header header)
 196           (mail-header-narrow-to-field)
 197           (when (search-forward address nil t)
 198             (delete-region (match-beginning 0) (match-end 0))
 199             (setq point (point))
 200             (while spec
 201               (goto-char point)
 202               (if (> (length spec) 2)
 203                   (insert ".")
 204                 (if (= (length spec) 2)
 205                   (insert "@")))
 206               (gnus-picon-insert-glyph (pop spec) category))))))))
 207
 208 (defun gnus-picon-transform-newsgroups (header)
 209   (interactive)
 210   (gnus-with-article-headers
 211     (gnus-article-goto-header header)
 212     (mail-header-narrow-to-field)
 213     (let ((groups (message-tokenize-header (mail-fetch-field header)))
 214           spec file point)
 215       (dolist (group groups)
 216         (unless (setq spec (cdr (assoc group gnus-picon-cache)))
 217           (setq spec (nreverse (split-string group "[.]")))
 218           (dotimes (i (length spec))
 219             (when (setq file (gnus-picon-find-face
 220                               (concat "unknown@"
 221                                       (mapconcat
 222                                        'identity (nthcdr i spec) "."))
 223                               gnus-picon-news-directories t))
 224               (setcar (nthcdr i spec)
 225                       (cons (gnus-picon-create-glyph file)
 226                             (nth i spec)))))
 227             (push (cons group spec) gnus-picon-cache))
 228         (when (search-forward group nil t)
 229           (delete-region (match-beginning 0) (match-end 0))
 230           (save-restriction
 231             (narrow-to-region (point) (point))
 232             (while spec
 233               (goto-char (point-min))
 234               (if (> (length spec) 1)
 235                   (insert "."))
 236               (gnus-picon-insert-glyph (pop spec) 'newsgroups-picon))
 237             (goto-char (point-max))))))))
 238
 239 ;;; Commands:
 240
 241 ;;;###autoload
 242 (defun gnus-treat-from-picon ()
 243   "Display picons in the From header.
 244 If picons are already displayed, remove them."
 245   (interactive)
 246   (gnus-with-article-buffer
 247     (if (memq 'from-picon gnus-article-wash-types)
 248         (gnus-delete-images 'from-picon)
 249       (gnus-picon-transform-address "from" 'from-picon))))
 250
 251 ;;;###autoload
 252 (defun gnus-treat-mail-picon ()
 253   "Display picons in the Cc and To headers.
 254 If picons are already displayed, remove them."
 255   (interactive)
 256   (gnus-with-article-buffer
 257     (if (memq 'mail-picon gnus-article-wash-types)
 258         (gnus-delete-images 'mail-picon)
 259       (gnus-picon-transform-address "cc" 'mail-picon)
 260       (gnus-picon-transform-address "to" 'mail-picon))))
 261
 262 ;;;###autoload
 263 (defun gnus-treat-newsgroups-picon ()
 264   "Display picons in the Newsgroups and Followup-To headers.
 265 If picons are already displayed, remove them."
 266   (interactive)
 267   (gnus-with-article-buffer
 268     (if (memq 'newsgroups-picon gnus-article-wash-types)
 269         (gnus-delete-images 'newsgroups-picon)
 270       (gnus-picon-transform-newsgroups "newsgroups")
 271       (gnus-picon-transform-newsgroups "followup-to"))))
 272
 273 (provide 'gnus-picon)
 274
 275 ;;; gnus-picon.el ends here