cgit.sxemacs.org Git - gnus/blob - lisp/gnus-mh.el

   1 ;;; gnus-mh.el --- mh-e interface for Gnus
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Send mail using mh-e.
  29
  30 ;; The following mh-e interface is all cooperative works of
  31 ;; tanaka@flab.fujitsu.CO.JP (TANAKA Hiroshi), kawabe@sra.CO.JP
  32 ;; (Yoshikatsu Kawabe), and shingu@casund.cpr.canon.co.jp (Toshiaki
  33 ;; SHINGU).
  34
  35 ;;; Code:
  36
  37 (require 'gnus)
  38 (require 'mh-e)
  39 (require 'mh-comp)
  40 (require 'gnus-msg)
  41 (require 'gnus-sum)
  42
  43 (defun gnus-summary-save-article-folder (&optional arg)
  44   "Append the current article to an mh folder.
  45 If N is a positive number, save the N next articles.
  46 If N is a negative number, save the N previous articles.
  47 If N is nil and any articles have been marked with the process mark,
  48 save those articles instead."
  49   (interactive "P")
  50   (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
  51     (gnus-summary-save-article arg)))
  52
  53 (defun gnus-summary-save-in-folder (&optional folder)
  54   "Save this article to MH folder (using `rcvstore' in MH library).
  55 Optional argument FOLDER specifies folder name."
  56   ;; Thanks to yuki@flab.Fujitsu.JUNET and ohm@kaba.junet.
  57   (mh-find-path)
  58   (let ((folder
  59          (cond ((and (eq folder 'default)
  60                      gnus-newsgroup-last-folder)
  61                 gnus-newsgroup-last-folder)
  62                (folder folder)
  63                (t (mh-prompt-for-folder
  64                    "Save article in"
  65                    (funcall gnus-folder-save-name gnus-newsgroup-name
  66                             gnus-current-headers gnus-newsgroup-last-folder)
  67                    t))))
  68         (errbuf (gnus-get-buffer-create " *Gnus rcvstore*"))
  69         ;; Find the rcvstore program.
  70         (exec-path (cond
  71                     ((and (boundp 'mh-lib-progs) mh-lib-progs)
  72                      (cons mh-lib-progs exec-path))
  73                     (mh-lib (cons mh-lib exec-path))
  74                     (t exec-path))))
  75     (with-current-buffer gnus-original-article-buffer
  76       (save-restriction
  77         (widen)
  78         (unwind-protect
  79             (call-process-region
  80              (point-min) (point-max) "rcvstore" nil errbuf nil folder)
  81           (set-buffer errbuf)
  82           (if (zerop (buffer-size))
  83               (message "Article saved in folder: %s" folder)
  84             (message "%s" (buffer-string)))
  85           (kill-buffer errbuf))))
  86     (setq gnus-newsgroup-last-folder folder)))
  87
  88 (defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
  89   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
  90 If variable `gnus-use-long-file-name' is nil, it is +News.group.
  91 Otherwise, it is like +news/group."
  92   (or last-folder
  93       (concat "+"
  94               (if gnus-use-long-file-name
  95                   (gnus-capitalize-newsgroup newsgroup)
  96                 (gnus-newsgroup-directory-form newsgroup)))))
  97
  98 (defun gnus-folder-save-name (newsgroup headers &optional last-folder)
  99   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
 100 If variable `gnus-use-long-file-name' is nil, it is +news.group.
 101 Otherwise, it is like +news/group."
 102   (or last-folder
 103       (concat "+"
 104               (if gnus-use-long-file-name
 105                   newsgroup
 106                 (gnus-newsgroup-directory-form newsgroup)))))
 107
 108 (provide 'gnus-mh)
 109
 110 ;;; gnus-mh.el ends here