cgit.sxemacs.org Git - gnus/blob - lisp/gnus-html.el

   1 ;;; gnus-html.el --- Render HTML in a buffer.
   2
   3 ;; Copyright (C) 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: html, web
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; The idea is to provide a simple, fast and pretty minimal way to
  26 ;; render HTML (including links and images) in a buffer, based on an
  27 ;; external HTML renderer (i.e., w3m).
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus-art)
  34 (eval-when-compile (require 'mm-decode))
  35
  36 (require 'mm-url)
  37 (require 'url)
  38 (require 'url-cache)
  39 (require 'xml)
  40 (require 'browse-url)
  41 (eval-and-compile (unless (featurep 'xemacs) (require 'help-fns)))
  42
  43 (defcustom gnus-html-image-cache-ttl (days-to-time 7)
  44   "Time used to determine if we should use images from the cache."
  45   :version "24.1"
  46   :group 'gnus-art
  47   :type 'integer)
  48
  49 (defcustom gnus-html-image-automatic-caching t
  50   "Whether automatically cache retrieve images."
  51   :version "24.1"
  52   :group 'gnus-art
  53   :type 'boolean)
  54
  55 (defcustom gnus-html-frame-width 70
  56   "What width to use when rendering HTML."
  57   :version "24.1"
  58   :group 'gnus-art
  59   :type 'integer)
  60
  61 (defcustom gnus-max-image-proportion 0.9
  62   "How big pictures displayed are in relation to the window they're in.
  63 A value of 0.7 means that they are allowed to take up 70% of the
  64 width and height of the window.  If they are larger than this,
  65 and Emacs supports it, then the images will be rescaled down to
  66 fit these criteria."
  67   :version "24.1"
  68   :group 'gnus-art
  69   :type 'float)
  70
  71 (defvar gnus-html-image-map
  72   (let ((map (make-sparse-keymap)))
  73     (define-key map "u" 'gnus-article-copy-string)
  74     (define-key map "i" 'gnus-html-insert-image)
  75     (define-key map "v" 'gnus-html-browse-url)
  76     map))
  77
  78 (defvar gnus-html-displayed-image-map
  79   (let ((map (make-sparse-keymap)))
  80     (define-key map "a" 'gnus-html-show-alt-text)
  81     (define-key map "i" 'gnus-html-browse-image)
  82     (define-key map "\r" 'gnus-html-browse-url)
  83     (define-key map "u" 'gnus-article-copy-string)
  84     (define-key map [tab] 'widget-forward)
  85     map))
  86
  87 (eval-and-compile
  88   (defalias 'gnus-html-encode-url-chars
  89     (if (fboundp 'browse-url-url-encode-chars)
  90         'browse-url-url-encode-chars
  91       (lambda (text chars)
  92         "URL-encode the chars in TEXT that match CHARS.
  93 CHARS is a regexp-like character alternative (e.g., \"[)$]\")."
  94         (let ((encoded-text (copy-sequence text))
  95               (s 0))
  96           (while (setq s (string-match chars encoded-text s))
  97             (setq encoded-text
  98                   (replace-match (format "%%%x"
  99                                          (string-to-char
 100                                           (match-string 0 encoded-text)))
 101                                  t t encoded-text)
 102                   s (1+ s)))
 103           encoded-text)))))
 104
 105 (defun gnus-html-encode-url (url)
 106   "Encode URL."
 107   (gnus-html-encode-url-chars url "[)$ ]"))
 108
 109 (defun gnus-html-cache-expired (url ttl)
 110   "Check if URL is cached for more than TTL."
 111   (cond (url-standalone-mode
 112          (not (file-exists-p (url-cache-create-filename url))))
 113         (t (let ((cache-time (url-is-cached url)))
 114              (if cache-time
 115                  (time-less-p
 116                   (time-add
 117                    cache-time
 118                    ttl)
 119                   (current-time))
 120                t)))))
 121
 122 ;;;###autoload
 123 (defun gnus-article-html (&optional handle)
 124   (let ((article-buffer (current-buffer)))
 125     (unless handle
 126       (setq handle (mm-dissect-buffer t)))
 127     (save-restriction
 128       (narrow-to-region (point) (point))
 129       (save-excursion
 130         (mm-with-part handle
 131           (let* ((coding-system-for-read 'utf-8)
 132                  (coding-system-for-write 'utf-8)
 133                  (default-process-coding-system
 134                    (cons coding-system-for-read coding-system-for-write))
 135                  (charset (mail-content-type-get (mm-handle-type handle)
 136                                                  'charset)))
 137             (when (and charset
 138                        (setq charset (mm-charset-to-coding-system charset))
 139                        (not (eq charset 'ascii)))
 140               (insert (prog1
 141                           (mm-decode-coding-string (buffer-string) charset)
 142                         (erase-buffer)
 143                         (mm-enable-multibyte))))
 144             (call-process-region (point-min) (point-max)
 145                                  "w3m"
 146                                  nil article-buffer nil
 147                                  "-halfdump"
 148                                  "-no-cookie"
 149                                  "-I" "UTF-8"
 150                                  "-O" "UTF-8"
 151                                  "-o" "ext_halfdump=1"
 152                                  "-o" "display_ins_del=2"
 153                                  "-o" "pre_conv=1"
 154                                  "-t" (format "%s" tab-width)
 155                                  "-cols" (format "%s" gnus-html-frame-width)
 156                                  "-o" "display_image=on"
 157                                  "-T" "text/html"))))
 158       (gnus-html-wash-tags))))
 159
 160 (defvar gnus-article-mouse-face)
 161
 162 (defun gnus-html-pre-wash ()
 163   (goto-char (point-min))
 164   (while (re-search-forward " *<pre_int> *</pre_int> *\n" nil t)
 165     (replace-match "" t t))
 166   (goto-char (point-min))
 167   (while (re-search-forward "<a name[^\n>]+>" nil t)
 168     (replace-match "" t t)))
 169
 170 (defun gnus-html-wash-images ()
 171   "Run through current buffer and replace img tags by images."
 172   (let (tag parameters string start end images url alt-text
 173             inhibit-images blocked-images)
 174     (if (buffer-live-p gnus-summary-buffer)
 175         (with-current-buffer gnus-summary-buffer
 176           (setq inhibit-images gnus-inhibit-images
 177                 blocked-images (gnus-blocked-images)))
 178       (setq inhibit-images gnus-inhibit-images
 179             blocked-images (gnus-blocked-images)))
 180     (goto-char (point-min))
 181     ;; Search for all the images first.
 182     (while (re-search-forward "<img_alt \\([^>]*\\)>" nil t)
 183       (setq parameters (match-string 1)
 184             start (match-beginning 0))
 185       (delete-region start (point))
 186       (when (search-forward "</img_alt>" (line-end-position) t)
 187         (delete-region (match-beginning 0) (match-end 0)))
 188       (setq end (point))
 189       (when (string-match "src=\"\\([^\"]+\\)" parameters)
 190         (gnus-message 8 "gnus-html-wash-tags: fetching image URL %s" url)
 191         (setq url (gnus-html-encode-url (match-string 1 parameters))
 192               alt-text (when (string-match "\\(alt\\|title\\)=\"\\([^\"]+\\)"
 193                                            parameters)
 194                          (xml-substitute-special (match-string 2 parameters))))
 195         (gnus-add-text-properties
 196          start end
 197          (list 'image-url url
 198                'image-displayer `(lambda (url start end)
 199                                    (gnus-html-display-image url start end
 200                                                             ,alt-text))
 201                'gnus-image (list url start end alt-text)))
 202         (gnus-overlay-put (gnus-make-overlay start end)
 203                           'local-map gnus-html-image-map)
 204         (if (string-match "\\`cid:" url)
 205             ;; URLs with cid: have their content stashed in other
 206             ;; parts of the MIME structure, so just insert them
 207             ;; immediately.
 208             (let* ((handle (mm-get-content-id (substring url (match-end 0))))
 209                    (image (when (and handle
 210                                      (not inhibit-images))
 211                             (gnus-create-image
 212                              (mm-with-part handle (buffer-string))
 213                              nil t))))
 214               (if image
 215                   (progn
 216                     (gnus-put-image
 217                      (gnus-rescale-image
 218                       image (gnus-html-maximum-image-size))
 219                      (gnus-string-or (prog1
 220                                          (buffer-substring start end)
 221                                        (delete-region start end))
 222                                      "*")
 223                      'cid)
 224                     (gnus-add-image 'cid image))
 225                 (widget-convert-button
 226                  'link start end
 227                  :action 'gnus-html-insert-image
 228                  :help-echo url
 229                  :keymap gnus-html-image-map
 230                  :button-keymap gnus-html-image-map)))
 231           ;; Normal, external URL.
 232           (if (or inhibit-images
 233                   (gnus-html-image-url-blocked-p url blocked-images))
 234               (widget-convert-button
 235                'link start end
 236                :action 'gnus-html-insert-image
 237                :help-echo url
 238                :keymap gnus-html-image-map
 239                :button-keymap gnus-html-image-map)
 240             ;; Non-blocked url
 241             (let ((width
 242                    (when (string-match "width=\"?\\([0-9]+\\)" parameters)
 243                      (string-to-number (match-string 1 parameters))))
 244                   (height
 245                    (when (string-match "height=\"?\\([0-9]+\\)" parameters)
 246                      (string-to-number (match-string 1 parameters)))))
 247               ;; Don't fetch images that are really small.  They're
 248               ;; probably tracking pictures.
 249               (when (and (or (null height)
 250                              (> height 4))
 251                          (or (null width)
 252                              (> width 4)))
 253                 (gnus-html-display-image url start end alt-text)))))))))
 254
 255 (defun gnus-html-display-image (url start end &optional alt-text)
 256   "Display image at URL on text from START to END.
 257 Use ALT-TEXT for the image string."
 258   (or alt-text (setq alt-text "*"))
 259   (if (string-match "\\`cid:" url)
 260       (let ((handle (mm-get-content-id (substring url (match-end 0)))))
 261         (when handle
 262           (gnus-html-put-image (mm-with-part handle (buffer-string))
 263                                url alt-text)))
 264     (if (gnus-html-cache-expired url gnus-html-image-cache-ttl)
 265         ;; We don't have it, so schedule it for fetching
 266         ;; asynchronously.
 267         (gnus-html-schedule-image-fetching
 268          (current-buffer)
 269          (list url alt-text))
 270       ;; It's already cached, so just insert it.
 271       (gnus-html-put-image (gnus-html-get-image-data url) url alt-text))))
 272
 273 (defun gnus-html-wash-tags ()
 274   (let (tag parameters string start end images url)
 275     (gnus-html-pre-wash)
 276     (gnus-html-wash-images)
 277
 278     (goto-char (point-min))
 279     ;; Then do the other tags.
 280     (while (re-search-forward "<\\([^ />]+\\)\\([^>]*\\)>" nil t)
 281       (setq tag (match-string 1)
 282             parameters (match-string 2)
 283             start (match-beginning 0))
 284       (when (> (length parameters) 0)
 285         (set-text-properties 0 (1- (length parameters)) nil parameters))
 286       (delete-region start (point))
 287       (when (search-forward (concat "</" tag ">") nil t)
 288         (delete-region (match-beginning 0) (match-end 0)))
 289       (setq end (point))
 290       (cond
 291        ;; Fetch and insert a picture.
 292        ((equal tag "img_alt"))
 293        ;; Add a link.
 294        ((or (equal tag "a")
 295             (equal tag "A"))
 296         (when (string-match "href=\"\\([^\"]+\\)" parameters)
 297           (setq url (match-string 1 parameters))
 298           (gnus-message 8 "gnus-html-wash-tags: fetching link URL %s" url)
 299           (gnus-article-add-button start end
 300                                    'browse-url (mm-url-decode-entities-string url)
 301                                    url)
 302           (let ((overlay (gnus-make-overlay start end)))
 303             (gnus-overlay-put overlay 'evaporate t)
 304             (gnus-overlay-put overlay 'gnus-button-url url)
 305             (gnus-put-text-property start end 'gnus-string url)
 306             (when gnus-article-mouse-face
 307               (gnus-overlay-put overlay 'mouse-face gnus-article-mouse-face)))))
 308        ;; The upper-case IMG_ALT is apparently just an artifact that
 309        ;; should be deleted.
 310        ((equal tag "IMG_ALT")
 311         (delete-region start end))
 312        ;; w3m does not normalize the case
 313        ((or (equal tag "b")
 314             (equal tag "B"))
 315         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-bold))
 316        ((or (equal tag "u")
 317             (equal tag "U"))
 318         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-underline))
 319        ((or (equal tag "i")
 320             (equal tag "I"))
 321         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-italic))
 322        ((or (equal tag "s")
 323             (equal tag "S"))
 324         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-strikethru))
 325        ((or (equal tag "ins")
 326             (equal tag "INS"))
 327         (gnus-overlay-put (gnus-make-overlay start end) 'face 'gnus-emphasis-underline))
 328        ;; Handle different UL types
 329        ((equal tag "_SYMBOL")
 330         (when (string-match "TYPE=\\(.+\\)" parameters)
 331           (let ((type (string-to-number (match-string 1 parameters))))
 332             (delete-region start end)
 333             (cond ((= type 33) (insert " "))
 334                   ((= type 34) (insert " "))
 335                   ((= type 35) (insert " "))
 336                   ((= type 36) (insert " "))
 337                   ((= type 37) (insert " "))
 338                   ((= type 38) (insert " "))
 339                   ((= type 39) (insert " "))
 340                   ((= type 40) (insert " "))
 341                   ((= type 42) (insert " "))
 342                   ((= type 43) (insert " "))
 343                   (t (insert " "))))))
 344        ;; Whatever.  Just ignore the tag.
 345        (t
 346         ))
 347       (goto-char start))
 348     (goto-char (point-min))
 349     ;; The output from -halfdump isn't totally regular, so strip
 350     ;; off any </pre_int>s that were left over.
 351     (while (re-search-forward "</pre_int>\\|</internal>" nil t)
 352       (replace-match "" t t))
 353     (mm-url-decode-entities)))
 354
 355 (defun gnus-html-insert-image (&rest args)
 356   "Fetch and insert the image under point."
 357   (interactive)
 358   (apply 'gnus-html-display-image (get-text-property (point) 'gnus-image)))
 359
 360 (defun gnus-html-show-alt-text ()
 361   "Show the ALT text of the image under point."
 362   (interactive)
 363   (message "%s" (get-text-property (point) 'gnus-alt-text)))
 364
 365 (defun gnus-html-browse-image ()
 366   "Browse the image under point."
 367   (interactive)
 368   (browse-url (get-text-property (point) 'image-url)))
 369
 370 (defun gnus-html-browse-url ()
 371   "Browse the image under point."
 372   (interactive)
 373   (let ((url (get-text-property (point) 'gnus-string)))
 374     (cond
 375      ((not url)
 376       (message "No link under point"))
 377      ((string-match "^mailto:" url)
 378       (gnus-url-mailto url))
 379      (t
 380       (browse-url url)))))
 381
 382 (defun gnus-html-schedule-image-fetching (buffer image)
 383   "Retrieve IMAGE, and place it into BUFFER on arrival."
 384   (gnus-message 8 "gnus-html-schedule-image-fetching: buffer %s, image %s"
 385                 buffer image)
 386   (let ((args (list (car image)
 387                     'gnus-html-image-fetched
 388                     (list buffer image))))
 389     (when (> (length (if (featurep 'xemacs)
 390                          (cdr (split-string (function-arglist 'url-retrieve)))
 391                        (help-function-arglist 'url-retrieve)))
 392              4)
 393       (setq args (nconc args (list t))))
 394     (ignore-errors
 395       (apply #'url-retrieve args))))
 396
 397 (defun gnus-html-image-fetched (status buffer image)
 398   "Callback function called when image has been fetched."
 399   (unless (plist-get status :error)
 400     (when gnus-html-image-automatic-caching
 401       (url-store-in-cache (current-buffer)))
 402     (when (and (or (search-forward "\n\n" nil t)
 403                    (search-forward "\r\n\r\n" nil t))
 404                (buffer-live-p buffer))
 405       (let ((data (buffer-substring (point) (point-max))))
 406         (with-current-buffer buffer
 407           (let ((inhibit-read-only t))
 408             (gnus-html-put-image data (car image) (cadr image)))))))
 409   (kill-buffer (current-buffer)))
 410
 411 (defun gnus-html-get-image-data (url)
 412   "Get image data for URL.
 413 Return a string with image data."
 414   (with-temp-buffer
 415     (mm-disable-multibyte)
 416     (url-cache-extract (url-cache-create-filename url))
 417     (when (or (search-forward "\n\n" nil t)
 418               (search-forward "\r\n\r\n" nil t))
 419       (buffer-substring (point) (point-max)))))
 420
 421 (defun gnus-html-maximum-image-size ()
 422   "Return the maximum size of an image according to `gnus-max-image-proportion'."
 423   (let ((edges (gnus-window-inside-pixel-edges
 424                 (get-buffer-window (current-buffer)))))
 425     ;; (width . height)
 426     (cons
 427      ;; Aimed width
 428      (truncate
 429       (* gnus-max-image-proportion
 430          (- (nth 2 edges) (nth 0 edges))))
 431      ;; Aimed height
 432      (truncate (* gnus-max-image-proportion
 433                   (- (nth 3 edges) (nth 1 edges)))))))
 434
 435 (defun gnus-html-put-image (data url &optional alt-text)
 436   "Put an image with DATA from URL and optional ALT-TEXT."
 437   (when (gnus-graphic-display-p)
 438     (let* ((start (text-property-any (point-min) (point-max)
 439                                      'image-url url))
 440            (end (when start
 441                   (next-single-property-change start 'image-url))))
 442       ;; Image found?
 443       (when start
 444         (let* ((image
 445                 (ignore-errors
 446                   (gnus-create-image data nil t)))
 447                (size (and image
 448                           (if (featurep 'xemacs)
 449                               (cons (glyph-width image) (glyph-height image))
 450                             (image-size image t)))))
 451           (save-excursion
 452             (goto-char start)
 453             (let ((alt-text (or alt-text
 454                                 (buffer-substring-no-properties start end)))
 455                   (inhibit-read-only t))
 456               (if (and image
 457                        ;; Kludge to avoid displaying 30x30 gif images, which
 458                        ;; seems to be a signal of a broken image.
 459                        (not (and (if (featurep 'xemacs)
 460                                      (glyphp image)
 461                                    (listp image))
 462                                  (eq (if (featurep 'xemacs)
 463                                          (let ((d (cdadar
 464                                                    (specifier-spec-list
 465                                                     (glyph-image image)))))
 466                                            (and (vectorp d)
 467                                                 (aref d 0)))
 468                                        (plist-get (cdr image) :type))
 469                                      'gif)
 470                                  (= (car size) 30)
 471                                  (= (cdr size) 30))))
 472                   ;; Good image, add it!
 473                   (let ((image (gnus-rescale-image image (gnus-html-maximum-image-size))))
 474                     (delete-region start end)
 475                     (gnus-put-image image alt-text 'external)
 476                     (gnus-put-text-property start (point) 'help-echo alt-text)
 477                     (gnus-overlay-put
 478                      (gnus-make-overlay start (point)) 'local-map
 479                      gnus-html-displayed-image-map)
 480                     (gnus-put-text-property start (point)
 481                                             'gnus-alt-text alt-text)
 482                     (when url
 483                       (gnus-put-text-property start (point)
 484                                               'image-url url))
 485                     (gnus-add-image 'external image)
 486                     t)
 487                 ;; Bad image, try to show something else
 488                 (when (fboundp 'find-image)
 489                   (delete-region start end)
 490                   (setq image (find-image
 491                                '((:type xpm :file "lock-broken.xpm"))))
 492                   (gnus-put-image image alt-text 'internal)
 493                   (gnus-add-image 'internal image))
 494                 nil))))))))
 495
 496 (defun gnus-html-image-url-blocked-p (url blocked-images)
 497   "Find out if URL is blocked by BLOCKED-IMAGES."
 498   (let ((ret (and blocked-images
 499                   (string-match blocked-images url))))
 500     (if ret
 501         (gnus-message 8 "gnus-html-image-url-blocked-p: %s blocked by regex %s"
 502                       url blocked-images)
 503       (gnus-message 9 "gnus-html-image-url-blocked-p: %s passes regex %s"
 504                     url blocked-images))
 505     ret))
 506
 507 ;;;###autoload
 508 (defun gnus-html-prefetch-images (summary)
 509   (when (buffer-live-p summary)
 510     (let (inhibit-images blocked-images)
 511       (with-current-buffer summary
 512         (setq inhibit-images gnus-inhibit-images
 513               blocked-images (gnus-blocked-images)))
 514       (save-match-data
 515         (while (re-search-forward "<img[^>]+src=[\"']\\(http[^\"']+\\)" nil t)
 516           (let ((url (gnus-html-encode-url
 517                       (mm-url-decode-entities-string (match-string 1)))))
 518             (unless (or inhibit-images
 519                         (gnus-html-image-url-blocked-p url blocked-images))
 520               (when (gnus-html-cache-expired url gnus-html-image-cache-ttl)
 521                 (gnus-html-schedule-image-fetching nil
 522                                                    (list url))))))))))
 523
 524 (provide 'gnus-html)
 525
 526 ;;; gnus-html.el ends here