cgit.sxemacs.org Git - gnus/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-int)
  30 (require 'nnheader)
  31 (require 'gnus)
  32
  33 (defvar gnus-demon-handlers nil
  34   "Alist of daemonic handlers to be run at intervals.
  35 Each handler is a list on the form
  36
  37 \(FUNCTION TIME IDLE)
  38
  39 FUNCTION is the function to be called.
  40 TIME is the number of `gnus-demon-timestep's between each call.
  41 If nil, never call.  If t, call each `gnus-demon-timestep'.
  42 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  43 is a number, only call when Emacs has been idle more than this number
  44 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  45 idleness.  If IDLE is a number and TIME is nil, then call once each
  46 time Emacs has been idle for IDLE `gnus-demon-timestep's.")
  47
  48 (defvar gnus-demon-timestep 60
  49   "*Number of seconds in each demon timestep.")
  50
  51 ;;; Internal variables.
  52
  53 (defvar gnus-demon-timer nil)
  54 (defvar gnus-demon-idle-has-been-called nil)
  55 (defvar gnus-demon-idle-time 0)
  56 (defvar gnus-demon-handler-state nil)
  57 (defvar gnus-demon-is-idle nil)
  58 (defvar gnus-demon-last-keys nil)
  59
  60 (eval-and-compile
  61   (autoload 'timezone-parse-date "timezone")
  62   (autoload 'timezone-make-arpa-date "timezone"))
  63
  64 ;;; Functions.
  65
  66 (defun gnus-demon-add-handler (function time idle)
  67   "Add the handler FUNCTION to be run at TIME and IDLE."
  68   ;; First remove any old handlers that use this function.
  69   (gnus-demon-remove-handler function)
  70   ;; Then add the new one.
  71   (push (list function time idle) gnus-demon-handlers)
  72   (gnus-demon-init))
  73
  74 (defun gnus-demon-remove-handler (function &optional no-init)
  75   "Remove the handler FUNCTION from the list of handlers."
  76   (setq gnus-demon-handlers
  77         (delq (assq function gnus-demon-handlers)
  78               gnus-demon-handlers))
  79   (or no-init (gnus-demon-init)))
  80
  81 (defun gnus-demon-init ()
  82   "Initialize the Gnus daemon."
  83   (interactive)
  84   (gnus-demon-cancel)
  85   (if (null gnus-demon-handlers)
  86       () ; Nothing to do.
  87     ;; Set up timer.
  88     (setq gnus-demon-timer
  89           (nnheader-run-at-time
  90            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
  91     ;; Reset control variables.
  92     (setq gnus-demon-handler-state
  93           (mapcar
  94            (lambda (handler)
  95              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
  96                    (nth 2 handler)))
  97            gnus-demon-handlers))
  98     (setq gnus-demon-idle-time 0)
  99     (setq gnus-demon-idle-has-been-called nil)
 100     (setq gnus-use-demon t)))
 101
 102 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 103
 104 (defun gnus-demon-cancel ()
 105   "Cancel any Gnus daemons."
 106   (interactive)
 107   (and gnus-demon-timer
 108        (nnheader-cancel-timer gnus-demon-timer))
 109   (setq gnus-demon-timer nil
 110         gnus-use-demon nil)
 111   (nnheader-cancel-function-timers 'gnus-demon))
 112
 113 (defun gnus-demon-is-idle-p ()
 114   "Whether Emacs is idle or not."
 115   ;; We do this simply by comparing the 100 most recent keystrokes
 116   ;; with the ones we had last time.  If they are the same, one might
 117   ;; guess that Emacs is indeed idle.  This only makes sense if one
 118   ;; calls this function seldom -- like once a minute, which is what
 119   ;; we do here.
 120   (let ((keys (recent-keys)))
 121     (or (equal keys gnus-demon-last-keys)
 122         (progn
 123           (setq gnus-demon-last-keys keys)
 124           nil))))
 125
 126 (defun gnus-demon-time-to-step (time)
 127   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 128   (if (not (stringp time))
 129       time
 130     (let* ((date (current-time-string))
 131            (dv (timezone-parse-date date))
 132            (tdate (timezone-make-arpa-date
 133                    (string-to-number (aref dv 0))
 134                    (string-to-number (aref dv 1))
 135                    (string-to-number (aref dv 2)) time
 136                    (or (aref dv 4) "UT")))
 137            (nseconds (gnus-time-minus
 138                       (gnus-encode-date tdate) (gnus-encode-date date))))
 139       (round
 140        (/ (if (< nseconds 0)
 141               (+ nseconds (* 60 60 24))
 142             nseconds) gnus-demon-timestep)))))
 143
 144 (defun gnus-demon ()
 145   "The Gnus daemon that takes care of running all Gnus handlers."
 146   ;; Increase or reset the time Emacs has been idle.
 147   (if (gnus-demon-is-idle-p)
 148       (incf gnus-demon-idle-time)
 149     (setq gnus-demon-idle-time 0)
 150     (setq gnus-demon-idle-has-been-called nil))
 151   ;; Then we go through all the handler and call those that are
 152   ;; sufficiently ripe.
 153   (let ((handlers gnus-demon-handler-state)
 154         handler time idle)
 155     (while handlers
 156       (setq handler (pop handlers))
 157       (cond
 158        ((numberp (setq time (nth 1 handler)))
 159         ;; These handlers use a regular timeout mechanism.  We decrease
 160         ;; the timer if it hasn't reached zero yet.
 161         (or (zerop time)
 162             (setcar (nthcdr 1 handler) (decf time)))
 163         (and (zerop time)               ; If the timer now is zero...
 164              (or (not (setq idle (nth 2 handler))) ; Don't care about idle.
 165                  (and (numberp idle)    ; Numerical idle...
 166                       (< idle gnus-demon-idle-time)) ; Idle timed out.
 167                  gnus-demon-is-idle)    ; Or just need to be idle.
 168              ;; So we call the handler.
 169              (progn
 170                (funcall (car handler))
 171                ;; And reset the timer.
 172                (setcar (nthcdr 1 handler)
 173                        (gnus-demon-time-to-step
 174                         (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 175        ;; These are only supposed to be called when Emacs is idle.
 176        ((null (setq idle (nth 2 handler)))
 177         ;; We do nothing.
 178         )
 179        ((not (numberp idle))
 180         ;; We want to call this handler each and every time that
 181         ;; Emacs is idle.
 182         (funcall (car handler)))
 183        (t
 184         ;; We want to call this handler only if Emacs has been idle
 185         ;; for a specified number of timesteps.
 186         (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 187              (< idle gnus-demon-idle-time)
 188              (progn
 189                (funcall (car handler))
 190                ;; Make sure the handler won't be called once more in
 191                ;; this idle-cycle.
 192                (push (car handler) gnus-demon-idle-has-been-called))))))))
 193
 194 (defun gnus-demon-add-nocem ()
 195   "Add daemonic NoCeM handling to Gnus."
 196   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 t))
 197
 198 (defun gnus-demon-scan-nocem ()
 199   "Scan NoCeM groups for NoCeM messages."
 200   (gnus-nocem-scan-groups))
 201
 202 (defun gnus-demon-add-disconnection ()
 203   "Add daemonic server disconnection to Gnus."
 204   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 205
 206 (defun gnus-demon-close-connections ()
 207   (gnus-close-backends))
 208
 209 (defun gnus-demon-add-scanmail ()
 210   "Add daemonic scanning of mail from the mail backends."
 211   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 212
 213 (defun gnus-demon-scan-mail ()
 214   (let ((servers gnus-opened-servers)
 215         server)
 216     (while (setq server (car (pop servers)))
 217       (and (gnus-check-backend-function 'request-scan (car server))
 218            (or (gnus-server-opened server)
 219                (gnus-open-server server))
 220            (gnus-request-scan nil server)))))
 221
 222 (defun gnus-demon-add-rescan ()
 223   "Add daemonic scanning of new articles from all backends."
 224   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 225
 226 (defun gnus-demon-scan-news ()
 227   (when (gnus-alive-p)
 228     (save-excursion
 229       (set-buffer gnus-group-buffer)
 230       (gnus-group-get-new-news))))
 231
 232 (provide 'gnus-demon)
 233
 234 ;;; gnus-demon.el ends here