cgit.sxemacs.org Git - gnus/blob - lisp/gnus-nocem.el

   1 ;;; gnus-nocem.el --- NoCeM pseudo-cancellation treatment
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'nnmail)
  32 (require 'gnus-art)
  33 (require 'gnus-sum)
  34 (require 'gnus-range)
  35
  36 (defgroup gnus-nocem nil
  37   "NoCeM pseudo-cancellation treatment."
  38   :group 'gnus-score)
  39
  40 (defcustom gnus-nocem-groups
  41   '("news.lists.filters" "news.admin.net-abuse.bulletins"
  42     "alt.nocem.misc" "news.admin.net-abuse.announce")
  43   "*List of groups that will be searched for NoCeM messages."
  44   :group 'gnus-nocem
  45   :type '(repeat (string :tag "Group")))
  46
  47 (defcustom gnus-nocem-issuers
  48   '("AutoMoose-1"                       ; CancelMoose[tm]
  49     "clewis@ferret.ocunix"              ; Chris Lewis
  50     "cosmo.roadkill"
  51     "SpamHippo"
  52     "hweede@snafu.de")
  53   "*List of NoCeM issuers to pay attention to.
  54
  55 This can also be a list of `(ISSUER CONDITION ...)' elements.
  56
  57 See <URL:http://www.xs4all.nl/~rosalind/nocemreg/nocemreg.html> for an
  58 issuer registry."
  59   :group 'gnus-nocem
  60   :link '(url-link "http://www.xs4all.nl/~rosalind/nocemreg/nocemreg.html")
  61   :type '(repeat (choice string sexp)))
  62
  63 (defcustom gnus-nocem-directory
  64   (nnheader-concat gnus-article-save-directory "NoCeM/")
  65   "*Directory where NoCeM files will be stored."
  66   :group 'gnus-nocem
  67   :type 'directory)
  68
  69 (defcustom gnus-nocem-expiry-wait 15
  70   "*Number of days to keep NoCeM headers in the cache."
  71   :group 'gnus-nocem
  72   :type 'integer)
  73
  74 (defcustom gnus-nocem-verifyer 'pgg-verify
  75   "*Function called to verify that the NoCeM message is valid.
  76 One likely value is `pgg-verify'.  If the function in this variable
  77 isn't bound, the message will be used unconditionally."
  78   :group 'gnus-nocem
  79   :type '(radio (function-item pgg-verify)
  80                 (function-item mc-verify)
  81                 (function :tag "other")))
  82
  83 (defcustom gnus-nocem-liberal-fetch nil
  84   "*If t try to fetch all messages which have @@NCM in the subject.
  85 Otherwise don't fetch messages which have references or whose message-id
  86 matches a previously scanned and verified nocem message."
  87   :group 'gnus-nocem
  88   :type 'boolean)
  89
  90 (defcustom gnus-nocem-check-article-limit 500
  91   "*If non-nil, the maximum number of articles to check in any NoCeM group."
  92   :group 'gnus-nocem
  93   :version "21.1"
  94   :type '(choice (const :tag "unlimited" nil)
  95                  (integer 1000)))
  96
  97 (defcustom gnus-nocem-check-from t
  98   "Non-nil means check for valid issuers in message bodies.
  99 Otherwise don't bother fetching articles unless their author matches a
 100 valid issuer, which is much faster if you are selective about the issuers."
 101   :group 'gnus-nocem
 102   :version "21.1"
 103   :type 'boolean)
 104
 105 ;;; Internal variables
 106
 107 (defvar gnus-nocem-active nil)
 108 (defvar gnus-nocem-alist nil)
 109 (defvar gnus-nocem-touched-alist nil)
 110 (defvar gnus-nocem-hashtb nil)
 111 (defvar gnus-nocem-seen-message-ids nil)
 112
 113 ;;; Functions
 114
 115 (defun gnus-nocem-active-file ()
 116   (concat (file-name-as-directory gnus-nocem-directory) "active"))
 117
 118 (defun gnus-nocem-cache-file ()
 119   (concat (file-name-as-directory gnus-nocem-directory) "cache"))
 120
 121 ;;
 122 ;; faster lookups for group names:
 123 ;;
 124
 125 (defvar gnus-nocem-real-group-hashtb nil
 126   "Real-name mappings of subscribed groups.")
 127
 128 (defun gnus-fill-real-hashtb ()
 129   "Fill up a hash table with the real-name mappings from the user's active file."
 130   (if (hash-table-p gnus-nocem-real-group-hashtb)
 131       (clrhash gnus-nocem-real-group-hashtb)
 132     (setq gnus-nocem-real-group-hashtb (make-hash-table :test 'equal)))
 133   (mapcar (lambda (group)
 134             (setq group (gnus-group-real-name (car group)))
 135             (puthash group t gnus-nocem-real-group-hashtb))
 136           gnus-newsrc-alist))
 137
 138 ;;;###autoload
 139 (defun gnus-nocem-scan-groups ()
 140   "Scan all NoCeM groups for new NoCeM messages."
 141   (interactive)
 142   (let ((groups gnus-nocem-groups)
 143         (gnus-inhibit-demon t)
 144         group active gactive articles check-headers)
 145     (gnus-make-directory gnus-nocem-directory)
 146     ;; Load any previous NoCeM headers.
 147     (gnus-nocem-load-cache)
 148     ;; Get the group name mappings:
 149     (gnus-fill-real-hashtb)
 150     ;; Read the active file if it hasn't been read yet.
 151     (and (file-exists-p (gnus-nocem-active-file))
 152          (not gnus-nocem-active)
 153          (ignore-errors
 154            (load (gnus-nocem-active-file) t t t)))
 155     ;; Go through all groups and see whether new articles have
 156     ;; arrived.
 157     (while (setq group (pop groups))
 158       (if (not (setq gactive (gnus-activate-group group)))
 159           ()                            ; This group doesn't exist.
 160         (setq active (nth 1 (assoc group gnus-nocem-active)))
 161         (when (and (not (< (cdr gactive) (car gactive))) ; Empty group.
 162                    (or (not active)
 163                        (< (cdr active) (cdr gactive))))
 164           ;; Ok, there are new articles in this group, se we fetch the
 165           ;; headers.
 166           (save-excursion
 167             (let ((dependencies (make-vector 10 nil))
 168                   headers header)
 169               (with-temp-buffer
 170                 (setq headers
 171                       (if (eq 'nov
 172                               (gnus-retrieve-headers
 173                                (setq articles
 174                                      (gnus-uncompress-range
 175                                       (cons
 176                                        (if active (1+ (cdr active))
 177                                          (car gactive))
 178                                        (cdr gactive))))
 179                                group))
 180                           (gnus-get-newsgroup-headers-xover
 181                            articles nil dependencies)
 182                         (gnus-get-newsgroup-headers dependencies)))
 183                 (while (setq header (pop headers))
 184                   ;; We take a closer look on all articles that have
 185                   ;; "@@NCM" in the subject.  Unless we already read
 186                   ;; this cross posted message.  Nocem messages
 187                   ;; are not allowed to have references, so we can
 188                   ;; ignore scanning followups.
 189                   (and (string-match "@@NCM" (mail-header-subject header))
 190                        (and gnus-nocem-check-from
 191                             (let ((case-fold-search t))
 192                               (catch 'ok
 193                                 (mapc
 194                                  (lambda (author)
 195                                    (if (consp author)
 196                                        (setq author (car author)))
 197                                    (if (string-match
 198                                         author (mail-header-from header))
 199                                        (throw 'ok t)))
 200                                  gnus-nocem-issuers)
 201                                 nil)))
 202                        (or gnus-nocem-liberal-fetch
 203                            (and (or (string= "" (mail-header-references
 204                                                  header))
 205                                     (null (mail-header-references header)))
 206                                 (not (member (mail-header-message-id header)
 207                                              gnus-nocem-seen-message-ids))))
 208                        (push header check-headers)))
 209                 (setq check-headers (last (nreverse check-headers)
 210                                           gnus-nocem-check-article-limit))
 211                 (let ((i 0)
 212                       (len (length check-headers)))
 213                   (dolist (h check-headers)
 214                     (gnus-message
 215                      7 "Checking article %d in %s for NoCeM (%d of %d)..."
 216                      (mail-header-number h) group (incf i) len)
 217                     (gnus-nocem-check-article group h)))))))
 218         (setq gnus-nocem-active
 219               (cons (list group gactive)
 220                     (delq (assoc group gnus-nocem-active)
 221                           gnus-nocem-active)))))
 222     ;; Save the results, if any.
 223     (gnus-nocem-save-cache)
 224     (gnus-nocem-save-active)))
 225
 226 (defun gnus-nocem-check-article (group header)
 227   "Check whether the current article is an NCM article and that we want it."
 228   ;; Get the article.
 229   (let ((date (mail-header-date header))
 230         (gnus-newsgroup-name group)
 231         issuer b e type)
 232     (when (or (not date)
 233               (time-less-p
 234                (time-since (date-to-time date))
 235                (days-to-time gnus-nocem-expiry-wait)))
 236       (gnus-request-article-this-buffer (mail-header-number header) group)
 237       (goto-char (point-min))
 238       (when (re-search-forward
 239              "-----BEGIN PGP\\(?: SIGNED\\)? MESSAGE-----"
 240              nil t)
 241         (delete-region (point-min) (match-beginning 0)))
 242       (when (re-search-forward
 243              "-----END PGP \\(?:MESSAGE\\|SIGNATURE\\)-----\n?"
 244              nil t)
 245         (delete-region (match-end 0) (point-max)))
 246       (goto-char (point-min))
 247       ;; The article has to have proper NoCeM headers.
 248       (when (and (setq b (search-forward "\n@@BEGIN NCM HEADERS\n" nil t))
 249                  (setq e (search-forward "\n@@BEGIN NCM BODY\n" nil t)))
 250         ;; We get the name of the issuer.
 251         (narrow-to-region b e)
 252         (setq issuer (mail-fetch-field "issuer")
 253               type (mail-fetch-field "type"))
 254         (widen)
 255         (if (not (gnus-nocem-message-wanted-p issuer type))
 256             (message "invalid NoCeM issuer: %s" issuer)
 257           (and (gnus-nocem-verify-issuer issuer) ; She is who she says she is.
 258                (gnus-nocem-enter-article) ; We gobble the message.
 259                (push (mail-header-message-id header) ; But don't come back for
 260                      gnus-nocem-seen-message-ids))))))) ; second helpings.
 261
 262 (defun gnus-nocem-message-wanted-p (issuer type)
 263   (let ((issuers gnus-nocem-issuers)
 264         wanted conditions condition)
 265     (cond
 266      ;; Do the quick check first.
 267      ((member issuer issuers)
 268       t)
 269      ((setq conditions (cdr (assoc issuer issuers)))
 270       ;; Check whether we want this type.
 271       (while (setq condition (pop conditions))
 272         (cond
 273          ((stringp condition)
 274           (when (string-match condition type)
 275             (setq wanted t)))
 276          ((and (consp condition)
 277                (eq (car condition) 'not)
 278                (stringp (cadr condition)))
 279           (when (string-match (cadr condition) type)
 280             (setq wanted nil)))
 281          (t
 282           (error "Invalid NoCeM condition: %S" condition))))
 283       wanted))))
 284
 285 (defun gnus-nocem-verify-issuer (person)
 286   "Verify using PGP that the canceler is who she says she is."
 287   (if (functionp gnus-nocem-verifyer)
 288       (ignore-errors
 289         (funcall gnus-nocem-verifyer))
 290     ;; If we don't have Mailcrypt, then we use the message anyway.
 291     t))
 292
 293 (defun gnus-nocem-enter-article ()
 294   "Enter the current article into the NoCeM cache."
 295   (goto-char (point-min))
 296   (let ((b (search-forward "\n@@BEGIN NCM BODY\n" nil t))
 297         (e (search-forward "\n@@END NCM BODY\n" nil t))
 298         (buf (current-buffer))
 299         ncm id group)
 300     (when (and b e)
 301       (narrow-to-region b (1+ (match-beginning 0)))
 302       (goto-char (point-min))
 303       (while (search-forward "\t" nil t)
 304         (cond
 305          ((not (ignore-errors
 306                  (setq group (gnus-group-real-name (symbol-name (read buf))))
 307                  (gethash group gnus-nocem-real-group-hashtb)))
 308           ;; An error.
 309           )
 310          (t
 311           ;; Valid group.
 312           (beginning-of-line)
 313           (while (eq (char-after) ?\t)
 314             (forward-line -1))
 315           (setq id (buffer-substring (point) (1- (search-forward "\t"))))
 316           (unless (if (hash-table-p gnus-nocem-hashtb)
 317                       (gethash id gnus-nocem-hashtb)
 318                     (setq gnus-nocem-hashtb (make-hash-table :test 'equal))
 319                     nil)
 320             ;; only store if not already present
 321             (puthash id t gnus-nocem-hashtb)
 322             (push id ncm))
 323           (forward-line 1)
 324           (while (eq (char-after) ?\t)
 325             (forward-line 1)))))
 326       (when ncm
 327         (setq gnus-nocem-touched-alist t)
 328         (push (cons (let ((time (current-time))) (setcdr (cdr time) nil) time)
 329                     ncm)
 330               gnus-nocem-alist))
 331       t)))
 332
 333 ;;;###autoload
 334 (defun gnus-nocem-load-cache ()
 335   "Load the NoCeM cache."
 336   (interactive)
 337   (unless gnus-nocem-alist
 338     ;; The buffer doesn't exist, so we create it and load the NoCeM
 339     ;; cache.
 340     (when (file-exists-p (gnus-nocem-cache-file))
 341       (load (gnus-nocem-cache-file) t t t)
 342       (gnus-nocem-alist-to-hashtb))))
 343
 344 (defun gnus-nocem-save-cache ()
 345   "Save the NoCeM cache."
 346   (when (and gnus-nocem-alist
 347              gnus-nocem-touched-alist)
 348     (with-temp-file (gnus-nocem-cache-file)
 349       (gnus-prin1 `(setq gnus-nocem-alist ',gnus-nocem-alist)))
 350     (setq gnus-nocem-touched-alist nil)))
 351
 352 (defun gnus-nocem-save-active ()
 353   "Save the NoCeM active file."
 354   (with-temp-file (gnus-nocem-active-file)
 355     (gnus-prin1 `(setq gnus-nocem-active ',gnus-nocem-active))))
 356
 357 (defun gnus-nocem-alist-to-hashtb ()
 358   "Create a hashtable from the Message-IDs we have."
 359   (let* ((alist gnus-nocem-alist)
 360          (pprev (cons nil alist))
 361          (prev pprev)
 362          (expiry (days-to-time gnus-nocem-expiry-wait))
 363          entry)
 364     (if (hash-table-p gnus-nocem-hashtb)
 365         (clrhash gnus-nocem-hashtb)
 366       (setq gnus-nocem-hashtb (make-hash-table :test 'equal)))
 367     (while (setq entry (car alist))
 368       (if (not (time-less-p (time-since (car entry)) expiry))
 369           ;; This entry has expired, so we remove it.
 370           (setcdr prev (cdr alist))
 371         (setq prev alist)
 372         ;; This is ok, so we enter it into the hashtable.
 373         (setq entry (cdr entry))
 374         (while entry
 375           (puthash (car entry) t gnus-nocem-hashtb)
 376           (setq entry (cdr entry))))
 377       (setq alist (cdr alist)))))
 378
 379 (gnus-add-shutdown 'gnus-nocem-close 'gnus)
 380
 381 (defun gnus-nocem-close ()
 382   "Clear internal NoCeM variables."
 383   (setq gnus-nocem-alist nil
 384         gnus-nocem-hashtb nil
 385         gnus-nocem-active nil
 386         gnus-nocem-touched-alist nil
 387         gnus-nocem-seen-message-ids nil
 388         gnus-nocem-real-group-hashtb nil))
 389
 390 (defun gnus-nocem-unwanted-article-p (id)
 391   "Say whether article ID in the current group is wanted."
 392   (and gnus-nocem-hashtb
 393        (gethash id gnus-nocem-hashtb)))
 394
 395 (provide 'gnus-nocem)
 396
 397 ;; arch-tag: 0e0c74ea-2f8e-4f3e-8fff-09f767c1adef
 398 ;;; gnus-nocem.el ends here