cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-ems)
  31 (require 'message)
  32 (require 'gnus-art)
  33
  34 ;; Added by Sudish Joseph <joseph@cis.ohio-state.edu>.
  35 (defvar gnus-post-method nil
  36   "*Preferred method for posting USENET news.
  37 If this variable is nil, Gnus will use the current method to decide
  38 which method to use when posting.  If it is non-nil, it will override
  39 the current method.  This method will not be used in mail groups and
  40 the like, only in \"real\" newsgroups.
  41
  42 The value must be a valid method as discussed in the documentation of
  43 `gnus-select-method'.  It can also be a list of methods.  If that is
  44 the case, the user will be queried for what select method to use when
  45 posting.")
  46
  47 (defvar gnus-outgoing-message-group nil
  48   "*All outgoing messages will be put in this group.
  49 If you want to store all your outgoing mail and articles in the group
  50 \"nnml:archive\", you set this variable to that value.  This variable
  51 can also be a list of group names.
  52
  53 If you want to have greater control over what group to put each
  54 message in, you can set this variable to a function that checks the
  55 current newsgroup name and then returns a suitable group name (or list
  56 of names).")
  57
  58 (defvar gnus-mailing-list-groups nil
  59   "*Regexp matching groups that are really mailing lists.
  60 This is useful when you're reading a mailing list that has been
  61 gatewayed to a newsgroup, and you want to followup to an article in
  62 the group.")
  63
  64 (defvar gnus-sent-message-ids-file
  65   (nnheader-concat gnus-directory "Sent-Message-IDs")
  66   "File where Gnus saves a cache of sent message ids.")
  67
  68 (defvar gnus-sent-message-ids-length 1000
  69   "The number of sent Message-IDs to save.")
  70
  71 (defvar gnus-crosspost-complaint
  72   "Hi,
  73
  74 You posted the article below with the following Newsgroups header:
  75
  76 Newsgroups: %s
  77
  78 The %s group, at least, was an inappropriate recipient
  79 of this message.  Please trim your Newsgroups header to exclude this
  80 group before posting in the future.
  81
  82 Thank you.
  83
  84 "
  85   "Format string to be inserted when complaining about crossposts.
  86 The first %s will be replaced by the Newsgroups header;
  87 the second with the current group name.")
  88
  89 ;;; Internal variables.
  90
  91 (defvar gnus-message-buffer "*Mail Gnus*")
  92 (defvar gnus-article-copy nil)
  93 (defvar gnus-last-posting-server nil)
  94
  95 (defconst gnus-bug-message
  96   "Sending a bug report to the Gnus Towers.
  97 ========================================
  98
  99 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 100 be sent to the Gnus Bug Exterminators.
 101
 102 At the bottom of the buffer you'll see lots of variable settings.
 103 Please do not delete those.  They will tell the Bug People what your
 104 environment is, so that it will be easier to locate the bugs.
 105
 106 If you have found a bug that makes Emacs go \"beep\", set
 107 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 108 and include the backtrace in your bug report.
 109
 110 Please describe the bug in annoying, painstaking detail.
 111
 112 Thank you for your help in stamping out bugs.
 113 ")
 114
 115 (eval-and-compile
 116   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 117   (autoload 'news-setup "rnewspost")
 118   (autoload 'news-reply-mode "rnewspost")
 119   (autoload 'rmail-dont-reply-to "mail-utils")
 120   (autoload 'rmail-output "rmailout"))
 121
 122 \f
 123 ;;;
 124 ;;; Gnus Posting Functions
 125 ;;;
 126
 127 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 128   "p" gnus-summary-post-news
 129   "f" gnus-summary-followup
 130   "F" gnus-summary-followup-with-original
 131   "c" gnus-summary-cancel-article
 132   "s" gnus-summary-supersede-article
 133   "r" gnus-summary-reply
 134   "R" gnus-summary-reply-with-original
 135   "n" gnus-summary-followup-to-mail
 136   "N" gnus-summary-followup-to-mail-with-original
 137   "m" gnus-summary-mail-other-window
 138   "u" gnus-uu-post-news
 139   "\M-c" gnus-summary-mail-crosspost-complaint
 140   "om" gnus-summary-mail-forward
 141   "op" gnus-summary-post-forward
 142   "Om" gnus-uu-digest-mail-forward
 143   "Op" gnus-uu-digest-post-forward)
 144
 145 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 146   "b" gnus-summary-resend-bounced-mail
 147   ;; "c" gnus-summary-send-draft
 148   "r" gnus-summary-resend-message)
 149
 150 ;;; Internal functions.
 151
 152 (defvar gnus-article-reply nil)
 153 (defmacro gnus-setup-message (config &rest forms)
 154   (let ((winconf (make-symbol "winconf"))
 155         (buffer (make-symbol "buffer"))
 156         (article (make-symbol "article")))
 157     `(let ((,winconf (current-window-configuration))
 158            (,buffer (buffer-name (current-buffer)))
 159            (,article (and gnus-article-reply (gnus-summary-article-number)))
 160            (message-header-setup-hook
 161             (copy-sequence message-header-setup-hook)))
 162        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 163        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 164        ,@forms
 165        (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 166        (setq gnus-message-buffer (current-buffer))
 167        (make-local-variable 'gnus-newsgroup-name)
 168        (gnus-configure-windows ,config t))))
 169
 170 (defun gnus-inews-add-send-actions (winconf buffer article)
 171   (gnus-make-local-hook 'message-sent-hook)
 172   (gnus-add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 173   (setq message-post-method
 174         `(lambda (arg)
 175            (gnus-post-method arg ,gnus-newsgroup-name)))
 176   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 177   (message-add-action
 178    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 179   (message-add-action
 180    `(when (buffer-name (get-buffer ,buffer))
 181       (save-excursion
 182         (set-buffer (get-buffer ,buffer))
 183         ,(when article
 184            `(gnus-summary-mark-article-as-replied ,article))))
 185    'send))
 186
 187 (put 'gnus-setup-message 'lisp-indent-function 1)
 188 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 189
 190 ;;; Post news commands of Gnus group mode and summary mode
 191
 192 (defun gnus-group-mail ()
 193   "Start composing a mail."
 194   (interactive)
 195   (gnus-setup-message 'message
 196     (message-mail)))
 197
 198 (defun gnus-group-post-news (&optional arg)
 199   "Start composing a news message.
 200 If ARG, post to the group under point.
 201 If ARG is 1, prompt for a group name."
 202   (interactive "P")
 203   ;; Bind this variable here to make message mode hooks
 204   ;; work ok.
 205   (let ((gnus-newsgroup-name
 206          (if arg
 207              (if (= 1 (prefix-numeric-value arg))
 208                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 209                                   (gnus-read-active-file-p))
 210                (gnus-group-group-name))
 211            "")))
 212     (gnus-post-news 'post gnus-newsgroup-name)))
 213
 214 (defun gnus-summary-post-news ()
 215   "Start composing a news message."
 216   (interactive)
 217   (gnus-set-global-variables)
 218   (gnus-post-news 'post gnus-newsgroup-name))
 219
 220 (defun gnus-summary-followup (yank &optional force-news)
 221   "Compose a followup to an article.
 222 If prefix argument YANK is non-nil, original article is yanked automatically."
 223   (interactive
 224    (list (and current-prefix-arg
 225               (gnus-summary-work-articles 1))))
 226   (gnus-set-global-variables)
 227   (when yank
 228     (gnus-summary-goto-subject (car yank)))
 229   (save-window-excursion
 230     (gnus-summary-select-article))
 231   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 232         (gnus-newsgroup-name gnus-newsgroup-name))
 233     ;; Send a followup.
 234     (gnus-post-news nil gnus-newsgroup-name
 235                     headers gnus-article-buffer
 236                     yank nil force-news)))
 237
 238 (defun gnus-summary-followup-with-original (n &optional force-news)
 239   "Compose a followup to an article and include the original article."
 240   (interactive "P")
 241   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 242
 243 (defun gnus-summary-followup-to-mail (&optional arg)
 244   "Followup to the current mail message via news."
 245   (interactive
 246    (list (and current-prefix-arg
 247               (gnus-summary-work-articles 1))))
 248   (gnus-summary-followup arg t))
 249
 250 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 251   "Followup to the current mail message via news."
 252   (interactive "P")
 253   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 254
 255 (defun gnus-inews-yank-articles (articles)
 256   (let (beg article)
 257     (message-goto-body)
 258     (while (setq article (pop articles))
 259       (save-window-excursion
 260         (set-buffer gnus-summary-buffer)
 261         (gnus-summary-select-article nil nil nil article)
 262         (gnus-summary-remove-process-mark article))
 263       (gnus-copy-article-buffer)
 264       (let ((message-reply-buffer gnus-article-copy)
 265             (message-reply-headers gnus-current-headers))
 266         (message-yank-original)
 267         (setq beg (or beg (mark t))))
 268       (when articles
 269         (insert "\n")))
 270     (push-mark)
 271     (goto-char beg)))
 272
 273 (defun gnus-summary-cancel-article (n)
 274   "Cancel an article you posted."
 275   (interactive "P")
 276   (gnus-set-global-variables)
 277   (let ((articles (gnus-summary-work-articles n))
 278         (message-post-method
 279          `(lambda (arg)
 280             (gnus-post-method nil ,gnus-newsgroup-name)))
 281         article)
 282     (while (setq article (pop articles))
 283       (when (gnus-summary-select-article t nil nil article)
 284         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 285                 (message-cancel-news))
 286           (gnus-summary-mark-as-read article gnus-canceled-mark)
 287           (gnus-cache-remove-article 1))
 288         (gnus-article-hide-headers-if-wanted))
 289       (gnus-summary-remove-process-mark article))))
 290
 291 (defun gnus-summary-supersede-article ()
 292   "Compose an article that will supersede a previous article.
 293 This is done simply by taking the old article and adding a Supersedes
 294 header line with the old Message-ID."
 295   (interactive)
 296   (gnus-set-global-variables)
 297   (let ((article (gnus-summary-article-number)))
 298     (gnus-setup-message 'reply-yank
 299       (gnus-summary-select-article t)
 300       (set-buffer gnus-original-article-buffer)
 301       (message-supersede)
 302       (push
 303        `((lambda ()
 304            (gnus-cache-possibly-remove-article ,article nil nil nil t)))
 305        message-send-actions))))
 306
 307 \f
 308
 309 (defun gnus-copy-article-buffer (&optional article-buffer)
 310   ;; make a copy of the article buffer with all text properties removed
 311   ;; this copy is in the buffer gnus-article-copy.
 312   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 313   ;; this buffer should be passed to all mail/news reply/post routines.
 314   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 315   (buffer-disable-undo gnus-article-copy)
 316   (or (memq gnus-article-copy gnus-buffer-list)
 317       (push gnus-article-copy gnus-buffer-list))
 318   (let ((article-buffer (or article-buffer gnus-article-buffer))
 319         end beg contents)
 320     (if (not (and (get-buffer article-buffer)
 321                   (buffer-name (get-buffer article-buffer))))
 322         (error "Can't find any article buffer")
 323       (save-excursion
 324         (set-buffer article-buffer)
 325         (save-restriction
 326           ;; Copy over the (displayed) article buffer, delete
 327           ;; hidden text and remove text properties.
 328           (widen)
 329           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 330           (set-buffer gnus-article-copy)
 331           (gnus-article-delete-text-of-type 'annotation)
 332           (gnus-remove-text-with-property 'gnus-prev)
 333           (gnus-remove-text-with-property 'gnus-next)
 334           (insert
 335            (prog1
 336                (format "%s" (buffer-string))
 337              (erase-buffer)))
 338           ;; Find the original headers.
 339           (set-buffer gnus-original-article-buffer)
 340           (goto-char (point-min))
 341           (while (looking-at message-unix-mail-delimiter)
 342             (forward-line 1))
 343           (setq beg (point))
 344           (setq end (or (search-forward "\n\n" nil t) (point)))
 345           ;; Delete the headers from the displayed articles.
 346           (set-buffer gnus-article-copy)
 347           (delete-region (goto-char (point-min))
 348                          (or (search-forward "\n\n" nil t) (point)))
 349           ;; Insert the original article headers.
 350           (insert-buffer-substring gnus-original-article-buffer beg end)
 351           (gnus-article-decode-rfc1522)))
 352       gnus-article-copy)))
 353
 354 (defun gnus-post-news (post &optional group header article-buffer yank subject
 355                             force-news)
 356   (when article-buffer
 357     (gnus-copy-article-buffer))
 358   (let ((gnus-article-reply article-buffer))
 359     (gnus-setup-message (cond (yank 'reply-yank)
 360                               (article-buffer 'reply)
 361                               (t 'message))
 362       (let* ((group (or group gnus-newsgroup-name))
 363              (pgroup group)
 364              to-address to-group mailing-list to-list
 365              newsgroup-p)
 366         (when group
 367           (setq to-address (gnus-group-find-parameter group 'to-address)
 368                 to-group (gnus-group-find-parameter group 'to-group)
 369                 to-list (gnus-group-find-parameter group 'to-list)
 370                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 371                 mailing-list (when gnus-mailing-list-groups
 372                                (string-match gnus-mailing-list-groups group))
 373                 group (gnus-group-real-name group)))
 374         (if (or (and to-group
 375                      (gnus-news-group-p to-group))
 376                 newsgroup-p
 377                 force-news
 378                 (and (gnus-news-group-p
 379                       (or pgroup gnus-newsgroup-name)
 380                       (if header (mail-header-number header)
 381                         gnus-current-article))
 382                      (not mailing-list)
 383                      (not to-list)
 384                      (not to-address)))
 385             ;; This is news.
 386             (if post
 387                 (message-news (or to-group group))
 388               (set-buffer gnus-article-copy)
 389               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 390           ;; The is mail.
 391           (if post
 392               (progn
 393                 (message-mail (or to-address to-list))
 394                 ;; Arrange for mail groups that have no `to-address' to
 395                 ;; get that when the user sends off the mail.
 396                 (push (list 'gnus-inews-add-to-address group)
 397                       message-send-actions))
 398             (set-buffer gnus-article-copy)
 399             (message-wide-reply to-address)))
 400         (when yank
 401           (gnus-inews-yank-articles yank))))))
 402
 403 (defun gnus-post-method (arg group &optional silent)
 404   "Return the posting method based on GROUP and ARG.
 405 If SILENT, don't prompt the user."
 406   (let ((group-method (gnus-find-method-for-group group)))
 407     (cond
 408      ;; If the group-method is nil (which shouldn't happen) we use
 409      ;; the default method.
 410      ((null group-method)
 411       (or gnus-post-method gnus-select-method message-post-method))
 412      ;; We want this group's method.
 413      ((and arg (not (eq arg 0)))
 414       group-method)
 415      ;; We query the user for a post method.
 416      ((or arg
 417           (and gnus-post-method
 418                (listp (car gnus-post-method))))
 419       (let* ((methods
 420               ;; Collect all methods we know about.
 421               (append
 422                (when gnus-post-method
 423                  (if (listp (car gnus-post-method))
 424                      gnus-post-method
 425                    (list gnus-post-method)))
 426                gnus-secondary-select-methods
 427                (list gnus-select-method)
 428                (list group-method)))
 429              method-alist post-methods method)
 430         ;; Weed out all mail methods.
 431         (while methods
 432           (setq method (gnus-server-get-method "" (pop methods)))
 433           (when (or (gnus-method-option-p method 'post)
 434                     (gnus-method-option-p method 'post-mail))
 435             (push method post-methods)))
 436         ;; Create a name-method alist.
 437         (setq method-alist
 438               (mapcar
 439                (lambda (m)
 440                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 441                post-methods))
 442         ;; Query the user.
 443         (cadr
 444          (assoc
 445           (setq gnus-last-posting-server
 446                 (if (and silent
 447                          gnus-last-posting-server)
 448                     ;; Just use the last value.
 449                     gnus-last-posting-server
 450                   (completing-read
 451                    "Posting method: " method-alist nil t
 452                    (cons (or gnus-last-posting-server "") 0))))
 453           method-alist))))
 454      ;; Override normal method.
 455      (gnus-post-method
 456       gnus-post-method)
 457      ;; Use the normal select method.
 458      (t gnus-select-method))))
 459
 460 (defun gnus-inews-narrow-to-headers ()
 461   (widen)
 462   (narrow-to-region
 463    (goto-char (point-min))
 464    (or (and (re-search-forward
 465              (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 466             (match-beginning 0))
 467        (point-max)))
 468   (goto-char (point-min)))
 469
 470 ;;;
 471 ;;; Check whether the message has been sent already.
 472 ;;;
 473
 474 (defvar gnus-inews-sent-ids nil)
 475
 476 (defun gnus-inews-reject-message ()
 477   "Check whether this message has already been sent."
 478   (when gnus-sent-message-ids-file
 479     (let ((message-id (save-restriction (gnus-inews-narrow-to-headers)
 480                                         (mail-fetch-field "message-id")))
 481           end)
 482       (when message-id
 483         (unless gnus-inews-sent-ids
 484           (ignore-errors
 485             (load t t t)))
 486         (if (member message-id gnus-inews-sent-ids)
 487             ;; Reject this message.
 488             (not (gnus-yes-or-no-p
 489                   (format "Message %s already sent.  Send anyway? "
 490                           message-id)))
 491           (push message-id gnus-inews-sent-ids)
 492           ;; Chop off the last Message-IDs.
 493           (when (setq end (nthcdr gnus-sent-message-ids-length
 494                                   gnus-inews-sent-ids))
 495             (setcdr end nil))
 496           (nnheader-temp-write gnus-sent-message-ids-file
 497             (gnus-prin1 `(setq gnus-inews-sent-ids ',gnus-inews-sent-ids)))
 498           nil)))))
 499
 500 \f
 501
 502 ;; Dummy to avoid byte-compile warning.
 503 (defvar nnspool-rejected-article-hook)
 504
 505 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 506 ;;; as well include the Emacs version as well.
 507 ;;; The following function works with later GNU Emacs, and XEmacs.
 508 (defun gnus-extended-version ()
 509   "Stringified Gnus version and Emacs version"
 510   (interactive)
 511   (concat
 512    gnus-version
 513    "/"
 514    (cond
 515     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 516      (concat "Emacs " (substring emacs-version
 517                                  (match-beginning 1)
 518                                  (match-end 1))))
 519     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)" emacs-version)
 520      (concat (substring emacs-version
 521                         (match-beginning 1)
 522                         (match-end 1))
 523              (format " %d.%d" emacs-major-version emacs-minor-version)))
 524     (t emacs-version))))
 525
 526 ;; Written by "Mr. Per Persson" <pp@gnu.ai.mit.edu>.
 527 (defun gnus-inews-insert-mime-headers ()
 528   (goto-char (point-min))
 529   (let ((mail-header-separator
 530          (progn
 531            (goto-char (point-min))
 532            (if (and (search-forward (concat "\n" mail-header-separator "\n")
 533                                     nil t)
 534                     (not (search-backward "\n\n" nil t)))
 535                mail-header-separator
 536              ""))))
 537     (or (mail-position-on-field "Mime-Version")
 538         (insert "1.0")
 539         (cond ((save-restriction
 540                  (widen)
 541                  (goto-char (point-min))
 542                  (re-search-forward "[\200-\377]" nil t))
 543                (or (mail-position-on-field "Content-Type")
 544                    (insert "text/plain; charset=ISO-8859-1"))
 545                (or (mail-position-on-field "Content-Transfer-Encoding")
 546                    (insert "8bit")))
 547               (t (or (mail-position-on-field "Content-Type")
 548                      (insert "text/plain; charset=US-ASCII"))
 549                  (or (mail-position-on-field "Content-Transfer-Encoding")
 550                      (insert "7bit")))))))
 551
 552 \f
 553 ;;;
 554 ;;; Gnus Mail Functions
 555 ;;;
 556
 557 ;;; Mail reply commands of Gnus summary mode
 558
 559 (defun gnus-summary-reply (&optional yank)
 560   "Reply mail to news author.
 561 If prefix argument YANK is non-nil, original article is yanked automatically."
 562   (interactive
 563    (list (and current-prefix-arg
 564               (gnus-summary-work-articles 1))))
 565   ;; Bug fix by jbw@bigbird.bu.edu (Joe Wells)
 566   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 567   (gnus-set-global-variables)
 568   (when yank
 569     (gnus-summary-goto-subject (car yank)))
 570   (let ((gnus-article-reply t))
 571     (gnus-setup-message (if yank 'reply-yank 'reply)
 572       (gnus-summary-select-article)
 573       (set-buffer (gnus-copy-article-buffer))
 574       (message-reply nil nil (gnus-group-find-parameter
 575                               gnus-newsgroup-name 'broken-reply-to))
 576       (when yank
 577         (gnus-inews-yank-articles yank)))))
 578
 579 (defun gnus-summary-reply-with-original (n)
 580   "Reply mail to news author with original article."
 581   (interactive "P")
 582   (gnus-summary-reply (gnus-summary-work-articles n)))
 583
 584 (defun gnus-summary-mail-forward (&optional full-headers post)
 585   "Forward the current message to another user.
 586 If FULL-HEADERS (the prefix), include full headers when forwarding."
 587   (interactive "P")
 588   (gnus-set-global-variables)
 589   (gnus-setup-message 'forward
 590     (gnus-summary-select-article)
 591     (set-buffer gnus-original-article-buffer)
 592     (let ((message-included-forward-headers
 593            (if full-headers "" message-included-forward-headers)))
 594       (message-forward post))))
 595
 596 (defun gnus-summary-resend-message (address)
 597   "Resend the current article to ADDRESS."
 598   (interactive "sResend message to: ")
 599   (gnus-summary-select-article)
 600   (save-excursion
 601     (set-buffer gnus-original-article-buffer)
 602     (message-resend address)))
 603
 604 (defun gnus-summary-post-forward (&optional full-headers)
 605   "Forward the current article to a newsgroup.
 606 If FULL-HEADERS (the prefix), include full headers when forwarding."
 607   (interactive "P")
 608   (gnus-summary-mail-forward full-headers t))
 609
 610 (defvar gnus-nastygram-message
 611   "The following article was inappropriately posted to %s.\n\n"
 612   "Format string to insert in nastygrams.
 613 The current group name will be inserted at \"%s\".")
 614
 615 (defun gnus-summary-mail-nastygram (n)
 616   "Send a nastygram to the author of the current article."
 617   (interactive "P")
 618   (when (or gnus-expert-user
 619             (gnus-y-or-n-p
 620              "Really send a nastygram to the author of the current article? "))
 621     (let ((group gnus-newsgroup-name))
 622       (gnus-summary-reply-with-original n)
 623       (set-buffer gnus-message-buffer)
 624       (message-goto-body)
 625       (insert (format gnus-nastygram-message group))
 626       (message-send-and-exit))))
 627
 628 (defun gnus-summary-mail-crosspost-complaint (n)
 629   "Send a complaint about crossposting to the current article(s)."
 630   (interactive "P")
 631   (let ((articles (gnus-summary-work-articles n))
 632         article)
 633     (while (setq article (pop articles))
 634       (set-buffer gnus-summary-buffer)
 635       (gnus-summary-goto-subject article)
 636       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 637             newsgroups followup-to)
 638         (gnus-summary-select-article)
 639         (set-buffer gnus-original-article-buffer)
 640         (if (and (<= (length (message-tokenize-header
 641                               (setq newsgroups (mail-fetch-field "newsgroups"))
 642                               ", "))
 643                      1)
 644                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 645                      (not (member group (message-tokenize-header
 646                                          followup-to ", ")))))
 647             (if followup-to
 648                 (gnus-message 1 "Followup-to restricted")
 649               (gnus-message 1 "Not a crossposted article"))
 650           (set-buffer gnus-summary-buffer)
 651           (gnus-summary-reply-with-original 1)
 652           (set-buffer gnus-message-buffer)
 653           (message-goto-body)
 654           (insert (format gnus-crosspost-complaint newsgroups group))
 655           (message-goto-subject)
 656           (re-search-forward " *$")
 657           (replace-match " (crosspost notification)" t t)
 658           (when (gnus-y-or-n-p "Send this complaint? ")
 659             (message-send-and-exit)))))))
 660
 661 (defun gnus-summary-mail-other-window ()
 662   "Compose mail in other window."
 663   (interactive)
 664   (gnus-setup-message 'message
 665     (message-mail)))
 666
 667 (defun gnus-mail-parse-comma-list ()
 668   (let (accumulated
 669         beg)
 670     (skip-chars-forward " ")
 671     (while (not (eobp))
 672       (setq beg (point))
 673       (skip-chars-forward "^,")
 674       (while (zerop
 675               (save-excursion
 676                 (save-restriction
 677                   (let ((i 0))
 678                     (narrow-to-region beg (point))
 679                     (goto-char beg)
 680                     (logand (progn
 681                               (while (search-forward "\"" nil t)
 682                                 (incf i))
 683                               (if (zerop i) 2 i))
 684                             2)))))
 685         (skip-chars-forward ",")
 686         (skip-chars-forward "^,"))
 687       (skip-chars-backward " ")
 688       (push (buffer-substring beg (point))
 689             accumulated)
 690       (skip-chars-forward "^,")
 691       (skip-chars-forward ", "))
 692     accumulated))
 693
 694 (defun gnus-inews-add-to-address (group)
 695   (let ((to-address (mail-fetch-field "to")))
 696     (when (and to-address
 697                (gnus-alive-p))
 698       ;; This mail group doesn't have a `to-list', so we add one
 699       ;; here.  Magic!
 700       (gnus-group-add-parameter group (cons 'to-list to-address)))))
 701
 702 (defun gnus-put-message ()
 703   "Put the current message in some group and return to Gnus."
 704   (interactive)
 705   (let ((reply gnus-article-reply)
 706         (winconf gnus-prev-winconf)
 707         (group gnus-newsgroup-name))
 708
 709     (or (and group (not (gnus-group-read-only-p group)))
 710         (setq group (read-string "Put in group: " nil
 711                                  (gnus-writable-groups))))
 712     (when (gnus-gethash group gnus-newsrc-hashtb)
 713       (error "No such group: %s" group))
 714
 715     (save-excursion
 716       (save-restriction
 717         (widen)
 718         (gnus-inews-narrow-to-headers)
 719         (let (gnus-deletable-headers)
 720           (if (message-news-p)
 721               (message-generate-headers message-required-news-headers)
 722             (message-generate-headers message-required-mail-headers)))
 723         (goto-char (point-max))
 724         (insert "Gcc: " group "\n")
 725         (widen)))
 726
 727     (gnus-inews-do-gcc)
 728
 729     (when (get-buffer gnus-group-buffer)
 730       (when (gnus-buffer-exists-p (car-safe reply))
 731         (set-buffer (car reply))
 732         (and (cdr reply)
 733              (gnus-summary-mark-article-as-replied
 734               (cdr reply))))
 735       (when winconf
 736         (set-window-configuration winconf)))))
 737
 738 (defun gnus-article-mail (yank)
 739   "Send a reply to the address near point.
 740 If YANK is non-nil, include the original article."
 741   (interactive "P")
 742   (let ((address
 743          (buffer-substring
 744           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 745           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 746     (when address
 747       (message-reply address)
 748       (when yank
 749         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 750
 751 (defvar nntp-server-type)
 752 (defun gnus-bug ()
 753   "Send a bug report to the Gnus maintainers."
 754   (interactive)
 755   (unless (gnus-alive-p)
 756     (error "Gnus has been shut down"))
 757   (gnus-setup-message 'bug
 758     (delete-other-windows)
 759     (switch-to-buffer "*Gnus Help Bug*")
 760     (erase-buffer)
 761     (insert gnus-bug-message)
 762     (goto-char (point-min))
 763     (message-pop-to-buffer "*Gnus Bug*")
 764     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 765     (push `(gnus-bug-kill-buffer) message-send-actions)
 766     (goto-char (point-min))
 767     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 768     (forward-line 1)
 769     (insert (gnus-version) "\n")
 770     (insert (emacs-version) "\n")
 771     (when (and (boundp 'nntp-server-type)
 772                (stringp nntp-server-type))
 773       (insert nntp-server-type))
 774     (insert "\n\n\n\n\n")
 775     (gnus-debug)
 776     (goto-char (point-min))
 777     (search-forward "Subject: " nil t)
 778     (message "")))
 779
 780 (defun gnus-bug-kill-buffer ()
 781   (when (get-buffer "*Gnus Help Bug*")
 782     (kill-buffer "*Gnus Help Bug*")))
 783
 784 (defun gnus-debug ()
 785   "Attempts to go through the Gnus source file and report what variables have been changed.
 786 The source file has to be in the Emacs load path."
 787   (interactive)
 788   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 789                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 790                  "gnus-msg.el" "gnus-score.el" "gnus-win.el"
 791                  "nnmail.el" "message.el"))
 792         file expr olist sym)
 793     (gnus-message 4 "Please wait while we snoop your variables...")
 794     (sit-for 0)
 795     ;; Go through all the files looking for non-default values for variables.
 796     (save-excursion
 797       (set-buffer (get-buffer-create " *gnus bug info*"))
 798       (buffer-disable-undo (current-buffer))
 799       (while files
 800         (erase-buffer)
 801         (when (and (setq file (locate-library (pop files)))
 802                    (file-exists-p file))
 803           (insert-file-contents file)
 804           (goto-char (point-min))
 805           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 806               (gnus-message 4 "Malformed sources in file %s" file)
 807             (narrow-to-region (point-min) (point))
 808             (goto-char (point-min))
 809             (while (setq expr (ignore-errors (read (current-buffer))))
 810               (ignore-errors
 811                 (and (or (eq (car expr) 'defvar)
 812                          (eq (car expr) 'defcustom))
 813                      (stringp (nth 3 expr))
 814                      (or (not (boundp (nth 1 expr)))
 815                          (not (equal (eval (nth 2 expr))
 816                                      (symbol-value (nth 1 expr)))))
 817                      (push (nth 1 expr) olist)))))))
 818       (kill-buffer (current-buffer)))
 819     (when (setq olist (nreverse olist))
 820       (insert "------------------ Environment follows ------------------\n\n"))
 821     (while olist
 822       (if (boundp (car olist))
 823           (condition-case ()
 824               (pp `(setq ,(car olist)
 825                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 826                                   (and (symbolp sym)
 827                                        (not (or (eq sym nil)
 828                                                 (eq sym t)))))
 829                               (list 'quote (symbol-value (car olist)))
 830                             (symbol-value (car olist))))
 831                   (current-buffer))
 832             (error
 833              (format "(setq %s 'whatever)\n" (car olist))))
 834         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 835       (setq olist (cdr olist)))
 836     (insert "\n\n")
 837     ;; Remove any null chars - they seem to cause trouble for some
 838     ;; mailers.  (Byte-compiled output from the stuff above.)
 839     (goto-char (point-min))
 840     (while (re-search-forward "[\000\200]" nil t)
 841       (replace-match "" t t))))
 842
 843 ;;; Treatment of rejected articles.
 844 ;;; Bounced mail.
 845
 846 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 847   "Re-mail the current message.
 848 This only makes sense if the current message is a bounce message than
 849 contains some mail you have written which has been bounced back to
 850 you.
 851 If FETCH, try to fetch the article that this is a reply to, if indeed
 852 this is a reply."
 853   (interactive "P")
 854   (gnus-summary-select-article t)
 855   (set-buffer gnus-original-article-buffer)
 856   (gnus-setup-message 'compose-bounce
 857     (let* ((references (mail-fetch-field "references"))
 858            (parent (and references (gnus-parent-id references))))
 859       (message-bounce)
 860       ;; If there are references, we fetch the article we answered to.
 861       (and fetch parent
 862            (gnus-summary-refer-article parent)
 863            (gnus-summary-show-all-headers)))))
 864
 865 ;;; Gcc handling.
 866
 867 ;; Do Gcc handling, which copied the message over to some group.
 868 (defun gnus-inews-do-gcc (&optional gcc)
 869   (when (gnus-alive-p)
 870     (save-excursion
 871       (save-restriction
 872         (message-narrow-to-headers)
 873         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 874               (cur (current-buffer))
 875               groups group method)
 876           (when gcc
 877             (message-remove-header "gcc")
 878             (widen)
 879             (setq groups (message-tokenize-header gcc " ,"))
 880             ;; Copy the article over to some group(s).
 881             (while (setq group (pop groups))
 882               (gnus-check-server
 883                (setq method
 884                      (cond ((and (null (gnus-get-info group))
 885                                  (eq (car gnus-message-archive-method)
 886                                      (car
 887                                       (gnus-server-to-method
 888                                        (gnus-group-method group)))))
 889                             ;; If the group doesn't exist, we assume
 890                             ;; it's an archive group...
 891                             gnus-message-archive-method)
 892                            ;; Use the method.
 893                            ((gnus-info-method (gnus-get-info group))
 894                             (gnus-info-method (gnus-get-info group)))
 895                            ;; Find the method.
 896                            (t (gnus-group-method group)))))
 897               (gnus-check-server method)
 898               (unless (gnus-request-group group t method)
 899                 (gnus-request-create-group group method))
 900               (save-excursion
 901                 (nnheader-set-temp-buffer " *acc*")
 902                 (insert-buffer-substring cur)
 903                 (goto-char (point-min))
 904                 (when (re-search-forward
 905                        (concat "^" (regexp-quote mail-header-separator) "$")
 906                        nil t)
 907                   (replace-match "" t t ))
 908                 (unless (gnus-request-accept-article group method t)
 909                   (gnus-message 1 "Couldn't store article in group %s: %s"
 910                                 group (gnus-status-message method))
 911                   (sit-for 2))
 912                 (kill-buffer (current-buffer))))))))))
 913
 914 (defun gnus-inews-insert-gcc ()
 915   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 916   (save-excursion
 917     (save-restriction
 918       (gnus-inews-narrow-to-headers)
 919       (let* ((group gnus-outgoing-message-group)
 920              (gcc (cond
 921                    ((gnus-functionp group)
 922                     (funcall group))
 923                    ((or (stringp group) (list group))
 924                     group))))
 925         (when gcc
 926           (insert "Gcc: "
 927                   (if (stringp gcc) gcc
 928                     (mapconcat 'identity gcc " "))
 929                   "\n"))))))
 930
 931 (defun gnus-inews-insert-archive-gcc (&optional group)
 932   "Insert the Gcc to say where the article is to be archived."
 933   (let* ((var gnus-message-archive-group)
 934          (group (or group gnus-newsgroup-name ""))
 935          result
 936          gcc-self-val
 937          (groups
 938           (cond
 939            ((null gnus-message-archive-method)
 940             ;; Ignore.
 941             nil)
 942            ((stringp var)
 943             ;; Just a single group.
 944             (list var))
 945            ((null var)
 946             ;; We don't want this.
 947             nil)
 948            ((and (listp var) (stringp (car var)))
 949             ;; A list of groups.
 950             var)
 951            ((gnus-functionp var)
 952             ;; A function.
 953             (funcall var group))
 954            (t
 955             ;; An alist of regexps/functions/forms.
 956             (while (and var
 957                         (not
 958                          (setq result
 959                                (cond
 960                                 ((stringp (caar var))
 961                                  ;; Regexp.
 962                                  (when (string-match (caar var) group)
 963                                    (cdar var)))
 964                                 ((gnus-functionp (car var))
 965                                  ;; Function.
 966                                  (funcall (car var) group))
 967                                 (t
 968                                  (eval (car var)))))))
 969               (setq var (cdr var)))
 970             result)))
 971          name)
 972     (when groups
 973       (when (stringp groups)
 974         (setq groups (list groups)))
 975       (save-excursion
 976         (save-restriction
 977           (gnus-inews-narrow-to-headers)
 978           (goto-char (point-max))
 979           (insert "Gcc: ")
 980           (if (and gnus-newsgroup-name
 981                    (setq gcc-self-val
 982                          (gnus-group-find-parameter
 983                           gnus-newsgroup-name 'gcc-self)))
 984               (progn
 985                 (insert
 986                  (if (stringp gcc-self-val)
 987                      gcc-self-val
 988                    group))
 989                 (if (not (eq gcc-self-val 'none))
 990                     (insert "\n")
 991                   (progn
 992                     (beginning-of-line)
 993                     (kill-line))))
 994             (while (setq name (pop groups))
 995               (insert (if (string-match ":" name)
 996                           name
 997                         (gnus-group-prefixed-name
 998                          name gnus-message-archive-method)))
 999               (when groups
1000                 (insert " ")))
1001             (insert "\n")))))))
1002
1003 (defun gnus-summary-send-draft ()
1004   "Enter a mail/post buffer to edit and send the draft."
1005   (interactive)
1006   (gnus-set-global-variables)
1007   (let (buf)
1008     (if (not (setq buf (gnus-request-restore-buffer
1009                         (gnus-summary-article-number) gnus-newsgroup-name)))
1010         (error "Couldn't restore the article")
1011       (switch-to-buffer buf)
1012       (when (eq major-mode 'news-reply-mode)
1013         (local-set-key "\C-c\C-c" 'gnus-inews-news))
1014       ;; Insert the separator.
1015       (goto-char (point-min))
1016       (search-forward "\n\n")
1017       (forward-char -1)
1018       (insert mail-header-separator)
1019       ;; Configure windows.
1020       (let ((gnus-draft-buffer (current-buffer)))
1021         (gnus-configure-windows 'draft t)
1022         (goto-char (point))))))
1023
1024 (gnus-add-shutdown 'gnus-inews-close 'gnus)
1025
1026 (defun gnus-inews-close ()
1027   (setq gnus-inews-sent-ids nil))
1028
1029 ;;; Allow redefinition of functions.
1030
1031 (gnus-ems-redefine)
1032
1033 (provide 'gnus-msg)
1034
1035 ;;; gnus-msg.el ends here