cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005, 2006, 2007
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (memq system-type '(win32 w32 mswindows windows-nt))
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form
 122             '(and (> 0 1)
 123                   (message "This should not appear in the byte-code."))
 124             t))
 125   (defadvice byte-optimize-form-code-walker
 126     (around fix-bug-in-and/or-forms (form for-effect) activate)
 127     "Optimize the rest of the and/or forms.
 128 It has been fixed in XEmacs before releasing 21.4 and also has been
 129 fixed in Emacs 22."
 130     (if (and for-effect (memq (car-safe form) '(and or)))
 131         (let ((fn (car form))
 132               (backwards (reverse (cdr form))))
 133           (while (and backwards
 134                       (null (setcar backwards
 135                                     (byte-optimize-form (car backwards) t))))
 136             (setq backwards (cdr backwards)))
 137           (if (and (cdr form) (null backwards))
 138               (byte-compile-log
 139                "  all subforms of %s called for effect; deleted" form))
 140           (when backwards
 141             (setcdr backwards
 142                     (mapcar 'byte-optimize-form (cdr backwards))))
 143           (setq ad-return-value (cons fn (nreverse backwards))))
 144       ad-do-it)))
 145
 146 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
 147 ;; following threads:
 148 ;;
 149 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
 150 ;; Subject: attachment problems found but not fixed
 151 ;;
 152 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
 153 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
 154 ;;
 155 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
 156 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
 157 ;;
 158 ;; Should be fixed in XEmacs (March 2007).
 159 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 160 ;; When should we remove this workaround?
 161 ;;
 162 (when (and (featurep 'xemacs)
 163            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 164              (modify-syntax-entry ?= " " table)
 165              (with-temp-buffer
 166                (with-syntax-table table
 167                  (insert "foo=bar")
 168                  (goto-char (point-min))
 169                  (forward-sexp 1)
 170                  (eolp)))))
 171   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 172   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 173   (defmacro with-syntax-table (syntab &rest body)
 174     "Evaluate BODY with the SYNTAB as the current syntax table."
 175     `(let ((stab (syntax-table)))
 176        (unwind-protect
 177            (progn
 178              ;;(set-syntax-table (copy-syntax-table ,syntab))
 179              (set-syntax-table ,syntab)
 180              ,@body)
 181          (set-syntax-table stab)))))
 182
 183 (push srcdir load-path)
 184 (push loaddir load-path)
 185 (load (expand-file-name "lpath.el" loaddir) nil t)
 186
 187 (defalias 'device-sound-enabled-p 'ignore)
 188 (defalias 'play-sound-file 'ignore)
 189 (defalias 'nndb-request-article 'ignore)
 190 (defalias 'efs-re-read-dir 'ignore)
 191 (defalias 'ange-ftp-re-read-dir 'ignore)
 192 (defalias 'define-mail-user-agent 'ignore)
 193
 194 (eval-and-compile
 195   (unless (featurep 'xemacs)
 196     (defalias 'get-popup-menu-response 'ignore)
 197     (defalias 'event-object 'ignore)
 198     (defalias 'x-defined-colors 'ignore)
 199     (defalias 'read-color 'ignore)))
 200
 201 (eval-and-compile
 202   (when (featurep 'xemacs)
 203     (unless (fboundp 'defadvice)
 204       (autoload 'defadvice "advice" nil nil 'macro))
 205     (autoload 'Info-directory "info" nil t)
 206     (autoload 'Info-menu "info" nil t)
 207     (autoload 'annotations-at "annotations")
 208     (autoload 'apropos "apropos" nil t)
 209     (autoload 'apropos-command "apropos" nil t)
 210     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 211     (autoload 'browse-url "browse-url" nil t)
 212     (autoload 'browse-url-of-file "browse-url" nil t)
 213     (autoload 'c-mode "cc-mode" nil t)
 214     (autoload 'customize-apropos "cus-edit" nil t)
 215     (autoload 'customize-group "cus-edit" nil t)
 216     (autoload 'customize-save-variable "cus-edit" nil t)
 217     (autoload 'customize-set-variable "cus-edit" nil t)
 218     (autoload 'customize-variable "cus-edit" nil t)
 219     (autoload 'delete-annotation "annotations")
 220     (autoload 'dolist "cl-macs" nil nil 'macro)
 221     (autoload 'enriched-decode "enriched")
 222     (autoload 'executable-find "executable")
 223     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 224     (autoload 'info "info" nil t)
 225     (autoload 'mail-extract-address-components "mail-extr")
 226     (autoload 'mail-fetch-field "mail-utils")
 227     (autoload 'make-annotation "annotations")
 228     (autoload 'make-display-table "disp-table")
 229     (autoload 'pp "pp")
 230     (autoload 'ps-despool "ps-print" nil t)
 231     (autoload 'ps-spool-buffer "ps-print" nil t)
 232     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 233     (autoload 'read-passwd "passwd")
 234     (autoload 'regexp-opt "regexp-opt")
 235     (autoload 'reporter-submit-bug-report "reporter")
 236     (if (and (emacs-version>= 21 5)
 237              (not (featurep 'sxemacs)))
 238         (autoload 'setenv "process" nil t)
 239       (autoload 'setenv "env" nil t))
 240     (autoload 'sgml-mode "psgml" nil t)
 241     (autoload 'smtpmail-send-it "smtpmail")
 242     (autoload 'sort-numeric-fields "sort" nil t)
 243     (autoload 'sort-subr "sort")
 244     (autoload 'toggle-truncate-lines "view-less" nil t)
 245     (autoload 'trace-function-background "trace" nil t)
 246     (autoload 'unmorse-region "morse" nil t)
 247     (autoload 'w3-do-setup "w3")
 248     (autoload 'w3-prepare-buffer "w3-display")
 249     (autoload 'w3-region "w3-display" nil t)
 250     (defalias 'frame-char-height 'frame-height)
 251     (defalias 'frame-char-width 'frame-width)
 252     (defalias 'frame-parameter 'frame-property)
 253     (defalias 'make-overlay 'ignore)
 254     (defalias 'overlay-end 'ignore)
 255     (defalias 'overlay-get 'ignore)
 256     (defalias 'overlay-put 'ignore)
 257     (defalias 'overlay-start 'ignore)
 258     (defalias 'overlays-in 'ignore)
 259     (defalias 'replace-dehighlight 'ignore)
 260     (defalias 'replace-highlight 'ignore)
 261     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 262
 263 (defun dgnushack-compile-verbosely ()
 264   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 265 patches to gnus, you should consider modifying make.bat to call
 266 dgnushack-compile-verbosely.  All other users should continue to use
 267 dgnushack-compile."
 268   (dgnushack-compile t))
 269
 270 (defun dgnushack-compile (&optional warn)
 271   ;;(setq byte-compile-dynamic t)
 272   (unless warn
 273     (setq byte-compile-warnings
 274           '(free-vars unresolved callargs redefine)))
 275   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 276         ;;(byte-compile-generate-call-tree t)
 277         file elc)
 278     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 279     ;; installed.
 280     (when (featurep 'xemacs)
 281       (setq gnus-xmas-glyph-directory "dummy"))
 282     (dolist (file '("dgnushack.el" "lpath.el"))
 283       (setq files (delete file files)))
 284     (when (featurep 'base64)
 285       (setq files (delete "base64.el" files)))
 286     (condition-case code
 287         (require 'w3-parse)
 288       (error
 289        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 290        (dolist (file '("nnultimate.el" "webmail.el" "nnwfm.el"))
 291          (setq files (delete file files)))))
 292     (condition-case code
 293         (require 'mh-e)
 294       (error
 295        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 296        (setq files (delete "gnus-mh.el" files))))
 297     (condition-case code
 298         (require 'xml)
 299       (error
 300        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 301        (setq files (delete "nnrss.el" files))))
 302     (dolist (file
 303              (if (featurep 'xemacs)
 304                  '("md5.el")
 305                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 306       (setq files (delete file files)))
 307
 308     (dolist (file files)
 309       (setq file (expand-file-name file srcdir))
 310       (when (and (file-exists-p
 311                   (setq elc (concat (file-name-nondirectory file) "c")))
 312                  (file-newer-than-file-p file elc))
 313         (delete-file elc)))
 314
 315     (while (setq file (pop files))
 316       (setq file (expand-file-name file srcdir))
 317       (when (or (not (file-exists-p
 318                       (setq elc (concat (file-name-nondirectory file) "c"))))
 319                 (file-newer-than-file-p file elc))
 320         (ignore-errors
 321           (byte-compile-file file))))))
 322
 323 (defun dgnushack-recompile ()
 324   (require 'gnus)
 325   (byte-recompile-directory "." 0))
 326
 327 (defvar dgnushack-gnus-load-file
 328   (if (featurep 'xemacs)
 329       (expand-file-name "auto-autoloads.el")
 330     (expand-file-name "gnus-load.el")))
 331
 332 (defvar dgnushack-cus-load-file
 333   (if (featurep 'xemacs)
 334       (expand-file-name "custom-load.el")
 335     (expand-file-name "cus-load.el")))
 336
 337 (defun dgnushack-make-cus-load ()
 338   (load "cus-dep")
 339   (let ((cusload-base-file dgnushack-cus-load-file))
 340     (if (fboundp 'custom-make-dependencies)
 341         (custom-make-dependencies)
 342       (Custom-make-dependencies))
 343     (when (featurep 'xemacs)
 344       (message "Compiling %s..." dgnushack-cus-load-file)
 345       (byte-compile-file dgnushack-cus-load-file))))
 346
 347 (defun dgnushack-make-auto-load ()
 348   (require 'autoload)
 349   (unless (make-autoload '(define-derived-mode child parent name
 350                             "docstring" body)
 351                          "file")
 352     (defadvice make-autoload (around handle-define-derived-mode activate)
 353       "Handle `define-derived-mode'."
 354       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 355           (setq ad-return-value
 356                 (list 'autoload
 357                       (list 'quote (nth 1 (ad-get-arg 0)))
 358                       (ad-get-arg 1)
 359                       (nth 4 (ad-get-arg 0))
 360                       t nil))
 361         ad-do-it))
 362     (put 'define-derived-mode 'doc-string-elt 3))
 363   (let ((generated-autoload-file dgnushack-gnus-load-file)
 364         (make-backup-files nil)
 365         (autoload-package-name "gnus"))
 366     (if (featurep 'xemacs)
 367         (if (file-exists-p generated-autoload-file)
 368             (delete-file generated-autoload-file))
 369       (with-temp-file generated-autoload-file
 370         (insert ?\014)))
 371     (batch-update-autoloads)))
 372
 373 (defun dgnushack-make-load ()
 374   (unless (featurep 'xemacs)
 375     (message "Generating %s..." dgnushack-gnus-load-file)
 376     (with-temp-file dgnushack-gnus-load-file
 377       (insert-file-contents dgnushack-cus-load-file)
 378       (delete-file dgnushack-cus-load-file)
 379       (goto-char (point-min))
 380       (search-forward ";;; Code:")
 381       (forward-line)
 382       (delete-region (point-min) (point))
 383       (insert "\
 384 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 385 ;;
 386 ;;; Code:
 387 ")
 388       (goto-char (point-max))
 389       (if (search-backward "custom-versions-load-alist" nil t)
 390           (forward-line -1)
 391         (forward-line -1)
 392         (while (eq (char-after) ?\;)
 393           (forward-line -1))
 394         (forward-line))
 395       (delete-region (point) (point-max))
 396       (insert "\n")
 397       ;; smiley-* are duplicated. Remove them all.
 398       (let ((point (point)))
 399         (insert-file-contents dgnushack-gnus-load-file)
 400         (goto-char point)
 401         (while (search-forward "smiley-" nil t)
 402           (beginning-of-line)
 403           (if (looking-at "(autoload ")
 404               (delete-region (point) (progn (forward-sexp) (point)))
 405             (forward-line))))
 406       ;;
 407       (goto-char (point-max))
 408       (when (search-backward "\n(provide " nil t)
 409         (forward-line -1)
 410         (delete-region (point) (point-max)))
 411       (insert "\
 412
 413 \(provide 'gnus-load)
 414
 415 ;;; Local Variables:
 416 ;;; version-control: never
 417 ;;; no-byte-compile: t
 418 ;;; no-update-autoloads: t
 419 ;;; End:
 420 ;;; gnus-load.el ends here
 421 ")
 422       ))
 423   (message "Compiling %s..." dgnushack-gnus-load-file)
 424   (byte-compile-file dgnushack-gnus-load-file)
 425   (when (featurep 'xemacs)
 426     (message "Creating dummy gnus-load.el...")
 427     (with-temp-file (expand-file-name "gnus-load.el")
 428       (insert "\
 429
 430 \(provide 'gnus-load)
 431
 432 ;;; Local Variables:
 433 ;;; version-control: never
 434 ;;; no-byte-compile: t
 435 ;;; no-update-autoloads: t
 436 ;;; End:
 437 ;;; gnus-load.el ends here"))))
 438
 439 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 440   "Return a list of directories in which other Gnus installations exist.
 441 This function looks for the other Gnus installations which will shadow
 442 the new Gnus Lisp modules which have been installed in LISPDIR, using
 443 the default `load-path'.  The return value will make sense only when
 444 LISPDIR is existent and is listed in the default `load-path'.  Assume
 445 LISPDIR will be prepended to `load-path' by a user if the default
 446 `load-path' does not contain it."
 447   (unless lispdir
 448     (setq lispdir (getenv "lispdir")))
 449   (when (and lispdir (file-directory-p lispdir))
 450     (setq lispdir (file-truename (directory-file-name lispdir)))
 451     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 452                      "message.elc" "message.el" "message.el.bz2"
 453                      "message.el.gz"))
 454           (path (delq nil (mapcar
 455                            (lambda (p)
 456                              (condition-case nil
 457                                  (when (and p (file-directory-p p))
 458                                    (file-truename (directory-file-name p)))
 459                                (error nil)))
 460                            dgnushack-default-load-path)))
 461           rest elcs)
 462       (while path
 463         (setq rest (cons (car path) rest)
 464               path (delete (car rest) (cdr path))))
 465       (setq path (nreverse (cdr (member lispdir rest)))
 466             rest nil)
 467       (while path
 468         (setq elcs indices)
 469         (while elcs
 470           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 471             (setq rest (cons (car path) rest)
 472                   elcs nil)))
 473         (setq path (cdr path)))
 474       (prog1
 475           (setq path (nreverse rest))
 476         (when path
 477           (let (print-level print-length)
 478             (princ (concat "\n\
 479 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 480  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 481 You will need to modify the run-time `load-path', remove them manually,
 482 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 483
 484 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 485   "Remove the other Gnus installations which shadow the recent one."
 486   (let ((path (with-temp-buffer
 487                 (let ((standard-output (current-buffer)))
 488                   (dgnushack-find-lisp-shadows lispdir))))
 489         elcs files shadows file)
 490     (when path
 491       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 492         (error "You should build .elc files first."))
 493       (setq files
 494             (apply
 495              'append
 496              (mapcar
 497               (lambda (el)
 498                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 499               (append
 500                (list (file-name-nondirectory dgnushack-gnus-load-file)
 501                      (file-name-nondirectory dgnushack-cus-load-file))
 502                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 503       (while path
 504         (setq shadows files)
 505         (while shadows
 506           (setq file (expand-file-name (pop shadows) (car path)))
 507           (when (file-exists-p file)
 508             (princ (concat "  Removing " file "..."))
 509             (condition-case nil
 510                 (progn
 511                   (delete-file file)
 512                   (princ "done\n"))
 513               (error (princ "failed\n")))))
 514         (setq path (cdr path))))))
 515
 516 ;;; dgnushack.el ends here
 517
 518 ;;; arch-tag: 579f585a-24eb-4e1c-8d34-4808e11b68f2