cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-int)
  30 (require 'nnheader)
  31 (eval-and-compile
  32   (if (string-match "XEmacs" (emacs-version))
  33       (require 'itimer)
  34     (require 'timer)))
  35
  36 (defgroup gnus-demon nil
  37   "Demonic behaviour."
  38   :group 'gnus)
  39
  40 (defcustom gnus-demon-handlers nil
  41   "Alist of daemonic handlers to be run at intervals.
  42 Each handler is a list on the form
  43
  44 \(FUNCTION TIME IDLE)
  45
  46 FUNCTION is the function to be called.
  47 TIME is the number of `gnus-demon-timestep's between each call.
  48 If nil, never call.  If t, call each `gnus-demon-timestep'.
  49 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  50 is a number, only call when Emacs has been idle more than this number
  51 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  52 idleness.  If IDLE is a number and TIME is nil, then call once each
  53 time Emacs has been idle for IDLE `gnus-demon-timestep's."
  54   :group 'gnus-demon
  55   :type '(repeat (list function
  56                        (choice :tag "Time"
  57                                (const :tag "never" nil)
  58                                (const :tag "one" t)
  59                                (integer :tag "steps" 1))
  60                        (choice :tag "Idle"
  61                                (const :tag "don't care" nil)
  62                                (const :tag "for a while" t)
  63                                (integer :tag "steps" 1)))))
  64
  65 (defcustom gnus-demon-timestep 60
  66   "*Number of seconds in each demon timestep."
  67   :group 'gnus-demon
  68   :type 'integer)
  69
  70 ;;; Internal variables.
  71
  72 (defvar gnus-demon-timer nil)
  73 (defvar gnus-demon-idle-has-been-called nil)
  74 (defvar gnus-demon-idle-time 0)
  75 (defvar gnus-demon-handler-state nil)
  76 (defvar gnus-demon-last-keys nil)
  77
  78 (eval-and-compile
  79   (autoload 'timezone-parse-date "timezone")
  80   (autoload 'timezone-make-arpa-date "timezone"))
  81
  82 ;;; Functions.
  83
  84 (defun gnus-demon-add-handler (function time idle)
  85   "Add the handler FUNCTION to be run at TIME and IDLE."
  86   ;; First remove any old handlers that use this function.
  87   (gnus-demon-remove-handler function)
  88   ;; Then add the new one.
  89   (push (list function time idle) gnus-demon-handlers)
  90   (gnus-demon-init))
  91
  92 (defun gnus-demon-remove-handler (function &optional no-init)
  93   "Remove the handler FUNCTION from the list of handlers."
  94   (setq gnus-demon-handlers
  95         (delq (assq function gnus-demon-handlers)
  96               gnus-demon-handlers))
  97   (unless no-init
  98     (gnus-demon-init)))
  99
 100 (defun gnus-demon-init ()
 101   "Initialize the Gnus daemon."
 102   (interactive)
 103   (gnus-demon-cancel)
 104   (if (null gnus-demon-handlers)
 105       ()                                ; Nothing to do.
 106     ;; Set up timer.
 107     (setq gnus-demon-timer
 108           (nnheader-run-at-time
 109            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
 110     ;; Reset control variables.
 111     (setq gnus-demon-handler-state
 112           (mapcar
 113            (lambda (handler)
 114              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 115                    (nth 2 handler)))
 116            gnus-demon-handlers))
 117     (setq gnus-demon-idle-time 0)
 118     (setq gnus-demon-idle-has-been-called nil)
 119     (setq gnus-use-demon t)))
 120
 121 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 122
 123 (defun gnus-demon-cancel ()
 124   "Cancel any Gnus daemons."
 125   (interactive)
 126   (when gnus-demon-timer
 127     (nnheader-cancel-timer gnus-demon-timer))
 128   (setq gnus-demon-timer nil
 129         gnus-use-demon nil)
 130   (condition-case ()
 131       (nnheader-cancel-function-timers 'gnus-demon)
 132     (error t)))
 133
 134 (defun gnus-demon-is-idle-p ()
 135   "Whether Emacs is idle or not."
 136   ;; We do this simply by comparing the 100 most recent keystrokes
 137   ;; with the ones we had last time.  If they are the same, one might
 138   ;; guess that Emacs is indeed idle.  This only makes sense if one
 139   ;; calls this function seldom -- like once a minute, which is what
 140   ;; we do here.
 141   (let ((keys (recent-keys)))
 142     (or (equal keys gnus-demon-last-keys)
 143         (progn
 144           (setq gnus-demon-last-keys keys)
 145           nil))))
 146
 147 (defun gnus-demon-time-to-step (time)
 148   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 149   (if (not (stringp time))
 150       time
 151     (let* ((date (current-time-string))
 152            (dv (timezone-parse-date date))
 153            (tdate (timezone-make-arpa-date
 154                    (string-to-number (aref dv 0))
 155                    (string-to-number (aref dv 1))
 156                    (string-to-number (aref dv 2)) time
 157                    (or (aref dv 4) "UT")))
 158            (nseconds (gnus-time-minus
 159                       (gnus-encode-date tdate) (gnus-encode-date date))))
 160       (round
 161        (/ (+ (if (< (car nseconds) 0)
 162                  86400 0)
 163              (* 65536 (car nseconds))
 164              (nth 1 nseconds))
 165           gnus-demon-timestep)))))
 166
 167 (defun gnus-demon ()
 168   "The Gnus daemon that takes care of running all Gnus handlers."
 169   ;; Increase or reset the time Emacs has been idle.
 170   (if (gnus-demon-is-idle-p)
 171       (incf gnus-demon-idle-time)
 172     (setq gnus-demon-idle-time 0)
 173     (setq gnus-demon-idle-has-been-called nil))
 174   ;; Then we go through all the handler and call those that are
 175   ;; sufficiently ripe.
 176   (let ((handlers gnus-demon-handler-state)
 177         handler time idle)
 178     (while handlers
 179       (setq handler (pop handlers))
 180       (cond
 181        ((numberp (setq time (nth 1 handler)))
 182         ;; These handlers use a regular timeout mechanism.  We decrease
 183         ;; the timer if it hasn't reached zero yet.
 184         (unless (zerop time)
 185           (setcar (nthcdr 1 handler) (decf time)))
 186         (and (zerop time)               ; If the timer now is zero...
 187              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 188                  (and (numberp idle)    ; Numerical idle...
 189                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 190                  gnus-demon-idle-time)  ; Or just need to be idle.
 191              ;; So we call the handler.
 192              (progn
 193                (funcall (car handler))
 194                ;; And reset the timer.
 195                (setcar (nthcdr 1 handler)
 196                        (gnus-demon-time-to-step
 197                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 198        ;; These are only supposed to be called when Emacs is idle.
 199        ((null (setq idle (nth 2 handler)))
 200         ;; We do nothing.
 201         )
 202        ((not (numberp idle))
 203         ;; We want to call this handler each and every time that
 204         ;; Emacs is idle.
 205         (funcall (car handler)))
 206        (t
 207         ;; We want to call this handler only if Emacs has been idle
 208         ;; for a specified number of timesteps.
 209         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 210              (< idle gnus-demon-idle-time)
 211              (progn
 212                (funcall (car handler))
 213                ;; Make sure the handler won't be called once more in
 214                ;; this idle-cycle.
 215                (push (car handler) gnus-demon-idle-has-been-called))))))))
 216
 217 (defun gnus-demon-add-nocem ()
 218   "Add daemonic NoCeM handling to Gnus."
 219   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 220
 221 (defun gnus-demon-scan-nocem ()
 222   "Scan NoCeM groups for NoCeM messages."
 223   (save-window-excursion
 224     (gnus-nocem-scan-groups)))
 225
 226 (defun gnus-demon-add-disconnection ()
 227   "Add daemonic server disconnection to Gnus."
 228   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 229
 230 (defun gnus-demon-close-connections ()
 231   (save-window-excursion
 232     (gnus-close-backends)))
 233
 234 (defun gnus-demon-add-scanmail ()
 235   "Add daemonic scanning of mail from the mail backends."
 236   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 237
 238 (defun gnus-demon-scan-mail ()
 239   (save-window-excursion
 240     (let ((servers gnus-opened-servers)
 241           server)
 242       (while (setq server (car (pop servers)))
 243         (and (gnus-check-backend-function 'request-scan (car server))
 244              (or (gnus-server-opened server)
 245                  (gnus-open-server server))
 246              (gnus-request-scan nil server))))))
 247
 248 (defun gnus-demon-add-rescan ()
 249   "Add daemonic scanning of new articles from all backends."
 250   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 251
 252 (defun gnus-demon-scan-news ()
 253   (save-window-excursion
 254     (when (gnus-alive-p)
 255       (save-excursion
 256         (set-buffer gnus-group-buffer)
 257         (gnus-group-get-new-news)))))
 258
 259 (defun gnus-demon-add-scan-timestamps ()
 260   "Add daemonic updating of timestamps in empty newgroups."
 261   (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
 262
 263 (defun gnus-demon-scan-timestamps ()
 264   "Set the timestamp on all newsgroups with no unread and no ticked articles."
 265   (when (gnus-alive-p)
 266     (let ((cur-time (current-time))
 267           (newsrc (cdr gnus-newsrc-alist))
 268           info group unread has-ticked)
 269       (while (setq info (pop newsrc))
 270         (setq group (gnus-info-group info)
 271               unread (gnus-group-unread group)
 272               has-ticked (cdr (assq 'tick (gnus-info-marks info))))
 273         (when (and (numberp unread)
 274                    (= unread 0)
 275                    (not has-ticked))
 276           (gnus-group-set-parameter group 'timestamp cur-time))))))
 277
 278 (provide 'gnus-demon)
 279
 280 ;;; gnus-demon.el ends here