cgit.sxemacs.org Git - gnus/blob - lisp/color-lab.el

   1 ;;; color-lab.el --- Color manipulation laboratory routines -*- coding: utf-8; -*-
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package provides color manipulation functions.
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl))
  31
  32 ;; Emacs < 23.3
  33 (eval-and-compile
  34   (unless (boundp 'float-pi)
  35     (defconst float-pi (* 4 (atan 1)) "The value of Pi (3.1415926...).")))
  36
  37 (defun rgb->hsv (red green blue)
  38   "Convert RED GREEN BLUE values to HSV representation.
  39 Hue is in radian. Saturation and values are between 0 and 1."
  40    (let* ((r (float red))
  41          (g (float green))
  42          (b (float blue))
  43          (max (max r g b))
  44          (min (min r g b)))
  45      (list
  46       (/ (* 2 float-pi
  47             (cond ((and (= r g) (= g b)) 0)
  48                   ((and (= r max)
  49                         (>= g b))
  50                    (* 60 (/ (- g b) (- max min))))
  51                   ((and (= r max)
  52                         (< g b))
  53                    (+ 360 (* 60 (/ (- g b) (- max min)))))
  54                   ((= max g)
  55                    (+ 120 (* 60 (/ (- b r) (- max min)))))
  56                   ((= max b)
  57                        (+ 240 (* 60 (/ (- r g) (- max min)))))))
  58          360)
  59       (if (= max 0)
  60           0
  61         (- 1 (/ min max)))
  62       (/ max 255.0))))
  63
  64 (defun rgb->hsl (red green blue)
  65   "Convert RED GREEN BLUE colors to their HSL representation.
  66 RED, GREEN and BLUE must be between 0 and 255."
  67   (let* ((r (/ red 255.0))
  68          (g (/ green 255.0))
  69          (b (/ blue 255.0))
  70          (max (max r g b))
  71          (min (min r g b))
  72          (delta (- max min))
  73          (l (/ (+ max min) 2.0)))
  74     (list
  75      (if (= max min)
  76          0
  77        (* 2 float-pi
  78           (/ (cond ((= max r)
  79                     (+ (/ (- g b) delta) (if (< g b) 6 0)))
  80                    ((= max g)
  81                  (+ (/ (- b r) delta) 2))
  82                    (t
  83                     (+ (/ (- r g) delta) 4)))
  84              6)))
  85      (if (= max min)
  86          0
  87        (if (> l 0.5)
  88            (/ delta (- 2 (+ max min)))
  89          (/ delta (+ max min))))
  90      l)))
  91
  92 (defun rgb->xyz (red green blue)
  93   "Converts RED GREEN BLUE colors to CIE XYZ representation.
  94 RED, BLUE and GREEN must be between 0 and 1."
  95   (let ((r (if (<= red 0.04045)
  96                (/ red 12.95)
  97              (expt (/ (+ red 0.055) 1.055) 2.4)))
  98         (g (if (<= green 0.04045)
  99                (/ green 12.95)
 100              (expt (/ (+ green 0.055) 1.055) 2.4)))
 101         (b (if (<= blue 0.04045)
 102                (/ blue 12.95)
 103              (expt (/ (+ blue 0.055) 1.055) 2.4))))
 104     (list (+ (* 0.4124564 r) (* 0.3575761 g) (* 0.1804375 b))
 105           (+ (* 0.21266729 r) (* 0.7151522 g) (* 0.0721750 b))
 106           (+ (* 0.0193339 r) (* 0.1191920 g) (* 0.9503041 b)))))
 107
 108 (defun xyz->rgb (X Y Z)
 109   "Converts CIE XYZ colors to RGB."
 110   (let ((r (+ (* 3.2404542 X) (* -1.5371385 Y) (* -0.4985314 Z)))
 111         (g (+ (* -0.9692660 X) (* 1.8760108 Y) (* 0.0415560 Z)))
 112         (b (+ (* 0.0556434 X) (* -0.2040259 Y) (* 1.0572252 Z))))
 113     (list (if (<= r 0.0031308)
 114               (* 12.92 r)
 115             (- (* 1.055 (expt r (/ 1 2.4))) 0.055))
 116           (if (<= g 0.0031308)
 117               (* 12.92 g)
 118             (- (* 1.055 (expt g (/ 1 2.4))) 0.055))
 119           (if (<= b 0.0031308)
 120               (* 12.92 b)
 121             (- (* 1.055 (expt b (/ 1 2.4))) 0.055)))))
 122
 123 (defconst color-lab-d65-xyz '(0.950455 1.0 1.088753)
 124   "D65 white point in CIE XYZ.")
 125
 126 (defconst color-lab-ε (/ 216 24389.0))
 127 (defconst color-lab-κ (/ 24389 27.0))
 128
 129 (defun xyz->lab (X Y Z &optional white-point)
 130   "Converts CIE XYZ to CIE L*a*b*.
 131 WHITE-POINT can be specified as (X Y Z) white point to use. If
 132 none is set, `color-lab-d65-xyz' is used."
 133   (destructuring-bind (Xr Yr Zr) (or white-point color-lab-d65-xyz)
 134       (let* ((xr (/ X Xr))
 135              (yr (/ Y Yr))
 136              (zr (/ Z Zr))
 137              (fx (if (> xr color-lab-ε)
 138                      (expt xr (/ 1 3.0))
 139                    (/ (+ (* color-lab-κ xr) 16) 116.0)))
 140              (fy (if (> yr color-lab-ε)
 141                      (expt yr (/ 1 3.0))
 142                    (/ (+ (* color-lab-κ yr) 16) 116.0)))
 143              (fz (if (> zr color-lab-ε)
 144                      (expt zr (/ 1 3.0))
 145                    (/ (+ (* color-lab-κ zr) 16) 116.0))))
 146         (list
 147          (- (* 116 fy) 16)                  ; L
 148          (* 500 (- fx fy))                  ; a
 149          (* 200 (- fy fz))))))              ; b
 150
 151 (defun lab->xyz (L a b &optional white-point)
 152   "Converts CIE L*a*b* to CIE XYZ.
 153 WHITE-POINT can be specified as (X Y Z) white point to use. If
 154 none is set, `color-lab-d65-xyz' is used."
 155   (destructuring-bind (Xr Yr Zr) (or white-point color-lab-d65-xyz)
 156       (let* ((fy (/ (+ L 16) 116.0))
 157              (fz (- fy (/ b 200.0)))
 158              (fx (+ (/ a 500.0) fy))
 159              (xr (if (> (expt fx 3.0) color-lab-ε)
 160                      (expt fx 3.0)
 161                (/ (- (* fx 116) 16) color-lab-κ)))
 162              (yr (if (> L (* color-lab-κ color-lab-ε))
 163                      (expt (/ (+ L 16) 116.0) 3.0)
 164                    (/ L color-lab-κ)))
 165              (zr (if (> (expt fz 3) color-lab-ε)
 166                      (expt fz 3.0)
 167                    (/ (- (* 116 fz) 16) color-lab-κ))))
 168         (list (* xr Xr)                 ; X
 169               (* yr Yr)                 ; Y
 170               (* zr Zr)))))             ; Z
 171
 172 (defun rgb->lab (red green blue)
 173   "Converts RGB to CIE L*a*b*."
 174   (apply 'xyz->lab (rgb->xyz red green blue)))
 175
 176 (defun rgb->normalize (color)
 177   "Normalize a RGB color to values between [0,1]."
 178   (mapcar (lambda (x) (/ x 65535.0)) (x-color-values color)))
 179
 180 (defun lab->rgb (L a b)
 181   "Converts CIE L*a*b* to RGB."
 182   (apply 'xyz->rgb (lab->xyz L a b)))
 183
 184 (defun color-lab-ciede2000 (color1 color2 &optional kL kC kH)
 185   "Computes the CIEDE2000 color distance between COLOR1 and COLOR2.
 186 Colors must be in CIE L*a*b* format."
 187   (destructuring-bind (L₁ a₁ b₁) color1
 188     (destructuring-bind (L₂ a₂ b₂) color2
 189       (let* ((kL (or kL 1))
 190              (kC (or kC 1))
 191              (kH (or kH 1))
 192              (C₁ (sqrt (+ (expt a₁ 2.0) (expt b₁ 2.0))))
 193              (C₂ (sqrt (+ (expt a₂ 2.0) (expt b₂ 2.0))))
 194              (C̄ (/ (+ C₁ C₂) 2.0))
 195              (G (* 0.5 (- 1 (sqrt (/ (expt C̄ 7.0) (+ (expt C̄ 7.0) (expt 25 7.0)))))))
 196              (a′₁ (* (+ 1 G) a₁))
 197              (a′₂ (* (+ 1 G) a₂))
 198              (C′₁ (sqrt (+ (expt a′₁ 2.0) (expt b₁ 2.0))))
 199              (C′₂ (sqrt (+ (expt a′₂ 2.0) (expt b₂ 2.0))))
 200              (h′₁ (if (and (= b₁ 0) (= a′₁ 0))
 201                       0
 202                     (let ((v (atan b₁ a′₁)))
 203                       (if (< v 0)
 204                           (+ v (* 2 float-pi))
 205                         v))))
 206              (h′₂ (if (and (= b₂ 0) (= a′₂ 0))
 207                       0
 208                     (let ((v (atan b₂ a′₂)))
 209                       (if (< v 0)
 210                           (+ v (* 2 float-pi))
 211                         v))))
 212              (ΔL′ (- L₂ L₁))
 213              (ΔC′ (- C′₂ C′₁))
 214              (Δh′ (cond ((= (* C′₁ C′₂) 0)
 215                          0)
 216                         ((<= (abs (- h′₂ h′₁)) float-pi)
 217                          (- h′₂ h′₁))
 218                         ((> (- h′₂ h′₁) float-pi)
 219                          (- (- h′₂ h′₁) (* 2 float-pi)))
 220                         ((< (- h′₂ h′₁) (- float-pi))
 221                          (+ (- h′₂ h′₁) (* 2 float-pi)))))
 222              (ΔH′ (* 2 (sqrt (* C′₁ C′₂)) (sin (/ Δh′ 2.0))))
 223              (L̄′ (/ (+ L₁ L₂) 2.0))
 224              (C̄′ (/ (+ C′₁ C′₂) 2.0))
 225              (h̄′ (cond ((= (* C′₁ C′₂) 0)
 226                         (+ h′₁ h′₂))
 227                        ((<= (abs (- h′₁ h′₂)) float-pi)
 228                         (/ (+ h′₁ h′₂) 2.0))
 229                        ((< (+ h′₁ h′₂) (* 2 float-pi))
 230                         (/ (+ h′₁ h′₂ (* 2 float-pi)) 2.0))
 231                        ((>= (+ h′₁ h′₂) (* 2 float-pi))
 232                         (/ (+ h′₁ h′₂ (* -2 float-pi)) 2.0))))
 233              (T (+ 1
 234                    (- (* 0.17 (cos (- h̄′ (degrees-to-radians 30)))))
 235                    (* 0.24 (cos (* h̄′ 2)))
 236                    (* 0.32 (cos (+ (* h̄′ 3) (degrees-to-radians 6))))
 237                    (- (* 0.20 (cos (- (* h̄′ 4) (degrees-to-radians 63)))))))
 238              (Δθ (* (degrees-to-radians 30) (exp (- (expt (/ (- h̄′ (degrees-to-radians 275)) (degrees-to-radians 25)) 2.0)))))
 239              (Rc (* 2 (sqrt (/ (expt C̄′ 7.0) (+ (expt C̄′ 7.0) (expt 25.0 7.0))))))
 240              (Sl (+ 1 (/ (* 0.015 (expt (- L̄′ 50) 2.0)) (sqrt (+ 20 (expt (- L̄′ 50) 2.0))))))
 241              (Sc (+ 1 (* C̄′ 0.045)))
 242              (Sh (+ 1 (* 0.015 C̄′ T)))
 243              (Rt (- (* (sin (* Δθ 2)) Rc))))
 244         (sqrt (+ (expt (/ ΔL′ (* Sl kL)) 2.0)
 245                  (expt (/ ΔC′ (* Sc kC)) 2.0)
 246                  (expt (/ ΔH′ (* Sh kH)) 2.0)
 247                  (* Rt (/ ΔC′ (* Sc kC)) (/ ΔH′ (* Sh kH)))))))))
 248
 249 (provide 'color-lab)
 250
 251 ;;; color-lab.el ends here