cgit.sxemacs.org Git - gnus/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36 (require 'iswitchb)
  37
  38 (condition-case nil
  39     (require 'org-entities)
  40   (error nil))
  41
  42 (defvar srcdir (or (getenv "srcdir") "."))
  43 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  44
  45 (defun my-getenv (str)
  46   (let ((val (getenv str)))
  47     (if (equal val "no") nil val)))
  48
  49 (if (my-getenv "lispdir")
  50     (push (my-getenv "lispdir") load-path))
  51
  52 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  53       load-path)
  54
  55 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  56       load-path)
  57
  58 ;(push "/usr/share/emacs/site-lisp" load-path)
  59
  60 ;; If we are building w3 in a different directory than the source
  61 ;; directory, we must read *.el from source directory and write *.elc
  62 ;; into the building directory.  For that, we define this function
  63 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  64 (defun byte-compile-dest-file (filename)
  65   "Convert an Emacs Lisp source file name to a compiled file name.
  66  In addition, remove directory name part from FILENAME."
  67   (setq filename (byte-compiler-base-file-name filename))
  68   (setq filename (file-name-sans-versions filename))
  69   (setq filename (file-name-nondirectory filename))
  70   (if (eq system-type 'windows-nt)
  71       (setq filename (downcase filename)))
  72   (cond ((eq system-type 'vax-vms)
  73          (concat (substring filename 0 (string-match ";" filename)) "c"))
  74         ((string-match emacs-lisp-file-regexp filename)
  75          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  76         (t (concat filename ".elc"))))
  77
  78 (require 'bytecomp)
  79 ;; To avoid having defsubsts and inlines happen.
  80 ;(if (featurep 'xemacs)
  81 ;    (require 'byte-optimize)
  82 ;  (require 'byte-opt))
  83 ;(defun byte-optimize-inline-handler (form)
  84 ;  "byte-optimize-handler for the `inline' special-form."
  85 ;  (cons 'progn (cdr form)))
  86 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  87
  88 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
  89 ;; following threads:
  90 ;;
  91 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
  92 ;; Subject: attachment problems found but not fixed
  93 ;;
  94 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
  95 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
  96 ;;
  97 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
  98 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
  99 ;;
 100 ;; Should be fixed in XEmacs (March 2007).
 101 ;; http://thread.gmane.org/gmane.emacs.xemacs.patches/8124
 102 ;; When should we remove this workaround?
 103 ;;
 104 (when (and (featurep 'xemacs)
 105            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 106              (modify-syntax-entry ?= " " table)
 107              (with-temp-buffer
 108                (with-syntax-table table
 109                  (insert "foo=bar")
 110                  (goto-char (point-min))
 111                  (forward-sexp 1)
 112                  (eolp)))))
 113   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 114   ;; doesn't seem to copy modified syntax entries in old XEmacs 21.5.
 115   (defmacro with-syntax-table (syntab &rest body)
 116     "Evaluate BODY with the SYNTAB as the current syntax table."
 117     `(let ((stab (syntax-table)))
 118        (unwind-protect
 119            (progn
 120              ;;(set-syntax-table (copy-syntax-table ,syntab))
 121              (set-syntax-table ,syntab)
 122              ,@body)
 123          (set-syntax-table stab)))))
 124
 125 (push srcdir load-path)
 126 (push loaddir load-path)
 127 (load (expand-file-name "lpath.el" loaddir) nil t)
 128
 129 (defalias 'device-sound-enabled-p 'ignore)
 130 (defalias 'play-sound-file 'ignore)
 131 (defalias 'efs-re-read-dir 'ignore)
 132 (defalias 'ange-ftp-re-read-dir 'ignore)
 133 (defalias 'define-mail-user-agent 'ignore)
 134
 135 (eval-and-compile
 136   (unless (featurep 'xemacs)
 137     (defalias 'get-popup-menu-response 'ignore)
 138     (defalias 'event-object 'ignore)
 139     (autoload 'iswitchb-read-buffer "iswitchb")
 140     (autoload 'netrc-credentials "netrc")
 141     (defalias 'x-defined-colors 'ignore)
 142     (defalias 'read-color 'ignore)))
 143
 144 (eval-and-compile
 145   (when (featurep 'xemacs)
 146     (unless (fboundp 'defadvice)
 147       (autoload 'defadvice "advice" nil nil 'macro))
 148     (autoload 'Info-directory "info" nil t)
 149     (autoload 'Info-index "info" nil t)
 150     (autoload 'Info-index-next "info" nil t)
 151     (autoload 'Info-menu "info" nil t)
 152     (autoload 'ad-add-advice "advice")
 153     (unless (and (emacs-version>= 21 5)
 154                  (not (featurep 'sxemacs)))
 155       ;; calendar/auto-autoloads.el provides it.
 156       (autoload 'add-to-invisibility-spec "dummy"))
 157     (autoload 'annotations-at "annotations")
 158     (autoload 'apropos "apropos" nil t)
 159     (autoload 'apropos-command "apropos" nil t)
 160     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 161     (autoload 'browse-url "browse-url" nil t)
 162     (autoload 'browse-url-of-file "browse-url" nil t)
 163     (autoload 'c-mode "cc-mode" nil t)
 164     (autoload 'customize-apropos "cus-edit" nil t)
 165     (autoload 'customize-group "cus-edit" nil t)
 166     (autoload 'customize-save-variable "cus-edit" nil t)
 167     (autoload 'customize-set-variable "cus-edit" nil t)
 168     (autoload 'customize-variable "cus-edit" nil t)
 169     (autoload 'debug "debug" nil t)
 170     (if (featurep 'mule)
 171         (unless (locate-library "mule-ccl")
 172           (autoload 'define-ccl-program "ccl" nil nil 'macro))
 173       (defalias 'define-ccl-program 'ignore))
 174     (autoload 'delete-annotation "annotations")
 175     (autoload 'dolist "cl-macs" nil nil 'macro)
 176     (autoload 'enriched-decode "enriched")
 177     (autoload 'eudc-expand-inline "eudc" nil t)
 178     (autoload 'executable-find "executable")
 179     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 180     (when (and (emacs-version>= 21 5)
 181                (not (featurep 'sxemacs)))
 182       (autoload 'get-display-table "disp-table")
 183       (autoload 'put-display-table "disp-table"))
 184     (autoload 'info "info" nil t)
 185     (autoload 'mail-extract-address-components "mail-extr")
 186     (autoload 'mail-fetch-field "mail-utils")
 187     (autoload 'make-annotation "annotations")
 188     (autoload 'make-display-table "disp-table")
 189     (autoload 'pgg-snarf-keys-region "pgg" nil t)
 190     (autoload 'pp "pp")
 191     (autoload 'ps-despool "ps-print" nil t)
 192     (autoload 'ps-spool-buffer "ps-print" nil t)
 193     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 194     (autoload 'read-passwd "passwd")
 195     (autoload 'regexp-opt "regexp-opt")
 196     (autoload 'reporter-submit-bug-report "reporter")
 197     (if (condition-case nil
 198             (progn
 199               (require 'rot13)
 200               (not (fboundp 'rot13-string)))
 201           (error nil))
 202         (defmacro rot13-string (string)
 203           "Return ROT13 encryption of STRING."
 204           `(with-temp-buffer
 205              (insert ,string)
 206              (translate-region (point-min) (point-max) ,rot13-display-table)
 207              (buffer-string))))
 208     (if (and (emacs-version>= 21 5)
 209              (not (featurep 'sxemacs)))
 210         (autoload 'setenv "process" nil t)
 211       (autoload 'setenv "env" nil t))
 212     (autoload 'sgml-mode "psgml" nil t)
 213     (autoload 'smtpmail-send-it "smtpmail")
 214     (autoload 'sort-numeric-fields "sort" nil t)
 215     (autoload 'sort-subr "sort")
 216     (autoload 'thing-at-point "thingatpt")
 217     (autoload 'toggle-truncate-lines "view-less" nil t)
 218     (autoload 'trace-function-background "trace" nil t)
 219     (autoload 'unmorse-region "morse" nil t)
 220     (autoload 'w3-do-setup "w3")
 221     (autoload 'w3-prepare-buffer "w3-display")
 222     (autoload 'w3-region "w3-display" nil t)
 223     (defalias 'frame-char-height 'frame-height)
 224     (defalias 'frame-char-width 'frame-width)
 225     (defalias 'frame-parameter 'frame-property)
 226     (defalias 'make-overlay 'ignore)
 227     (defalias 'overlay-end 'ignore)
 228     (defalias 'overlay-get 'ignore)
 229     (defalias 'overlay-put 'ignore)
 230     (defalias 'overlay-start 'ignore)
 231     (defalias 'overlays-in 'ignore)
 232     (defalias 'replace-dehighlight 'ignore)
 233     (defalias 'replace-highlight 'ignore)
 234     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 235
 236 (defun dgnushack-emacs-compile-defcustom-p ()
 237   "Return non-nil if Emacs byte compiles `defcustom' forms.
 238 Those Emacsen will warn against undefined variables and functions used
 239 in `defcustom' forms."
 240   (let ((outbuf (with-temp-buffer
 241                   (insert "(defcustom foo (1+ (random)) \"\" :group 'emacs)\n")
 242                   (byte-compile-from-buffer (current-buffer) "foo.el"))))
 243     (when outbuf
 244       (prog1
 245           (with-current-buffer outbuf
 246             (goto-char (point-min))
 247             (search-forward " 'foo '(byte-code " nil t))
 248         (kill-buffer outbuf)))))
 249
 250 (when (dgnushack-emacs-compile-defcustom-p)
 251   (maybe-fbind '(defined-colors face-attribute))
 252   (maybe-bind '(idna-program installation-directory)))
 253
 254 (when (featurep 'xemacs)
 255   (defadvice byte-optimize-apply (before use-mapcan (form) activate)
 256     "Replace (apply 'nconc (mapcar ...)) with (mapcan ...)."
 257     (let ((last (nth (1- (length form)) form)))
 258       (when (and (eq last (third form))
 259                  (consp last)
 260                  (eq 'mapcar (car last))
 261                  (equal (nth 1 form) ''nconc))
 262         (setq form (cons 'mapcan (cdr last)))))))
 263
 264 (defun dgnushack-compile-verbosely ()
 265   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 266 patches to gnus, you should consider modifying make.bat to call
 267 dgnushack-compile-verbosely.  All other users should continue to use
 268 dgnushack-compile."
 269   (dgnushack-compile t))
 270
 271 (defun dgnushack-compile (&optional warn)
 272   ;;(setq byte-compile-dynamic t)
 273   (unless warn
 274     (setq byte-compile-warnings
 275           '(free-vars unresolved callargs redefine suspicious)))
 276   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 277         ;;(byte-compile-generate-call-tree t)
 278         file elc)
 279     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 280     ;; installed.
 281     (when (featurep 'xemacs)
 282       (setq gnus-xmas-glyph-directory "dummy"))
 283     (dolist (file '(".dir-locals.el" "dgnushack.el" "lpath.el"))
 284       (setq files (delete file files)))
 285     (when (featurep 'base64)
 286       (setq files (delete "base64.el" files)))
 287     (condition-case code
 288         (require 'w3-parse)
 289       (error
 290        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 291        (dolist (file '("webmail.el" "nnwfm.el"))
 292          (setq files (delete file files)))))
 293     (condition-case code
 294         ;; Under XEmacs 21.4 this loads easy-mmode.elc that provides
 295         ;; the Emacs functions `propertize' and `replace-regexp-in-string'.
 296         (require 'mh-e)
 297       (error
 298        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 299        (setq files (delete "gnus-mh.el" files))))
 300     (condition-case code
 301         (require 'xml)
 302       (error
 303        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 304        (setq files (delete "nnrss.el" files))))
 305     (dolist (file
 306              (if (featurep 'xemacs)
 307                  '("md5.el")
 308                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 309       (setq files (delete file files)))
 310     (unless (and (fboundp 'libxml-parse-html-region)
 311                  ;; lpath.el binds it.
 312                  (not (eq (symbol-function 'libxml-parse-html-region)
 313                           'ignore)))
 314       (setq files (delete "shr-color.el" (delete "shr.el" files))))
 315
 316     (dolist (file files)
 317       (setq file (expand-file-name file srcdir))
 318       (when (and (file-exists-p
 319                   (setq elc (concat (file-name-nondirectory file) "c")))
 320                  (file-newer-than-file-p file elc))
 321         (delete-file elc)))
 322
 323     (while (setq file (pop files))
 324       (setq file (expand-file-name file srcdir))
 325       (when (or (not (file-exists-p
 326                       (setq elc (concat (file-name-nondirectory file) "c"))))
 327                 (file-newer-than-file-p file elc))
 328         (ignore-errors
 329           (byte-compile-file file))))))
 330
 331 (defun dgnushack-recompile ()
 332   (require 'gnus)
 333   (byte-recompile-directory "." 0))
 334
 335 (defvar dgnushack-gnus-load-file
 336   (if (featurep 'xemacs)
 337       (expand-file-name "auto-autoloads.el")
 338     (expand-file-name "gnus-load.el")))
 339
 340 (defvar dgnushack-cus-load-file
 341   (if (featurep 'xemacs)
 342       (expand-file-name "custom-load.el")
 343     (expand-file-name "cus-load.el")))
 344
 345 (defun dgnushack-make-cus-load ()
 346   (load "cus-dep")
 347   (let ((cusload-base-file dgnushack-cus-load-file))
 348     (defadvice directory-files (after exclude-dir-locals activate)
 349       "Exclude .dir-locals.el file."
 350       (dolist (file ad-return-value)
 351         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 352             (setq ad-return-value (delete file ad-return-value)))))
 353     (unwind-protect
 354         (if (fboundp 'custom-make-dependencies)
 355             (custom-make-dependencies)
 356           (Custom-make-dependencies))
 357       (ad-unadvise 'directory-files))
 358     (when (featurep 'xemacs)
 359       (message "Compiling %s..." dgnushack-cus-load-file)
 360       (byte-compile-file dgnushack-cus-load-file))))
 361
 362 (defun dgnushack-make-auto-load ()
 363   (require 'autoload)
 364   (let ((generated-autoload-file dgnushack-gnus-load-file)
 365         (make-backup-files nil)
 366         (autoload-package-name "gnus"))
 367     (if (featurep 'xemacs)
 368         (if (file-exists-p generated-autoload-file)
 369             (delete-file generated-autoload-file))
 370       (with-temp-file generated-autoload-file
 371         (insert ?\014)))
 372     (defadvice directory-files (after exclude-dir-locals activate)
 373       "Exclude .dir-locals.el file."
 374       (dolist (file ad-return-value)
 375         (if (string-match "\\(?:\\`\\|/\\)\\.dir-locals\\.el\\'" file)
 376             (setq ad-return-value (delete file ad-return-value)))))
 377     (unwind-protect
 378         (batch-update-autoloads)
 379       (ad-unadvise 'directory-files))))
 380
 381 (defun dgnushack-make-load ()
 382   (unless (featurep 'xemacs)
 383     (message "Generating %s..." dgnushack-gnus-load-file)
 384     (with-temp-file dgnushack-gnus-load-file
 385       (insert-file-contents dgnushack-cus-load-file)
 386       (delete-file dgnushack-cus-load-file)
 387       (goto-char (point-min))
 388       (search-forward ";;; Code:")
 389       (forward-line)
 390       (delete-region (point-min) (point))
 391       (insert "\
 392 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 393 ;;
 394 ;;; Code:
 395 ")
 396       (goto-char (point-max))
 397       (if (search-backward "custom-versions-load-alist" nil t)
 398           (forward-line -1)
 399         (forward-line -1)
 400         (while (eq (char-after) ?\;)
 401           (forward-line -1))
 402         (forward-line))
 403       (delete-region (point) (point-max))
 404       (insert "\n")
 405       ;; smiley-* are duplicated. Remove them all.
 406       (let ((point (point)))
 407         (insert-file-contents dgnushack-gnus-load-file)
 408         (goto-char point)
 409         (while (search-forward "smiley-" nil t)
 410           (beginning-of-line)
 411           (if (looking-at "(autoload ")
 412               (delete-region (point) (progn (forward-sexp) (point)))
 413             (forward-line))))
 414       ;;
 415       (goto-char (point-max))
 416       (when (search-backward "\n(provide " nil t)
 417         (forward-line -1)
 418         (delete-region (point) (point-max)))
 419       (insert "\
 420
 421 \(provide 'gnus-load)
 422
 423 ;;; Local Variables:
 424 ;;; version-control: never
 425 ;;; no-byte-compile: t
 426 ;;; no-update-autoloads: t
 427 ;;; End:
 428 ;;; gnus-load.el ends here
 429 ")
 430       ))
 431   (message "Compiling %s..." dgnushack-gnus-load-file)
 432   (byte-compile-file dgnushack-gnus-load-file)
 433   (when (featurep 'xemacs)
 434     (message "Creating dummy gnus-load.el...")
 435     (with-temp-file (expand-file-name "gnus-load.el")
 436       (insert "\
 437
 438 \(provide 'gnus-load)
 439
 440 ;;; Local Variables:
 441 ;;; version-control: never
 442 ;;; no-byte-compile: t
 443 ;;; no-update-autoloads: t
 444 ;;; End:
 445 ;;; gnus-load.el ends here"))))
 446
 447 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 448   "Return a list of directories in which other Gnus installations exist.
 449 This function looks for the other Gnus installations which will shadow
 450 the new Gnus Lisp modules which have been installed in LISPDIR, using
 451 the default `load-path'.  The return value will make sense only when
 452 LISPDIR is existent and is listed in the default `load-path'.  Assume
 453 LISPDIR will be prepended to `load-path' by a user if the default
 454 `load-path' does not contain it."
 455   (unless lispdir
 456     (setq lispdir (getenv "lispdir")))
 457   (when (and lispdir (file-directory-p lispdir))
 458     (setq lispdir (file-truename (directory-file-name lispdir)))
 459     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 460                      "message.elc" "message.el" "message.el.bz2"
 461                      "message.el.gz"))
 462           (path (delq nil (mapcar
 463                            (lambda (p)
 464                              (condition-case nil
 465                                  (when (and p (file-directory-p p))
 466                                    (file-truename (directory-file-name p)))
 467                                (error nil)))
 468                            dgnushack-default-load-path)))
 469           rest elcs)
 470       (while path
 471         (setq rest (cons (car path) rest)
 472               path (delete (car rest) (cdr path))))
 473       (setq path (nreverse (cdr (member lispdir rest)))
 474             rest nil)
 475       (while path
 476         (setq elcs indices)
 477         (while elcs
 478           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 479             (setq rest (cons (car path) rest)
 480                   elcs nil)))
 481         (setq path (cdr path)))
 482       (prog1
 483           (setq path (nreverse rest))
 484         (when path
 485           (let (print-level print-length)
 486             (princ (concat "\n\
 487 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 488  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 489 You will need to modify the run-time `load-path', remove them manually,
 490 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 491
 492 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 493   "Remove the other Gnus installations which shadow the recent one."
 494   (let ((path (with-temp-buffer
 495                 (let ((standard-output (current-buffer)))
 496                   (dgnushack-find-lisp-shadows lispdir))))
 497         elcs files shadows file)
 498     (when path
 499       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 500         (error "You should build .elc files first."))
 501       (setq files
 502             (apply
 503              'append
 504              (mapcar
 505               (lambda (el)
 506                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 507               (append
 508                (list (file-name-nondirectory dgnushack-gnus-load-file)
 509                      (file-name-nondirectory dgnushack-cus-load-file))
 510                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 511       (while path
 512         (setq shadows files)
 513         (while shadows
 514           (setq file (expand-file-name (pop shadows) (car path)))
 515           (when (file-exists-p file)
 516             (princ (concat "  Removing " file "..."))
 517             (condition-case nil
 518                 (progn
 519                   (delete-file file)
 520                   (princ "done\n"))
 521               (error (princ "failed\n")))))
 522         (setq path (cdr path))))))
 523
 524 ;;; dgnushack.el ends here