cgit.sxemacs.org Git - gnus/blob - lisp/gnus-mh.el

   1 ;;; gnus-mh.el --- mh-e interface for Gnus
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Send mail using mh-e.
  29
  30 ;; The following mh-e interface is all cooperative works of
  31 ;; tanaka@flab.fujitsu.CO.JP (TANAKA Hiroshi), kawabe@sra.CO.JP
  32 ;; (Yoshikatsu Kawabe), and shingu@casund.cpr.canon.co.jp (Toshiaki
  33 ;; SHINGU).
  34
  35 ;;; Code:
  36
  37 (require 'gnus)
  38 (require 'mh-e)
  39 (require 'mh-comp)
  40 (require 'gnus-msg)
  41 (require 'gnus-sum)
  42
  43 (eval-when-compile
  44   (defvar mh-lib-progs))
  45
  46 (defun gnus-summary-save-article-folder (&optional arg)
  47   "Append the current article to an mh folder.
  48 If N is a positive number, save the N next articles.
  49 If N is a negative number, save the N previous articles.
  50 If N is nil and any articles have been marked with the process mark,
  51 save those articles instead."
  52   (interactive "P")
  53   (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
  54     (gnus-summary-save-article arg)))
  55
  56 (defun gnus-summary-save-in-folder (&optional folder)
  57   "Save this article to MH folder (using `rcvstore' in MH library).
  58 Optional argument FOLDER specifies folder name."
  59   ;; Thanks to yuki@flab.Fujitsu.JUNET and ohm@kaba.junet.
  60   (mh-find-path)
  61   (let ((folder
  62          (cond ((and (eq folder 'default)
  63                      gnus-newsgroup-last-folder)
  64                 gnus-newsgroup-last-folder)
  65                (folder folder)
  66                (t (mh-prompt-for-folder
  67                    "Save article in"
  68                    (funcall gnus-folder-save-name gnus-newsgroup-name
  69                             gnus-current-headers gnus-newsgroup-last-folder)
  70                    t))))
  71         (errbuf (gnus-get-buffer-create " *Gnus rcvstore*"))
  72         ;; Find the rcvstore program.
  73         (exec-path (cond
  74                     ((and (boundp 'mh-lib-progs) mh-lib-progs)
  75                      (cons mh-lib-progs exec-path))
  76                     (mh-lib (cons mh-lib exec-path))
  77                     (t exec-path))))
  78     (with-current-buffer gnus-original-article-buffer
  79       (save-restriction
  80         (widen)
  81         (unwind-protect
  82             (call-process-region
  83              (point-min) (point-max) "rcvstore" nil errbuf nil folder)
  84           (set-buffer errbuf)
  85           (if (zerop (buffer-size))
  86               (message "Article saved in folder: %s" folder)
  87             (message "%s" (buffer-string)))
  88           (kill-buffer errbuf))))
  89     (setq gnus-newsgroup-last-folder folder)))
  90
  91 (defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
  92   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
  93 If variable `gnus-use-long-file-name' is nil, it is +News.group.
  94 Otherwise, it is like +news/group."
  95   (or last-folder
  96       (concat "+"
  97               (if gnus-use-long-file-name
  98                   (gnus-capitalize-newsgroup newsgroup)
  99                 (gnus-newsgroup-directory-form newsgroup)))))
 100
 101 (defun gnus-folder-save-name (newsgroup headers &optional last-folder)
 102   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
 103 If variable `gnus-use-long-file-name' is nil, it is +news.group.
 104 Otherwise, it is like +news/group."
 105   (or last-folder
 106       (concat "+"
 107               (if gnus-use-long-file-name
 108                   newsgroup
 109                 (gnus-newsgroup-directory-form newsgroup)))))
 110
 111 (provide 'gnus-mh)
 112
 113 ;;; gnus-mh.el ends here