cgit.sxemacs.org Git - gnus/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;      Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-ems)
  33 (require 'message)
  34 (require 'gnus-art)
  35
  36 ;; Added by Sudish Joseph <joseph@cis.ohio-state.edu>.
  37 (defvar gnus-post-method nil
  38   "*Preferred method for posting USENET news.
  39 If this variable is nil, Gnus will use the current method to decide
  40 which method to use when posting.  If it is non-nil, it will override
  41 the current method.  This method will not be used in mail groups and
  42 the like, only in \"real\" newsgroups.
  43
  44 The value must be a valid method as discussed in the documentation of
  45 `gnus-select-method'.  It can also be a list of methods.  If that is
  46 the case, the user will be queried for what select method to use when
  47 posting.")
  48
  49 (defvar gnus-outgoing-message-group nil
  50   "*All outgoing messages will be put in this group.
  51 If you want to store all your outgoing mail and articles in the group
  52 \"nnml:archive\", you set this variable to that value.  This variable
  53 can also be a list of group names.
  54
  55 If you want to have greater control over what group to put each
  56 message in, you can set this variable to a function that checks the
  57 current newsgroup name and then returns a suitable group name (or list
  58 of names).")
  59
  60 (defvar gnus-mailing-list-groups nil
  61   "*Regexp matching groups that are really mailing lists.
  62 This is useful when you're reading a mailing list that has been
  63 gatewayed to a newsgroup, and you want to followup to an article in
  64 the group.")
  65
  66 (defvar gnus-add-to-list nil
  67   "*If non-nil, add a `to-list' parameter automatically.")
  68
  69 (defvar gnus-sent-message-ids-file
  70   (nnheader-concat gnus-directory "Sent-Message-IDs")
  71   "File where Gnus saves a cache of sent message ids.")
  72
  73 (defvar gnus-sent-message-ids-length 1000
  74   "The number of sent Message-IDs to save.")
  75
  76 (defvar gnus-crosspost-complaint
  77   "Hi,
  78
  79 You posted the article below with the following Newsgroups header:
  80
  81 Newsgroups: %s
  82
  83 The %s group, at least, was an inappropriate recipient
  84 of this message.  Please trim your Newsgroups header to exclude this
  85 group before posting in the future.
  86
  87 Thank you.
  88
  89 "
  90   "Format string to be inserted when complaining about crossposts.
  91 The first %s will be replaced by the Newsgroups header;
  92 the second with the current group name.")
  93
  94 (defvar gnus-message-setup-hook nil
  95   "Hook run after setting up a message buffer.")
  96
  97 ;;; Internal variables.
  98
  99 (defvar gnus-message-buffer "*Mail Gnus*")
 100 (defvar gnus-article-copy nil)
 101 (defvar gnus-last-posting-server nil)
 102 (defvar gnus-message-group-art nil)
 103
 104 (defconst gnus-bug-message
 105   "Sending a bug report to the Gnus Towers.
 106 ========================================
 107
 108 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 109 be sent to the Gnus Bug Exterminators.
 110
 111 At the bottom of the buffer you'll see lots of variable settings.
 112 Please do not delete those.  They will tell the Bug People what your
 113 environment is, so that it will be easier to locate the bugs.
 114
 115 If you have found a bug that makes Emacs go \"beep\", set
 116 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 117 and include the backtrace in your bug report.
 118
 119 Please describe the bug in annoying, painstaking detail.
 120
 121 Thank you for your help in stamping out bugs.
 122 ")
 123
 124 (eval-and-compile
 125   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 126   (autoload 'news-setup "rnewspost")
 127   (autoload 'news-reply-mode "rnewspost")
 128   (autoload 'rmail-dont-reply-to "mail-utils")
 129   (autoload 'rmail-output "rmailout"))
 130
 131 \f
 132 ;;;
 133 ;;; Gnus Posting Functions
 134 ;;;
 135
 136 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 137   "p" gnus-summary-post-news
 138   "f" gnus-summary-followup
 139   "F" gnus-summary-followup-with-original
 140   "c" gnus-summary-cancel-article
 141   "s" gnus-summary-supersede-article
 142   "r" gnus-summary-reply
 143   "R" gnus-summary-reply-with-original
 144   "w" gnus-summary-wide-reply
 145   "W" gnus-summary-wide-reply-with-original
 146   "n" gnus-summary-followup-to-mail
 147   "N" gnus-summary-followup-to-mail-with-original
 148   "m" gnus-summary-mail-other-window
 149   "u" gnus-uu-post-news
 150   "\M-c" gnus-summary-mail-crosspost-complaint
 151   "om" gnus-summary-mail-forward
 152   "op" gnus-summary-post-forward
 153   "Om" gnus-uu-digest-mail-forward
 154   "Op" gnus-uu-digest-post-forward)
 155
 156 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 157   "b" gnus-summary-resend-bounced-mail
 158   ;; "c" gnus-summary-send-draft
 159   "r" gnus-summary-resend-message)
 160
 161 ;;; Internal functions.
 162
 163 (defvar gnus-article-reply nil)
 164 (defmacro gnus-setup-message (config &rest forms)
 165   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 166         (buffer (make-symbol "gnus-setup-message-buffer"))
 167         (article (make-symbol "gnus-setup-message-article")))
 168     `(let ((,winconf (current-window-configuration))
 169            (,buffer (buffer-name (current-buffer)))
 170            (,article (and gnus-article-reply (gnus-summary-article-number)))
 171            (message-header-setup-hook
 172             (copy-sequence message-header-setup-hook)))
 173        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 174        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 175        (unwind-protect
 176            (progn
 177              ,@forms)
 178          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 179          (setq gnus-message-buffer (current-buffer))
 180          (set (make-local-variable 'gnus-message-group-art)
 181               (cons ,gnus-newsgroup-name ,article))
 182          (make-local-variable 'gnus-newsgroup-name)
 183          (run-hooks 'gnus-message-setup-hook))
 184        (gnus-configure-windows ,config t)
 185        (set-buffer-modified-p nil))))
 186
 187 (defun gnus-inews-add-send-actions (winconf buffer article)
 188   (make-local-hook 'message-sent-hook)
 189   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 190   (setq message-post-method
 191         `(lambda (arg)
 192            (gnus-post-method arg ,gnus-newsgroup-name)))
 193   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 194   (message-add-action
 195    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 196   (message-add-action
 197    `(when (buffer-name (get-buffer ,buffer))
 198       (save-excursion
 199         (set-buffer (get-buffer ,buffer))
 200         ,(when article
 201            `(gnus-summary-mark-article-as-replied ,article))))
 202    'send))
 203
 204 (put 'gnus-setup-message 'lisp-indent-function 1)
 205 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 206
 207 ;;; Post news commands of Gnus group mode and summary mode
 208
 209 (defun gnus-group-mail ()
 210   "Start composing a mail."
 211   (interactive)
 212   (gnus-setup-message 'message
 213     (message-mail)))
 214
 215 (defun gnus-group-post-news (&optional arg)
 216   "Start composing a news message.
 217 If ARG, post to the group under point.
 218 If ARG is 1, prompt for a group name."
 219   (interactive "P")
 220   ;; Bind this variable here to make message mode hooks work ok.
 221   (let ((gnus-newsgroup-name
 222          (if arg
 223              (if (= 1 (prefix-numeric-value arg))
 224                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 225                                   (gnus-read-active-file-p))
 226                (gnus-group-group-name))
 227            "")))
 228     (gnus-post-news 'post gnus-newsgroup-name)))
 229
 230 (defun gnus-summary-post-news ()
 231   "Start composing a news message."
 232   (interactive)
 233   (gnus-post-news 'post gnus-newsgroup-name))
 234
 235 (defun gnus-summary-followup (yank &optional force-news)
 236   "Compose a followup to an article.
 237 If prefix argument YANK is non-nil, original article is yanked automatically."
 238   (interactive
 239    (list (and current-prefix-arg
 240               (gnus-summary-work-articles 1))))
 241   (when yank
 242     (gnus-summary-goto-subject (car yank)))
 243   (save-window-excursion
 244     (gnus-summary-select-article))
 245   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 246         (gnus-newsgroup-name gnus-newsgroup-name))
 247     ;; Send a followup.
 248     (gnus-post-news nil gnus-newsgroup-name
 249                     headers gnus-article-buffer
 250                     yank nil force-news)))
 251
 252 (defun gnus-summary-followup-with-original (n &optional force-news)
 253   "Compose a followup to an article and include the original article."
 254   (interactive "P")
 255   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 256
 257 (defun gnus-summary-followup-to-mail (&optional arg)
 258   "Followup to the current mail message via news."
 259   (interactive
 260    (list (and current-prefix-arg
 261               (gnus-summary-work-articles 1))))
 262   (gnus-summary-followup arg t))
 263
 264 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 265   "Followup to the current mail message via news."
 266   (interactive "P")
 267   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 268
 269 (defun gnus-inews-yank-articles (articles)
 270   (let (beg article)
 271     (message-goto-body)
 272     (while (setq article (pop articles))
 273       (save-window-excursion
 274         (set-buffer gnus-summary-buffer)
 275         (gnus-summary-select-article nil nil nil article)
 276         (gnus-summary-remove-process-mark article))
 277       (gnus-copy-article-buffer)
 278       (let ((message-reply-buffer gnus-article-copy)
 279             (message-reply-headers gnus-current-headers))
 280         (message-yank-original)
 281         (setq beg (or beg (mark t))))
 282       (when articles
 283         (insert "\n")))
 284     (push-mark)
 285     (goto-char beg)))
 286
 287 (defun gnus-summary-cancel-article (&optional n symp)
 288   "Cancel an article you posted.
 289 Uses the process-prefix convention.  If given the symbolic
 290 prefix `a', cancel using the standard posting method; if not
 291 post using the current select method."
 292   (interactive (gnus-interactive "P\ny"))
 293   (let ((articles (gnus-summary-work-articles n))
 294         (message-post-method
 295          `(lambda (arg)
 296             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 297         article)
 298     (while (setq article (pop articles))
 299       (when (gnus-summary-select-article t nil nil article)
 300         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 301                 (message-cancel-news))
 302           (gnus-summary-mark-as-read article gnus-canceled-mark)
 303           (gnus-cache-remove-article 1))
 304         (gnus-article-hide-headers-if-wanted))
 305       (gnus-summary-remove-process-mark article))))
 306
 307 (defun gnus-summary-supersede-article ()
 308   "Compose an article that will supersede a previous article.
 309 This is done simply by taking the old article and adding a Supersedes
 310 header line with the old Message-ID."
 311   (interactive)
 312   (let ((article (gnus-summary-article-number)))
 313     (gnus-setup-message 'reply-yank
 314       (gnus-summary-select-article t)
 315       (set-buffer gnus-original-article-buffer)
 316       (message-supersede)
 317       (push
 318        `((lambda ()
 319            (when (buffer-name (get-buffer ,gnus-summary-buffer))
 320              (save-excursion
 321                (set-buffer (get-buffer ,gnus-summary-buffer))
 322                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 323                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 324        message-send-actions))))
 325
 326 \f
 327
 328 (defun gnus-copy-article-buffer (&optional article-buffer)
 329   ;; make a copy of the article buffer with all text properties removed
 330   ;; this copy is in the buffer gnus-article-copy.
 331   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 332   ;; this buffer should be passed to all mail/news reply/post routines.
 333   (setq gnus-article-copy (get-buffer-create " *gnus article copy*"))
 334   (buffer-disable-undo gnus-article-copy)
 335   (or (memq gnus-article-copy gnus-buffer-list)
 336       (push gnus-article-copy gnus-buffer-list))
 337   (let ((article-buffer (or article-buffer gnus-article-buffer))
 338         end beg contents)
 339     (if (not (and (get-buffer article-buffer)
 340                   (buffer-name (get-buffer article-buffer))))
 341         (error "Can't find any article buffer")
 342       (save-excursion
 343         (set-buffer article-buffer)
 344         (save-restriction
 345           ;; Copy over the (displayed) article buffer, delete
 346           ;; hidden text and remove text properties.
 347           (widen)
 348           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 349           (set-buffer gnus-article-copy)
 350           (gnus-article-delete-text-of-type 'annotation)
 351           (gnus-remove-text-with-property 'gnus-prev)
 352           (gnus-remove-text-with-property 'gnus-next)
 353           (insert
 354            (prog1
 355                (format "%s" (buffer-string))
 356              (erase-buffer)))
 357           ;; Find the original headers.
 358           (set-buffer gnus-original-article-buffer)
 359           (goto-char (point-min))
 360           (while (looking-at message-unix-mail-delimiter)
 361             (forward-line 1))
 362           (setq beg (point))
 363           (setq end (or (search-forward "\n\n" nil t) (point)))
 364           ;; Delete the headers from the displayed articles.
 365           (set-buffer gnus-article-copy)
 366           (delete-region (goto-char (point-min))
 367                          (or (search-forward "\n\n" nil t) (point)))
 368           ;; Insert the original article headers.
 369           (insert-buffer-substring gnus-original-article-buffer beg end)
 370           (gnus-article-decode-rfc1522)))
 371       gnus-article-copy)))
 372
 373 (defun gnus-post-news (post &optional group header article-buffer yank subject
 374                             force-news)
 375   (when article-buffer
 376     (gnus-copy-article-buffer))
 377   (let ((gnus-article-reply article-buffer)
 378         (add-to-list gnus-add-to-list))
 379     (gnus-setup-message (cond (yank 'reply-yank)
 380                               (article-buffer 'reply)
 381                               (t 'message))
 382       (let* ((group (or group gnus-newsgroup-name))
 383              (pgroup group)
 384              to-address to-group mailing-list to-list
 385              newsgroup-p)
 386         (when group
 387           (setq to-address (gnus-group-find-parameter group 'to-address)
 388                 to-group (gnus-group-find-parameter group 'to-group)
 389                 to-list (gnus-group-find-parameter group 'to-list)
 390                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 391                 mailing-list (when gnus-mailing-list-groups
 392                                (string-match gnus-mailing-list-groups group))
 393                 group (gnus-group-real-name group)))
 394         (if (or (and to-group
 395                      (gnus-news-group-p to-group))
 396                 newsgroup-p
 397                 force-news
 398                 (and (gnus-news-group-p
 399                       (or pgroup gnus-newsgroup-name)
 400                       (if header (mail-header-number header)
 401                         gnus-current-article))
 402                      (not mailing-list)
 403                      (not to-list)
 404                      (not to-address)))
 405             ;; This is news.
 406             (if post
 407                 (message-news (or to-group group))
 408               (set-buffer gnus-article-copy)
 409               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 410           ;; The is mail.
 411           (if post
 412               (progn
 413                 (message-mail (or to-address to-list))
 414                 ;; Arrange for mail groups that have no `to-address' to
 415                 ;; get that when the user sends off the mail.
 416                 (when (and (not to-list)
 417                            (not to-address)
 418                            add-to-list)
 419                   (push (list 'gnus-inews-add-to-address pgroup)
 420                         message-send-actions)))
 421             (set-buffer gnus-article-copy)
 422             (message-wide-reply to-address
 423                                 (gnus-group-find-parameter
 424                                  gnus-newsgroup-name 'broken-reply-to))))
 425         (when yank
 426           (gnus-inews-yank-articles yank))))))
 427
 428 (defun gnus-post-method (arg group &optional silent)
 429   "Return the posting method based on GROUP and ARG.
 430 If SILENT, don't prompt the user."
 431   (let ((group-method (gnus-find-method-for-group group)))
 432     (cond
 433      ;; If the group-method is nil (which shouldn't happen) we use
 434      ;; the default method.
 435      ((null group-method)
 436       (or gnus-post-method gnus-select-method message-post-method))
 437      ;; We want this group's method.
 438      ((and arg (not (eq arg 0)))
 439       group-method)
 440      ;; We query the user for a post method.
 441      ((or arg
 442           (and gnus-post-method
 443                (listp (car gnus-post-method))))
 444       (let* ((methods
 445               ;; Collect all methods we know about.
 446               (append
 447                (when gnus-post-method
 448                  (if (listp (car gnus-post-method))
 449                      gnus-post-method
 450                    (list gnus-post-method)))
 451                gnus-secondary-select-methods
 452                (list gnus-select-method)
 453                (list group-method)))
 454              method-alist post-methods method)
 455         ;; Weed out all mail methods.
 456         (while methods
 457           (setq method (gnus-server-get-method "" (pop methods)))
 458           (when (or (gnus-method-option-p method 'post)
 459                     (gnus-method-option-p method 'post-mail))
 460             (push method post-methods)))
 461         ;; Create a name-method alist.
 462         (setq method-alist
 463               (mapcar
 464                (lambda (m)
 465                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 466                post-methods))
 467         ;; Query the user.
 468         (cadr
 469          (assoc
 470           (setq gnus-last-posting-server
 471                 (if (and silent
 472                          gnus-last-posting-server)
 473                     ;; Just use the last value.
 474                     gnus-last-posting-server
 475                   (completing-read
 476                    "Posting method: " method-alist nil t
 477                    (cons (or gnus-last-posting-server "") 0))))
 478           method-alist))))
 479      ;; Override normal method.
 480      (gnus-post-method
 481       gnus-post-method)
 482      ;; Use the normal select method.
 483      (t gnus-select-method))))
 484
 485 ;;;
 486 ;;; Check whether the message has been sent already.
 487 ;;;
 488
 489 (defvar gnus-inews-sent-ids nil)
 490
 491 (defun gnus-inews-reject-message ()
 492   "Check whether this message has already been sent."
 493   (when gnus-sent-message-ids-file
 494     (let ((message-id (save-restriction (message-narrow-to-headers)
 495                                         (mail-fetch-field "message-id")))
 496           end)
 497       (when message-id
 498         (unless gnus-inews-sent-ids
 499           (ignore-errors
 500             (load t t t)))
 501         (if (member message-id gnus-inews-sent-ids)
 502             ;; Reject this message.
 503             (not (gnus-yes-or-no-p
 504                   (format "Message %s already sent.  Send anyway? "
 505                           message-id)))
 506           (push message-id gnus-inews-sent-ids)
 507           ;; Chop off the last Message-IDs.
 508           (when (setq end (nthcdr gnus-sent-message-ids-length
 509                                   gnus-inews-sent-ids))
 510             (setcdr end nil))
 511           (nnheader-temp-write gnus-sent-message-ids-file
 512             (gnus-prin1 `(setq gnus-inews-sent-ids ',gnus-inews-sent-ids)))
 513           nil)))))
 514
 515 \f
 516
 517 ;; Dummy to avoid byte-compile warning.
 518 (defvar nnspool-rejected-article-hook)
 519 (defvar xemacs-codename)
 520
 521 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 522 ;;; as well include the Emacs version as well.
 523 ;;; The following function works with later GNU Emacs, and XEmacs.
 524 (defun gnus-extended-version ()
 525   "Stringified Gnus version and Emacs version"
 526   (interactive)
 527   (concat
 528    gnus-version
 529    "/"
 530    (cond
 531     ((string-match "^\\([0-9]+\\.[0-9]+\\)\\.[.0-9]+$" emacs-version)
 532      (concat "Emacs " (substring emacs-version
 533                                  (match-beginning 1)
 534                                  (match-end 1))))
 535     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
 536                    emacs-version)
 537      (concat (substring emacs-version
 538                         (match-beginning 1)
 539                         (match-end 1))
 540              (format " %d.%d" emacs-major-version emacs-minor-version)
 541              (if (match-beginning 3)
 542                  (substring emacs-version
 543                             (match-beginning 3)
 544                             (match-end 3))
 545                "")
 546              (if (boundp 'xemacs-codename)
 547                  (concat " - \"" xemacs-codename "\""))))
 548     (t emacs-version))))
 549
 550 ;; Written by "Mr. Per Persson" <pp@gnu.ai.mit.edu>.
 551 (defun gnus-inews-insert-mime-headers ()
 552   "Insert MIME headers.
 553 Assumes ISO-Latin-1 is used iff 8-bit characters are present."
 554   (goto-char (point-min))
 555   (let ((mail-header-separator
 556          (progn
 557            (goto-char (point-min))
 558            (if (and (search-forward (concat "\n" mail-header-separator "\n")
 559                                     nil t)
 560                     (not (search-backward "\n\n" nil t)))
 561                mail-header-separator
 562              ""))))
 563     (or (mail-position-on-field "Mime-Version")
 564         (insert "1.0")
 565         (cond ((save-restriction
 566                  (widen)
 567                  (goto-char (point-min))
 568                  (re-search-forward "[^\000-\177]" nil t))
 569                (or (mail-position-on-field "Content-Type")
 570                    (insert "text/plain; charset=ISO-8859-1"))
 571                (or (mail-position-on-field "Content-Transfer-Encoding")
 572                    (insert "8bit")))
 573               (t (or (mail-position-on-field "Content-Type")
 574                      (insert "text/plain; charset=US-ASCII"))
 575                  (or (mail-position-on-field "Content-Transfer-Encoding")
 576                      (insert "7bit")))))))
 577
 578 (custom-add-option 'message-header-hook 'gnus-inews-insert-mime-headers)
 579
 580 \f
 581 ;;;
 582 ;;; Gnus Mail Functions
 583 ;;;
 584
 585 ;;; Mail reply commands of Gnus summary mode
 586
 587 (defun gnus-summary-reply (&optional yank wide)
 588   "Start composing a reply mail to the current message.
 589 If prefix argument YANK is non-nil, the original article is yanked
 590 automatically."
 591   (interactive
 592    (list (and current-prefix-arg
 593               (gnus-summary-work-articles 1))))
 594   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 595   (when yank
 596     (gnus-summary-goto-subject (car yank)))
 597   (let ((gnus-article-reply t))
 598     (gnus-setup-message (if yank 'reply-yank 'reply)
 599       (gnus-summary-select-article)
 600       (set-buffer (gnus-copy-article-buffer))
 601       (message-reply nil wide (gnus-group-find-parameter
 602                                gnus-newsgroup-name 'broken-reply-to))
 603       (when yank
 604         (gnus-inews-yank-articles yank)))))
 605
 606 (defun gnus-summary-reply-with-original (n &optional wide)
 607   "Start composing a reply mail to the current message.
 608 The original article will be yanked."
 609   (interactive "P")
 610   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 611
 612 (defun gnus-summary-wide-reply (&optional yank)
 613   "Start composing a wide reply mail to the current message.
 614 If prefix argument YANK is non-nil, the original article is yanked
 615 automatically."
 616   (interactive
 617    (list (and current-prefix-arg
 618               (gnus-summary-work-articles 1))))
 619   (gnus-summary-reply yank t))
 620
 621 (defun gnus-summary-wide-reply-with-original (n)
 622   "Start composing a wide reply mail to the current message.
 623 The original article will be yanked."
 624   (interactive "P")
 625   (gnus-summary-reply-with-original n t))
 626
 627 (defun gnus-summary-mail-forward (&optional full-headers post)
 628   "Forward the current message to another user.
 629 If FULL-HEADERS (the prefix), include full headers when forwarding."
 630   (interactive "P")
 631   (gnus-setup-message 'forward
 632     (gnus-summary-select-article)
 633     (set-buffer gnus-original-article-buffer)
 634     (let ((message-included-forward-headers
 635            (if full-headers "" message-included-forward-headers)))
 636       (message-forward post))))
 637
 638 (defun gnus-summary-resend-message (address n)
 639   "Resend the current article to ADDRESS."
 640   (interactive "sResend message(s) to: \nP")
 641   (let ((articles (gnus-summary-work-articles n))
 642         article)
 643     (while (setq article (pop articles))
 644       (gnus-summary-select-article nil nil nil article)
 645       (save-excursion
 646         (set-buffer gnus-original-article-buffer)
 647         (message-resend address)))))
 648
 649 (defun gnus-summary-post-forward (&optional full-headers)
 650   "Forward the current article to a newsgroup.
 651 If FULL-HEADERS (the prefix), include full headers when forwarding."
 652   (interactive "P")
 653   (gnus-summary-mail-forward full-headers t))
 654
 655 (defvar gnus-nastygram-message
 656   "The following article was inappropriately posted to %s.\n\n"
 657   "Format string to insert in nastygrams.
 658 The current group name will be inserted at \"%s\".")
 659
 660 (defun gnus-summary-mail-nastygram (n)
 661   "Send a nastygram to the author of the current article."
 662   (interactive "P")
 663   (when (or gnus-expert-user
 664             (gnus-y-or-n-p
 665              "Really send a nastygram to the author of the current article? "))
 666     (let ((group gnus-newsgroup-name))
 667       (gnus-summary-reply-with-original n)
 668       (set-buffer gnus-message-buffer)
 669       (message-goto-body)
 670       (insert (format gnus-nastygram-message group))
 671       (message-send-and-exit))))
 672
 673 (defun gnus-summary-mail-crosspost-complaint (n)
 674   "Send a complaint about crossposting to the current article(s)."
 675   (interactive "P")
 676   (let ((articles (gnus-summary-work-articles n))
 677         article)
 678     (while (setq article (pop articles))
 679       (set-buffer gnus-summary-buffer)
 680       (gnus-summary-goto-subject article)
 681       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 682             newsgroups followup-to)
 683         (gnus-summary-select-article)
 684         (set-buffer gnus-original-article-buffer)
 685         (if (and (<= (length (message-tokenize-header
 686                               (setq newsgroups (mail-fetch-field "newsgroups"))
 687                               ", "))
 688                      1)
 689                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 690                      (not (member group (message-tokenize-header
 691                                          followup-to ", ")))))
 692             (if followup-to
 693                 (gnus-message 1 "Followup-to restricted")
 694               (gnus-message 1 "Not a crossposted article"))
 695           (set-buffer gnus-summary-buffer)
 696           (gnus-summary-reply-with-original 1)
 697           (set-buffer gnus-message-buffer)
 698           (message-goto-body)
 699           (insert (format gnus-crosspost-complaint newsgroups group))
 700           (message-goto-subject)
 701           (re-search-forward " *$")
 702           (replace-match " (crosspost notification)" t t)
 703           (gnus-deactivate-mark)
 704           (when (gnus-y-or-n-p "Send this complaint? ")
 705             (message-send-and-exit)))))))
 706
 707 (defun gnus-summary-mail-other-window ()
 708   "Compose mail in other window."
 709   (interactive)
 710   (gnus-setup-message 'message
 711     (message-mail)))
 712
 713 (defun gnus-mail-parse-comma-list ()
 714   (let (accumulated
 715         beg)
 716     (skip-chars-forward " ")
 717     (while (not (eobp))
 718       (setq beg (point))
 719       (skip-chars-forward "^,")
 720       (while (zerop
 721               (save-excursion
 722                 (save-restriction
 723                   (let ((i 0))
 724                     (narrow-to-region beg (point))
 725                     (goto-char beg)
 726                     (logand (progn
 727                               (while (search-forward "\"" nil t)
 728                                 (incf i))
 729                               (if (zerop i) 2 i))
 730                             2)))))
 731         (skip-chars-forward ",")
 732         (skip-chars-forward "^,"))
 733       (skip-chars-backward " ")
 734       (push (buffer-substring beg (point))
 735             accumulated)
 736       (skip-chars-forward "^,")
 737       (skip-chars-forward ", "))
 738     accumulated))
 739
 740 (defun gnus-inews-add-to-address (group)
 741   (let ((to-address (mail-fetch-field "to")))
 742     (when (and to-address
 743                (gnus-alive-p))
 744       ;; This mail group doesn't have a `to-list', so we add one
 745       ;; here.  Magic!
 746       (when (gnus-y-or-n-p
 747              (format "Do you want to add this as `to-list': %s " to-address))
 748         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 749
 750 (defun gnus-put-message ()
 751   "Put the current message in some group and return to Gnus."
 752   (interactive)
 753   (let ((reply gnus-article-reply)
 754         (winconf gnus-prev-winconf)
 755         (group gnus-newsgroup-name))
 756
 757     (or (and group (not (gnus-group-read-only-p group)))
 758         (setq group (read-string "Put in group: " nil
 759                                  (gnus-writable-groups))))
 760     (when (gnus-gethash group gnus-newsrc-hashtb)
 761       (error "No such group: %s" group))
 762
 763     (save-excursion
 764       (save-restriction
 765         (widen)
 766         (message-narrow-to-headers)
 767         (let (gnus-deletable-headers)
 768           (if (message-news-p)
 769               (message-generate-headers message-required-news-headers)
 770             (message-generate-headers message-required-mail-headers)))
 771         (goto-char (point-max))
 772         (insert "Gcc: " group "\n")
 773         (widen)))
 774
 775     (gnus-inews-do-gcc)
 776
 777     (when (get-buffer gnus-group-buffer)
 778       (when (gnus-buffer-exists-p (car-safe reply))
 779         (set-buffer (car reply))
 780         (and (cdr reply)
 781              (gnus-summary-mark-article-as-replied
 782               (cdr reply))))
 783       (when winconf
 784         (set-window-configuration winconf)))))
 785
 786 (defun gnus-article-mail (yank)
 787   "Send a reply to the address near point.
 788 If YANK is non-nil, include the original article."
 789   (interactive "P")
 790   (let ((address
 791          (buffer-substring
 792           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 793           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 794     (when address
 795       (message-reply address)
 796       (when yank
 797         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 798
 799 (defvar nntp-server-type)
 800 (defun gnus-bug ()
 801   "Send a bug report to the Gnus maintainers."
 802   (interactive)
 803   (unless (gnus-alive-p)
 804     (error "Gnus has been shut down"))
 805   (gnus-setup-message 'bug
 806     (delete-other-windows)
 807     (switch-to-buffer (get-buffer-create "*Gnus Help Bug*"))
 808     (erase-buffer)
 809     (insert gnus-bug-message)
 810     (goto-char (point-min))
 811     (message-pop-to-buffer "*Gnus Bug*")
 812     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 813     (push `(gnus-bug-kill-buffer) message-send-actions)
 814     (goto-char (point-min))
 815     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 816     (forward-line 1)
 817     (insert (gnus-version) "\n")
 818     (insert (emacs-version) "\n")
 819     (when (and (boundp 'nntp-server-type)
 820                (stringp nntp-server-type))
 821       (insert nntp-server-type))
 822     (insert "\n\n\n\n\n")
 823     (gnus-debug)
 824     (goto-char (point-min))
 825     (search-forward "Subject: " nil t)
 826     (message "")))
 827
 828 (defun gnus-bug-kill-buffer ()
 829   (when (get-buffer "*Gnus Help Bug*")
 830     (kill-buffer "*Gnus Help Bug*")))
 831
 832 (defun gnus-debug ()
 833   "Attempts to go through the Gnus source file and report what variables have been changed.
 834 The source file has to be in the Emacs load path."
 835   (interactive)
 836   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 837                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 838                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 839                  "nnmail.el" "message.el"))
 840         (point (point))
 841         file expr olist sym)
 842     (gnus-message 4 "Please wait while we snoop your variables...")
 843     (sit-for 0)
 844     ;; Go through all the files looking for non-default values for variables.
 845     (save-excursion
 846       (set-buffer (get-buffer-create " *gnus bug info*"))
 847       (buffer-disable-undo (current-buffer))
 848       (while files
 849         (erase-buffer)
 850         (when (and (setq file (locate-library (pop files)))
 851                    (file-exists-p file))
 852           (insert-file-contents file)
 853           (goto-char (point-min))
 854           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 855               (gnus-message 4 "Malformed sources in file %s" file)
 856             (narrow-to-region (point-min) (point))
 857             (goto-char (point-min))
 858             (while (setq expr (ignore-errors (read (current-buffer))))
 859               (ignore-errors
 860                 (and (or (eq (car expr) 'defvar)
 861                          (eq (car expr) 'defcustom))
 862                      (stringp (nth 3 expr))
 863                      (or (not (boundp (nth 1 expr)))
 864                          (not (equal (eval (nth 2 expr))
 865                                      (symbol-value (nth 1 expr)))))
 866                      (push (nth 1 expr) olist)))))))
 867       (kill-buffer (current-buffer)))
 868     (when (setq olist (nreverse olist))
 869       (insert "------------------ Environment follows ------------------\n\n"))
 870     (while olist
 871       (if (boundp (car olist))
 872           (condition-case ()
 873               (pp `(setq ,(car olist)
 874                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 875                                   (and (symbolp sym)
 876                                        (not (or (eq sym nil)
 877                                                 (eq sym t)))))
 878                               (list 'quote (symbol-value (car olist)))
 879                             (symbol-value (car olist))))
 880                   (current-buffer))
 881             (error
 882              (format "(setq %s 'whatever)\n" (car olist))))
 883         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 884       (setq olist (cdr olist)))
 885     (insert "\n\n")
 886     ;; Remove any control chars - they seem to cause trouble for some
 887     ;; mailers.  (Byte-compiled output from the stuff above.)
 888     (goto-char point)
 889     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 890       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 891                      t t))))
 892
 893 ;;; Treatment of rejected articles.
 894 ;;; Bounced mail.
 895
 896 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 897   "Re-mail the current message.
 898 This only makes sense if the current message is a bounce message than
 899 contains some mail you have written which has been bounced back to
 900 you.
 901 If FETCH, try to fetch the article that this is a reply to, if indeed
 902 this is a reply."
 903   (interactive "P")
 904   (gnus-summary-select-article t)
 905   (set-buffer gnus-original-article-buffer)
 906   (gnus-setup-message 'compose-bounce
 907     (let* ((references (mail-fetch-field "references"))
 908            (parent (and references (gnus-parent-id references))))
 909       (message-bounce)
 910       ;; If there are references, we fetch the article we answered to.
 911       (and fetch parent
 912            (gnus-summary-refer-article parent)
 913            (gnus-summary-show-all-headers)))))
 914
 915 ;;; Gcc handling.
 916
 917 ;; Do Gcc handling, which copied the message over to some group.
 918 (defun gnus-inews-do-gcc (&optional gcc)
 919   (interactive)
 920   (when (gnus-alive-p)
 921     (save-excursion
 922       (save-restriction
 923         (message-narrow-to-headers)
 924         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 925               (cur (current-buffer))
 926               groups group method)
 927           (when gcc
 928             (message-remove-header "gcc")
 929             (widen)
 930             (setq groups (message-tokenize-header gcc " ,"))
 931             ;; Copy the article over to some group(s).
 932             (while (setq group (pop groups))
 933               (gnus-check-server
 934                (setq method
 935                      (cond ((and (null (gnus-get-info group))
 936                                  (eq (car gnus-message-archive-method)
 937                                      (car
 938                                       (gnus-server-to-method
 939                                        (gnus-group-method group)))))
 940                             ;; If the group doesn't exist, we assume
 941                             ;; it's an archive group...
 942                             gnus-message-archive-method)
 943                            ;; Use the method.
 944                            ((gnus-info-method (gnus-get-info group))
 945                             (gnus-info-method (gnus-get-info group)))
 946                            ;; Find the method.
 947                            (t (gnus-group-method group)))))
 948               (gnus-check-server method)
 949               (unless (gnus-request-group group t method)
 950                 (gnus-request-create-group group method))
 951               (save-excursion
 952                 (nnheader-set-temp-buffer " *acc*")
 953                 (insert-buffer-substring cur)
 954                 (goto-char (point-min))
 955                 (when (re-search-forward
 956                        (concat "^" (regexp-quote mail-header-separator) "$")
 957                        nil t)
 958                   (replace-match "" t t ))
 959                 (unless (gnus-request-accept-article group method t)
 960                   (gnus-message 1 "Couldn't store article in group %s: %s"
 961                                 group (gnus-status-message method))
 962                   (sit-for 2))
 963                 (kill-buffer (current-buffer))))))))))
 964
 965 (defun gnus-inews-insert-gcc ()
 966   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 967   (save-excursion
 968     (save-restriction
 969       (message-narrow-to-headers)
 970       (let* ((group gnus-outgoing-message-group)
 971              (gcc (cond
 972                    ((gnus-functionp group)
 973                     (funcall group))
 974                    ((or (stringp group) (list group))
 975                     group))))
 976         (when gcc
 977           (insert "Gcc: "
 978                   (if (stringp gcc) gcc
 979                     (mapconcat 'identity gcc " "))
 980                   "\n"))))))
 981
 982 (defun gnus-inews-insert-archive-gcc (&optional group)
 983   "Insert the Gcc to say where the article is to be archived."
 984   (let* ((var gnus-message-archive-group)
 985          (group (or group gnus-newsgroup-name ""))
 986          (gcc-self-val
 987           (and gnus-newsgroup-name
 988                (gnus-group-find-parameter
 989                 gnus-newsgroup-name 'gcc-self)))
 990          result
 991          (groups
 992           (cond
 993            ((null gnus-message-archive-method)
 994             ;; Ignore.
 995             nil)
 996            ((stringp var)
 997             ;; Just a single group.
 998             (list var))
 999            ((null var)
1000             ;; We don't want this.
1001             nil)
1002            ((and (listp var) (stringp (car var)))
1003             ;; A list of groups.
1004             var)
1005            ((gnus-functionp var)
1006             ;; A function.
1007             (funcall var group))
1008            (t
1009             ;; An alist of regexps/functions/forms.
1010             (while (and var
1011                         (not
1012                          (setq result
1013                                (cond
1014                                 ((stringp (caar var))
1015                                  ;; Regexp.
1016                                  (when (string-match (caar var) group)
1017                                    (cdar var)))
1018                                 ((gnus-functionp (car var))
1019                                  ;; Function.
1020                                  (funcall (car var) group))
1021                                 (t
1022                                  (eval (car var)))))))
1023               (setq var (cdr var)))
1024             result)))
1025          name)
1026     (when (or groups gcc-self-val)
1027       (when (stringp groups)
1028         (setq groups (list groups)))
1029       (save-excursion
1030         (save-restriction
1031           (message-narrow-to-headers)
1032           (goto-char (point-max))
1033           (insert "Gcc: ")
1034           (if gcc-self-val
1035               ;; Use the `gcc-self' param value instead.
1036               (progn
1037                 (insert
1038                  (if (stringp gcc-self-val)
1039                      gcc-self-val
1040                    group))
1041                 (if (not (eq gcc-self-val 'none))
1042                     (insert "\n")
1043                   (progn
1044                     (beginning-of-line)
1045                     (kill-line))))
1046             ;; Use the list of groups.
1047             (while (setq name (pop groups))
1048               (insert (if (string-match ":" name)
1049                           name
1050                         (gnus-group-prefixed-name
1051                          name gnus-message-archive-method)))
1052               (when groups
1053                 (insert " ")))
1054             (insert "\n")))))))
1055
1056 (gnus-add-shutdown 'gnus-inews-close 'gnus)
1057
1058 (defun gnus-inews-close ()
1059   (setq gnus-inews-sent-ids nil))
1060
1061 ;;; Allow redefinition of functions.
1062
1063 (gnus-ems-redefine)
1064
1065 (provide 'gnus-msg)
1066
1067 ;;; gnus-msg.el ends here