cgit.sxemacs.org Git - gnus/blob - lisp/gnus-bookmark.el

   1 ;;; gnus-bookmark.el --- Bookmarks in Gnus
   2
   3 ;; Copyright (C) 2006 Free Software Foundation, Inc.
   4
   5 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file implements real bookmarks for Gnus, closely following the way
  28 ;; `bookmark.el' handles bookmarks.  Most of the code comes from
  29 ;; `bookmark.el'.
  30 ;;
  31 ;; Set a Gnus bookmark:
  32 ;; M-x `gnus-bookmark-set' from the summary buffer.
  33 ;;
  34 ;; Jump to a Gnus bookmark:
  35 ;; M-x `gnus-bookmark-jump'.
  36 ;;
  37 ;; Display a list of bookmarks
  38 ;; M-x `gnus-bookmark-bmenu-list'.
  39 ;;
  40
  41 ;;; Todo:
  42
  43 ;; - add tags to bookmarks
  44 ;; - don't write file each time a bookmark is created
  45 ;; - better annotation interactive buffer
  46 ;; - edit annotation in gnus-bookmark-bmenu
  47 ;; - sort gnus-bookmark-buffer by author/subject/date/group/message-id
  48 ;; - auto-bmk-name customizable format
  49 ;; - renaming bookmarks in gnus-bookmark-bmenu-list
  50 ;; - better (formatted string) display in bmenu-list
  51
  52 ;; - Fix use of `split-string' and `assoc-string' for compatibility with Emacs
  53 ;;   21 and XEmacs 21.4.
  54 ;; - Integrate the `gnus-summary-*-bookmark' functionality
  55 ;; - Initialize defcustoms from corresponding `bookmark.el' variables?
  56
  57 ;;; Code:
  58
  59 (require 'gnus-sum)
  60
  61 ;; FIXME: should avoid using C-c (no?)
  62 ;; (define-key gnus-summary-mode-map "\C-crm" 'gnus-bookmark-set)
  63 ;; (define-key global-map "\C-crb" 'gnus-bookmark-jump)
  64 ;; (define-key global-map "\C-crj" 'gnus-bookmark-jump)
  65 ;; (define-key global-map "\C-crl" 'gnus-bookmark-bmenu-list)
  66
  67 (defgroup gnus-bookmark nil
  68   "Setting, annotation and jumping to Gnus bookmarks."
  69   :group 'gnus)
  70
  71 (defcustom gnus-bookmark-default-file
  72   (cond
  73    ;; Backward compatibility with previous versions:
  74    ((file-exists-p "~/.gnus.bmk") "~/.gnus.bmk")
  75    (t (nnheader-concat gnus-directory "bookmarks.el")))
  76   "The default Gnus bookmarks file."
  77   :type 'string
  78   :group 'gnus-bookmark)
  79
  80 (defcustom gnus-bookmark-sort-flag t
  81   "Non-nil means Gnus bookmarks are sorted by bookmark names.
  82 Otherwise they will be displayed in LIFO order (that is,
  83 most recently set ones come first, oldest ones come last)."
  84   :type 'boolean
  85   :group 'gnus-bookmark)
  86
  87 (defcustom gnus-bookmark-bmenu-toggle-infos t
  88   "Non-nil means show details when listing Gnus bookmarks.
  89 List of details is defined in `gnus-bookmark-bookmark-inline-details'.
  90 This may result in truncated bookmark names.  To disable this, put the
  91 following in your `.emacs' file:
  92
  93 \(setq gnus-bookmark-bmenu-toggle-infos nil\)"
  94   :type 'boolean
  95   :group 'gnus-bookmark)
  96
  97 (defcustom gnus-bookmark-bmenu-file-column 30
  98   "Column at which to display details in a buffer listing Gnus bookmarks.
  99 You can toggle whether details are shown with \\<gnus-bookmark-bmenu-mode-map>\\[gnus-bookmark-bmenu-toggle-infos]."
 100   :type 'integer
 101   :group 'gnus-bookmark)
 102
 103 (defcustom gnus-bookmark-use-annotations nil
 104   "If non-nil, ask for an annotation when setting a bookmark."
 105   :type 'boolean
 106   :group 'gnus-bookmark)
 107
 108 (defcustom gnus-bookmark-bookmark-inline-details '(author)
 109   "Details to be shown with `gnus-bookmark-bmenu-toggle-infos'.
 110 The default value is \(subject\)."
 111   :type '(list :tag "Gnus bookmark details"
 112                (set :inline t
 113                     (const :tag "Author" author)
 114                     (const :tag "Subject" subject)
 115                     (const :tag "Date" date)
 116                     (const :tag "Group" group)
 117                     (const :tag "Message-id" message-id)))
 118   :group 'gnus-bookmark)
 119
 120 (defcustom gnus-bookmark-bookmark-details
 121   '(author subject date group annotation)
 122   "Details to be shown with `gnus-bookmark-bmenu-show-details'.
 123 The default value is \(author subject date group annotation\)."
 124   :type '(list :tag "Gnus bookmark details"
 125                (set :inline t
 126                     (const :tag "Author" author)
 127                     (const :tag "Subject" subject)
 128                     (const :tag "Date" date)
 129                     (const :tag "Group" group)
 130                     (const :tag "Message-id" message-id)
 131                     (const :tag "Annotation" annotation)))
 132   :group 'gnus-bookmark)
 133
 134 (defface gnus-bookmark-menu-heading
 135   '((t (:inherit font-lock-type-face)))
 136   "Face used to highlight the heading in Gnus bookmark menu buffers."
 137   :version "23.0" ;; No Gnus
 138   :group 'gnus-bookmark)
 139
 140 (defconst gnus-bookmark-end-of-version-stamp-marker
 141   "-*- End Of Bookmark File Format Version Stamp -*-\n"
 142   "This string marks the end of the version stamp in a Gnus bookmark file.")
 143
 144 (defconst gnus-bookmark-file-format-version 0
 145   "The current version of the format used by bookmark files.
 146 You should never need to change this.")
 147
 148 (defvar gnus-bookmark-after-jump-hook nil
 149   "Hook run after `gnus-bookmark-jump' jumps to a Gnus bookmark.")
 150
 151 (defvar gnus-bookmark-alist ()
 152   "Association list of Gnus bookmarks and their records.
 153 The format of the alist is
 154
 155      \(BMK1 BMK2 ...\)
 156
 157 where each BMK is of the form
 158
 159 \(NAME
 160   \(group . GROUP\)
 161   \(message-id . MESSAGE-ID\)
 162   \(author . AUTHOR\)
 163   \(date . DATE\)
 164   \(subject . SUBJECT\)
 165   \(annotation . ANNOTATION\)\)
 166
 167 So the cdr of each bookmark is an alist too.")
 168
 169 ;;;###autoload
 170 (defun gnus-bookmark-set ()
 171   "Set a bookmark for this article."
 172   (interactive)
 173   (gnus-bookmark-maybe-load-default-file)
 174   (if (or (not (eq major-mode 'gnus-summary-mode))
 175           (not gnus-article-current))
 176       (error "Please select an article in the Gnus summary buffer")
 177     (let* ((group (car gnus-article-current))
 178            (article (cdr gnus-article-current))
 179            (header (gnus-summary-article-header article))
 180            (author (mail-header-from header))
 181            (message-id (mail-header-id header))
 182            (date (mail-header-date header))
 183            (subject (gnus-summary-subject-string))
 184            (bmk-name (gnus-bookmark-set-bookmark-name group author subject))
 185            ;; Maybe ask for annotation
 186            (annotation
 187             (if gnus-bookmark-use-annotations
 188                  (read-from-minibuffer
 189                   (format "Annotation for %s: " bmk-name)) "")))
 190       ;; Set the bookmark list
 191       (setq gnus-bookmark-alist
 192             (cons
 193              (list bmk-name
 194                    (gnus-bookmark-make-cell
 195                     group message-id author date subject annotation))
 196              gnus-bookmark-alist))))
 197   (gnus-bookmark-bmenu-surreptitiously-rebuild-list)
 198   (gnus-bookmark-write-file))
 199
 200 (defun gnus-bookmark-make-cell
 201   (group message-id author date subject annotation)
 202   "Return the record part of a new bookmark, given GROUP MESSAGE-ID AUTHOR DATE SUBJECT and ANNOTATION."
 203   (let ((the-record
 204          `((group . ,group)
 205            (message-id . ,message-id)
 206            (author . ,author)
 207            (date . ,date)
 208            (subject . ,subject)
 209            (annotation . ,annotation))))
 210     the-record))
 211
 212 (defun gnus-bookmark-set-bookmark-name (group author subject)
 213   "Set bookmark name from GROUP AUTHOR and SUBJECT."
 214   (let* ((subject (split-string subject))
 215          (default-name-0 ;; Should be merged with -1?
 216            ;; FIXME: In Emacs 21 or XEmacs 21.4 split-string accepts only 1-2
 217            ;; args.
 218            (concat (car (reverse (split-string group "[\\.:]" t))) "-"
 219                    (car (split-string author)) "-"
 220                    (concat (car subject) "-"
 221                            (cadr subject))))
 222          (default-name-1
 223            ;; Strip "[]" chars from the bookmark name:
 224            (gnus-replace-in-string default-name-0 "[]_[]" ""))
 225          (name (read-from-minibuffer
 226                 (format "Set bookmark (%s): " default-name-1)
 227                 nil nil nil nil
 228                 default-name-1)))
 229     (if (string-equal name "")
 230         default-name-1
 231       name)))
 232
 233 (defun gnus-bookmark-write-file ()
 234   "Write currently defined Gnus bookmarks into `gnus-bookmark-default-file'."
 235   (interactive)
 236   (save-excursion
 237     (save-window-excursion
 238       ;; Avoir warnings?
 239       ;; (message "Saving Gnus bookmarks to file %s..." gnus-bookmark-default-file)
 240       (set-buffer (get-buffer-create  " *Gnus bookmarks*"))
 241       (erase-buffer)
 242       (gnus-bookmark-insert-file-format-version-stamp)
 243       (pp gnus-bookmark-alist (current-buffer))
 244       (condition-case nil
 245           (write-region (point-min) (point-max)
 246                         gnus-bookmark-default-file)
 247         (file-error (message "Can't write %s"
 248                              gnus-bookmark-default-file)))
 249       (kill-buffer (current-buffer))
 250       (message
 251        "Saving Gnus bookmarks to file %s...done"
 252        gnus-bookmark-default-file))))
 253
 254 (defun gnus-bookmark-insert-file-format-version-stamp ()
 255   "Insert text indicating current version of Gnus bookmark file format."
 256   (insert
 257    (format ";;;; Gnus Bookmark Format Version %d ;;;;\n"
 258            gnus-bookmark-file-format-version))
 259   (insert ";;; This format is meant to be slightly human-readable;\n"
 260           ";;; nevertheless, you probably don't want to edit it.\n"
 261           ";;; "
 262           gnus-bookmark-end-of-version-stamp-marker))
 263
 264 ;;;###autoload
 265 (defun gnus-bookmark-jump (&optional bmk-name)
 266   "Jump to a Gnus bookmark (BMK-NAME)."
 267   (interactive)
 268   (gnus-bookmark-maybe-load-default-file)
 269   (let* ((bookmark (or bmk-name
 270           (completing-read "Jump to bookmarked article: "
 271                            (mapcar 'car gnus-bookmark-alist))))
 272          (bmk-cell (cadr (assoc bookmark gnus-bookmark-alist)))
 273          (group (cdr (assoc 'group bmk-cell)))
 274          (message-id (cdr (assoc 'message-id bmk-cell))))
 275     (require 'gnus)
 276     (if group (gnus-fetch-group group))
 277     (if message-id
 278       (or (gnus-summary-goto-article message-id nil 'force)
 279           (if (fboundp 'gnus-summary-insert-cached-articles)
 280               (progn
 281                 (gnus-summary-insert-cached-articles)
 282                 (gnus-summary-goto-article message-id nil 'force))
 283             (message "Message could not be found."))))))
 284
 285 (defvar gnus-bookmark-already-loaded nil)
 286
 287 (defun gnus-bookmark-alist-from-buffer ()
 288   "Return a `gnus-bookmark-alist' from the current buffer.
 289 The buffer must of course contain Gnus bookmark format information.
 290 Does not care from where in the buffer it is called, and does not
 291 affect point."
 292   (save-excursion
 293     (goto-char (point-min))
 294     (if (search-forward
 295          gnus-bookmark-end-of-version-stamp-marker nil t)
 296         (read (current-buffer))
 297       ;; Else no hope of getting information here.
 298       (error "Not Gnus bookmark format"))))
 299
 300 (defun gnus-bookmark-load (file)
 301   "Load Gnus bookmarks from FILE (which must be in bookmark format)."
 302   (interactive
 303    (list (read-file-name
 304           (format "Load Gnus bookmarks from: (%s) "
 305                   gnus-bookmark-default-file)
 306           "~/" gnus-bookmark-default-file 'confirm)))
 307   (setq file (expand-file-name file))
 308   (if (file-readable-p file)
 309       (save-excursion
 310         (save-window-excursion
 311           (set-buffer (let ((enable-local-variables nil))
 312                         (find-file-noselect file)))
 313           (goto-char (point-min))
 314           (let ((blist (gnus-bookmark-alist-from-buffer)))
 315             (if (listp blist)
 316                 (progn (setq gnus-bookmark-already-loaded t)
 317                        (setq gnus-bookmark-alist blist))
 318               (error "Not Gnus bookmark format")))))))
 319
 320 (defun gnus-bookmark-maybe-load-default-file ()
 321   "Maybe load Gnus bookmarks in `gnus-bookmark-alist'."
 322   (and (not gnus-bookmark-already-loaded)
 323        (null gnus-bookmark-alist)
 324        (file-readable-p (expand-file-name gnus-bookmark-default-file))
 325        (gnus-bookmark-load gnus-bookmark-default-file)))
 326
 327 (defun gnus-bookmark-maybe-sort-alist ()
 328   "Return the gnus-bookmark-alist for display.
 329 If the gnus-bookmark-sort-flag is non-nil, then return a sorted
 330 copy of the alist."
 331   (when gnus-bookmark-sort-flag
 332     (setq gnus-bookmark-alist
 333           (sort (copy-alist gnus-bookmark-alist)
 334                 (function
 335                  (lambda (x y) (string-lessp (car x) (car y))))))))
 336
 337 ;;;###autoload
 338 (defun gnus-bookmark-bmenu-list ()
 339   "Display a list of existing Gnus bookmarks.
 340 The list is displayed in a buffer named `*Gnus Bookmark List*'.
 341 The leftmost column displays a D if the bookmark is flagged for
 342 deletion, or > if it is flagged for displaying."
 343   (interactive)
 344   (gnus-bookmark-maybe-load-default-file)
 345   (if (interactive-p)
 346       (switch-to-buffer (get-buffer-create "*Gnus Bookmark List*"))
 347     (set-buffer (get-buffer-create "*Gnus Bookmark List*")))
 348   (let ((inhibit-read-only t))
 349     (erase-buffer)
 350     (insert "% Gnus Bookmark\n- --------\n")
 351     (add-text-properties (point-min) (point)
 352                          '(font-lock-face gnus-bookmark-menu-heading))
 353     ;; sort before displaying
 354     (gnus-bookmark-maybe-sort-alist)
 355     ;; Display gnus bookmarks
 356     (mapcar
 357      (lambda (full-record)
 358        ;; if a Gnus bookmark has an annotation, prepend a "*"
 359        ;; in the list of bookmarks.
 360        (let ((annotation (gnus-bookmark-get-annotation
 361                           (gnus-bookmark-name-from-full-record full-record))))
 362          (if (and annotation (not (string-equal annotation "")))
 363              (insert " *")
 364            (insert "  "))
 365          (let ((start (point)))
 366            (insert (gnus-bookmark-name-from-full-record full-record))
 367            (if (and (display-color-p) (display-mouse-p))
 368                (add-text-properties
 369                 start
 370                 (save-excursion (re-search-backward
 371                                  "[^ \t]")
 372                                 (1+ (point)))
 373                 '(mouse-face highlight
 374                   follow-link t
 375                   help-echo "mouse-2: go to this article")))
 376            (insert "\n")
 377            )))
 378      gnus-bookmark-alist)
 379     (goto-char (point-min))
 380     (forward-line 2)
 381     (gnus-bookmark-bmenu-mode)
 382     (if gnus-bookmark-bmenu-toggle-infos
 383         (gnus-bookmark-bmenu-toggle-infos t))))
 384
 385 (defun gnus-bookmark-bmenu-surreptitiously-rebuild-list ()
 386   "Rebuild the Bookmark List if it exists.
 387 Don't affect the buffer ring order."
 388   (if (get-buffer "*Gnus Bookmark List*")
 389       (save-excursion
 390         (save-window-excursion
 391           (gnus-bookmark-bmenu-list)))))
 392
 393 (defun gnus-bookmark-get-annotation (bookmark)
 394   "Return the annotation of Gnus BOOKMARK, or nil if none."
 395   (cdr (assq 'annotation (gnus-bookmark-get-bookmark-record bookmark))))
 396
 397 (defun gnus-bookmark-get-bookmark (bookmark)
 398   "Return the full entry for Gnus BOOKMARK in `gnus-bookmark-alist'.
 399 If BOOKMARK is not a string, return nil."
 400   (when (stringp bookmark)
 401     ;; FIXME: `assoc-string' doesn't exist in Emacs 21 and XEmacs 21.4:
 402     (assoc-string bookmark gnus-bookmark-alist t)))
 403
 404 (defun gnus-bookmark-get-bookmark-record (bookmark)
 405   "Return the guts of the entry for Gnus BOOKMARK in `gnus-bookmark-alist'.
 406 That is, all information but the name."
 407   (car (cdr (gnus-bookmark-get-bookmark bookmark))))
 408
 409 (defun gnus-bookmark-name-from-full-record (full-record)
 410   "Return name of FULL-RECORD \(an alist element instead of a string\)."
 411   (car full-record))
 412
 413 (defvar gnus-bookmark-bmenu-bookmark-column nil)
 414 (defvar gnus-bookmark-bmenu-hidden-bookmarks ())
 415 (defvar gnus-bookmark-bmenu-mode-map nil)
 416
 417 (if gnus-bookmark-bmenu-mode-map
 418     nil
 419   (setq gnus-bookmark-bmenu-mode-map (make-keymap))
 420   (suppress-keymap gnus-bookmark-bmenu-mode-map t)
 421   (define-key gnus-bookmark-bmenu-mode-map "q" 'quit-window)
 422   (define-key gnus-bookmark-bmenu-mode-map "\C-m" 'gnus-bookmark-bmenu-select)
 423   (define-key gnus-bookmark-bmenu-mode-map "v" 'gnus-bookmark-bmenu-select)
 424   (define-key gnus-bookmark-bmenu-mode-map "d" 'gnus-bookmark-bmenu-delete)
 425   (define-key gnus-bookmark-bmenu-mode-map "k" 'gnus-bookmark-bmenu-delete)
 426   (define-key gnus-bookmark-bmenu-mode-map "\C-d" 'gnus-bookmark-bmenu-delete-backwards)
 427   (define-key gnus-bookmark-bmenu-mode-map "x" 'gnus-bookmark-bmenu-execute-deletions)
 428   (define-key gnus-bookmark-bmenu-mode-map " " 'next-line)
 429   (define-key gnus-bookmark-bmenu-mode-map "n" 'next-line)
 430   (define-key gnus-bookmark-bmenu-mode-map "p" 'previous-line)
 431   (define-key gnus-bookmark-bmenu-mode-map "\177" 'gnus-bookmark-bmenu-backup-unmark)
 432   (define-key gnus-bookmark-bmenu-mode-map "?" 'describe-mode)
 433   (define-key gnus-bookmark-bmenu-mode-map "u" 'gnus-bookmark-bmenu-unmark)
 434   (define-key gnus-bookmark-bmenu-mode-map "m" 'gnus-bookmark-bmenu-mark)
 435   (define-key gnus-bookmark-bmenu-mode-map "l" 'gnus-bookmark-bmenu-load)
 436   (define-key gnus-bookmark-bmenu-mode-map "s" 'gnus-bookmark-bmenu-save)
 437   (define-key gnus-bookmark-bmenu-mode-map "t" 'gnus-bookmark-bmenu-toggle-infos)
 438   (define-key gnus-bookmark-bmenu-mode-map "a" 'gnus-bookmark-bmenu-show-details)
 439   (define-key gnus-bookmark-bmenu-mode-map [mouse-2] 'gnus-bookmark-bmenu-select))
 440
 441 ;; Bookmark Buffer Menu mode is suitable only for specially formatted
 442 ;; data.
 443 (put 'gnus-bookmark-bmenu-mode 'mode-class 'special)
 444
 445 ;; Been to lazy to use gnus-bookmark-save...
 446 (defalias 'gnus-bookmark-bmenu-save 'gnus-bookmark-write-file)
 447
 448 (defun gnus-bookmark-bmenu-mode ()
 449   "Major mode for editing a list of Gnus bookmarks.
 450 Each line describes one of the bookmarks in Gnus.
 451 Letters do not insert themselves; instead, they are commands.
 452 Gnus bookmarks names preceded by a \"*\" have annotations.
 453 \\<gnus-bookmark-bmenu-mode-map>
 454 \\[gnus-bookmark-bmenu-mark] -- mark bookmark to be displayed.
 455 \\[gnus-bookmark-bmenu-select] -- select bookmark of line point is on.
 456   Also show bookmarks marked using m in other windows.
 457 \\[gnus-bookmark-bmenu-toggle-infos] -- toggle displaying of details (they may obscure long bookmark names).
 458 \\[gnus-bookmark-bmenu-locate] -- display (in minibuffer) location of this bookmark.
 459 \\[gnus-bookmark-bmenu-rename] -- rename this bookmark \(prompts for new name\).
 460 \\[gnus-bookmark-bmenu-delete] -- mark this bookmark to be deleted, and move down.
 461 \\[gnus-bookmark-bmenu-delete-backwards] -- mark this bookmark to be deleted, and move up.
 462 \\[gnus-bookmark-bmenu-execute-deletions] -- delete bookmarks marked with `\\[gnus-bookmark-bmenu-delete]'.
 463 \\[gnus-bookmark-bmenu-load] -- load in a file of bookmarks (prompts for file.)
 464 \\[gnus-bookmark-bmenu-save] -- load in a file of bookmarks (prompts for file.)
 465 \\[gnus-bookmark-bmenu-unmark] -- remove all kinds of marks from current line.
 466   With prefix argument, also move up one line.
 467 \\[gnus-bookmark-bmenu-backup-unmark] -- back up a line and remove marks.
 468 \\[gnus-bookmark-bmenu-show-details] -- show the annotation, if it exists, for the current bookmark
 469   in another buffer.
 470 \\[gnus-bookmark-bmenu-show-all-annotations] -- show the annotations of all bookmarks in another buffer.
 471 \\[gnus-bookmark-bmenu-edit-annotation] -- edit the annotation for the current bookmark."
 472   (kill-all-local-variables)
 473   (use-local-map gnus-bookmark-bmenu-mode-map)
 474   (setq truncate-lines t)
 475   (setq buffer-read-only t)
 476   (setq major-mode 'gnus-bookmark-bmenu-mode)
 477   (setq mode-name "Bookmark Menu")
 478   (gnus-run-mode-hooks 'gnus-bookmark-bmenu-mode-hook))
 479
 480 ;; avoid compilation warnings
 481 (defvar gnus-bookmark-bmenu-toggle-infos nil)
 482
 483 (defun gnus-bookmark-bmenu-toggle-infos (&optional show)
 484   "Toggle whether details are shown in the Gnus bookmark list.
 485 Optional argument SHOW means show them unconditionally."
 486   (interactive)
 487   (cond
 488    (show
 489     (setq gnus-bookmark-bmenu-toggle-infos nil)
 490     (gnus-bookmark-bmenu-show-infos)
 491     (setq gnus-bookmark-bmenu-toggle-infos t))
 492    (gnus-bookmark-bmenu-toggle-infos
 493     (gnus-bookmark-bmenu-hide-infos)
 494     (setq gnus-bookmark-bmenu-toggle-infos nil))
 495    (t
 496     (gnus-bookmark-bmenu-show-infos)
 497     (setq gnus-bookmark-bmenu-toggle-infos t))))
 498
 499 (defun gnus-bookmark-bmenu-show-infos (&optional force)
 500   "Show infos in bmenu, maybe FORCE display of infos."
 501   (if (and (not force) gnus-bookmark-bmenu-toggle-infos)
 502       nil ;already shown, so do nothing
 503     (save-excursion
 504       (save-window-excursion
 505         (goto-char (point-min))
 506         (forward-line 2)
 507         (setq gnus-bookmark-bmenu-hidden-bookmarks ())
 508         (let ((inhibit-read-only t))
 509           (while (< (point) (point-max))
 510             (let ((bmrk (gnus-bookmark-bmenu-bookmark)))
 511               (setq gnus-bookmark-bmenu-hidden-bookmarks
 512                     (cons bmrk gnus-bookmark-bmenu-hidden-bookmarks))
 513               (let ((start (save-excursion (end-of-line) (point))))
 514                 (move-to-column gnus-bookmark-bmenu-file-column t)
 515                 ;; Strip off `mouse-face' from the white spaces region.
 516                 (if (and (display-color-p) (display-mouse-p))
 517                     (remove-text-properties start (point)
 518                                             '(mouse-face nil help-echo nil))))
 519               (delete-region (point) (progn (end-of-line) (point)))
 520               (insert "  ")
 521               ;; Pass the NO-HISTORY arg:
 522               (gnus-bookmark-insert-details bmrk)
 523               (forward-line 1))))))))
 524
 525 (defun gnus-bookmark-insert-details (bmk-name)
 526   "Insert the details of the article associated with BMK-NAME."
 527   (let ((start (point)))
 528     (prog1
 529         (insert (gnus-bookmark-get-details
 530                  bmk-name
 531                  gnus-bookmark-bookmark-inline-details))
 532       (if (and (display-color-p) (display-mouse-p))
 533           (add-text-properties
 534            start
 535            (save-excursion (re-search-backward
 536                             "[^ \t]")
 537                                                (1+ (point)))
 538            '(mouse-face highlight
 539              follow-link t
 540              help-echo "mouse-2: go to this article"))))))
 541
 542 (defun gnus-bookmark-kill-line (&optional newline-too)
 543   "Kill from point to end of line.
 544 If optional arg NEWLINE-TOO is non-nil, delete the newline too.
 545 Does not affect the kill ring."
 546   (let ((eol (save-excursion (end-of-line) (point))))
 547     (delete-region (point) eol)
 548     (if (and newline-too (looking-at "\n"))
 549         (delete-char 1))))
 550
 551 (defun gnus-bookmark-get-details (bmk-name details-list)
 552   "Get details for a Gnus BMK-NAME depending on DETAILS-LIST."
 553   (let ((details (cadr (assoc bmk-name gnus-bookmark-alist))))
 554     (mapconcat
 555      (lambda (info)
 556        (cdr (assoc info details)))
 557      details-list " | ")))
 558
 559 (defun gnus-bookmark-bmenu-hide-infos (&optional force)
 560   "Hide infos in bmenu, maybe FORCE."
 561   (if (and (not force) gnus-bookmark-bmenu-toggle-infos)
 562       ;; nothing to hide if above is nil
 563       (save-excursion
 564         (save-window-excursion
 565           (goto-char (point-min))
 566           (forward-line 2)
 567           (setq gnus-bookmark-bmenu-hidden-bookmarks
 568                 (nreverse gnus-bookmark-bmenu-hidden-bookmarks))
 569           (save-excursion
 570             (goto-char (point-min))
 571             (search-forward "Gnus Bookmark")
 572             (backward-word 2)
 573             (setq gnus-bookmark-bmenu-bookmark-column (current-column)))
 574           (save-excursion
 575             (let ((inhibit-read-only t))
 576               (while gnus-bookmark-bmenu-hidden-bookmarks
 577                 (move-to-column gnus-bookmark-bmenu-bookmark-column t)
 578                 (gnus-bookmark-kill-line)
 579                 (let ((start (point)))
 580                   (insert (car gnus-bookmark-bmenu-hidden-bookmarks))
 581                   (if (and (display-color-p) (display-mouse-p))
 582                       (add-text-properties
 583                        start
 584                        (save-excursion (re-search-backward
 585                                         "[^ \t]")
 586                                        (1+ (point)))
 587                        '(mouse-face highlight
 588                          follow-link t
 589                          help-echo
 590                          "mouse-2: go to this bookmark in other window"))))
 591                 (setq gnus-bookmark-bmenu-hidden-bookmarks
 592                       (cdr gnus-bookmark-bmenu-hidden-bookmarks))
 593                 (forward-line 1))))))))
 594
 595 (defun gnus-bookmark-bmenu-check-position ()
 596   "Return non-nil if on a line with a bookmark.
 597 The actual value returned is gnus-bookmark-alist.  Else
 598 reposition and try again, else return nil."
 599   (cond ((< (count-lines (point-min) (point)) 2)
 600          (goto-char (point-min))
 601          (forward-line 2)
 602          gnus-bookmark-alist)
 603         ((and (bolp) (eobp))
 604          (beginning-of-line 0)
 605          gnus-bookmark-alist)
 606         (t
 607          gnus-bookmark-alist)))
 608
 609 (defun gnus-bookmark-bmenu-bookmark ()
 610   "Return a string which is bookmark of this line."
 611   (if (gnus-bookmark-bmenu-check-position)
 612       (save-excursion
 613         (save-window-excursion
 614           (goto-char (point-min))
 615           (search-forward "Gnus Bookmark")
 616           (backward-word 2)
 617           (setq gnus-bookmark-bmenu-bookmark-column (current-column)))))
 618   (if gnus-bookmark-bmenu-toggle-infos
 619       (gnus-bookmark-bmenu-hide-infos))
 620   (save-excursion
 621     (save-window-excursion
 622       (beginning-of-line)
 623       (forward-char gnus-bookmark-bmenu-bookmark-column)
 624       (prog1
 625           (buffer-substring-no-properties (point)
 626                             (progn
 627                               (end-of-line)
 628                               (point)))
 629         ;; well, this is certainly crystal-clear:
 630         (if gnus-bookmark-bmenu-toggle-infos
 631             (gnus-bookmark-bmenu-toggle-infos t))))))
 632
 633 (defun gnus-bookmark-show-details (bookmark)
 634   "Display the annotation for BOOKMARK in a buffer."
 635   (let ((record (gnus-bookmark-get-bookmark-record bookmark))
 636         (details-list gnus-bookmark-bookmark-details))
 637     (save-excursion
 638       (let ((old-buf (current-buffer)))
 639         (pop-to-buffer (get-buffer-create "*Gnus Bookmark Annotation*") t)
 640         (delete-region (point-min) (point-max))
 641         (mapcar
 642          (lambda (detail)
 643            (when (not (equal (cdr (assoc detail record)) ""))
 644              (insert (concat (symbol-name detail) ": "
 645                              (cdr (assoc detail record))
 646                              "\n"))))
 647          gnus-bookmark-bookmark-details)
 648         (goto-char (point-min))
 649         (pop-to-buffer old-buf)))))
 650
 651 (defun gnus-bookmark-bmenu-show-details ()
 652   "Show the annotation for the current bookmark in another window."
 653   (interactive)
 654   (let ((bookmark (gnus-bookmark-bmenu-bookmark)))
 655     (if (gnus-bookmark-bmenu-check-position)
 656         (gnus-bookmark-show-details bookmark))))
 657
 658 (defun gnus-bookmark-bmenu-mark ()
 659   "Mark bookmark on this line to be displayed by \\<gnus-bookmark-bmenu-mode-map>\\[gnus-bookmark-bmenu-select]."
 660   (interactive)
 661   (beginning-of-line)
 662   (if (gnus-bookmark-bmenu-check-position)
 663       (let ((inhibit-read-only t))
 664         (delete-char 1)
 665         (insert ?>)
 666         (forward-line 1)
 667         (gnus-bookmark-bmenu-check-position))))
 668
 669 (defun gnus-bookmark-bmenu-unmark (&optional backup)
 670   "Cancel all requested operations on bookmark on this line and move down.
 671 Optional BACKUP means move up."
 672   (interactive "P")
 673   (beginning-of-line)
 674   (if (gnus-bookmark-bmenu-check-position)
 675       (progn
 676         (let ((inhibit-read-only t))
 677           (delete-char 1)
 678           ;; any flags to reset according to circumstances?  How about a
 679           ;; flag indicating whether this bookmark is being visited?
 680           ;; well, we don't have this now, so maybe later.
 681           (insert " "))
 682         (forward-line (if backup -1 1))
 683         (gnus-bookmark-bmenu-check-position))))
 684
 685 (defun gnus-bookmark-bmenu-backup-unmark ()
 686   "Move up and cancel all requested operations on bookmark on line above."
 687   (interactive)
 688   (forward-line -1)
 689   (if (gnus-bookmark-bmenu-check-position)
 690       (progn
 691         (gnus-bookmark-bmenu-unmark)
 692         (forward-line -1)
 693         (gnus-bookmark-bmenu-check-position))))
 694
 695 (defun gnus-bookmark-bmenu-delete ()
 696   "Mark Gnus bookmark on this line to be deleted.
 697 To carry out the deletions that you've marked, use
 698 \\<gnus-bookmark-bmenu-mode-map>\\[gnus-bookmark-bmenu-execute-deletions]."
 699   (interactive)
 700   (beginning-of-line)
 701   (if (gnus-bookmark-bmenu-check-position)
 702       (let ((inhibit-read-only t))
 703         (delete-char 1)
 704         (insert ?D)
 705         (forward-line 1)
 706         (gnus-bookmark-bmenu-check-position))))
 707
 708 (defun gnus-bookmark-bmenu-delete-backwards ()
 709   "Mark bookmark on this line to be deleted, then move up one line.
 710 To carry out the deletions that you've marked, use
 711 \\<gnus-bookmark-bmenu-mode-map>\\[gnus-bookmark-bmenu-execute-deletions]."
 712   (interactive)
 713   (gnus-bookmark-bmenu-delete)
 714   (forward-line -2)
 715   (if (gnus-bookmark-bmenu-check-position)
 716       (forward-line 1))
 717   (gnus-bookmark-bmenu-check-position))
 718
 719 (defun gnus-bookmark-bmenu-select ()
 720   "Select this line's bookmark; also display bookmarks marked with `>'.
 721 You can mark bookmarks with the
 722 \\<gnus-bookmark-bmenu-mode-map>\\[gnus-bookmark-bmenu-mark]
 723 command."
 724   (interactive)
 725   (if (gnus-bookmark-bmenu-check-position)
 726       (let ((bmrk (gnus-bookmark-bmenu-bookmark))
 727             (menu (current-buffer)))
 728         (goto-char (point-min))
 729         (delete-other-windows)
 730         (gnus-bookmark-jump bmrk)
 731         (bury-buffer menu))))
 732
 733 (defun gnus-bookmark-bmenu-load ()
 734   "Load the Gnus bookmark file and rebuild the bookmark menu-buffer."
 735   (interactive)
 736   (if (gnus-bookmark-bmenu-check-position)
 737       (save-excursion
 738         (save-window-excursion
 739           ;; This will call `gnus-bookmark-bmenu-list'
 740           (call-interactively 'gnus-bookmark-load)))))
 741
 742 (defun gnus-bookmark-bmenu-execute-deletions ()
 743   "Delete Gnus bookmarks marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 744   (interactive)
 745   (message "Deleting Gnus bookmarks...")
 746   (let ((hide-em gnus-bookmark-bmenu-toggle-infos)
 747         (o-point  (point))
 748         (o-str    (save-excursion
 749                     (beginning-of-line)
 750                     (if (looking-at "^D")
 751                         nil
 752                       (buffer-substring
 753                        (point)
 754                        (progn (end-of-line) (point))))))
 755         (o-col     (current-column)))
 756     (if hide-em (gnus-bookmark-bmenu-hide-infos))
 757     (setq gnus-bookmark-bmenu-toggle-infos nil)
 758     (goto-char (point-min))
 759     (forward-line 1)
 760     (while (re-search-forward "^D" (point-max) t)
 761       (gnus-bookmark-delete (gnus-bookmark-bmenu-bookmark) t)) ; pass BATCH arg
 762     (gnus-bookmark-bmenu-list)
 763     (setq gnus-bookmark-bmenu-toggle-infos hide-em)
 764     (if gnus-bookmark-bmenu-toggle-infos
 765         (gnus-bookmark-bmenu-toggle-infos t))
 766     (if o-str
 767         (progn
 768           (goto-char (point-min))
 769           (search-forward o-str)
 770           (beginning-of-line)
 771           (forward-char o-col))
 772       (goto-char o-point))
 773     (beginning-of-line)
 774     (gnus-bookmark-write-file)
 775     (message "Deleting bookmarks...done")))
 776
 777 (defun gnus-bookmark-delete (bookmark &optional batch)
 778   "Delete BOOKMARK from the bookmark list.
 779 Removes only the first instance of a bookmark with that name.  If
 780 there are one or more other bookmarks with the same name, they will
 781 not be deleted.  Defaults to the \"current\" bookmark \(that is, the
 782 one most recently used in this file, if any\).
 783 Optional second arg BATCH means don't update the bookmark list buffer,
 784 probably because we were called from there."
 785   (gnus-bookmark-maybe-load-default-file)
 786   (let ((will-go (gnus-bookmark-get-bookmark bookmark)))
 787     (setq gnus-bookmark-alist (delq will-go gnus-bookmark-alist)))
 788   ;; Don't rebuild the list
 789   (if batch
 790       nil
 791     (gnus-bookmark-bmenu-surreptitiously-rebuild-list)))
 792
 793 (provide 'gnus-bookmark)
 794
 795 ;; arch-tag: 779df694-366f-46e8-84b2-1d0340e6f525
 796 ;;; gnus-bookmark.el ends here