cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96,97 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-int)
  30 (require 'nnheader)
  31 (eval-and-compile
  32   (if (string-match "XEmacs" (emacs-version))
  33       (require 'itimer)
  34     (require 'timer)))
  35
  36 (defgroup gnus-demon nil
  37   "Demonic behaviour."
  38   :group 'gnus)
  39
  40 (defcustom gnus-demon-handlers nil
  41   "Alist of daemonic handlers to be run at intervals.
  42 Each handler is a list on the form
  43
  44 \(FUNCTION TIME IDLE)
  45
  46 FUNCTION is the function to be called.
  47 TIME is the number of `gnus-demon-timestep's between each call.
  48 If nil, never call.  If t, call each `gnus-demon-timestep'.
  49 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  50 is a number, only call when Emacs has been idle more than this number
  51 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  52 idleness.  If IDLE is a number and TIME is nil, then call once each
  53 time Emacs has been idle for IDLE `gnus-demon-timestep's."
  54   :group 'gnus-demon
  55   :type '(repeat (list function
  56                        (choice :tag "Time"
  57                                (const :tag "never" nil)
  58                                (const :tag "one" t)
  59                                (integer :tag "steps" 1))
  60                        (choice :tag "Idle"
  61                                (const :tag "don't care" nil)
  62                                (const :tag "for a while" t)
  63                                (integer :tag "steps" 1)))))
  64
  65 (defcustom gnus-demon-timestep 60
  66   "*Number of seconds in each demon timestep."
  67   :group 'gnus-demon
  68   :type 'integer)
  69
  70 ;;; Internal variables.
  71
  72 (defvar gnus-demon-timer nil)
  73 (defvar gnus-demon-idle-has-been-called nil)
  74 (defvar gnus-demon-idle-time 0)
  75 (defvar gnus-demon-handler-state nil)
  76 (defvar gnus-demon-last-keys nil)
  77 (defvar gnus-inhibit-demon nil
  78   "*If non-nil, no daemonic function will be run.")
  79
  80 (eval-and-compile
  81   (autoload 'timezone-parse-date "timezone")
  82   (autoload 'timezone-make-arpa-date "timezone"))
  83
  84 ;;; Functions.
  85
  86 (defun gnus-demon-add-handler (function time idle)
  87   "Add the handler FUNCTION to be run at TIME and IDLE."
  88   ;; First remove any old handlers that use this function.
  89   (gnus-demon-remove-handler function)
  90   ;; Then add the new one.
  91   (push (list function time idle) gnus-demon-handlers)
  92   (gnus-demon-init))
  93
  94 (defun gnus-demon-remove-handler (function &optional no-init)
  95   "Remove the handler FUNCTION from the list of handlers."
  96   (setq gnus-demon-handlers
  97         (delq (assq function gnus-demon-handlers)
  98               gnus-demon-handlers))
  99   (unless no-init
 100     (gnus-demon-init)))
 101
 102 (defun gnus-demon-init ()
 103   "Initialize the Gnus daemon."
 104   (interactive)
 105   (gnus-demon-cancel)
 106   (if (null gnus-demon-handlers)
 107       ()                                ; Nothing to do.
 108     ;; Set up timer.
 109     (setq gnus-demon-timer
 110           (nnheader-run-at-time
 111            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
 112     ;; Reset control variables.
 113     (setq gnus-demon-handler-state
 114           (mapcar
 115            (lambda (handler)
 116              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 117                    (nth 2 handler)))
 118            gnus-demon-handlers))
 119     (setq gnus-demon-idle-time 0)
 120     (setq gnus-demon-idle-has-been-called nil)
 121     (setq gnus-use-demon t)))
 122
 123 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 124
 125 (defun gnus-demon-cancel ()
 126   "Cancel any Gnus daemons."
 127   (interactive)
 128   (when gnus-demon-timer
 129     (nnheader-cancel-timer gnus-demon-timer))
 130   (setq gnus-demon-timer nil
 131         gnus-use-demon nil)
 132   (condition-case ()
 133       (nnheader-cancel-function-timers 'gnus-demon)
 134     (error t)))
 135
 136 (defun gnus-demon-is-idle-p ()
 137   "Whether Emacs is idle or not."
 138   ;; We do this simply by comparing the 100 most recent keystrokes
 139   ;; with the ones we had last time.  If they are the same, one might
 140   ;; guess that Emacs is indeed idle.  This only makes sense if one
 141   ;; calls this function seldom -- like once a minute, which is what
 142   ;; we do here.
 143   (let ((keys (recent-keys)))
 144     (or (equal keys gnus-demon-last-keys)
 145         (progn
 146           (setq gnus-demon-last-keys keys)
 147           nil))))
 148
 149 (defun gnus-demon-time-to-step (time)
 150   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 151   (if (not (stringp time))
 152       time
 153     (let* ((now (current-time))
 154            ;; obtain NOW as discrete components -- make a vector for speed
 155            (nowParts (apply 'vector (decode-time now)))
 156            ;; obtain THEN as discrete components
 157            (thenParts (timezone-parse-time time))
 158            (thenHour (string-to-int (elt thenParts 0)))
 159            (thenMin (string-to-int (elt thenParts 1)))
 160            ;; convert time as elements into number of seconds since EPOCH.
 161            (then (encode-time 0
 162                               thenMin
 163                               thenHour
 164                               ;; If THEN is earlier than NOW, make it
 165                               ;; same time tomorrow. Doc for encode-time
 166                               ;; says that this is OK.
 167                               (+ (elt nowParts 3)
 168                                  (if (or (< thenHour (elt nowParts 2))
 169                                          (and (= thenHour (elt nowParts 2))
 170                                               (<= thenMin (elt nowParts 1))))
 171                                      1 0))
 172                               (elt nowParts 4)
 173                               (elt nowParts 5)
 174                               (elt nowParts 6)
 175                               (elt nowParts 7)
 176                               (elt nowParts 8)))
 177            ;; calculate number of seconds between NOW and THEN
 178            (diff (+ (* 65536 (- (car then) (car now)))
 179                     (- (cadr then) (cadr now)))))
 180       ;; return number of timesteps in the number of seconds
 181       (round (/ diff gnus-demon-timestep)))))
 182
 183 (defun gnus-demon ()
 184   "The Gnus daemon that takes care of running all Gnus handlers."
 185   ;; Increase or reset the time Emacs has been idle.
 186   (if (gnus-demon-is-idle-p)
 187       (incf gnus-demon-idle-time)
 188     (setq gnus-demon-idle-time 0)
 189     (setq gnus-demon-idle-has-been-called nil))
 190   ;; Disable all daemonic stuff if we're in the minibuffer
 191   (when (and (not (window-minibuffer-p (selected-window)))
 192              (not gnus-inhibit-demon))
 193     ;; Then we go through all the handler and call those that are
 194     ;; sufficiently ripe.
 195     (let ((handlers gnus-demon-handler-state)
 196           (gnus-inhibit-demon t)
 197           handler time idle)
 198       (while handlers
 199         (setq handler (pop handlers))
 200         (cond
 201          ((numberp (setq time (nth 1 handler)))
 202           ;; These handlers use a regular timeout mechanism.  We decrease
 203           ;; the timer if it hasn't reached zero yet.
 204           (unless (zerop time)
 205             (setcar (nthcdr 1 handler) (decf time)))
 206           (and (zerop time)             ; If the timer now is zero...
 207                ;; Test for appropriate idleness
 208                (progn
 209                  (setq idle (nth 2 handler))
 210                  (cond
 211                   ((null idle) t)       ; Don't care about idle.
 212                   ((numberp idle)       ; Numerical idle...
 213                    (< idle gnus-demon-idle-time)) ; Idle timed out.
 214                   (t (< 0 gnus-demon-idle-time)))) ; Or just need to be idle.
 215                ;; So we call the handler.
 216                (progn
 217                  (ignore-errors (funcall (car handler)))
 218                  ;; And reset the timer.
 219                  (setcar (nthcdr 1 handler)
 220                          (gnus-demon-time-to-step
 221                           (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 222          ;; These are only supposed to be called when Emacs is idle.
 223          ((null (setq idle (nth 2 handler)))
 224           ;; We do nothing.
 225           )
 226          ((not (numberp idle))
 227           ;; We want to call this handler each and every time that
 228           ;; Emacs is idle.
 229           (ignore-errors (funcall (car handler))))
 230          (t
 231           ;; We want to call this handler only if Emacs has been idle
 232           ;; for a specified number of timesteps.
 233           (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 234                (< idle gnus-demon-idle-time)
 235                (progn
 236                  (ignore-errors (funcall (car handler)))
 237                  ;; Make sure the handler won't be called once more in
 238                  ;; this idle-cycle.
 239                  (push (car handler) gnus-demon-idle-has-been-called)))))))))
 240
 241 (defun gnus-demon-add-nocem ()
 242   "Add daemonic NoCeM handling to Gnus."
 243   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 30))
 244
 245 (defun gnus-demon-scan-nocem ()
 246   "Scan NoCeM groups for NoCeM messages."
 247   (save-window-excursion
 248     (gnus-nocem-scan-groups)))
 249
 250 (defun gnus-demon-add-disconnection ()
 251   "Add daemonic server disconnection to Gnus."
 252   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 253
 254 (defun gnus-demon-close-connections ()
 255   (save-window-excursion
 256     (gnus-close-backends)))
 257
 258 (defun gnus-demon-add-scanmail ()
 259   "Add daemonic scanning of mail from the mail backends."
 260   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 261
 262 (defun gnus-demon-scan-mail ()
 263   (save-window-excursion
 264     (let ((servers gnus-opened-servers)
 265           server)
 266       (while (setq server (car (pop servers)))
 267         (and (gnus-check-backend-function 'request-scan (car server))
 268              (or (gnus-server-opened server)
 269                  (gnus-open-server server))
 270              (gnus-request-scan nil server))))))
 271
 272 (defun gnus-demon-add-rescan ()
 273   "Add daemonic scanning of new articles from all backends."
 274   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 275
 276 (defun gnus-demon-scan-news ()
 277   (save-window-excursion
 278     (when (gnus-alive-p)
 279       (save-excursion
 280         (set-buffer gnus-group-buffer)
 281         (gnus-group-get-new-news)))))
 282
 283 (defun gnus-demon-add-scan-timestamps ()
 284   "Add daemonic updating of timestamps in empty newgroups."
 285   (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
 286
 287 (defun gnus-demon-scan-timestamps ()
 288   "Set the timestamp on all newsgroups with no unread and no ticked articles."
 289   (when (gnus-alive-p)
 290     (let ((cur-time (current-time))
 291           (newsrc (cdr gnus-newsrc-alist))
 292           info group unread has-ticked)
 293       (while (setq info (pop newsrc))
 294         (setq group (gnus-info-group info)
 295               unread (gnus-group-unread group)
 296               has-ticked (cdr (assq 'tick (gnus-info-marks info))))
 297         (when (and (numberp unread)
 298                    (= unread 0)
 299                    (not has-ticked))
 300           (gnus-group-set-parameter group 'timestamp cur-time))))))
 301
 302 (provide 'gnus-demon)
 303
 304 ;;; gnus-demon.el ends here