cgit.sxemacs.org Git - gnus/blob - lisp/gnus-cache.el

   1 ;;; gnus-cache.el --- cache interface for Gnus
   2 ;; Copyright (C) 1995,96 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-int)
  30 (require 'gnus-range)
  31 (require 'gnus-sum)
  32 (require 'gnus-start)
  33
  34 (defgroup gnus-cache nil
  35   "Cache interface."
  36   :group 'gnus)
  37
  38 (defcustom gnus-cache-directory
  39   (nnheader-concat gnus-directory "cache/")
  40   "*The directory where cached articles will be stored."
  41   :group 'gnus-cache
  42   :type 'directory)
  43
  44 (defcustom gnus-cache-active-file
  45   (concat (file-name-as-directory gnus-cache-directory) "active")
  46   "*The cache active file."
  47   :group 'gnus-cache
  48   :type 'file)
  49
  50 (defcustom gnus-cache-enter-articles '(ticked dormant)
  51   "Classes of articles to enter into the cache."
  52   :group 'gnus-cache
  53   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  54
  55 (defcustom gnus-cache-remove-articles '(read)
  56   "Classes of articles to remove from the cache."
  57   :group 'gnus-cache
  58   :type '(set (const ticked) (const dormant) (const unread) (const read)))
  59
  60 (defcustom gnus-uncacheable-groups nil
  61   "*Groups that match this regexp will not be cached.
  62
  63 If you want to avoid caching your nnml groups, you could set this
  64 variable to \"^nnml\"."
  65   :group 'gnus-cache
  66   :type '(choice (const :tag "off" nil)
  67                  regexp))
  68
  69 \f
  70
  71 ;;; Internal variables.
  72
  73 (defvar gnus-cache-removable-articles nil)
  74 (defvar gnus-cache-buffer nil)
  75 (defvar gnus-cache-active-hashtb nil)
  76 (defvar gnus-cache-active-altered nil)
  77
  78 (eval-and-compile
  79   (autoload 'nnml-generate-nov-databases-1 "nnml")
  80   (autoload 'nnvirtual-find-group-art "nnvirtual"))
  81
  82 \f
  83
  84 ;;; Functions called from Gnus.
  85
  86 (defun gnus-cache-open ()
  87   "Initialize the cache."
  88   (when (or (file-exists-p gnus-cache-directory)
  89             (and gnus-use-cache
  90                  (not (eq gnus-use-cache 'passive))))
  91     (gnus-cache-read-active)))
  92
  93 ;; Complexities of byte-compiling makes this kludge necessary.  Eeek.
  94 (ignore-errors
  95   (gnus-add-shutdown 'gnus-cache-close 'gnus))
  96
  97 (defun gnus-cache-close ()
  98   "Shut down the cache."
  99   (gnus-cache-write-active)
 100   (gnus-cache-save-buffers)
 101   (setq gnus-cache-active-hashtb nil))
 102
 103 (defun gnus-cache-save-buffers ()
 104   ;; save the overview buffer if it exists and has been modified
 105   ;; delete empty cache subdirectories
 106   (when gnus-cache-buffer
 107     (let ((buffer (cdr gnus-cache-buffer))
 108           (overview-file (gnus-cache-file-name
 109                           (car gnus-cache-buffer) ".overview")))
 110       ;; write the overview only if it was modified
 111       (when (buffer-modified-p buffer)
 112         (save-excursion
 113           (set-buffer buffer)
 114           (if (> (buffer-size) 0)
 115               ;; Non-empty overview, write it to a file.
 116               (gnus-write-buffer overview-file)
 117             ;; Empty overview file, remove it
 118             (when (file-exists-p overview-file)
 119               (delete-file overview-file))
 120             ;; If possible, remove group's cache subdirectory.
 121             (condition-case nil
 122                 ;; FIXME: we can detect the error type and warn the user
 123                 ;; of any inconsistencies (articles w/o nov entries?).
 124                 ;; for now, just be conservative...delete only if safe -- sj
 125                 (delete-directory (file-name-directory overview-file))
 126               (error nil)))))
 127       ;; Kill the buffer -- it's either unmodified or saved.
 128       (gnus-kill-buffer buffer)
 129       (setq gnus-cache-buffer nil))))
 130
 131 (defun gnus-cache-possibly-enter-article
 132   (group article headers ticked dormant unread &optional force)
 133   (when (and (or force (not (eq gnus-use-cache 'passive)))
 134              (numberp article)
 135              (> article 0)
 136              (vectorp headers))
 137                                         ; This might be a dummy article.
 138     ;; If this is a virtual group, we find the real group.
 139     (when (gnus-virtual-group-p group)
 140       (let ((result (nnvirtual-find-group-art
 141                      (gnus-group-real-name group) article)))
 142         (setq group (car result)
 143               headers (copy-sequence headers))
 144         (mail-header-set-number headers (cdr result))))
 145     (let ((number (mail-header-number headers))
 146           file dir)
 147       (when (and (> number 0)           ; Reffed article.
 148                  (or force
 149                      (and (or (not gnus-uncacheable-groups)
 150                               (not (string-match
 151                                     gnus-uncacheable-groups group)))
 152                           (gnus-cache-member-of-class
 153                            gnus-cache-enter-articles ticked dormant unread)))
 154                  (not (file-exists-p (setq file (gnus-cache-file-name
 155                                                  group number)))))
 156         ;; Possibly create the cache directory.
 157         (gnus-make-directory (setq dir (file-name-directory file)))
 158         ;; Save the article in the cache.
 159         (if (file-exists-p file)
 160             t                           ; The article already is saved.
 161           (save-excursion
 162             (set-buffer nntp-server-buffer)
 163             (let ((gnus-use-cache nil))
 164               (gnus-request-article-this-buffer number group))
 165             (when (> (buffer-size) 0)
 166               (gnus-write-buffer file)
 167               (gnus-cache-change-buffer group)
 168               (set-buffer (cdr gnus-cache-buffer))
 169               (goto-char (point-max))
 170               (forward-line -1)
 171               (while (condition-case ()
 172                          (when (not (bobp))
 173                            (> (read (current-buffer)) number))
 174                        (error
 175                         ;; The line was malformed, so we just remove it!!
 176                         (gnus-delete-line)
 177                         t))
 178                 (forward-line -1))
 179               (if (bobp)
 180                   (if (not (eobp))
 181                       (progn
 182                         (beginning-of-line)
 183                         (when (< (read (current-buffer)) number)
 184                           (forward-line 1)))
 185                     (beginning-of-line))
 186                 (forward-line 1))
 187               (beginning-of-line)
 188               ;; [number subject from date id references chars lines xref]
 189               (insert (format "%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t%s\t\n"
 190                               (mail-header-number headers)
 191                               (mail-header-subject headers)
 192                               (mail-header-from headers)
 193                               (mail-header-date headers)
 194                               (mail-header-id headers)
 195                               (or (mail-header-references headers) "")
 196                               (or (mail-header-chars headers) "")
 197                               (or (mail-header-lines headers) "")
 198                               (or (mail-header-xref headers) "")))
 199               ;; Update the active info.
 200               (set-buffer gnus-summary-buffer)
 201               (gnus-cache-update-active group number)
 202               (push article gnus-newsgroup-cached)
 203               (gnus-summary-update-secondary-mark article))
 204             t))))))
 205
 206 (defun gnus-cache-enter-remove-article (article)
 207   "Mark ARTICLE for later possible removal."
 208   (when article
 209     (push article gnus-cache-removable-articles)))
 210
 211 (defun gnus-cache-possibly-remove-articles ()
 212   "Possibly remove some of the removable articles."
 213   (if (not (gnus-virtual-group-p gnus-newsgroup-name))
 214       (gnus-cache-possibly-remove-articles-1)
 215     (let ((arts gnus-cache-removable-articles)
 216           ga)
 217       (while arts
 218         (when (setq ga (nnvirtual-find-group-art
 219                         (gnus-group-real-name gnus-newsgroup-name) (pop arts)))
 220           (let ((gnus-cache-removable-articles (list (cdr ga)))
 221                 (gnus-newsgroup-name (car ga)))
 222             (gnus-cache-possibly-remove-articles-1)))))
 223     (setq gnus-cache-removable-articles nil)))
 224
 225 (defun gnus-cache-possibly-remove-articles-1 ()
 226   "Possibly remove some of the removable articles."
 227   (unless (eq gnus-use-cache 'passive)
 228     (let ((articles gnus-cache-removable-articles)
 229           (cache-articles gnus-newsgroup-cached)
 230           article)
 231       (gnus-cache-change-buffer gnus-newsgroup-name)
 232       (while articles
 233         (when (memq (setq article (pop articles)) cache-articles)
 234           ;; The article was in the cache, so we see whether we are
 235           ;; supposed to remove it from the cache.
 236           (gnus-cache-possibly-remove-article
 237            article (memq article gnus-newsgroup-marked)
 238            (memq article gnus-newsgroup-dormant)
 239            (or (memq article gnus-newsgroup-unreads)
 240                (memq article gnus-newsgroup-unselected))))))
 241     ;; The overview file might have been modified, save it
 242     ;; safe because we're only called at group exit anyway.
 243     (gnus-cache-save-buffers)))
 244
 245 (defun gnus-cache-request-article (article group)
 246   "Retrieve ARTICLE in GROUP from the cache."
 247   (let ((file (gnus-cache-file-name group article))
 248         (buffer-read-only nil))
 249     (when (file-exists-p file)
 250       (erase-buffer)
 251       (gnus-kill-all-overlays)
 252       (insert-file-contents file)
 253       t)))
 254
 255 (defun gnus-cache-possibly-alter-active (group active)
 256   "Alter the ACTIVE info for GROUP to reflect the articles in the cache."
 257   (when (equal group "no.norsk") (error "hie"))
 258   (when gnus-cache-active-hashtb
 259     (let ((cache-active (gnus-gethash group gnus-cache-active-hashtb)))
 260       (and cache-active
 261            (< (car cache-active) (car active))
 262            (setcar active (car cache-active)))
 263       (and cache-active
 264            (> (cdr cache-active) (cdr active))
 265            (setcdr active (cdr cache-active))))))
 266
 267 (defun gnus-cache-retrieve-headers (articles group &optional fetch-old)
 268   "Retrieve the headers for ARTICLES in GROUP."
 269   (let ((cached
 270          (setq gnus-newsgroup-cached (gnus-cache-articles-in-group group))))
 271     (if (not cached)
 272         ;; No cached articles here, so we just retrieve them
 273         ;; the normal way.
 274         (let ((gnus-use-cache nil))
 275           (gnus-retrieve-headers articles group fetch-old))
 276       (let ((uncached-articles (gnus-sorted-intersection
 277                                 (gnus-sorted-complement articles cached)
 278                                 articles))
 279             (cache-file (gnus-cache-file-name group ".overview"))
 280             type)
 281         ;; We first retrieve all the headers that we don't have in
 282         ;; the cache.
 283         (let ((gnus-use-cache nil))
 284           (when uncached-articles
 285             (setq type (and articles
 286                             (gnus-retrieve-headers
 287                              uncached-articles group fetch-old)))))
 288         (gnus-cache-save-buffers)
 289         ;; Then we insert the cached headers.
 290         (save-excursion
 291           (cond
 292            ((not (file-exists-p cache-file))
 293             ;; There are no cached headers.
 294             type)
 295            ((null type)
 296             ;; There were no uncached headers (or retrieval was
 297             ;; unsuccessful), so we use the cached headers exclusively.
 298             (set-buffer nntp-server-buffer)
 299             (erase-buffer)
 300             (insert-file-contents cache-file)
 301             'nov)
 302            ((eq type 'nov)
 303             ;; We have both cached and uncached NOV headers, so we
 304             ;; braid them.
 305             (gnus-cache-braid-nov group cached)
 306             type)
 307            (t
 308             ;; We braid HEADs.
 309             (gnus-cache-braid-heads group (gnus-sorted-intersection
 310                                            cached articles))
 311             type)))))))
 312
 313 (defun gnus-cache-enter-article (&optional n)
 314   "Enter the next N articles into the cache.
 315 If not given a prefix, use the process marked articles instead.
 316 Returns the list of articles entered."
 317   (interactive "P")
 318   (gnus-set-global-variables)
 319   (let ((articles (gnus-summary-work-articles n))
 320         article out)
 321     (while articles
 322       (setq article (pop articles))
 323       (when (gnus-cache-possibly-enter-article
 324              gnus-newsgroup-name article (gnus-summary-article-header article)
 325              nil nil nil t)
 326         (push article out))
 327       (gnus-summary-remove-process-mark article)
 328       (gnus-summary-update-secondary-mark article))
 329     (gnus-summary-next-subject 1)
 330     (gnus-summary-position-point)
 331     (nreverse out)))
 332
 333 (defun gnus-cache-remove-article (n)
 334   "Remove the next N articles from the cache.
 335 If not given a prefix, use the process marked articles instead.
 336 Returns the list of articles removed."
 337   (interactive "P")
 338   (gnus-set-global-variables)
 339   (gnus-cache-change-buffer gnus-newsgroup-name)
 340   (let ((articles (gnus-summary-work-articles n))
 341         article out)
 342     (while articles
 343       (setq article (pop articles))
 344       (when (gnus-cache-possibly-remove-article article nil nil nil t)
 345         (push article out))
 346       (gnus-summary-remove-process-mark article)
 347       (gnus-summary-update-secondary-mark article))
 348     (gnus-summary-next-subject 1)
 349     (gnus-summary-position-point)
 350     (nreverse out)))
 351
 352 (defun gnus-cached-article-p (article)
 353   "Say whether ARTICLE is cached in the current group."
 354   (memq article gnus-newsgroup-cached))
 355
 356 (defun gnus-summary-insert-cached-articles ()
 357   "Insert all the articles cached for this group into the current buffer."
 358   (interactive)
 359   (let ((cached gnus-newsgroup-cached))
 360     (unless cached
 361       (error "No cached articles for this group"))
 362     (while cached
 363       (gnus-summary-goto-subject (pop cached) t))))
 364
 365 ;;; Internal functions.
 366
 367 (defun gnus-cache-change-buffer (group)
 368   (and gnus-cache-buffer
 369        ;; See if the current group's overview cache has been loaded.
 370        (or (string= group (car gnus-cache-buffer))
 371            ;; Another overview cache is current, save it.
 372            (gnus-cache-save-buffers)))
 373   ;; if gnus-cache buffer is nil, create it
 374   (unless gnus-cache-buffer
 375     ;; Create cache buffer
 376     (save-excursion
 377       (setq gnus-cache-buffer
 378             (cons group
 379                   (set-buffer (get-buffer-create " *gnus-cache-overview*"))))
 380       (buffer-disable-undo (current-buffer))
 381       ;; Insert the contents of this group's cache overview.
 382       (erase-buffer)
 383       (let ((file (gnus-cache-file-name group ".overview")))
 384         (when (file-exists-p file)
 385           (nnheader-insert-file-contents file)))
 386       ;; We have a fresh (empty/just loaded) buffer,
 387       ;; mark it as unmodified to save a redundant write later.
 388       (set-buffer-modified-p nil))))
 389
 390 ;; Return whether an article is a member of a class.
 391 (defun gnus-cache-member-of-class (class ticked dormant unread)
 392   (or (and ticked (memq 'ticked class))
 393       (and dormant (memq 'dormant class))
 394       (and unread (memq 'unread class))
 395       (and (not unread) (not ticked) (not dormant) (memq 'read class))))
 396
 397 (defun gnus-cache-file-name (group article)
 398   (concat (file-name-as-directory gnus-cache-directory)
 399           (file-name-as-directory
 400            (nnheader-translate-file-chars
 401             (if (gnus-use-long-file-name 'not-cache)
 402                 group
 403               (let ((group (nnheader-replace-chars-in-string group ?/ ?_)))
 404                 ;; Translate the first colon into a slash.
 405                 (when (string-match ":" group)
 406                   (aset group (match-beginning 0) ?/))
 407                 (nnheader-replace-chars-in-string group ?. ?/)))))
 408           (if (stringp article) article (int-to-string article))))
 409
 410 (defun gnus-cache-update-article (group article)
 411   "If ARTICLE is in the cache, remove it and re-enter it."
 412   (when (gnus-cache-possibly-remove-article article nil nil nil t)
 413     (let ((gnus-use-cache nil))
 414       (gnus-cache-possibly-enter-article
 415        gnus-newsgroup-name article (gnus-summary-article-header article)
 416        nil nil nil t))))
 417
 418 (defun gnus-cache-possibly-remove-article (article ticked dormant unread
 419                                                    &optional force)
 420   "Possibly remove ARTICLE from the cache."
 421   (let ((group gnus-newsgroup-name)
 422         (number article)
 423         file)
 424     ;; If this is a virtual group, we find the real group.
 425     (when (gnus-virtual-group-p group)
 426       (let ((result (nnvirtual-find-group-art
 427                      (gnus-group-real-name group) article)))
 428         (setq group (car result)
 429               number (cdr result))))
 430     (setq file (gnus-cache-file-name group number))
 431     (when (and (file-exists-p file)
 432                (or force
 433                    (gnus-cache-member-of-class
 434                     gnus-cache-remove-articles ticked dormant unread)))
 435       (save-excursion
 436         (delete-file file)
 437         (set-buffer (cdr gnus-cache-buffer))
 438         (goto-char (point-min))
 439         (when (or (looking-at (concat (int-to-string number) "\t"))
 440                   (search-forward (concat "\n" (int-to-string number) "\t")
 441                                   (point-max) t))
 442           (delete-region (progn (beginning-of-line) (point))
 443                          (progn (forward-line 1) (point)))))
 444       (setq gnus-newsgroup-cached
 445             (delq article gnus-newsgroup-cached))
 446       (gnus-summary-update-secondary-mark article)
 447       t)))
 448
 449 (defun gnus-cache-articles-in-group (group)
 450   "Return a sorted list of cached articles in GROUP."
 451   (let ((dir (file-name-directory (gnus-cache-file-name group 1))))
 452     (when (file-exists-p dir)
 453       (sort (mapcar (lambda (name) (string-to-int name))
 454                     (directory-files dir nil "^[0-9]+$" t))
 455             '<))))
 456
 457 (defun gnus-cache-braid-nov (group cached)
 458   (let ((cache-buf (get-buffer-create " *gnus-cache*"))
 459         beg end)
 460     (gnus-cache-save-buffers)
 461     (save-excursion
 462       (set-buffer cache-buf)
 463       (buffer-disable-undo (current-buffer))
 464       (erase-buffer)
 465       (insert-file-contents (gnus-cache-file-name group ".overview"))
 466       (goto-char (point-min))
 467       (insert "\n")
 468       (goto-char (point-min)))
 469     (set-buffer nntp-server-buffer)
 470     (goto-char (point-min))
 471     (while cached
 472       (while (and (not (eobp))
 473                   (< (read (current-buffer)) (car cached)))
 474         (forward-line 1))
 475       (beginning-of-line)
 476       (save-excursion
 477         (set-buffer cache-buf)
 478         (if (search-forward (concat "\n" (int-to-string (car cached)) "\t")
 479                             nil t)
 480             (setq beg (progn (beginning-of-line) (point))
 481                   end (progn (end-of-line) (point)))
 482           (setq beg nil)))
 483       (when beg
 484         (insert-buffer-substring cache-buf beg end)
 485         (insert "\n"))
 486       (setq cached (cdr cached)))
 487     (kill-buffer cache-buf)))
 488
 489 (defun gnus-cache-braid-heads (group cached)
 490   (let ((cache-buf (get-buffer-create " *gnus-cache*")))
 491     (save-excursion
 492       (set-buffer cache-buf)
 493       (buffer-disable-undo (current-buffer))
 494       (erase-buffer))
 495     (set-buffer nntp-server-buffer)
 496     (goto-char (point-min))
 497     (while cached
 498       (while (and (not (eobp))
 499                   (looking-at "2.. +\\([0-9]+\\) ")
 500                   (< (progn (goto-char (match-beginning 1))
 501                             (read (current-buffer)))
 502                      (car cached)))
 503         (search-forward "\n.\n" nil 'move))
 504       (beginning-of-line)
 505       (save-excursion
 506         (set-buffer cache-buf)
 507         (erase-buffer)
 508         (insert-file-contents (gnus-cache-file-name group (car cached)))
 509         (goto-char (point-min))
 510         (insert "220 ")
 511         (princ (car cached) (current-buffer))
 512         (insert " Article retrieved.\n")
 513         (search-forward "\n\n" nil 'move)
 514         (delete-region (point) (point-max))
 515         (forward-char -1)
 516         (insert "."))
 517       (insert-buffer-substring cache-buf)
 518       (setq cached (cdr cached)))
 519     (kill-buffer cache-buf)))
 520
 521 ;;;###autoload
 522 (defun gnus-jog-cache ()
 523   "Go through all groups and put the articles into the cache.
 524
 525 Usage:
 526 $ emacs -batch -l ~/.emacs -l gnus -f gnus-jog-cache"
 527   (interactive)
 528   (let ((gnus-mark-article-hook nil)
 529         (gnus-expert-user t)
 530         (nnmail-spool-file nil)
 531         (gnus-use-dribble-file nil)
 532         (gnus-novice-user nil)
 533         (gnus-large-newsgroup nil))
 534     ;; Start Gnus.
 535     (gnus)
 536     ;; Go through all groups...
 537     (gnus-group-mark-buffer)
 538     (gnus-group-universal-argument
 539      nil nil
 540      (lambda ()
 541        (gnus-summary-read-group (gnus-group-group-name) nil t)
 542        ;; ... and enter the articles into the cache.
 543        (when (eq major-mode 'gnus-summary-mode)
 544          (gnus-uu-mark-buffer)
 545          (gnus-cache-enter-article)
 546          (kill-buffer (current-buffer)))))))
 547
 548 (defun gnus-cache-read-active (&optional force)
 549   "Read the cache active file."
 550   (gnus-make-directory gnus-cache-directory)
 551   (if (not (and (file-exists-p gnus-cache-active-file)
 552                 (or force (not gnus-cache-active-hashtb))))
 553       ;; There is no active file, so we generate one.
 554       (gnus-cache-generate-active)
 555     ;; We simply read the active file.
 556     (save-excursion
 557       (gnus-set-work-buffer)
 558       (insert-file-contents gnus-cache-active-file)
 559       (gnus-active-to-gnus-format
 560        nil (setq gnus-cache-active-hashtb
 561                  (gnus-make-hashtable
 562                   (count-lines (point-min) (point-max)))))
 563       (setq gnus-cache-active-altered nil))))
 564
 565 (defun gnus-cache-write-active (&optional force)
 566   "Write the active hashtb to the active file."
 567   (when (or force
 568             (and gnus-cache-active-hashtb
 569                  gnus-cache-active-altered))
 570     (nnheader-temp-write gnus-cache-active-file
 571       (mapatoms
 572        (lambda (sym)
 573          (when (and sym (boundp sym))
 574            (insert (format "%s %d %d y\n"
 575                            (symbol-name sym) (cdr (symbol-value sym))
 576                            (car (symbol-value sym))))))
 577        gnus-cache-active-hashtb))
 578     ;; Mark the active hashtb as unaltered.
 579     (setq gnus-cache-active-altered nil)))
 580
 581 (defun gnus-cache-update-active (group number &optional low)
 582   "Update the upper bound of the active info of GROUP to NUMBER.
 583 If LOW, update the lower bound instead."
 584   (let ((active (gnus-gethash group gnus-cache-active-hashtb)))
 585     (if (null active)
 586         ;; We just create a new active entry for this group.
 587         (gnus-sethash group (cons number number) gnus-cache-active-hashtb)
 588       ;; Update the lower or upper bound.
 589       (if low
 590           (setcar active number)
 591         (setcdr active number)))
 592     ;; Mark the active hashtb as altered.
 593     (setq gnus-cache-active-altered t)))
 594
 595 ;;;###autoload
 596 (defun gnus-cache-generate-active (&optional directory)
 597   "Generate the cache active file."
 598   (interactive)
 599   (let* ((top (null directory))
 600          (directory (expand-file-name (or directory gnus-cache-directory)))
 601          (files (directory-files directory 'full))
 602          (group
 603           (if top
 604               ""
 605             (string-match
 606              (concat "^" (file-name-as-directory
 607                           (expand-file-name gnus-cache-directory)))
 608              (directory-file-name directory))
 609             (nnheader-replace-chars-in-string
 610              (substring (directory-file-name directory) (match-end 0))
 611              ?/ ?.)))
 612          nums alphs)
 613     (when top
 614       (gnus-message 5 "Generating the cache active file...")
 615       (setq gnus-cache-active-hashtb (gnus-make-hashtable 123)))
 616     ;; Separate articles from all other files and directories.
 617     (while files
 618       (if (string-match "^[0-9]+$" (file-name-nondirectory (car files)))
 619           (push (string-to-int (file-name-nondirectory (pop files))) nums)
 620         (push (pop files) alphs)))
 621     ;; If we have nums, then this is probably a valid group.
 622     (when (setq nums (sort nums '<))
 623       (gnus-sethash group (cons (car nums) (gnus-last-element nums))
 624                     gnus-cache-active-hashtb))
 625     ;; Go through all the other files.
 626     (while alphs
 627       (when (and (file-directory-p (car alphs))
 628                  (not (string-match "^\\.\\.?$"
 629                                     (file-name-nondirectory (car alphs)))))
 630         ;; We descend directories.
 631         (gnus-cache-generate-active (car alphs)))
 632       (setq alphs (cdr alphs)))
 633     ;; Write the new active file.
 634     (when top
 635       (gnus-cache-write-active t)
 636       (gnus-message 5 "Generating the cache active file...done"))))
 637
 638 ;;;###autoload
 639 (defun gnus-cache-generate-nov-databases (dir)
 640   "Generate NOV files recursively starting in DIR."
 641   (interactive (list gnus-cache-directory))
 642   (gnus-cache-close)
 643   (let ((nnml-generate-active-function 'identity))
 644     (nnml-generate-nov-databases-1 dir)))
 645
 646 (defun gnus-cache-move-cache (dir)
 647   "Move the cache tree to somewhere else."
 648   (interactive "DMove the cache tree to: ")
 649   (rename-file gnus-cache-directory dir))
 650
 651 (provide 'gnus-cache)
 652
 653 ;;; gnus-cache.el ends here