cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (eq system-type 'windows-nt)
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form
 122             '(and (> 0 1)
 123                   (message "This should not appear in the byte-code."))
 124             t))
 125   (defadvice byte-optimize-form-code-walker
 126     (around fix-bug-in-and/or-forms (form for-effect) activate)
 127     "Optimize the rest of the and/or forms.
 128 It has been fixed in XEmacs before releasing 21.4 and also has been
 129 fixed in Emacs 22."
 130     (if (and for-effect (memq (car-safe form) '(and or)))
 131         (let ((fn (car form))
 132               (backwards (reverse (cdr form))))
 133           (while (and backwards
 134                       (null (setcar backwards
 135                                     (byte-optimize-form (car backwards) t))))
 136             (setq backwards (cdr backwards)))
 137           (if (and (cdr form) (null backwards))
 138               (byte-compile-log
 139                "  all subforms of %s called for effect; deleted" form))
 140           (when backwards
 141             (setcdr backwards
 142                     (mapcar 'byte-optimize-form (cdr backwards))))
 143           (setq ad-return-value (cons fn (nreverse backwards))))
 144       ad-do-it)))
 145
 146 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
 147 ;; following threads:
 148 ;;
 149 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
 150 ;; Subject: attachment problems found but not fixed
 151 ;;
 152 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
 153 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
 154 ;;
 155 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
 156 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
 157 ;;
 158 ;; Should be fixed in XEmacs (March 2007).
 159 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 160 ;; When should we remove this workaround?
 161 ;;
 162 (when (and (featurep 'xemacs)
 163            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 164              (modify-syntax-entry ?= " " table)
 165              (with-temp-buffer
 166                (with-syntax-table table
 167                  (insert "foo=bar")
 168                  (goto-char (point-min))
 169                  (forward-sexp 1)
 170                  (eolp)))))
 171   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 172   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 173   (defmacro with-syntax-table (syntab &rest body)
 174     "Evaluate BODY with the SYNTAB as the current syntax table."
 175     `(let ((stab (syntax-table)))
 176        (unwind-protect
 177            (progn
 178              ;;(set-syntax-table (copy-syntax-table ,syntab))
 179              (set-syntax-table ,syntab)
 180              ,@body)
 181          (set-syntax-table stab)))))
 182
 183 (push srcdir load-path)
 184 (push loaddir load-path)
 185 (load (expand-file-name "lpath.el" loaddir) nil t)
 186
 187 (defalias 'device-sound-enabled-p 'ignore)
 188 (defalias 'play-sound-file 'ignore)
 189 (defalias 'efs-re-read-dir 'ignore)
 190 (defalias 'ange-ftp-re-read-dir 'ignore)
 191 (defalias 'define-mail-user-agent 'ignore)
 192
 193 (eval-and-compile
 194   (unless (featurep 'xemacs)
 195     (defalias 'get-popup-menu-response 'ignore)
 196     (defalias 'event-object 'ignore)
 197     (defalias 'x-defined-colors 'ignore)
 198     (defalias 'read-color 'ignore)))
 199
 200 (eval-and-compile
 201   (when (featurep 'xemacs)
 202     (unless (fboundp 'defadvice)
 203       (autoload 'defadvice "advice" nil nil 'macro))
 204     (autoload 'Info-directory "info" nil t)
 205     (autoload 'Info-index "info" nil t)
 206     (autoload 'Info-index-next "info" nil t)
 207     (autoload 'Info-menu "info" nil t)
 208     (autoload 'ad-add-advice "advice")
 209     (unless (and (emacs-version>= 21 5)
 210                  (not (featurep 'sxemacs)))
 211       ;; calendar/auto-autoloads.el provides it.
 212       (autoload 'add-to-invisibility-spec "dummy"))
 213     (autoload 'annotations-at "annotations")
 214     (autoload 'apropos "apropos" nil t)
 215     (autoload 'apropos-command "apropos" nil t)
 216     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 217     (autoload 'browse-url "browse-url" nil t)
 218     (autoload 'browse-url-of-file "browse-url" nil t)
 219     (autoload 'c-mode "cc-mode" nil t)
 220     (autoload 'customize-apropos "cus-edit" nil t)
 221     (autoload 'customize-group "cus-edit" nil t)
 222     (autoload 'customize-save-variable "cus-edit" nil t)
 223     (autoload 'customize-set-variable "cus-edit" nil t)
 224     (autoload 'customize-variable "cus-edit" nil t)
 225     (autoload 'debug "debug" nil t)
 226     (if (featurep 'mule)
 227         (unless (locate-library "mule-ccl")
 228           (autoload 'define-ccl-program "ccl" nil nil 'macro))
 229       (defalias 'define-ccl-program 'ignore))
 230     (autoload 'delete-annotation "annotations")
 231     (autoload 'dolist "cl-macs" nil nil 'macro)
 232     (autoload 'enriched-decode "enriched")
 233     (autoload 'eudc-expand-inline "eudc" nil t)
 234     (autoload 'executable-find "executable")
 235     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 236     (when (and (emacs-version>= 21 5)
 237                (not (featurep 'sxemacs)))
 238       (autoload 'get-display-table "disp-table")
 239       (autoload 'put-display-table "disp-table"))
 240     (autoload 'info "info" nil t)
 241     (autoload 'mail-extract-address-components "mail-extr")
 242     (autoload 'mail-fetch-field "mail-utils")
 243     (autoload 'make-annotation "annotations")
 244     (autoload 'make-display-table "disp-table")
 245     (autoload 'pgg-snarf-keys-region "pgg" nil t)
 246     (autoload 'pp "pp")
 247     (autoload 'ps-despool "ps-print" nil t)
 248     (autoload 'ps-spool-buffer "ps-print" nil t)
 249     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 250     (autoload 'read-passwd "passwd")
 251     (autoload 'regexp-opt "regexp-opt")
 252     (autoload 'reporter-submit-bug-report "reporter")
 253     (if (and (emacs-version>= 21 5)
 254              (not (featurep 'sxemacs)))
 255         (autoload 'setenv "process" nil t)
 256       (autoload 'setenv "env" nil t))
 257     (autoload 'sgml-mode "psgml" nil t)
 258     (autoload 'smtpmail-send-it "smtpmail")
 259     (autoload 'sort-numeric-fields "sort" nil t)
 260     (autoload 'sort-subr "sort")
 261     (autoload 'thing-at-point "thingatpt")
 262     (autoload 'toggle-truncate-lines "view-less" nil t)
 263     (autoload 'trace-function-background "trace" nil t)
 264     (autoload 'unmorse-region "morse" nil t)
 265     (autoload 'w3-do-setup "w3")
 266     (autoload 'w3-prepare-buffer "w3-display")
 267     (autoload 'w3-region "w3-display" nil t)
 268     (defalias 'frame-char-height 'frame-height)
 269     (defalias 'frame-char-width 'frame-width)
 270     (defalias 'frame-parameter 'frame-property)
 271     (defalias 'make-overlay 'ignore)
 272     (defalias 'overlay-end 'ignore)
 273     (defalias 'overlay-get 'ignore)
 274     (defalias 'overlay-put 'ignore)
 275     (defalias 'overlay-start 'ignore)
 276     (defalias 'overlays-in 'ignore)
 277     (defalias 'replace-dehighlight 'ignore)
 278     (defalias 'replace-highlight 'ignore)
 279     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 280
 281 (defun dgnushack-emacs-compile-defcustom-p ()
 282   "Return non-nil if Emacs byte compiles `defcustom' forms.
 283 Those Emacsen will warn against undefined variables and functions used
 284 in `defcustom' forms."
 285   (let ((outbuf (with-temp-buffer
 286                   (insert "(defcustom foo (1+ (random)) \"\" :group 'emacs)\n")
 287                   (byte-compile-from-buffer (current-buffer) "foo.el"))))
 288     (when outbuf
 289       (prog1
 290           (with-current-buffer outbuf
 291             (goto-char (point-min))
 292             (search-forward " 'foo '(byte-code " nil t))
 293         (kill-buffer outbuf)))))
 294
 295 (when (dgnushack-emacs-compile-defcustom-p)
 296   (maybe-fbind '(defined-colors face-attribute))
 297   (maybe-bind '(idna-program installation-directory)))
 298
 299 (defun dgnushack-compile-verbosely ()
 300   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 301 patches to gnus, you should consider modifying make.bat to call
 302 dgnushack-compile-verbosely.  All other users should continue to use
 303 dgnushack-compile."
 304   (dgnushack-compile t))
 305
 306 (defun dgnushack-compile (&optional warn)
 307   ;;(setq byte-compile-dynamic t)
 308   (unless warn
 309     (setq byte-compile-warnings
 310           '(free-vars unresolved callargs redefine)))
 311   (let ((files (delete ".dir-locals.el"
 312                        (directory-files srcdir nil "^[^=].*\\.el$")))
 313         ;;(byte-compile-generate-call-tree t)
 314         file elc)
 315     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 316     ;; installed.
 317     (when (featurep 'xemacs)
 318       (setq gnus-xmas-glyph-directory "dummy"))
 319     (dolist (file '("dgnushack.el" "lpath.el"))
 320       (setq files (delete file files)))
 321     (when (featurep 'base64)
 322       (setq files (delete "base64.el" files)))
 323     (condition-case code
 324         (require 'w3-parse)
 325       (error
 326        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 327        (dolist (file '("webmail.el" "nnwfm.el"))
 328          (setq files (delete file files)))))
 329     (condition-case code
 330         (require 'mh-e)
 331       (error
 332        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 333        (setq files (delete "gnus-mh.el" files))))
 334     (condition-case code
 335         (require 'xml)
 336       (error
 337        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 338        (setq files (delete "nnrss.el" files))))
 339     (dolist (file
 340              (if (featurep 'xemacs)
 341                  '("md5.el")
 342                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 343       (setq files (delete file files)))
 344
 345     (dolist (file files)
 346       (setq file (expand-file-name file srcdir))
 347       (when (and (file-exists-p
 348                   (setq elc (concat (file-name-nondirectory file) "c")))
 349                  (file-newer-than-file-p file elc))
 350         (delete-file elc)))
 351
 352     (while (setq file (pop files))
 353       (setq file (expand-file-name file srcdir))
 354       (when (or (not (file-exists-p
 355                       (setq elc (concat (file-name-nondirectory file) "c"))))
 356                 (file-newer-than-file-p file elc))
 357         (ignore-errors
 358           (byte-compile-file file))))))
 359
 360 (defun dgnushack-recompile ()
 361   (require 'gnus)
 362   (byte-recompile-directory "." 0))
 363
 364 (defvar dgnushack-gnus-load-file
 365   (if (featurep 'xemacs)
 366       (expand-file-name "auto-autoloads.el")
 367     (expand-file-name "gnus-load.el")))
 368
 369 (defvar dgnushack-cus-load-file
 370   (if (featurep 'xemacs)
 371       (expand-file-name "custom-load.el")
 372     (expand-file-name "cus-load.el")))
 373
 374 (defun dgnushack-make-cus-load ()
 375   (load "cus-dep")
 376   (let ((cusload-base-file dgnushack-cus-load-file))
 377     (defadvice directory-files (after exclude-dir-locals activate)
 378       "Exclude .dir-locals.el file."
 379       (dolist (file ad-return-value)
 380         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 381             (setq ad-return-value (delete file ad-return-value)))))
 382     (unwind-protect
 383         (if (fboundp 'custom-make-dependencies)
 384             (custom-make-dependencies)
 385           (Custom-make-dependencies))
 386       (ad-unadvise 'directory-files))
 387     (when (featurep 'xemacs)
 388       (message "Compiling %s..." dgnushack-cus-load-file)
 389       (byte-compile-file dgnushack-cus-load-file))))
 390
 391 (defun dgnushack-make-auto-load ()
 392   (require 'autoload)
 393   (unless (make-autoload '(define-derived-mode child parent name
 394                             "docstring" body)
 395                          "file")
 396     (defadvice make-autoload (around handle-define-derived-mode activate)
 397       "Handle `define-derived-mode'."
 398       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 399           (setq ad-return-value
 400                 (list 'autoload
 401                       (list 'quote (nth 1 (ad-get-arg 0)))
 402                       (ad-get-arg 1)
 403                       (nth 4 (ad-get-arg 0))
 404                       t nil))
 405         ad-do-it))
 406     (put 'define-derived-mode 'doc-string-elt 3))
 407   (let ((generated-autoload-file dgnushack-gnus-load-file)
 408         (make-backup-files nil)
 409         (autoload-package-name "gnus"))
 410     (if (featurep 'xemacs)
 411         (if (file-exists-p generated-autoload-file)
 412             (delete-file generated-autoload-file))
 413       (with-temp-file generated-autoload-file
 414         (insert ?\014)))
 415     (defadvice directory-files (after exclude-dir-locals activate)
 416       "Exclude .dir-locals.el file."
 417       (dolist (file ad-return-value)
 418         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 419             (setq ad-return-value (delete file ad-return-value)))))
 420     (unwind-protect
 421         (batch-update-autoloads)
 422       (ad-unadvise 'directory-files))))
 423
 424 (defun dgnushack-make-load ()
 425   (unless (featurep 'xemacs)
 426     (message "Generating %s..." dgnushack-gnus-load-file)
 427     (with-temp-file dgnushack-gnus-load-file
 428       (insert-file-contents dgnushack-cus-load-file)
 429       (delete-file dgnushack-cus-load-file)
 430       (goto-char (point-min))
 431       (search-forward ";;; Code:")
 432       (forward-line)
 433       (delete-region (point-min) (point))
 434       (insert "\
 435 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 436 ;;
 437 ;;; Code:
 438 ")
 439       (goto-char (point-max))
 440       (if (search-backward "custom-versions-load-alist" nil t)
 441           (forward-line -1)
 442         (forward-line -1)
 443         (while (eq (char-after) ?\;)
 444           (forward-line -1))
 445         (forward-line))
 446       (delete-region (point) (point-max))
 447       (insert "\n")
 448       ;; smiley-* are duplicated. Remove them all.
 449       (let ((point (point)))
 450         (insert-file-contents dgnushack-gnus-load-file)
 451         (goto-char point)
 452         (while (search-forward "smiley-" nil t)
 453           (beginning-of-line)
 454           (if (looking-at "(autoload ")
 455               (delete-region (point) (progn (forward-sexp) (point)))
 456             (forward-line))))
 457       ;;
 458       (goto-char (point-max))
 459       (when (search-backward "\n(provide " nil t)
 460         (forward-line -1)
 461         (delete-region (point) (point-max)))
 462       (insert "\
 463
 464 \(provide 'gnus-load)
 465
 466 ;;; Local Variables:
 467 ;;; version-control: never
 468 ;;; no-byte-compile: t
 469 ;;; no-update-autoloads: t
 470 ;;; End:
 471 ;;; gnus-load.el ends here
 472 ")
 473       ))
 474   (message "Compiling %s..." dgnushack-gnus-load-file)
 475   (byte-compile-file dgnushack-gnus-load-file)
 476   (when (featurep 'xemacs)
 477     (message "Creating dummy gnus-load.el...")
 478     (with-temp-file (expand-file-name "gnus-load.el")
 479       (insert "\
 480
 481 \(provide 'gnus-load)
 482
 483 ;;; Local Variables:
 484 ;;; version-control: never
 485 ;;; no-byte-compile: t
 486 ;;; no-update-autoloads: t
 487 ;;; End:
 488 ;;; gnus-load.el ends here"))))
 489
 490 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 491   "Return a list of directories in which other Gnus installations exist.
 492 This function looks for the other Gnus installations which will shadow
 493 the new Gnus Lisp modules which have been installed in LISPDIR, using
 494 the default `load-path'.  The return value will make sense only when
 495 LISPDIR is existent and is listed in the default `load-path'.  Assume
 496 LISPDIR will be prepended to `load-path' by a user if the default
 497 `load-path' does not contain it."
 498   (unless lispdir
 499     (setq lispdir (getenv "lispdir")))
 500   (when (and lispdir (file-directory-p lispdir))
 501     (setq lispdir (file-truename (directory-file-name lispdir)))
 502     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 503                      "message.elc" "message.el" "message.el.bz2"
 504                      "message.el.gz"))
 505           (path (delq nil (mapcar
 506                            (lambda (p)
 507                              (condition-case nil
 508                                  (when (and p (file-directory-p p))
 509                                    (file-truename (directory-file-name p)))
 510                                (error nil)))
 511                            dgnushack-default-load-path)))
 512           rest elcs)
 513       (while path
 514         (setq rest (cons (car path) rest)
 515               path (delete (car rest) (cdr path))))
 516       (setq path (nreverse (cdr (member lispdir rest)))
 517             rest nil)
 518       (while path
 519         (setq elcs indices)
 520         (while elcs
 521           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 522             (setq rest (cons (car path) rest)
 523                   elcs nil)))
 524         (setq path (cdr path)))
 525       (prog1
 526           (setq path (nreverse rest))
 527         (when path
 528           (let (print-level print-length)
 529             (princ (concat "\n\
 530 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 531  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 532 You will need to modify the run-time `load-path', remove them manually,
 533 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 534
 535 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 536   "Remove the other Gnus installations which shadow the recent one."
 537   (let ((path (with-temp-buffer
 538                 (let ((standard-output (current-buffer)))
 539                   (dgnushack-find-lisp-shadows lispdir))))
 540         elcs files shadows file)
 541     (when path
 542       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 543         (error "You should build .elc files first."))
 544       (setq files
 545             (apply
 546              'append
 547              (mapcar
 548               (lambda (el)
 549                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 550               (append
 551                (list (file-name-nondirectory dgnushack-gnus-load-file)
 552                      (file-name-nondirectory dgnushack-cus-load-file))
 553                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 554       (while path
 555         (setq shadows files)
 556         (while shadows
 557           (setq file (expand-file-name (pop shadows) (car path)))
 558           (when (file-exists-p file)
 559             (princ (concat "  Removing " file "..."))
 560             (condition-case nil
 561                 (progn
 562                   (delete-file file)
 563                   (princ "done\n"))
 564               (error (princ "failed\n")))))
 565         (setq path (cdr path))))))
 566
 567 ;;; dgnushack.el ends here