cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (memq system-type '(win32 w32 mswindows windows-nt))
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form '(and (> 0 1) foo) t))
 122   (defadvice byte-optimize-form-code-walker
 123     (around fix-bug-in-and/or-forms (form for-effect) activate)
 124     "Optimize the rest of the and/or forms.
 125 It has been fixed in XEmacs before releasing 21.4 and also has been
 126 fixed in Emacs after 21.3."
 127     (if (and for-effect (memq (car-safe form) '(and or)))
 128         (let ((fn (car form))
 129               (backwards (reverse (cdr form))))
 130           (while (and backwards
 131                       (null (setcar backwards
 132                                     (byte-optimize-form (car backwards) t))))
 133             (setq backwards (cdr backwards)))
 134           (if (and (cdr form) (null backwards))
 135               (byte-compile-log
 136                "  all subforms of %s called for effect; deleted" form))
 137           (when backwards
 138             (setcdr backwards
 139                     (mapcar 'byte-optimize-form (cdr backwards))))
 140           (setq ad-return-value (cons fn (nreverse backwards))))
 141       ad-do-it)))
 142
 143 (when (and (featurep 'xemacs)
 144            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 145              (modify-syntax-entry ?= " " table)
 146              (with-temp-buffer
 147                (with-syntax-table table
 148                  (insert "foo=bar")
 149                  (goto-char (point-min))
 150                  (forward-sexp 1)
 151                  (eolp)))))
 152   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 153   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 154   (defmacro with-syntax-table (syntab &rest body)
 155     "Evaluate BODY with the SYNTAB as the current syntax table."
 156     `(let ((stab (syntax-table)))
 157        (unwind-protect
 158            (progn
 159              ;;(set-syntax-table (copy-syntax-table ,syntab))
 160              (set-syntax-table ,syntab)
 161              ,@body)
 162          (set-syntax-table stab)))))
 163
 164 (push srcdir load-path)
 165 (push loaddir load-path)
 166 (load (expand-file-name "lpath.el" loaddir) nil t)
 167
 168 (defalias 'device-sound-enabled-p 'ignore)
 169 (defalias 'play-sound-file 'ignore)
 170 (defalias 'nndb-request-article 'ignore)
 171 (defalias 'efs-re-read-dir 'ignore)
 172 (defalias 'ange-ftp-re-read-dir 'ignore)
 173 (defalias 'define-mail-user-agent 'ignore)
 174
 175 (eval-and-compile
 176   (unless (featurep 'xemacs)
 177     (defalias 'get-popup-menu-response 'ignore)
 178     (defalias 'event-object 'ignore)
 179     (defalias 'x-defined-colors 'ignore)
 180     (defalias 'read-color 'ignore)))
 181
 182 (eval-and-compile
 183   (when (featurep 'xemacs)
 184     (unless (fboundp 'defadvice)
 185       (autoload 'defadvice "advice" nil nil 'macro))
 186     (autoload 'Info-directory "info" nil t)
 187     (autoload 'Info-menu "info" nil t)
 188     (autoload 'annotations-at "annotations")
 189     (autoload 'apropos "apropos" nil t)
 190     (autoload 'apropos-command "apropos" nil t)
 191     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 192     (autoload 'browse-url "browse-url" nil t)
 193     (autoload 'c-mode "cc-mode" nil t)
 194     (autoload 'customize-apropos "cus-edit" nil t)
 195     (autoload 'customize-save-variable "cus-edit" nil t)
 196     (autoload 'customize-set-variable "cus-edit" nil t)
 197     (autoload 'customize-variable "cus-edit" nil t)
 198     (autoload 'delete-annotation "annotations")
 199     (autoload 'dolist "cl-macs" nil nil 'macro)
 200     (autoload 'enriched-decode "enriched")
 201     (autoload 'executable-find "executable")
 202     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 203     (autoload 'info "info" nil t)
 204     (autoload 'mail-extract-address-components "mail-extr")
 205     (autoload 'mail-fetch-field "mail-utils")
 206     (autoload 'make-annotation "annotations")
 207     (autoload 'make-display-table "disp-table")
 208     (autoload 'pp "pp")
 209     (autoload 'ps-despool "ps-print" nil t)
 210     (autoload 'ps-spool-buffer "ps-print" nil t)
 211     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 212     (autoload 'read-passwd "passwd")
 213     (autoload 'regexp-opt "regexp-opt")
 214     (autoload 'reporter-submit-bug-report "reporter")
 215     (if (and (emacs-version>= 21 5)
 216              (not (featurep 'sxemacs)))
 217         (autoload 'setenv "process" nil t)
 218       (autoload 'setenv "env" nil t))
 219     (autoload 'sgml-mode "psgml" nil t)
 220     (autoload 'smtpmail-send-it "smtpmail")
 221     (autoload 'sort-numeric-fields "sort" nil t)
 222     (autoload 'sort-subr "sort")
 223     (autoload 'trace-function-background "trace" nil t)
 224     (autoload 'w3-do-setup "w3")
 225     (autoload 'w3-prepare-buffer "w3-display")
 226     (autoload 'w3-region "w3-display" nil t)
 227     (defalias 'frame-char-height 'frame-height)
 228     (defalias 'frame-char-width 'frame-width)
 229     (defalias 'frame-parameter 'frame-property)
 230     (defalias 'make-overlay 'ignore)
 231     (defalias 'overlay-end 'ignore)
 232     (defalias 'overlay-get 'ignore)
 233     (defalias 'overlay-put 'ignore)
 234     (defalias 'overlay-start 'ignore)
 235     (defalias 'overlays-in 'ignore)
 236     (defalias 'replace-dehighlight 'ignore)
 237     (defalias 'replace-highlight 'ignore)
 238     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 239
 240 (defun dgnushack-compile-verbosely ()
 241   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 242 patches to gnus, you should consider modifying make.bat to call
 243 dgnushack-compile-verbosely.  All other users should continue to use
 244 dgnushack-compile."
 245   (dgnushack-compile t))
 246
 247 (defun dgnushack-compile (&optional warn)
 248   ;;(setq byte-compile-dynamic t)
 249   (unless warn
 250     (setq byte-compile-warnings
 251           '(free-vars unresolved callargs redefine)))
 252   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 253         ;;(byte-compile-generate-call-tree t)
 254         file elc)
 255     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 256     ;; installed.
 257     (when (featurep 'xemacs)
 258       (setq gnus-xmas-glyph-directory "dummy"))
 259     (dolist (file '("dgnushack.el" "lpath.el"))
 260       (setq files (delete file files)))
 261     (when (featurep 'base64)
 262       (setq files (delete "base64.el" files)))
 263     (condition-case code
 264         (require 'w3-parse)
 265       (error
 266        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 267        (dolist (file '("nnultimate.el" "webmail.el" "nnwfm.el"))
 268          (setq files (delete file files)))))
 269     (condition-case code
 270         (require 'mh-e)
 271       (error
 272        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 273        (setq files (delete "gnus-mh.el" files))))
 274     (condition-case code
 275         (require 'xml)
 276       (error
 277        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 278        (setq files (delete "nnrss.el" files))))
 279     (dolist (file
 280              (if (featurep 'xemacs)
 281                  '("md5.el")
 282                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 283       (setq files (delete file files)))
 284
 285     (dolist (file files)
 286       (setq file (expand-file-name file srcdir))
 287       (when (and (file-exists-p
 288                   (setq elc (concat (file-name-nondirectory file) "c")))
 289                  (file-newer-than-file-p file elc))
 290         (delete-file elc)))
 291
 292     (while (setq file (pop files))
 293       (setq file (expand-file-name file srcdir))
 294       (when (or (not (file-exists-p
 295                       (setq elc (concat (file-name-nondirectory file) "c"))))
 296                 (file-newer-than-file-p file elc))
 297         (ignore-errors
 298           (byte-compile-file file))))))
 299
 300 (defun dgnushack-recompile ()
 301   (require 'gnus)
 302   (byte-recompile-directory "." 0))
 303
 304 (defvar dgnushack-gnus-load-file
 305   (if (featurep 'xemacs)
 306       (expand-file-name "auto-autoloads.el")
 307     (expand-file-name "gnus-load.el")))
 308
 309 (defvar dgnushack-cus-load-file
 310   (if (featurep 'xemacs)
 311       (expand-file-name "custom-load.el")
 312     (expand-file-name "cus-load.el")))
 313
 314 (defun dgnushack-make-cus-load ()
 315   (load "cus-dep")
 316   (let ((cusload-base-file dgnushack-cus-load-file))
 317     (if (fboundp 'custom-make-dependencies)
 318         (custom-make-dependencies)
 319       (Custom-make-dependencies))
 320     (when (featurep 'xemacs)
 321       (message "Compiling %s..." dgnushack-cus-load-file)
 322       (byte-compile-file dgnushack-cus-load-file))))
 323
 324 (defun dgnushack-make-auto-load ()
 325   (require 'autoload)
 326   (unless (make-autoload '(define-derived-mode child parent name
 327                             "docstring" body)
 328                          "file")
 329     (defadvice make-autoload (around handle-define-derived-mode activate)
 330       "Handle `define-derived-mode'."
 331       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 332           (setq ad-return-value
 333                 (list 'autoload
 334                       (list 'quote (nth 1 (ad-get-arg 0)))
 335                       (ad-get-arg 1)
 336                       (nth 4 (ad-get-arg 0))
 337                       t nil))
 338         ad-do-it))
 339     (put 'define-derived-mode 'doc-string-elt 3))
 340   (let ((generated-autoload-file dgnushack-gnus-load-file)
 341         (make-backup-files nil)
 342         (autoload-package-name "gnus"))
 343     (if (featurep 'xemacs)
 344         (if (file-exists-p generated-autoload-file)
 345             (delete-file generated-autoload-file))
 346       (with-temp-file generated-autoload-file
 347         (insert ?\014)))
 348     (batch-update-autoloads)))
 349
 350 (defun dgnushack-make-load ()
 351   (unless (featurep 'xemacs)
 352     (message "Generating %s..." dgnushack-gnus-load-file)
 353     (with-temp-file dgnushack-gnus-load-file
 354       (insert-file-contents dgnushack-cus-load-file)
 355       (delete-file dgnushack-cus-load-file)
 356       (goto-char (point-min))
 357       (search-forward ";;; Code:")
 358       (forward-line)
 359       (delete-region (point-min) (point))
 360       (insert "\
 361 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 362 ;;
 363 ;;; Code:
 364 ")
 365       (goto-char (point-max))
 366       (if (search-backward "custom-versions-load-alist" nil t)
 367           (forward-line -1)
 368         (forward-line -1)
 369         (while (eq (char-after) ?\;)
 370           (forward-line -1))
 371         (forward-line))
 372       (delete-region (point) (point-max))
 373       (insert "\n")
 374       ;; smiley-* are duplicated. Remove them all.
 375       (let ((point (point)))
 376         (insert-file-contents dgnushack-gnus-load-file)
 377         (goto-char point)
 378         (while (search-forward "smiley-" nil t)
 379           (beginning-of-line)
 380           (if (looking-at "(autoload ")
 381               (delete-region (point) (progn (forward-sexp) (point)))
 382             (forward-line))))
 383       ;;
 384       (goto-char (point-max))
 385       (when (search-backward "\n(provide " nil t)
 386         (forward-line -1)
 387         (delete-region (point) (point-max)))
 388       (insert "\
 389
 390 \(provide 'gnus-load)
 391
 392 ;;; Local Variables:
 393 ;;; version-control: never
 394 ;;; no-byte-compile: t
 395 ;;; no-update-autoloads: t
 396 ;;; End:
 397 ;;; gnus-load.el ends here
 398 ")
 399       ))
 400   (message "Compiling %s..." dgnushack-gnus-load-file)
 401   (byte-compile-file dgnushack-gnus-load-file)
 402   (when (featurep 'xemacs)
 403     (message "Creating dummy gnus-load.el...")
 404     (with-temp-file (expand-file-name "gnus-load.el")
 405       (insert "\
 406
 407 \(provide 'gnus-load)
 408
 409 ;;; Local Variables:
 410 ;;; version-control: never
 411 ;;; no-byte-compile: t
 412 ;;; no-update-autoloads: t
 413 ;;; End:
 414 ;;; gnus-load.el ends here"))))
 415
 416 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 417   "Return a list of directories in which other Gnus installations exist.
 418 This function looks for the other Gnus installations which will shadow
 419 the new Gnus Lisp modules which have been installed in LISPDIR, using
 420 the default `load-path'.  The return value will make sense only when
 421 LISPDIR is existent and is listed in the default `load-path'.  Assume
 422 LISPDIR will be prepended to `load-path' by a user if the default
 423 `load-path' does not contain it."
 424   (unless lispdir
 425     (setq lispdir (getenv "lispdir")))
 426   (when (and lispdir (file-directory-p lispdir))
 427     (setq lispdir (file-truename (directory-file-name lispdir)))
 428     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 429                      "message.elc" "message.el" "message.el.bz2"
 430                      "message.el.gz"))
 431           (path (delq nil (mapcar
 432                            (lambda (p)
 433                              (condition-case nil
 434                                  (when (and p (file-directory-p p))
 435                                    (file-truename (directory-file-name p)))
 436                                (error nil)))
 437                            dgnushack-default-load-path)))
 438           rest elcs)
 439       (while path
 440         (setq rest (cons (car path) rest)
 441               path (delete (car rest) (cdr path))))
 442       (setq path (nreverse (cdr (member lispdir rest)))
 443             rest nil)
 444       (while path
 445         (setq elcs indices)
 446         (while elcs
 447           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 448             (setq rest (cons (car path) rest)
 449                   elcs nil)))
 450         (setq path (cdr path)))
 451       (prog1
 452           (setq path (nreverse rest))
 453         (when path
 454           (let (print-level print-length)
 455             (princ (concat "\n\
 456 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 457  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 458 You will need to modify the run-time `load-path', remove them manually,
 459 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 460
 461 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 462   "Remove the other Gnus installations which shadow the recent one."
 463   (let ((path (with-temp-buffer
 464                 (let ((standard-output (current-buffer)))
 465                   (dgnushack-find-lisp-shadows lispdir))))
 466         elcs files shadows file)
 467     (when path
 468       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 469         (error "You should build .elc files first."))
 470       (setq files
 471             (apply
 472              'append
 473              (mapcar
 474               (lambda (el)
 475                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 476               (append
 477                (list (file-name-nondirectory dgnushack-gnus-load-file)
 478                      (file-name-nondirectory dgnushack-cus-load-file))
 479                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 480       (while path
 481         (setq shadows files)
 482         (while shadows
 483           (setq file (expand-file-name (pop shadows) (car path)))
 484           (when (file-exists-p file)
 485             (princ (concat "  Removing " file "..."))
 486             (condition-case nil
 487                 (progn
 488                   (delete-file file)
 489                   (princ "done\n"))
 490               (error (princ "failed\n")))))
 491         (setq path (cdr path))))))
 492
 493 ;;; dgnushack.el ends here
 494
 495 ;;; arch-tag: 579f585a-24eb-4e1c-8d34-4808e11b68f2