cgit.sxemacs.org Git - gnus/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (mml-mode)
  80       (gnus-run-hooks 'gnus-draft-mode-hook))))
  81
  82 ;;; Commands
  83
  84 (defun gnus-draft-toggle-sending (article)
  85   "Toggle whether to send an article or not."
  86   (interactive (list (gnus-summary-article-number)))
  87   (if (gnus-draft-article-sendable-p article)
  88       (progn
  89         (push article gnus-newsgroup-unsendable)
  90         (gnus-summary-mark-article article gnus-unsendable-mark))
  91     (setq gnus-newsgroup-unsendable
  92           (delq article gnus-newsgroup-unsendable))
  93     (gnus-summary-mark-article article gnus-unread-mark))
  94   (gnus-summary-position-point))
  95
  96 (defun gnus-draft-edit-message ()
  97   "Enter a mail/post buffer to edit and send the draft."
  98   (interactive)
  99   (let ((article (gnus-summary-article-number))
 100         (group gnus-newsgroup-name))
 101     (gnus-draft-check-draft-articles (list article))
 102     (gnus-summary-mark-as-read article gnus-canceled-mark)
 103     (gnus-draft-setup article group t)
 104     (set-buffer-modified-p t)
 105     (save-excursion
 106       (save-restriction
 107         (message-narrow-to-headers)
 108         (message-remove-header "date")))
 109     (save-buffer)
 110     (let ((gnus-verbose-backends nil))
 111       (gnus-request-expire-articles (list article) group t))
 112     (push
 113      `((lambda ()
 114          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 115            (save-excursion
 116              (set-buffer ,gnus-summary-buffer)
 117              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 118      message-send-actions)))
 119
 120 (defun gnus-draft-send-message (&optional n)
 121   "Send the current draft."
 122   (interactive "P")
 123   (let* ((articles (gnus-summary-work-articles n))
 124          (total (length articles))
 125          article)
 126     (gnus-draft-check-draft-articles articles)
 127     (while (setq article (pop articles))
 128       (gnus-summary-remove-process-mark article)
 129       (unless (memq article gnus-newsgroup-unsendable)
 130         (let ((message-sending-message
 131                (format "Sending message %d of %d..."
 132                        (- total (length articles)) total)))
 133           (gnus-draft-send article gnus-newsgroup-name t))
 134         (gnus-summary-mark-article article gnus-canceled-mark)))))
 135
 136 (defun gnus-draft-send (article &optional group interactive)
 137   "Send message ARTICLE."
 138   (let* ((is-queue (or (not group)
 139                        (equal group "nndraft:queue")))
 140          (message-syntax-checks (if interactive message-syntax-checks
 141                                   'dont-check-for-anything-just-trust-me))
 142          (message-hidden-headers nil)
 143          (message-inhibit-body-encoding (or is-queue
 144                                             message-inhibit-body-encoding))
 145          (message-send-hook (and (not is-queue)
 146                                  message-send-hook))
 147          (message-setup-hook (and (not is-queue)
 148                                   message-setup-hook))
 149          (gnus-agent-queue-mail (and (not is-queue)
 150                                      gnus-agent-queue-mail))
 151          (rfc2047-encode-encoded-words nil)
 152          type method move-to)
 153     (gnus-draft-setup article (or group "nndraft:queue"))
 154     ;; We read the meta-information that says how and where
 155     ;; this message is to be sent.
 156     (save-restriction
 157       (message-narrow-to-headers)
 158       (when (re-search-forward
 159              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 160                      ":") nil t)
 161         (skip-syntax-forward "-")
 162         (setq move-to (buffer-substring (point) (point-at-eol)))
 163         (message-remove-header gnus-agent-target-move-group-header))
 164       (goto-char (point-min))
 165       (when (re-search-forward
 166              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 167              nil t)
 168         (setq type (ignore-errors (read (current-buffer)))
 169               method (ignore-errors (read (current-buffer))))
 170         (message-remove-header gnus-agent-meta-information-header)))
 171     ;; Let Agent restore any GCC lines and have message.el perform them.
 172     (gnus-agent-restore-gcc)
 173     ;; Then we send it.  If we have no meta-information, we just send
 174     ;; it and let Message figure out how.
 175     (when (and (or (null method)
 176                    (gnus-server-opened method)
 177                    (gnus-open-server method))
 178                (if type
 179                    (let ((message-this-is-news (eq type 'news))
 180                          (message-this-is-mail (eq type 'mail))
 181                          (gnus-post-method method)
 182                          (message-post-method method))
 183                      (if move-to
 184                          (gnus-inews-do-gcc move-to)
 185                        (message-send-and-exit)))
 186                  (if move-to
 187                      (gnus-inews-do-gcc move-to)
 188                    (message-send-and-exit))))
 189       (let ((gnus-verbose-backends nil))
 190         (gnus-request-expire-articles
 191          (list article) (or group "nndraft:queue") t)))))
 192
 193 (defun gnus-draft-send-all-messages ()
 194   "Send all the sendable drafts."
 195   (interactive)
 196   (when (or
 197          gnus-expert-user
 198          (gnus-y-or-n-p
 199           "Send all drafts? "))
 200     (gnus-uu-mark-buffer)
 201     (gnus-draft-send-message)))
 202
 203 (defun gnus-group-send-queue ()
 204   "Send all sendable articles from the queue group."
 205   (interactive)
 206   (when (or gnus-plugged
 207             (not gnus-agent-prompt-send-queue)
 208             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 209     (gnus-activate-group "nndraft:queue")
 210     (save-excursion
 211       (let* ((articles (nndraft-articles))
 212              (unsendable (gnus-uncompress-range
 213                           (cdr (assq 'unsend
 214                                      (gnus-info-marks
 215                                       (gnus-get-info "nndraft:queue"))))))
 216              (gnus-posting-styles nil)
 217              (total (length articles))
 218              article)
 219         (while (setq article (pop articles))
 220           (unless (memq article unsendable)
 221             (let ((message-sending-message
 222                    (format "Sending message %d of %d..."
 223                            (- total (length articles)) total)))
 224               (gnus-draft-send article))))))))
 225
 226 ;;;###autoload
 227 (defun gnus-draft-reminder ()
 228   "Reminder user if there are unsent drafts."
 229   (interactive)
 230   (if (gnus-alive-p)
 231       (let (active)
 232         (catch 'continue
 233           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 234             (setq active (gnus-activate-group group))
 235             (if (and active (>= (cdr active) (car active)))
 236                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 237                     (throw 'continue t)
 238                   (error "Stop!"))))))))
 239
 240 ;;; Utility functions
 241
 242 ;;;!!!If this is byte-compiled, it fails miserably.
 243 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 244 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 245 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 246
 247 (progn
 248   (defun gnus-draft-setup (narticle group &optional restore)
 249     (let (ga)
 250       (gnus-setup-message 'forward
 251         (let ((article narticle))
 252           (message-mail)
 253           (erase-buffer)
 254           (if (not (gnus-request-restore-buffer article group))
 255               (error "Couldn't restore the article")
 256             (when (and restore
 257                        (equal group "nndraft:queue"))
 258               (mime-to-mml))
 259             ;; Insert the separator.
 260             (goto-char (point-min))
 261             (search-forward "\n\n")
 262             (forward-char -1)
 263             (save-restriction
 264               (narrow-to-region (point-min) (point))
 265               (setq ga
 266                     (message-fetch-field gnus-draft-meta-information-header)))
 267             (insert mail-header-separator)
 268             (forward-line 1)
 269             (message-set-auto-save-file-name))))
 270       (gnus-backlog-remove-article group narticle)
 271       (when (and ga
 272                  (ignore-errors (setq ga (car (read-from-string ga)))))
 273         (setq gnus-newsgroup-name
 274               (if (equal (car ga) "") nil (car ga)))
 275         (gnus-configure-posting-styles)
 276         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 277         (setq message-post-method
 278               `(lambda (arg)
 279                  (gnus-post-method arg ,(car ga))))
 280         (unless (equal (cadr ga) "")
 281           (dolist (article (cdr ga))
 282             (message-add-action
 283              `(progn
 284                 (gnus-add-mark ,(car ga) 'replied ,article)
 285                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 286                                                              'add '(reply)))))
 287              'send)))))))
 288
 289 (defun gnus-draft-article-sendable-p (article)
 290   "Say whether ARTICLE is sendable."
 291   (not (memq article gnus-newsgroup-unsendable)))
 292
 293 (defun gnus-draft-check-draft-articles (articles)
 294   "Check whether the draft articles ARTICLES are under edit."
 295   (when (equal gnus-newsgroup-name "nndraft:drafts")
 296     (let ((buffers (buffer-list))
 297           file buffs buff)
 298       (save-current-buffer
 299         (while (and articles
 300                     (not buff))
 301           (setq file (nndraft-article-filename (pop articles))
 302                 buffs buffers)
 303           (while buffs
 304             (set-buffer (setq buff (pop buffs)))
 305             (if (and buffer-file-name
 306                      (string-equal (file-truename buffer-file-name)
 307                                    (file-truename file))
 308                      (buffer-modified-p))
 309                 (setq buffs nil)
 310               (setq buff nil)))))
 311       (when buff
 312         (let* ((window (get-buffer-window buff t))
 313                (frame (and window (window-frame window))))
 314           (if frame
 315               (gnus-select-frame-set-input-focus frame)
 316             (pop-to-buffer buff t)))
 317         (error "The draft %s is under edit" file)))))
 318
 319 (provide 'gnus-draft)
 320
 321 ;;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 322 ;;; gnus-draft.el ends here