cgit.sxemacs.org Git - gnus/blob - lisp/gnus-async.el

   1 ;;; gnus-async.el --- asynchronous support for Gnus
   2 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@ifi.uio.no>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus-load)
  29 (require 'gnus-sum)
  30 (require 'nntp)
  31
  32 (defvar gnus-asynchronous t
  33   "*If nil, inhibit all Gnus asynchronicity.
  34 If non-nil, let the other asynch variables be heeded.")
  35
  36 (defvar gnus-use-article-prefetch 30
  37   "*If non-nil, prefetch articles in groups that allow this.
  38 If a number, prefetch only that many articles forward;
  39 if t, prefetch as many articles as possible.")
  40
  41 (defvar gnus-prefetched-article-deletion-strategy '(read exit)
  42   "List of symbols that say when to remove articles from the prefetch buffer.
  43 Possible values in this list are `read', which means that
  44 articles are removed as they are read, and `exit', which means
  45 that all articles belonging to a group are removed on exit
  46 from that group.")
  47
  48 (defvar gnus-use-header-prefetch nil
  49   "*If non-nil, prefetch the headers to the next group.")
  50
  51 ;;; Internal variables.
  52
  53 (defvar gnus-async-prefetch-article-buffer " *Async Prefetch Article*")
  54 (defvar gnus-async-article-alist nil)
  55 (defvar gnus-async-article-semaphore '(nil))
  56 (defvar gnus-async-fetch-list nil)
  57
  58 (defvar gnus-async-prefetch-headers-buffer " *Async Prefetch Headers*")
  59 (defvar gnus-async-header-prefetched nil)
  60
  61 ;;; Utility functions.
  62
  63 (defun gnus-group-asynchronous-p (group)
  64   "Say whether GROUP is fetched from a server that supports asynchronocity."
  65   (gnus-asynchronous-p (gnus-find-method-for-group group)))
  66
  67 ;;; Somewhat bogus semaphores.
  68
  69 (defun gnus-async-get-semaphore (semaphore)
  70   "Wait until SEMAPHORE is released."
  71   (while (/= (length (nconc (symbol-value semaphore) (list nil))) 2)
  72     (sleep-for 1)))
  73
  74 (defun gnus-async-release-semaphore (semaphore)
  75   "Release SEMAPHORE."
  76   (setcdr (symbol-value semaphore) nil))
  77
  78 ;;;
  79 ;;; Article prefetch
  80 ;;;
  81
  82 (gnus-add-shutdown 'gnus-async-close 'gnus)
  83 (defun gnus-async-close ()
  84   (gnus-kill-buffer gnus-async-prefetch-article-buffer)
  85   (gnus-kill-buffer gnus-async-prefetch-headers-buffer)
  86   (setq gnus-async-article-alist nil
  87         gnus-async-header-prefetched nil))
  88
  89 (defun gnus-async-set-buffer ()
  90   (nnheader-set-temp-buffer gnus-async-prefetch-article-buffer t))
  91
  92 (defun gnus-async-prefetch-next (group article summary)
  93   "Possibly prefetch several articles starting with the article after ARTICLE."
  94   (when (gnus-buffer-live-p summary)
  95     (save-excursion
  96       (set-buffer gnus-summary-buffer)
  97       (let ((next (caadr (gnus-data-find-list article))))
  98         (when next
  99           (if gnus-xemacs
 100               (gnus-async-prefetch-article group next summary)
 101             (run-with-idle-timer
 102              0.1 nil 'gnus-async-prefetch-article group next summary)))))))
 103
 104 (defun gnus-async-prefetch-article (group article summary &optional next)
 105   "Possibly prefetch several articles starting with ARTICLE."
 106   (when (and gnus-asynchronous
 107              (gnus-alive-p))
 108     (when next
 109       (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 110       (pop gnus-async-fetch-list)
 111       (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 112     (let ((do-fetch next))
 113       (when (and (gnus-group-asynchronous-p group)
 114                  (gnus-buffer-live-p summary)
 115                  (or (not next)
 116                      gnus-async-fetch-list))
 117         (unwind-protect
 118             (progn
 119               (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 120               (unless next
 121                 (setq do-fetch (not gnus-async-fetch-list))
 122                 ;; Nix out any outstanding requests.
 123                 (setq gnus-async-fetch-list nil)
 124                 ;; Fill in the new list.
 125                 (let ((n gnus-use-article-prefetch)
 126                       (data (gnus-data-find-list article))
 127                       d)
 128                   (while (and (setq d (pop data))
 129                               (if (numberp n)
 130                                   (natnump (decf n))
 131                                 n))
 132                     (unless (or (gnus-async-prefetched-article-entry
 133                                  group (setq article (gnus-data-number d)))
 134                                 (not (natnump article)))
 135                       ;; Not already fetched -- so we add it to the list.
 136                       (push article gnus-async-fetch-list)))
 137                   (setq gnus-async-fetch-list
 138                         (nreverse gnus-async-fetch-list))))
 139
 140               (when do-fetch
 141                 (setq article (car gnus-async-fetch-list))))
 142
 143           (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 144
 145         (when (and do-fetch article)
 146           ;; We want to fetch some more articles.
 147           (save-excursion
 148             (set-buffer summary)
 149             (let (mark)
 150               (gnus-async-set-buffer)
 151               (goto-char (point-max))
 152               (setq mark (point-marker))
 153               (let ((nnheader-callback-function
 154                      (gnus-make-async-article-function
 155                       group article mark summary next))
 156                     (nntp-server-buffer (get-buffer
 157                                          gnus-async-prefetch-article-buffer)))
 158                 (gnus-message 7 "Prefetching article %d in group %s"
 159                               article group)
 160                 (gnus-request-article article group)))))))))
 161
 162 (defun gnus-make-async-article-function (group article mark summary next)
 163   "Return a callback function."
 164   `(lambda (arg)
 165      (save-excursion
 166        (gnus-async-set-buffer)
 167        (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 168        (push (list ',(intern (format "%s-%d" group article))
 169                    ,mark (set-marker (make-marker)
 170                                      (point-max))
 171                    ,group ,article)
 172              gnus-async-article-alist)
 173        (gnus-async-release-semaphore
 174         'gnus-async-article-semaphore)
 175        (when (gnus-buffer-live-p ,summary)
 176          (gnus-async-prefetch-article
 177           ,group ,next ,summary t)))))
 178
 179 (defun gnus-async-request-fetched-article (group article buffer)
 180   "See whether we have ARTICLE from GROUP and put it in BUFFER."
 181   (when (numberp article)
 182     (let ((entry (gnus-async-prefetched-article-entry group article)))
 183       (when entry
 184         (save-excursion
 185           (gnus-async-set-buffer)
 186           (copy-to-buffer buffer (cadr entry) (caddr entry))
 187           ;; Remove the read article from the prefetch buffer.
 188           (when (memq 'read gnus-prefetched-article-deletion-strategy)
 189             (gnus-async-delete-prefected-entry entry))
 190           t)))))
 191
 192 (defun gnus-async-delete-prefected-entry (entry)
 193   "Delete ENTRY from buffer and alist."
 194   (delete-region (cadr entry) (caddr entry))
 195   (set-marker (cadr entry) nil)
 196   (set-marker (caddr entry) nil)
 197   (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 198   (setq gnus-async-article-alist
 199         (delq entry gnus-async-article-alist))
 200   (gnus-async-release-semaphore 'gnus-async-article-semaphore))
 201
 202 (defun gnus-async-prefetch-remove-group (group)
 203   "Remove all articles belonging to GROUP from the prefetch buffer."
 204   (when (and (gnus-group-asynchronous-p group)
 205              (memq 'exit gnus-prefetched-article-deletion-strategy))
 206     (let ((alist gnus-async-article-alist))
 207       (save-excursion
 208         (gnus-async-set-buffer)
 209         (while alist
 210           (when (equal group (nth 3 (car alist)))
 211             (gnus-async-delete-prefected-entry (car alist)))
 212           (pop alist))))))
 213
 214 (defun gnus-async-prefetched-article-entry (group article)
 215   "Return the entry for ARTICLE in GROUP iff it has been prefetched."
 216   (assq (intern (format "%s-%d" group article))
 217         gnus-async-article-alist))
 218
 219 ;;;
 220 ;;; Header prefetch
 221 ;;;
 222
 223 (defun gnus-async-prefetch-headers (group)
 224   "Prefetch the headers for group GROUP."
 225   (save-excursion
 226     (let (unread)
 227       (when (and gnus-use-header-prefetch
 228                  gnus-asynchronous
 229                  (gnus-group-asynchronous-p group)
 230                  (listp gnus-async-header-prefetched)
 231                  (setq unread (gnus-list-of-unread-articles group)))
 232         ;; Mark that a fetch is in progress.
 233         (setq gnus-async-header-prefetched t)
 234         (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 235         (erase-buffer)
 236         (let ((nntp-server-buffer (current-buffer))
 237               (nnheader-callback-function
 238                `(lambda (arg)
 239                   (setq gnus-async-header-prefetched
 240                         ,(cons group unread)))))
 241           (gnus-retrieve-headers unread group gnus-fetch-old-headers))))))
 242
 243 (defun gnus-async-retrieve-fetched-headers (articles group)
 244   "See whether we have prefetched headers."
 245   (when (and gnus-use-header-prefetch
 246              (gnus-group-asynchronous-p group)
 247              (listp gnus-async-header-prefetched)
 248              (equal group (car gnus-async-header-prefetched))
 249              (equal articles (cdr gnus-async-header-prefetched)))
 250     (save-excursion
 251       (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 252       (nntp-decode-text)
 253       (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 254       (erase-buffer)
 255       (setq gnus-async-header-prefetched nil)
 256       t)))
 257
 258 (provide 'gnus-async)
 259
 260 ;;; gnus-async.el ends here