cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                (if (null arg) (not gnus-draft-mode)
  72                  (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (mml-mode)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number))
  98         (group gnus-newsgroup-name))
  99     (gnus-summary-mark-as-read article gnus-canceled-mark)
 100     (gnus-draft-setup article group t)
 101     (set-buffer-modified-p t)
 102     (save-excursion
 103       (save-restriction
 104         (message-narrow-to-headers)
 105         (message-remove-header "date")))
 106     (save-buffer)
 107     (let ((gnus-verbose-backends nil))
 108       (gnus-request-expire-articles (list article) group t))
 109     (push
 110      `((lambda ()
 111          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 112            (save-excursion
 113              (set-buffer ,gnus-summary-buffer)
 114              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 115      message-send-actions)))
 116
 117 (defun gnus-draft-send-message (&optional n)
 118   "Send the current draft."
 119   (interactive "P")
 120   (let* ((articles (gnus-summary-work-articles n))
 121          (total (length articles))
 122          article)
 123     (while (setq article (pop articles))
 124       (gnus-summary-remove-process-mark article)
 125       (unless (memq article gnus-newsgroup-unsendable)
 126         (let ((message-sending-message
 127                (format "Sending message %d of %d..."
 128                        (- total (length articles)) total)))
 129           (gnus-draft-send article gnus-newsgroup-name t))
 130         (gnus-summary-mark-article article gnus-canceled-mark)))))
 131
 132 (defun gnus-draft-send (article &optional group interactive)
 133   "Send message ARTICLE."
 134   (let ((message-syntax-checks (if interactive message-syntax-checks
 135                                  'dont-check-for-anything-just-trust-me))
 136         (message-inhibit-body-encoding (or (not group)
 137                                            (equal group "nndraft:queue")
 138                                            message-inhibit-body-encoding))
 139         (message-send-hook (and group (not (equal group "nndraft:queue"))
 140                                 message-send-hook))
 141         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 142                                  message-setup-hook))
 143         type method)
 144     (gnus-draft-setup article (or group "nndraft:queue"))
 145     ;; We read the meta-information that says how and where
 146     ;; this message is to be sent.
 147     (save-restriction
 148       (message-narrow-to-head)
 149       (when (re-search-forward
 150              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 151              nil t)
 152         (setq type (ignore-errors (read (current-buffer)))
 153               method (ignore-errors (read (current-buffer))))
 154         (message-remove-header gnus-agent-meta-information-header)))
 155     ;; Let Agent restore any GCC lines and have message.el perform them.
 156     (gnus-agent-restore-gcc)
 157     ;; Then we send it.  If we have no meta-information, we just send
 158     ;; it and let Message figure out how.
 159     (when (and (or (null method)
 160                    (gnus-server-opened method)
 161                    (gnus-open-server method))
 162                (if type
 163                    (let ((message-this-is-news (eq type 'news))
 164                          (message-this-is-mail (eq type 'mail))
 165                          (gnus-post-method method)
 166                          (message-post-method method))
 167                      (message-send-and-exit))
 168                  (message-send-and-exit)))
 169       (let ((gnus-verbose-backends nil))
 170         (gnus-request-expire-articles
 171          (list article) (or group "nndraft:queue") t)))))
 172
 173 (defun gnus-draft-send-all-messages ()
 174   "Send all the sendable drafts."
 175   (interactive)
 176   (gnus-uu-mark-buffer)
 177   (gnus-draft-send-message))
 178
 179 (defun gnus-group-send-queue ()
 180   "Send all sendable articles from the queue group."
 181   (interactive)
 182   (gnus-activate-group "nndraft:queue")
 183   (save-excursion
 184     (let* ((articles (nndraft-articles))
 185            (unsendable (gnus-uncompress-range
 186                         (cdr (assq 'unsend
 187                                    (gnus-info-marks
 188                                     (gnus-get-info "nndraft:queue"))))))
 189            (gnus-posting-styles nil)
 190            (total (length articles))
 191            article)
 192       (while (setq article (pop articles))
 193         (unless (memq article unsendable)
 194           (let ((message-sending-message
 195                  (format "Sending message %d of %d..."
 196                          (- total (length articles)) total)))
 197             (gnus-draft-send article)))))))
 198
 199 ;;;###autoload
 200 (defun gnus-draft-reminder ()
 201   "Reminder user if there are unsent drafts."
 202   (interactive)
 203   (if (gnus-alive-p)
 204       (let (active)
 205         (catch 'continue
 206           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 207             (setq active (gnus-activate-group group))
 208             (if (and active (>= (cdr active) (car active)))
 209                 (if (y-or-n-p "There are unsent drafts. Confirm to exit?")
 210                     (throw 'continue t)
 211                   (error "Stop!"))))))))
 212
 213 ;;; Utility functions
 214
 215 ;;;!!!If this is byte-compiled, it fails miserably.
 216 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 217 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 218 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 219
 220 (progn
 221   (defun gnus-draft-setup (narticle group &optional restore)
 222     (let (ga)
 223       (gnus-setup-message 'forward
 224         (let ((article narticle))
 225           (message-mail)
 226           (erase-buffer)
 227           (if (not (gnus-request-restore-buffer article group))
 228               (error "Couldn't restore the article")
 229             (when (and restore
 230                        (equal group "nndraft:queue"))
 231               (mime-to-mml))
 232             ;; Insert the separator.
 233             (goto-char (point-min))
 234             (search-forward "\n\n")
 235             (forward-char -1)
 236             (insert mail-header-separator)
 237             (forward-line 1)
 238             (setq ga (message-fetch-field gnus-draft-meta-information-header))
 239             (message-set-auto-save-file-name))))
 240       (gnus-backlog-remove-article group narticle)
 241       (when (and ga
 242                  (ignore-errors (setq ga (car (read-from-string ga)))))
 243         (setq gnus-newsgroup-name
 244               (if (equal (car ga) "") nil (car ga)))
 245         (gnus-configure-posting-styles)
 246         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 247         (setq message-post-method
 248               `(lambda (arg)
 249                  (gnus-post-method arg ,(car ga))))
 250         (unless (equal (cadr ga) "")
 251           (message-add-action
 252            `(progn
 253               (gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 254               (gnus-request-set-mark ,(car ga) (list (list (list ,(cadr ga))
 255                                                            'add '(reply)))))
 256            'send))))))
 257
 258 (defun gnus-draft-article-sendable-p (article)
 259   "Say whether ARTICLE is sendable."
 260   (not (memq article gnus-newsgroup-unsendable)))
 261
 262 (provide 'gnus-draft)
 263
 264 ;;; gnus-draft.el ends here