cgit.sxemacs.org Git - gnus/blob - lisp/color-lab.el

   1 ;;; color-lab.el --- Color manipulation laboratory routines
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: html
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package provides color manipulation functions.
  26
  27 ;;; Code:
  28
  29 (defun rgb->hsv (red green blue)
  30   "Convert RED GREEN BLUE values to HSV representation.
  31 Hue is in radian. Saturation and values are between 0 and 1."
  32    (let* ((r (float red))
  33          (g (float green))
  34          (b (float blue))
  35          (max (max r g b))
  36          (min (min r g b)))
  37      (list
  38       (/ (* 2 float-pi
  39             (cond ((and (= r g) (= g b)) 0)
  40                   ((and (= r max)
  41                         (>= g b))
  42                    (* 60 (/ (- g b) (- max min))))
  43                   ((and (= r max)
  44                         (< g b))
  45                    (+ 360 (* 60 (/ (- g b) (- max min)))))
  46                   ((= max g)
  47                    (+ 120 (* 60 (/ (- b r) (- max min)))))
  48                   ((= max b)
  49                        (+ 240 (* 60 (/ (- r g) (- max min)))))))
  50          360)
  51       (if (= max 0)
  52           0
  53         (- 1 (/ min max)))
  54       (/ max 255.0))))
  55
  56 (defun rgb->hsl (red green blue)
  57   "Convert RED GREEN BLUE colors to their HSL representation.
  58 RED, GREEN and BLUE must be between 0 and 255."
  59   (let* ((r (/ red 255.0))
  60          (g (/ green 255.0))
  61          (b (/ blue 255.0))
  62          (max (max r g b))
  63          (min (min r g b))
  64          (delta (- max min))
  65          (l (/ (+ max min) 2.0)))
  66     (list
  67      (if (= max min)
  68          0
  69        (* 2 float-pi
  70           (/ (cond ((= max r)
  71                     (+ (/ (- g b) delta) (if (< g b) 6 0)))
  72                    ((= max g)
  73                  (+ (/ (- b r) delta) 2))
  74                    (t
  75                     (+ (/ (- r g) delta) 4)))
  76              6)))
  77      (if (= max min)
  78          0
  79        (if (> l 0.5)
  80            (/ delta (- 2 (+ max min)))
  81          (/ delta (+ max min))))
  82      l)))
  83
  84 (defun rgb->xyz (red green blue)
  85   "Converts RED GREEN BLUE colors to CIE XYZ representation.
  86 RED, BLUE and GREEN must be between 0 and 1."
  87   (let ((r (if (<= red 0.04045)
  88                (/ red 12.95)
  89              (expt (/ (+ red 0.055) 1.055) 2.4)))
  90         (g (if (<= green 0.04045)
  91                (/ green 12.95)
  92              (expt (/ (+ green 0.055) 1.055) 2.4)))
  93         (b (if (<= blue 0.04045)
  94                (/ blue 12.95)
  95              (expt (/ (+ blue 0.055) 1.055) 2.4))))
  96     (list (+ (* 0.4124564 r) (* 0.3575761 g) (* 0.1804375 b))
  97           (+ (* 0.21266729 r) (* 0.7151522 g) (* 0.0721750 b))
  98           (+ (* 0.0193339 r) (* 0.1191920 g) (* 0.9503041 b)))))
  99
 100 (defun xyz->rgb (X Y Z)
 101   "Converts CIE XYZ colors to RGB."
 102   (let ((r (+ (* 3.2404542 X) (* -1.5371385 Y) (* -0.4985314 Z)))
 103         (g (+ (* -0.9692660 X) (* 1.8760108 Y) (* 0.0415560 Z)))
 104         (b (+ (* 0.0556434 X) (* -0.2040259 Y) (* 1.0572252 Z))))
 105     (list (if (<= r 0.0031308)
 106               (* 12.92 r)
 107             (- (* 1.055 (expt r (/ 1 2.4))) 0.055))
 108           (if (<= g 0.0031308)
 109               (* 12.92 g)
 110             (- (* 1.055 (expt g (/ 1 2.4))) 0.055))
 111           (if (<= b 0.0031308)
 112               (* 12.92 b)
 113             (- (* 1.055 (expt b (/ 1 2.4))) 0.055)))))
 114
 115 (defconst color-lab-d65-xyz '(0.950455 1.0 1.088753)
 116   "D65 white point in CIE XYZ.")
 117
 118 (defconst color-lab-ε (/ 216 24389.0))
 119 (defconst color-lab-κ (/ 24389 27.0))
 120
 121 (defun xyz->lab (X Y Z &optional white-point)
 122   "Converts CIE XYZ to CIE L*a*b*.
 123 WHITE-POINT can be specified as (X Y Z) white point to use. If
 124 none is set, `color-lab-d65-xyz' is used."
 125   (destructuring-bind (Xr Yr Zr) (or white-point color-lab-d65-xyz)
 126       (let* ((xr (/ X Xr))
 127              (yr (/ Y Yr))
 128              (zr (/ Z Zr))
 129              (fx (if (> xr color-lab-ε)
 130                      (expt xr (/ 1 3.0))
 131                    (/ (+ (* color-lab-κ xr) 16) 116.0)))
 132              (fy (if (> yr color-lab-ε)
 133                      (expt yr (/ 1 3.0))
 134                    (/ (+ (* color-lab-κ yr) 16) 116.0)))
 135              (fz (if (> zr color-lab-ε)
 136                      (expt zr (/ 1 3.0))
 137                    (/ (+ (* color-lab-κ zr) 16) 116.0))))
 138         (list
 139          (- (* 116 fy) 16)                  ; L
 140          (* 500 (- fx fy))                  ; a
 141          (* 200 (- fy fz))))))              ; b
 142
 143 (defun lab->xyz (L a b &optional white-point)
 144   "Converts CIE L*a*b* to CIE XYZ.
 145 WHITE-POINT can be specified as (X Y Z) white point to use. If
 146 none is set, `color-lab-d65-xyz' is used."
 147   (destructuring-bind (Xr Yr Zr) (or white-point color-lab-d65-xyz)
 148       (let* ((fy (/ (+ L 16) 116.0))
 149              (fz (- fy (/ b 200.0)))
 150              (fx (+ (/ a 500.0) fy))
 151              (xr (if (> (expt fx 3) color-lab-ε)
 152                      (expt fx 3)
 153                (/ (- (* fx 116) 16) color-lab-κ)))
 154              (yr (if (> L (* color-lab-κ color-lab-ε))
 155                      (expt (/ (+ L 16) 116.0) 3)
 156                    (/ L color-lab-κ)))
 157              (zr (if (> (expt fz 3) color-lab-ε)
 158                      (expt fz 3)
 159                    (/ (- (* 116 fz) 16) color-lab-κ))))
 160         (list (* xr Xr)                 ; X
 161               (* yr Yr)                 ; Y
 162               (* zr Zr)))))             ; Z
 163
 164 (defun rgb->lab (red green blue)
 165   "Converts RGB to CIE L*a*b*."
 166   (apply 'xyz->lab (rgb->xyz red green blue)))
 167
 168 (defun rgb->normalize (color)
 169   "Normalize a RGB color to values between [0,1]."
 170   (mapcar (lambda (x) (/ x 65535.0)) (x-color-values color)))
 171
 172 (defun lab->rgb (L a b)
 173   "Converts CIE L*a*b* to RGB."
 174   (apply 'xyz->rgb (lab->xyz L a b)))
 175
 176 (defun color-lab-ciede2000 (color1 color2 &optional kL kC kH)
 177   "Computes the CIEDE2000 color distance between COLOR1 and COLOR2.
 178 Colors must be in CIE L*a*b* format."
 179   (destructuring-bind (L₁ a₁ b₁) color1
 180     (destructuring-bind (L₂ a₂ b₂) color2
 181       (let* ((kL (or kL 1))
 182              (kC (or kC 1))
 183              (kH (or kH 1))
 184              (C₁ (sqrt (+ (expt a₁ 2) (expt b₁ 2))))
 185              (C₂ (sqrt (+ (expt a₂ 2) (expt b₂ 2))))
 186              (C̄ (/ (+ C₁ C₂) 2.0))
 187              (G (* 0.5 (- 1 (sqrt (/ (expt C̄ 7) (+ (expt C̄ 7) (expt 25 7)))))))
 188              (a′₁ (* (+ 1 G) a₁))
 189              (a′₂ (* (+ 1 G) a₂))
 190              (C′₁ (sqrt (+ (expt a′₁ 2) (expt b₁ 2))))
 191              (C′₂ (sqrt (+ (expt a′₂ 2) (expt b₂ 2))))
 192              (h′₁ (if (and (= b₁ 0) (= a′₁ 0))
 193                       0
 194                     (let ((v (atan b₁ a′₁)))
 195                       (if (< v 0)
 196                           (+ v (* 2 float-pi))
 197                         v))))
 198              (h′₂ (if (and (= b₂ 0) (= a′₂ 0))
 199                       0
 200                     (let ((v (atan b₂ a′₂)))
 201                       (if (< v 0)
 202                           (+ v (* 2 float-pi))
 203                         v))))
 204              (ΔL′ (- L₂ L₁))
 205              (ΔC′ (- C′₂ C′₁))
 206              (Δh′ (cond ((= (* C′₁ C′₂) 0)
 207                          0)
 208                         ((<= (abs (- h′₂ h′₁)) float-pi)
 209                          (- h′₂ h′₁))
 210                         ((> (- h′₂ h′₁) float-pi)
 211                          (- (- h′₂ h′₁) (* 2 float-pi)))
 212                         ((< (- h′₂ h′₁) (- float-pi))
 213                          (+ (- h′₂ h′₁) (* 2 float-pi)))))
 214              (ΔH′ (* 2 (sqrt (* C′₁ C′₂)) (sin (/ Δh′ 2.0))))
 215              (L̄′ (/ (+ L₁ L₂) 2.0))
 216              (C̄′ (/ (+ C′₁ C′₂) 2.0))
 217              (h̄′ (cond ((= (* C′₁ C′₂) 0)
 218                         (+ h′₁ h′₂))
 219                        ((<= (abs (- h′₁ h′₂)) float-pi)
 220                         (/ (+ h′₁ h′₂) 2.0))
 221                        ((< (+ h′₁ h′₂) (* 2 float-pi))
 222                         (/ (+ h′₁ h′₂ (* 2 float-pi)) 2.0))
 223                        ((>= (+ h′₁ h′₂) (* 2 float-pi))
 224                         (/ (+ h′₁ h′₂ (* -2 float-pi)) 2.0))))
 225              (T (+ 1
 226                    (- (* 0.17 (cos (- h̄′ (degrees-to-radians 30)))))
 227                    (* 0.24 (cos (* h̄′ 2)))
 228                    (* 0.32 (cos (+ (* h̄′ 3) (degrees-to-radians 6))))
 229                    (- (* 0.20 (cos (- (* h̄′ 4) (degrees-to-radians 63)))))))
 230              (Δθ (* (degrees-to-radians 30) (exp (- (expt (/ (- h̄′ (degrees-to-radians 275)) (degrees-to-radians 25)) 2)))))
 231              (Rc (* 2 (sqrt (/ (expt C̄′ 7) (+ (expt C̄′ 7) (expt 25 7))))))
 232              (Sl (+ 1 (/ (* 0.015 (expt (- L̄′ 50) 2)) (sqrt (+ 20 (expt (- L̄′ 50) 2))))))
 233              (Sc (+ 1 (* C̄′ 0.045)))
 234              (Sh (+ 1 (* 0.015 C̄′ T)))
 235              (Rt (- (* (sin (* Δθ 2)) Rc))))
 236         (sqrt (+ (expt (/ ΔL′ (* Sl kL)) 2)
 237                  (expt (/ ΔC′ (* Sc kC)) 2)
 238                  (expt (/ ΔH′ (* Sh kH)) 2)
 239                  (* Rt (/ ΔC′ (* Sc kC)) (/ ΔH′ (* Sh kH)))))))))
 240
 241 (provide 'color-lab)