cgit.sxemacs.org Git - gnus/blob - lisp/auth-source.el

   1 ;;; auth-source.el --- authentication sources for Gnus and Emacs
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the auth-source.el package.  It lets users tell Gnus how to
  26 ;; authenticate in a single place.  Simplicity is the goal.  Instead
  27 ;; of providing 5000 options, we'll stick to simple, easy to
  28 ;; understand options.
  29
  30 ;; See the auth.info Info documentation for details.
  31
  32 ;; TODO:
  33
  34 ;; - never decode the backend file unless it's necessary
  35 ;; - a more generic way to match backends and search backend contents
  36 ;; - absorb netrc.el and simplify it
  37 ;; - protect passwords better
  38 ;; - allow creating and changing netrc lines (not files) e.g. change a password
  39
  40 ;;; Code:
  41
  42 (require 'password-cache)
  43 (require 'mm-util)
  44 (require 'gnus-util)
  45 (require 'assoc)
  46 (eval-when-compile (require 'cl))
  47 (eval-and-compile
  48   (or (ignore-errors (require 'eieio))
  49       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  50       (ignore-errors
  51         (let ((load-path (cons (expand-file-name
  52                                 "gnus-fallback-lib/eieio"
  53                                 (file-name-directory (locate-library "gnus")))
  54                                load-path)))
  55           (require 'eieio)))
  56       (error
  57        "eieio not found in `load-path' or gnus-fallback-lib/ directory.")))
  58
  59 (autoload 'secrets-create-item "secrets")
  60 (autoload 'secrets-delete-item "secrets")
  61 (autoload 'secrets-get-alias "secrets")
  62 (autoload 'secrets-get-attributes "secrets")
  63 (autoload 'secrets-get-secret "secrets")
  64 (autoload 'secrets-list-collections "secrets")
  65 (autoload 'secrets-search-items "secrets")
  66
  67 (autoload 'rfc2104-hash "rfc2104")
  68
  69 (defvar secrets-enabled)
  70
  71 (defgroup auth-source nil
  72   "Authentication sources."
  73   :version "23.1" ;; No Gnus
  74   :group 'gnus)
  75
  76 ;;;###autoload
  77 (defcustom auth-source-cache-expiry 7200
  78   "How many seconds passwords are cached, or nil to disable
  79 expiring.  Overrides `password-cache-expiry' through a
  80 let-binding."
  81   :group 'auth-source
  82   :type '(choice (const :tag "Never" nil)
  83                  (const :tag "All Day" 86400)
  84                  (const :tag "2 Hours" 7200)
  85                  (const :tag "30 Minutes" 1800)
  86                  (integer :tag "Seconds")))
  87
  88 (defclass auth-source-backend ()
  89   ((type :initarg :type
  90          :initform 'netrc
  91          :type symbol
  92          :custom symbol
  93          :documentation "The backend type.")
  94    (source :initarg :source
  95            :type string
  96            :custom string
  97            :documentation "The backend source.")
  98    (host :initarg :host
  99          :initform t
 100          :type t
 101          :custom string
 102          :documentation "The backend host.")
 103    (user :initarg :user
 104          :initform t
 105          :type t
 106          :custom string
 107          :documentation "The backend user.")
 108    (port :initarg :port
 109          :initform t
 110          :type t
 111          :custom string
 112          :documentation "The backend protocol.")
 113    (create-function :initarg :create-function
 114                     :initform ignore
 115                     :type function
 116                     :custom function
 117                     :documentation "The create function.")
 118    (search-function :initarg :search-function
 119                     :initform ignore
 120                     :type function
 121                     :custom function
 122                     :documentation "The search function.")))
 123
 124 (defcustom auth-source-protocols '((imap "imap" "imaps" "143" "993")
 125                                    (pop3 "pop3" "pop" "pop3s" "110" "995")
 126                                    (ssh  "ssh" "22")
 127                                    (sftp "sftp" "115")
 128                                    (smtp "smtp" "25"))
 129   "List of authentication protocols and their names"
 130
 131   :group 'auth-source
 132   :version "23.2" ;; No Gnus
 133   :type '(repeat :tag "Authentication Protocols"
 134                  (cons :tag "Protocol Entry"
 135                        (symbol :tag "Protocol")
 136                        (repeat :tag "Names"
 137                                (string :tag "Name")))))
 138
 139 ;;; generate all the protocols in a format Customize can use
 140 ;;; TODO: generate on the fly from auth-source-protocols
 141 (defconst auth-source-protocols-customize
 142   (mapcar (lambda (a)
 143             (let ((p (car-safe a)))
 144               (list 'const
 145                     :tag (upcase (symbol-name p))
 146                     p)))
 147           auth-source-protocols))
 148
 149 (defvar auth-source-creation-defaults nil
 150   "Defaults for creating token values.  Usually let-bound.")
 151
 152 (defvar auth-source-creation-prompts nil
 153   "Default prompts for token values.  Usually let-bound.")
 154
 155 (make-obsolete 'auth-source-hide-passwords nil "Emacs 24.1")
 156
 157 (defcustom auth-source-save-behavior 'ask
 158   "If set, auth-source will respect it for save behavior."
 159   :group 'auth-source
 160   :version "23.2" ;; No Gnus
 161   :type `(choice
 162           :tag "auth-source new token save behavior"
 163           (const :tag "Always save" t)
 164           (const :tag "Never save" nil)
 165           (const :tag "Ask" ask)))
 166
 167 ;; TODO: make the default (setq auth-source-netrc-use-gpg-tokens `((,(if (boundp 'epa-file-auto-mode-alist-entry) (car (symbol-value 'epa-file-auto-mode-alist-entry)) "\\.gpg\\'") never) (t gpg)))
 168 ;; TODO: or maybe leave as (setq auth-source-netrc-use-gpg-tokens 'never)
 169
 170 (defcustom auth-source-netrc-use-gpg-tokens 'never
 171   "Set this to tell auth-source when to create GPG password
 172 tokens in netrc files.  It's either an alist or `never'."
 173   :group 'auth-source
 174   :version "23.2" ;; No Gnus
 175   :type `(choice
 176           (const :tag "Always use GPG password tokens" (t gpg))
 177           (const :tag "Never use GPG password tokens" never)
 178           (repeat :tag "Use a lookup list"
 179                   (list
 180                    (choice :tag "Matcher"
 181                            (const :tag "Match anything" t)
 182                            (const :tag "The EPA encrypted file extensions"
 183                                   ,(if (boundp 'epa-file-auto-mode-alist-entry)
 184                                        (car (symbol-value
 185                                              'epa-file-auto-mode-alist-entry))
 186                                      "\\.gpg\\'"))
 187                            (regexp :tag "Regular expression"))
 188                    (choice :tag "What to do"
 189                            (const :tag "Save GPG-encrypted password tokens" gpg)
 190                            (const :tag "Don't encrypt tokens" never))))))
 191
 192 (defvar auth-source-magic "auth-source-magic ")
 193
 194 (defcustom auth-source-do-cache t
 195   "Whether auth-source should cache information with `password-cache'."
 196   :group 'auth-source
 197   :version "23.2" ;; No Gnus
 198   :type `boolean)
 199
 200 (defcustom auth-source-debug nil
 201   "Whether auth-source should log debug messages.
 202
 203 If the value is nil, debug messages are not logged.
 204
 205 If the value is t, debug messages are logged with `message'.  In
 206 that case, your authentication data will be in the clear (except
 207 for passwords).
 208
 209 If the value is a function, debug messages are logged by calling
 210  that function using the same arguments as `message'."
 211   :group 'auth-source
 212   :version "23.2" ;; No Gnus
 213   :type `(choice
 214           :tag "auth-source debugging mode"
 215           (const :tag "Log using `message' to the *Messages* buffer" t)
 216           (const :tag "Log all trivia with `message' to the *Messages* buffer"
 217                  trivia)
 218           (function :tag "Function that takes arguments like `message'")
 219           (const :tag "Don't log anything" nil)))
 220
 221 (defcustom auth-sources '("~/.authinfo" "~/.authinfo.gpg" "~/.netrc")
 222   "List of authentication sources.
 223
 224 The default will get login and password information from
 225 \"~/.authinfo.gpg\", which you should set up with the EPA/EPG
 226 packages to be encrypted.  If that file doesn't exist, it will
 227 try the unencrypted version \"~/.authinfo\" and the famous
 228 \"~/.netrc\" file.
 229
 230 See the auth.info manual for details.
 231
 232 Each entry is the authentication type with optional properties.
 233
 234 It's best to customize this with `M-x customize-variable' because the choices
 235 can get pretty complex."
 236   :group 'auth-source
 237   :version "24.1" ;; No Gnus
 238   :type `(repeat :tag "Authentication Sources"
 239                  (choice
 240                   (string :tag "Just a file")
 241                   (const :tag "Default Secrets API Collection" 'default)
 242                   (const :tag "Login Secrets API Collection" "secrets:Login")
 243                   (const :tag "Temp Secrets API Collection" "secrets:session")
 244                   (list :tag "Source definition"
 245                         (const :format "" :value :source)
 246                         (choice :tag "Authentication backend choice"
 247                                 (string :tag "Authentication Source (file)")
 248                                 (list
 249                                  :tag "Secret Service API/KWallet/GNOME Keyring"
 250                                  (const :format "" :value :secrets)
 251                                  (choice :tag "Collection to use"
 252                                          (string :tag "Collection name")
 253                                          (const :tag "Default" 'default)
 254                                          (const :tag "Login" "Login")
 255                                          (const
 256                                           :tag "Temporary" "session"))))
 257                         (repeat :tag "Extra Parameters" :inline t
 258                                 (choice :tag "Extra parameter"
 259                                         (list
 260                                          :tag "Host"
 261                                          (const :format "" :value :host)
 262                                          (choice :tag "Host (machine) choice"
 263                                                  (const :tag "Any" t)
 264                                                  (regexp
 265                                                   :tag "Regular expression")))
 266                                         (list
 267                                          :tag "Protocol"
 268                                          (const :format "" :value :port)
 269                                          (choice
 270                                           :tag "Protocol"
 271                                           (const :tag "Any" t)
 272                                           ,@auth-source-protocols-customize))
 273                                         (list :tag "User" :inline t
 274                                               (const :format "" :value :user)
 275                                               (choice
 276                                                :tag "Personality/Username"
 277                                                       (const :tag "Any" t)
 278                                                       (string
 279                                                        :tag "Name")))))))))
 280
 281 (defcustom auth-source-gpg-encrypt-to t
 282   "List of recipient keys that `authinfo.gpg' encrypted to.
 283 If the value is not a list, symmetric encryption will be used."
 284   :group 'auth-source
 285   :version "24.1" ;; No Gnus
 286   :type '(choice (const :tag "Symmetric encryption" t)
 287                  (repeat :tag "Recipient public keys"
 288                          (string :tag "Recipient public key"))))
 289
 290 ;; temp for debugging
 291 ;; (unintern 'auth-source-protocols)
 292 ;; (unintern 'auth-sources)
 293 ;; (customize-variable 'auth-sources)
 294 ;; (setq auth-sources nil)
 295 ;; (format "%S" auth-sources)
 296 ;; (customize-variable 'auth-source-protocols)
 297 ;; (setq auth-source-protocols nil)
 298 ;; (format "%S" auth-source-protocols)
 299 ;; (auth-source-pick nil :host "a" :port 'imap)
 300 ;; (auth-source-user-or-password "login" "imap.myhost.com" 'imap)
 301 ;; (auth-source-user-or-password "password" "imap.myhost.com" 'imap)
 302 ;; (auth-source-user-or-password-imap "login" "imap.myhost.com")
 303 ;; (auth-source-user-or-password-imap "password" "imap.myhost.com")
 304 ;; (auth-source-protocol-defaults 'imap)
 305
 306 ;; (let ((auth-source-debug 'debug)) (auth-source-do-debug "hello"))
 307 ;; (let ((auth-source-debug t)) (auth-source-do-debug "hello"))
 308 ;; (let ((auth-source-debug nil)) (auth-source-do-debug "hello"))
 309 (defun auth-source-do-debug (&rest msg)
 310   (when auth-source-debug
 311     (apply 'auth-source-do-warn msg)))
 312
 313 (defun auth-source-do-trivia (&rest msg)
 314   (when (or (eq auth-source-debug 'trivia)
 315             (functionp auth-source-debug))
 316     (apply 'auth-source-do-warn msg)))
 317
 318 (defun auth-source-do-warn (&rest msg)
 319   (apply
 320     ;; set logger to either the function in auth-source-debug or 'message
 321     ;; note that it will be 'message if auth-source-debug is nil
 322    (if (functionp auth-source-debug)
 323        auth-source-debug
 324      'message)
 325    msg))
 326
 327
 328 ;;; (auth-source-read-char-choice "enter choice? " '(?a ?b ?q))
 329 (defun auth-source-read-char-choice (prompt choices)
 330   "Read one of CHOICES by `read-char-choice', or `read-char'.
 331 `dropdown-list' support is disabled because it doesn't work reliably.
 332 Only one of CHOICES will be returned.  The PROMPT is augmented
 333 with \"[a/b/c] \" if CHOICES is '\(?a ?b ?c\)."
 334   (when choices
 335     (let* ((prompt-choices
 336             (apply 'concat (loop for c in choices
 337                                  collect (format "%c/" c))))
 338            (prompt-choices (concat "[" (substring prompt-choices 0 -1) "] "))
 339            (full-prompt (concat prompt prompt-choices))
 340            k)
 341
 342       (while (not (memq k choices))
 343         (setq k (cond
 344                  ((fboundp 'read-char-choice)
 345                   (read-char-choice full-prompt choices))
 346                  (t (message "%s" full-prompt)
 347                     (setq k (read-char))))))
 348       k)))
 349
 350 ;; (auth-source-pick nil :host "any" :port 'imap :user "joe")
 351 ;; (auth-source-pick t :host "any" :port 'imap :user "joe")
 352 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 353 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 354 ;;                   (:source (:secrets "Login") :host t :port t)
 355 ;;                   (:source "~/.authinfo.gpg" :host t :port t)))
 356
 357 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 358 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 359 ;;                   (:source (:secrets "Login") :host t :port t)
 360 ;;                   ))
 361
 362 ;; (setq auth-sources '((:source "~/.authinfo.gpg" :host t :port t)))
 363
 364 ;; (auth-source-backend-parse "myfile.gpg")
 365 ;; (auth-source-backend-parse 'default)
 366 ;; (auth-source-backend-parse "secrets:Login")
 367
 368 (defun auth-source-backend-parse (entry)
 369   "Creates an auth-source-backend from an ENTRY in `auth-sources'."
 370   (auth-source-backend-parse-parameters
 371    entry
 372    (cond
 373     ;; take 'default and recurse to get it as a Secrets API default collection
 374     ;; matching any user, host, and protocol
 375     ((eq entry 'default)
 376      (auth-source-backend-parse '(:source (:secrets default))))
 377     ;; take secrets:XYZ and recurse to get it as Secrets API collection "XYZ"
 378     ;; matching any user, host, and protocol
 379     ((and (stringp entry) (string-match "^secrets:\\(.+\\)" entry))
 380      (auth-source-backend-parse `(:source (:secrets ,(match-string 1 entry)))))
 381     ;; take just a file name and recurse to get it as a netrc file
 382     ;; matching any user, host, and protocol
 383     ((stringp entry)
 384      (auth-source-backend-parse `(:source ,entry)))
 385
 386     ;; a file name with parameters
 387     ((stringp (plist-get entry :source))
 388      (auth-source-backend
 389       (plist-get entry :source)
 390       :source (plist-get entry :source)
 391       :type 'netrc
 392       :search-function 'auth-source-netrc-search
 393       :create-function 'auth-source-netrc-create))
 394
 395     ;; the Secrets API.  We require the package, in order to have a
 396     ;; defined value for `secrets-enabled'.
 397     ((and
 398       (not (null (plist-get entry :source))) ; the source must not be nil
 399       (listp (plist-get entry :source))      ; and it must be a list
 400       (require 'secrets nil t)               ; and we must load the Secrets API
 401       secrets-enabled)                       ; and that API must be enabled
 402
 403      ;; the source is either the :secrets key in ENTRY or
 404      ;; if that's missing or nil, it's "session"
 405      (let ((source (or (plist-get (plist-get entry :source) :secrets)
 406                        "session")))
 407
 408        ;; if the source is a symbol, we look for the alias named so,
 409        ;; and if that alias is missing, we use "Login"
 410        (when (symbolp source)
 411          (setq source (or (secrets-get-alias (symbol-name source))
 412                           "Login")))
 413
 414        (if (featurep 'secrets)
 415            (auth-source-backend
 416             (format "Secrets API (%s)" source)
 417             :source source
 418             :type 'secrets
 419             :search-function 'auth-source-secrets-search
 420             :create-function 'auth-source-secrets-create)
 421          (auth-source-do-warn
 422           "auth-source-backend-parse: no Secrets API, ignoring spec: %S" entry)
 423          (auth-source-backend
 424           (format "Ignored Secrets API (%s)" source)
 425           :source ""
 426           :type 'ignore))))
 427
 428     ;; none of them
 429     (t
 430      (auth-source-do-warn
 431       "auth-source-backend-parse: invalid backend spec: %S" entry)
 432      (auth-source-backend
 433       "Empty"
 434       :source ""
 435       :type 'ignore)))))
 436
 437 (defun auth-source-backend-parse-parameters (entry backend)
 438   "Fills in the extra auth-source-backend parameters of ENTRY.
 439 Using the plist ENTRY, get the :host, :port, and :user search
 440 parameters."
 441   (let ((entry (if (stringp entry)
 442                    nil
 443                  entry))
 444         val)
 445     (when (setq val (plist-get entry :host))
 446       (oset backend host val))
 447     (when (setq val (plist-get entry :user))
 448       (oset backend user val))
 449     (when (setq val (plist-get entry :port))
 450       (oset backend port val)))
 451   backend)
 452
 453 ;; (mapcar 'auth-source-backend-parse auth-sources)
 454
 455 (defun* auth-source-search (&rest spec
 456                                   &key type max host user port secret
 457                                   require create delete
 458                                   &allow-other-keys)
 459   "Search or modify authentication backends according to SPEC.
 460
 461 This function parses `auth-sources' for matches of the SPEC
 462 plist.  It can optionally create or update an authentication
 463 token if requested.  A token is just a standard Emacs property
 464 list with a :secret property that can be a function; all the
 465 other properties will always hold scalar values.
 466
 467 Typically the :secret property, if present, contains a password.
 468
 469 Common search keys are :max, :host, :port, and :user.  In
 470 addition, :create specifies how tokens will be or created.
 471 Finally, :type can specify which backend types you want to check.
 472
 473 A string value is always matched literally.  A symbol is matched
 474 as its string value, literally.  All the SPEC values can be
 475 single values (symbol or string) or lists thereof (in which case
 476 any of the search terms matches).
 477
 478 :create t means to create a token if possible.
 479
 480 A new token will be created if no matching tokens were found.
 481 The new token will have only the keys the backend requires.  For
 482 the netrc backend, for instance, that's the user, host, and
 483 port keys.
 484
 485 Here's an example:
 486
 487 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 488                                         (A    . \"default A\"))))
 489   (auth-source-search :host \"mine\" :type 'netrc :max 1
 490                       :P \"pppp\" :Q \"qqqq\"
 491                       :create t))
 492
 493 which says:
 494
 495 \"Search for any entry matching host 'mine' in backends of type
 496  'netrc', maximum one result.
 497
 498  Create a new entry if you found none.  The netrc backend will
 499  automatically require host, user, and port.  The host will be
 500  'mine'.  We prompt for the user with default 'defaultUser' and
 501  for the port without a default.  We will not prompt for A, Q,
 502  or P.  The resulting token will only have keys user, host, and
 503  port.\"
 504
 505 :create '(A B C) also means to create a token if possible.
 506
 507 The behavior is like :create t but if the list contains any
 508 parameter, that parameter will be required in the resulting
 509 token.  The value for that parameter will be obtained from the
 510 search parameters or from user input.  If any queries are needed,
 511 the alist `auth-source-creation-defaults' will be checked for the
 512 default value.  If the user, host, or port are missing, the alist
 513 `auth-source-creation-prompts' will be used to look up the
 514 prompts IN THAT ORDER (so the 'user prompt will be queried first,
 515 then 'host, then 'port, and finally 'secret).  Each prompt string
 516 can use %u, %h, and %p to show the user, host, and port.
 517
 518 Here's an example:
 519
 520 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 521                                         (A    . \"default A\")))
 522        (auth-source-creation-prompts
 523         '((password . \"Enter IMAP password for %h:%p: \"))))
 524   (auth-source-search :host '(\"nonesuch\" \"twosuch\") :type 'netrc :max 1
 525                       :P \"pppp\" :Q \"qqqq\"
 526                       :create '(A B Q)))
 527
 528 which says:
 529
 530 \"Search for any entry matching host 'nonesuch'
 531  or 'twosuch' in backends of type 'netrc', maximum one result.
 532
 533  Create a new entry if you found none.  The netrc backend will
 534  automatically require host, user, and port.  The host will be
 535  'nonesuch' and Q will be 'qqqq'.  We prompt for the password
 536  with the shown prompt.  We will not prompt for Q.  The resulting
 537  token will have keys user, host, port, A, B, and Q.  It will not
 538  have P with any value, even though P is used in the search to
 539  find only entries that have P set to 'pppp'.\"
 540
 541 When multiple values are specified in the search parameter, the
 542 user is prompted for which one.  So :host (X Y Z) would ask the
 543 user to choose between X, Y, and Z.
 544
 545 This creation can fail if the search was not specific enough to
 546 create a new token (it's up to the backend to decide that).  You
 547 should `catch' the backend-specific error as usual.  Some
 548 backends (netrc, at least) will prompt the user rather than throw
 549 an error.
 550
 551 :require (A B C) means that only results that contain those
 552 tokens will be returned.  Thus for instance requiring :secret
 553 will ensure that any results will actually have a :secret
 554 property.
 555
 556 :delete t means to delete any found entries.  nil by default.
 557 Use `auth-source-delete' in ELisp code instead of calling
 558 `auth-source-search' directly with this parameter.
 559
 560 :type (X Y Z) will check only those backend types.  'netrc and
 561 'secrets are the only ones supported right now.
 562
 563 :max N means to try to return at most N items (defaults to 1).
 564 When 0 the function will return just t or nil to indicate if any
 565 matches were found.  More than N items may be returned, depending
 566 on the search and the backend.
 567
 568 :host (X Y Z) means to match only hosts X, Y, or Z according to
 569 the match rules above.  Defaults to t.
 570
 571 :user (X Y Z) means to match only users X, Y, or Z according to
 572 the match rules above.  Defaults to t.
 573
 574 :port (P Q R) means to match only protocols P, Q, or R.
 575 Defaults to t.
 576
 577 :K (V1 V2 V3) for any other key K will match values V1, V2, or
 578 V3 (note the match rules above).
 579
 580 The return value is a list with at most :max tokens.  Each token
 581 is a plist with keys :backend :host :port :user, plus any other
 582 keys provided by the backend (notably :secret).  But note the
 583 exception for :max 0, which see above.
 584
 585 The token can hold a :save-function key.  If you call that, the
 586 user will be prompted to save the data to the backend.  You can't
 587 request that this should happen right after creation, because
 588 `auth-source-search' has no way of knowing if the token is
 589 actually useful.  So the caller must arrange to call this function.
 590
 591 The token's :secret key can hold a function.  In that case you
 592 must call it to obtain the actual value."
 593   (let* ((backends (mapcar 'auth-source-backend-parse auth-sources))
 594          (max (or max 1))
 595          (ignored-keys '(:require :create :delete :max))
 596          (keys (loop for i below (length spec) by 2
 597                      unless (memq (nth i spec) ignored-keys)
 598                      collect (nth i spec)))
 599          (cached (auth-source-remembered-p spec))
 600          ;; note that we may have cached results but found is still nil
 601          ;; (there were no results from the search)
 602          (found (auth-source-recall spec))
 603          filtered-backends accessor-key backend)
 604
 605     (if (and cached auth-source-do-cache)
 606         (auth-source-do-debug
 607          "auth-source-search: found %d CACHED results matching %S"
 608          (length found) spec)
 609
 610       (assert
 611        (or (eq t create) (listp create)) t
 612        "Invalid auth-source :create parameter (must be t or a list): %s %s")
 613
 614       (assert
 615        (listp require) t
 616        "Invalid auth-source :require parameter (must be a list): %s")
 617
 618       (setq filtered-backends (copy-sequence backends))
 619       (dolist (backend backends)
 620         (dolist (key keys)
 621           ;; ignore invalid slots
 622           (condition-case signal
 623               (unless (eval `(auth-source-search-collection
 624                               (plist-get spec key)
 625                               (oref backend ,key)))
 626                 (setq filtered-backends (delq backend filtered-backends))
 627                 (return))
 628             (invalid-slot-name))))
 629
 630       (auth-source-do-trivia
 631        "auth-source-search: found %d backends matching %S"
 632        (length filtered-backends) spec)
 633
 634       ;; (debug spec "filtered" filtered-backends)
 635       ;; First go through all the backends without :create, so we can
 636       ;; query them all.
 637       (setq found (auth-source-search-backends filtered-backends
 638                                                spec
 639                                                ;; to exit early
 640                                                max
 641                                                ;; create is always nil here
 642                                                nil delete
 643                                                require))
 644
 645       (auth-source-do-debug
 646        "auth-source-search: found %d results (max %d) matching %S"
 647        (length found) max spec)
 648
 649       ;; If we didn't find anything, then we allow the backend(s) to
 650       ;; create the entries.
 651       (when (and create
 652                  (not found))
 653         (setq found (auth-source-search-backends filtered-backends
 654                                                  spec
 655                                                  ;; to exit early
 656                                                  max
 657                                                  create delete
 658                                                  require))
 659         (auth-source-do-debug
 660          "auth-source-search: CREATED %d results (max %d) matching %S"
 661          (length found) max spec))
 662
 663       ;; note we remember the lack of result too, if it's applicable
 664       (when auth-source-do-cache
 665         (auth-source-remember spec found)))
 666
 667       found))
 668
 669 (defun auth-source-search-backends (backends spec max create delete require)
 670   (let (matches)
 671     (dolist (backend backends)
 672       (when (> max (length matches))   ; when we need more matches...
 673         (let* ((bmatches (apply
 674                           (slot-value backend 'search-function)
 675                           :backend backend
 676                           ;; note we're overriding whatever the spec
 677                           ;; has for :require, :create, and :delete
 678                           :require require
 679                           :create create
 680                           :delete delete
 681                           spec)))
 682           (when bmatches
 683             (auth-source-do-trivia
 684              "auth-source-search-backend: got %d (max %d) in %s:%s matching %S"
 685              (length bmatches) max
 686              (slot-value backend :type)
 687              (slot-value backend :source)
 688              spec)
 689             (setq matches (append matches bmatches))))))
 690     matches))
 691
 692 ;;; (auth-source-search :max 1)
 693 ;;; (funcall (plist-get (nth 0 (auth-source-search :max 1)) :secret))
 694 ;;; (auth-source-search :host "nonesuch" :type 'netrc :K 1)
 695 ;;; (auth-source-search :host "nonesuch" :type 'secrets)
 696
 697 (defun* auth-source-delete (&rest spec
 698                                   &key delete
 699                                   &allow-other-keys)
 700   "Delete entries from the authentication backends according to SPEC.
 701 Calls `auth-source-search' with the :delete property in SPEC set to t.
 702 The backend may not actually delete the entries.
 703
 704 Returns the deleted entries."
 705   (auth-source-search (plist-put spec :delete t)))
 706
 707 (defun auth-source-search-collection (collection value)
 708   "Returns t is VALUE is t or COLLECTION is t or contains VALUE."
 709   (when (and (atom collection) (not (eq t collection)))
 710     (setq collection (list collection)))
 711
 712   ;; (debug :collection collection :value value)
 713   (or (eq collection t)
 714       (eq value t)
 715       (equal collection value)
 716       (member value collection)))
 717
 718 (defun auth-source-forget-all-cached ()
 719   "Forget all cached auth-source data."
 720   (interactive)
 721   (loop for sym being the symbols of password-data
 722         ;; when the symbol name starts with auth-source-magic
 723         when (string-match (concat "^" auth-source-magic)
 724                            (symbol-name sym))
 725         ;; remove that key
 726         do (password-cache-remove (symbol-name sym))))
 727
 728 (defun auth-source-remember (spec found)
 729   "Remember FOUND search results for SPEC."
 730   (let ((password-cache-expiry auth-source-cache-expiry))
 731     (password-cache-add
 732      (concat auth-source-magic (format "%S" spec)) found)))
 733
 734 (defun auth-source-recall (spec)
 735   "Recall FOUND search results for SPEC."
 736   (password-read-from-cache
 737    (concat auth-source-magic (format "%S" spec))))
 738
 739 (defun auth-source-remembered-p (spec)
 740   "Check if SPEC is remembered."
 741   (password-in-cache-p
 742    (concat auth-source-magic (format "%S" spec))))
 743
 744 (defun auth-source-forget (spec)
 745   "Forget any cached data matching SPEC exactly.
 746
 747 This is the same SPEC you passed to `auth-source-search'.
 748 Returns t or nil for forgotten or not found."
 749   (password-cache-remove (concat auth-source-magic (format "%S" spec))))
 750
 751 ;;; (loop for sym being the symbols of password-data when (string-match (concat "^" auth-source-magic) (symbol-name sym)) collect (symbol-name sym))
 752
 753 ;;; (auth-source-remember '(:host "wedd") '(4 5 6))
 754 ;;; (auth-source-remembered-p '(:host "wedd"))
 755 ;;; (auth-source-remember '(:host "xedd") '(1 2 3))
 756 ;;; (auth-source-remembered-p '(:host "xedd"))
 757 ;;; (auth-source-remembered-p '(:host "zedd"))
 758 ;;; (auth-source-recall '(:host "xedd"))
 759 ;;; (auth-source-recall '(:host t))
 760 ;;; (auth-source-forget+ :host t)
 761
 762 (defun* auth-source-forget+ (&rest spec &allow-other-keys)
 763   "Forget any cached data matching SPEC.  Returns forgotten count.
 764
 765 This is not a full `auth-source-search' spec but works similarly.
 766 For instance, \(:host \"myhost\" \"yourhost\") would find all the
 767 cached data that was found with a search for those two hosts,
 768 while \(:host t) would find all host entries."
 769   (let ((count 0)
 770         sname)
 771     (loop for sym being the symbols of password-data
 772           ;; when the symbol name matches with auth-source-magic
 773           when (and (setq sname (symbol-name sym))
 774                     (string-match (concat "^" auth-source-magic "\\(.+\\)")
 775                                   sname)
 776                     ;; and the spec matches what was stored in the cache
 777                     (auth-source-specmatchp spec (read (match-string 1 sname))))
 778           ;; remove that key
 779           do (progn
 780                (password-cache-remove sname)
 781                (incf count)))
 782     count))
 783
 784 (defun auth-source-specmatchp (spec stored)
 785   (let ((keys (loop for i below (length spec) by 2
 786                    collect (nth i spec))))
 787     (not (eq
 788           (dolist (key keys)
 789             (unless (auth-source-search-collection (plist-get stored key)
 790                                                    (plist-get spec key))
 791               (return 'no)))
 792           'no))))
 793
 794 ;;; (auth-source-pick-first-password :host "z.lifelogs.com")
 795 ;;; (auth-source-pick-first-password :port "imap")
 796 (defun auth-source-pick-first-password (&rest spec)
 797   "Pick the first secret found from applying SPEC to `auth-source-search'."
 798   (let* ((result (nth 0 (apply 'auth-source-search (plist-put spec :max 1))))
 799          (secret (plist-get result :secret)))
 800
 801     (if (functionp secret)
 802         (funcall secret)
 803       secret)))
 804
 805 ;; (auth-source-format-prompt "test %u %h %p" '((?u "user") (?h "host")))
 806 (defun auth-source-format-prompt (prompt alist)
 807   "Format PROMPT using %x (for any character x) specifiers in ALIST."
 808   (dolist (cell alist)
 809     (let ((c (nth 0 cell))
 810           (v (nth 1 cell)))
 811       (when (and c v)
 812         (setq prompt (replace-regexp-in-string (format "%%%c" c)
 813                                                (format "%s" v)
 814                                                prompt)))))
 815   prompt)
 816
 817 (defun auth-source-ensure-strings (values)
 818   (unless (listp values)
 819     (setq values (list values)))
 820   (mapcar (lambda (value)
 821             (if (numberp value)
 822                 (format "%s" value)
 823               value))
 824           values))
 825
 826 ;;; Backend specific parsing: netrc/authinfo backend
 827
 828 (defvar auth-source-netrc-cache nil)
 829
 830 ;;; (auth-source-netrc-parse "~/.authinfo.gpg")
 831 (defun* auth-source-netrc-parse (&rest
 832                                  spec
 833                                  &key file max host user port delete require
 834                                  &allow-other-keys)
 835   "Parse FILE and return a list of all entries in the file.
 836 Note that the MAX parameter is used so we can exit the parse early."
 837   (if (listp file)
 838       ;; We got already parsed contents; just return it.
 839       file
 840     (when (file-exists-p file)
 841       (setq port (auth-source-ensure-strings port))
 842       (with-temp-buffer
 843         (let* ((tokens '("machine" "host" "default" "login" "user"
 844                          "password" "account" "macdef" "force"
 845                          "port" "protocol"))
 846                (max (or max 5000))       ; sanity check: default to stop at 5K
 847                (modified 0)
 848                (cached (cdr-safe (assoc file auth-source-netrc-cache)))
 849                (cached-mtime (plist-get cached :mtime))
 850                (cached-secrets (plist-get cached :secret))
 851                alist elem result pair)
 852
 853           (if (and (functionp cached-secrets)
 854                    (equal cached-mtime
 855                           (nth 5 (file-attributes file))))
 856               (progn
 857                 (auth-source-do-trivia
 858                  "auth-source-netrc-parse: using CACHED file data for %s"
 859                  file)
 860                 (insert (funcall cached-secrets)))
 861             (insert-file-contents file)
 862             ;; cache all netrc files (used to be just .gpg files)
 863             ;; Store the contents of the file heavily encrypted in memory.
 864             ;; (note for the irony-impaired: they are just obfuscated)
 865             (aput 'auth-source-netrc-cache file
 866                   (list :mtime (nth 5 (file-attributes file))
 867                         :secret (lexical-let ((v (rot13-string
 868                                                   (base64-encode-string
 869                                                    (buffer-string)))))
 870                                   (lambda () (base64-decode-string
 871                                          (rot13-string v)))))))
 872           (goto-char (point-min))
 873           ;; Go through the file, line by line.
 874           (while (and (not (eobp))
 875                       (> max 0))
 876
 877             (narrow-to-region (point) (point-at-eol))
 878             ;; For each line, get the tokens and values.
 879             (while (not (eobp))
 880               (skip-chars-forward "\t ")
 881               ;; Skip lines that begin with a "#".
 882               (if (eq (char-after) ?#)
 883                   (goto-char (point-max))
 884                 (unless (eobp)
 885                   (setq elem
 886                         (if (= (following-char) ?\")
 887                             (read (current-buffer))
 888                           (buffer-substring
 889                            (point) (progn (skip-chars-forward "^\t ")
 890                                           (point)))))
 891                   (cond
 892                    ((equal elem "macdef")
 893                     ;; We skip past the macro definition.
 894                     (widen)
 895                     (while (and (zerop (forward-line 1))
 896                                 (looking-at "$")))
 897                     (narrow-to-region (point) (point)))
 898                    ((member elem tokens)
 899                     ;; Tokens that don't have a following value are ignored,
 900                     ;; except "default".
 901                     (when (and pair (or (cdr pair)
 902                                         (equal (car pair) "default")))
 903                       (push pair alist))
 904                     (setq pair (list elem)))
 905                    (t
 906                     ;; Values that haven't got a preceding token are ignored.
 907                     (when pair
 908                       (setcdr pair elem)
 909                       (push pair alist)
 910                       (setq pair nil)))))))
 911
 912             (when (and alist
 913                        (> max 0)
 914                        (auth-source-search-collection
 915                         host
 916                         (or
 917                          (aget alist "machine")
 918                          (aget alist "host")
 919                          t))
 920                        (auth-source-search-collection
 921                         user
 922                         (or
 923                          (aget alist "login")
 924                          (aget alist "account")
 925                          (aget alist "user")
 926                          t))
 927                        (auth-source-search-collection
 928                         port
 929                         (or
 930                          (aget alist "port")
 931                          (aget alist "protocol")
 932                          t))
 933                        (or
 934                         ;; the required list of keys is nil, or
 935                         (null require)
 936                         ;; every element of require is in the normalized list
 937                         (let ((normalized (nth 0 (auth-source-netrc-normalize
 938                                                  (list alist) file))))
 939                           (loop for req in require
 940                                 always (plist-get normalized req)))))
 941               (decf max)
 942               (push (nreverse alist) result)
 943               ;; to delete a line, we just comment it out
 944               (when delete
 945                 (goto-char (point-min))
 946                 (insert "#")
 947                 (incf modified)))
 948             (setq alist nil
 949                   pair nil)
 950             (widen)
 951             (forward-line 1))
 952
 953           (when (< 0 modified)
 954             (when auth-source-gpg-encrypt-to
 955               ;; (see bug#7487) making `epa-file-encrypt-to' local to
 956               ;; this buffer lets epa-file skip the key selection query
 957               ;; (see the `local-variable-p' check in
 958               ;; `epa-file-write-region').
 959               (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 960                 (make-local-variable 'epa-file-encrypt-to))
 961               (if (listp auth-source-gpg-encrypt-to)
 962                   (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 963
 964             ;; ask AFTER we've successfully opened the file
 965             (when (y-or-n-p (format "Save file %s? (%d deletions)"
 966                                     file modified))
 967               (write-region (point-min) (point-max) file nil 'silent)
 968               (auth-source-do-debug
 969                "auth-source-netrc-parse: modified %d lines in %s"
 970                modified file)))
 971
 972           (nreverse result))))))
 973
 974 (defmacro with-auth-source-epa-overrides (&rest body)
 975   `(let ((file-name-handler-alist
 976           ',(if (boundp 'epa-file-handler)
 977                 (remove (symbol-value 'epa-file-handler)
 978                         file-name-handler-alist)
 979               file-name-handler-alist))
 980          (,(if (boundp 'find-file-hook) 'find-file-hook 'find-file-hooks)
 981           ',(remove
 982              'epa-file-find-file-hook
 983              (if (boundp 'find-file-hook) 'find-file-hook 'find-file-hooks)))
 984          (auto-mode-alist
 985           ',(if (boundp 'epa-file-auto-mode-alist-entry)
 986                 (remove (symbol-value 'epa-file-auto-mode-alist-entry)
 987                         auto-mode-alist)
 988               auto-mode-alist)))
 989      ,@body))
 990
 991 (defun auth-source-epa-make-gpg-token (secret file)
 992   (require 'epa nil t)
 993   (unless (featurep 'epa)
 994     (error "EPA could not be loaded."))
 995   (let* ((base (file-name-sans-extension file))
 996          (passkey (format "gpg:-%s" base))
 997          (stash (concat base ".gpg"))
 998          ;; temporarily disable EPA
 999          (stashfile
1000           (with-auth-source-epa-overrides
1001            (make-temp-file "gpg-token" nil
1002                            stash)))
1003          (epa-file-passphrase-alist
1004           `((,stashfile
1005              . ,(password-read
1006                  (format
1007                   "token pass for %s? "
1008                   file)
1009                  passkey)))))
1010     (write-region secret nil stashfile)
1011     ;; temporarily disable EPA
1012     (unwind-protect
1013         (with-auth-source-epa-overrides
1014          (with-temp-buffer
1015            (insert-file-contents stashfile)
1016            (base64-encode-region (point-min) (point-max) t)
1017            (concat "gpg:"
1018                    (buffer-substring-no-properties
1019                     (point-min)
1020                     (point-max)))))
1021       (delete-file stashfile))))
1022
1023 (defun auth-source-netrc-normalize (alist filename)
1024   (mapcar (lambda (entry)
1025             (let (ret item)
1026               (while (setq item (pop entry))
1027                 (let ((k (car item))
1028                       (v (cdr item)))
1029
1030                   ;; apply key aliases
1031                   (setq k (cond ((member k '("machine")) "host")
1032                                 ((member k '("login" "account")) "user")
1033                                 ((member k '("protocol")) "port")
1034                                 ((member k '("password")) "secret")
1035                                 (t k)))
1036
1037                   ;; send back the secret in a function (lexical binding)
1038                   (when (equal k "secret")
1039                     (setq v (lexical-let ((v v)
1040                                           (filename filename)
1041                                           (base (file-name-nondirectory
1042                                                  filename))
1043                                           (token-decoder nil)
1044                                           (gpgdata nil)
1045                                           (stash nil))
1046                               (setq stash (concat base ".gpg"))
1047                               (when (string-match "gpg:\\(.+\\)" v)
1048                                 (require 'epa nil t)
1049                                 (unless (featurep 'epa)
1050                                   (error "EPA could not be loaded."))
1051                                 (setq gpgdata (base64-decode-string
1052                                                (match-string 1 v)))
1053                                 ;; it's a GPG token
1054                                 (setq
1055                                  token-decoder
1056                                  (lambda (gpgdata)
1057 ;;; FIXME: this relies on .gpg files being handled by EPA/EPG
1058                                    (let* ((passkey (format "gpg:-%s" base))
1059                                           ;; temporarily disable EPA
1060                                           (stashfile
1061                                            (with-auth-source-epa-overrides
1062                                             (make-temp-file "gpg-token" nil
1063                                                             stash)))
1064                                           (epa-file-passphrase-alist
1065                                            `((,stashfile
1066                                               . ,(password-read
1067                                                   (format
1068                                                    "token pass for %s? "
1069                                                    filename)
1070                                                   passkey)))))
1071                                      (unwind-protect
1072                                          (progn
1073                                            ;; temporarily disable EPA
1074                                            (with-auth-source-epa-overrides
1075                                             (write-region gpgdata
1076                                                           nil
1077                                                           stashfile))
1078                                            (setq
1079                                             v
1080                                             (with-temp-buffer
1081                                               (insert-file-contents stashfile)
1082                                               (buffer-substring-no-properties
1083                                                (point-min)
1084                                                (point-max)))))
1085                                        (delete-file stashfile)))
1086                                    ;; clear out the decoder at end
1087                                    (setq token-decoder nil
1088                                          gpgdata nil))))
1089                           (lambda ()
1090                             (when token-decoder
1091                               (funcall token-decoder gpgdata))
1092                             v))))
1093                 (setq ret (plist-put ret
1094                                      (intern (concat ":" k))
1095                                      v))))
1096             ret))
1097   alist))
1098
1099 ;;; (setq secret (plist-get (nth 0 (auth-source-search :host t :type 'netrc :K 1 :max 1)) :secret))
1100 ;;; (funcall secret)
1101
1102 (defun* auth-source-netrc-search (&rest
1103                                   spec
1104                                   &key backend require create delete
1105                                   type max host user port
1106                                   &allow-other-keys)
1107 "Given a property list SPEC, return search matches from the :backend.
1108 See `auth-source-search' for details on SPEC."
1109   ;; just in case, check that the type is correct (null or same as the backend)
1110   (assert (or (null type) (eq type (oref backend type)))
1111           t "Invalid netrc search: %s %s")
1112
1113   (let ((results (auth-source-netrc-normalize
1114                   (auth-source-netrc-parse
1115                    :max max
1116                    :require require
1117                    :delete delete
1118                    :file (oref backend source)
1119                    :host (or host t)
1120                    :user (or user t)
1121                    :port (or port t))
1122                   (oref backend source))))
1123
1124     ;; if we need to create an entry AND none were found to match
1125     (when (and create
1126                (not results))
1127
1128       ;; create based on the spec and record the value
1129       (setq results (or
1130                      ;; if the user did not want to create the entry
1131                      ;; in the file, it will be returned
1132                      (apply (slot-value backend 'create-function) spec)
1133                      ;; if not, we do the search again without :create
1134                      ;; to get the updated data.
1135
1136                      ;; the result will be returned, even if the search fails
1137                      (apply 'auth-source-netrc-search
1138                             (plist-put spec :create nil)))))
1139     results))
1140
1141 (defun auth-source-netrc-element-or-first (v)
1142   (if (listp v)
1143       (nth 0 v)
1144     v))
1145
1146 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t)
1147 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t :create-extra-keys '((A "default A") (B)))
1148
1149 (defun* auth-source-netrc-create (&rest spec
1150                                         &key backend
1151                                         secret host user port create
1152                                         &allow-other-keys)
1153   (let* ((base-required '(host user port secret))
1154          ;; we know (because of an assertion in auth-source-search) that the
1155          ;; :create parameter is either t or a list (which includes nil)
1156          (create-extra (if (eq t create) nil create))
1157          (required (append base-required create-extra))
1158          (file (oref backend source))
1159          (add "")
1160          ;; `valist' is an alist
1161          valist
1162          ;; `artificial' will be returned if no creation is needed
1163          artificial)
1164
1165     ;; only for base required elements (defined as function parameters):
1166     ;; fill in the valist with whatever data we may have from the search
1167     ;; we complete the first value if it's a list and use the value otherwise
1168     (dolist (br base-required)
1169       (when (symbol-value br)
1170         (let ((br-choice (cond
1171                           ;; all-accepting choice (predicate is t)
1172                           ((eq t (symbol-value br)) nil)
1173                           ;; just the value otherwise
1174                           (t (symbol-value br)))))
1175           (when br-choice
1176             (aput 'valist br br-choice)))))
1177
1178     ;; for extra required elements, see if the spec includes a value for them
1179     (dolist (er create-extra)
1180       (let ((name (concat ":" (symbol-name er)))
1181             (keys (loop for i below (length spec) by 2
1182                         collect (nth i spec))))
1183         (dolist (k keys)
1184           (when (equal (symbol-name k) name)
1185             (aput 'valist er (plist-get spec k))))))
1186
1187     ;; for each required element
1188     (dolist (r required)
1189       (let* ((data (aget valist r))
1190              ;; take the first element if the data is a list
1191              (data (auth-source-netrc-element-or-first data))
1192              ;; this is the default to be offered
1193              (given-default (aget auth-source-creation-defaults r))
1194              ;; the default supplementals are simple:
1195              ;; for the user, try `given-default' and then (user-login-name);
1196              ;; otherwise take `given-default'
1197              (default (cond
1198                        ((and (not given-default) (eq r 'user))
1199                         (user-login-name))
1200                        (t given-default)))
1201              (printable-defaults (list
1202                                   (cons 'user
1203                                         (or
1204                                          (auth-source-netrc-element-or-first
1205                                           (aget valist 'user))
1206                                          (plist-get artificial :user)
1207                                          "[any user]"))
1208                                   (cons 'host
1209                                         (or
1210                                          (auth-source-netrc-element-or-first
1211                                           (aget valist 'host))
1212                                          (plist-get artificial :host)
1213                                          "[any host]"))
1214                                   (cons 'port
1215                                         (or
1216                                          (auth-source-netrc-element-or-first
1217                                           (aget valist 'port))
1218                                          (plist-get artificial :port)
1219                                          "[any port]"))))
1220              (prompt (or (aget auth-source-creation-prompts r)
1221                          (case r
1222                            (secret "%p password for %u@%h: ")
1223                            (user "%p user name for %h: ")
1224                            (host "%p host name for user %u: ")
1225                            (port "%p port for %u@%h: "))
1226                          (format "Enter %s (%%u@%%h:%%p): " r)))
1227              (prompt (auth-source-format-prompt
1228                       prompt
1229                       `((?u ,(aget printable-defaults 'user))
1230                         (?h ,(aget printable-defaults 'host))
1231                         (?p ,(aget printable-defaults 'port))))))
1232
1233         ;; Store the data, prompting for the password if needed.
1234         (setq data
1235               (cond
1236                ((and (null data) (eq r 'secret))
1237                 ;; Special case prompt for passwords.
1238 ;; TODO: make the default (setq auth-source-netrc-use-gpg-tokens `((,(if (boundp 'epa-file-auto-mode-alist-entry) (car (symbol-value 'epa-file-auto-mode-alist-entry)) "\\.gpg\\'") nil) (t gpg)))
1239 ;; TODO: or maybe leave as (setq auth-source-netrc-use-gpg-tokens 'never)
1240                 (let* ((ep (format "Use GPG password tokens in %s?" file))
1241                        (gpg-encrypt
1242                         (cond
1243                          ((eq auth-source-netrc-use-gpg-tokens 'never)
1244                           'never)
1245                          ((listp auth-source-netrc-use-gpg-tokens)
1246                           (let ((check (copy-sequence
1247                                         auth-source-netrc-use-gpg-tokens))
1248                                 item ret)
1249                             (while check
1250                               (setq item (pop check))
1251                               (when (or (eq (car item) t)
1252                                         (string-match (car item) file))
1253                                 (setq ret (cdr item))
1254                                 (setq check nil)))))
1255                          (t 'never)))
1256                         (plain (read-passwd prompt)))
1257                   ;; ask if we don't know what to do (in which case
1258                   ;; auth-source-netrc-use-gpg-tokens must be a list)
1259                   (unless gpg-encrypt
1260                     (setq gpg-encrypt (if (y-or-n-p ep) 'gpg 'never))
1261                     ;; TODO: save the defcustom now? or ask?
1262                     (setq auth-source-netrc-use-gpg-tokens
1263                           (cons `(,file ,gpg-encrypt)
1264                                 auth-source-netrc-use-gpg-tokens)))
1265                   (if (eq gpg-encrypt 'gpg)
1266                       (auth-source-epa-make-gpg-token plain file)
1267                     plain)))
1268                ((null data)
1269                 (when default
1270                   (setq prompt
1271                         (if (string-match ": *\\'" prompt)
1272                             (concat (substring prompt 0 (match-beginning 0))
1273                                     " (default " default "): ")
1274                           (concat prompt "(default " default ") "))))
1275                 (read-string prompt nil nil default))
1276                (t (or data default))))
1277
1278         (when data
1279           (setq artificial (plist-put artificial
1280                                       (intern (concat ":" (symbol-name r)))
1281                                       (if (eq r 'secret)
1282                                           (lexical-let ((data data))
1283                                             (lambda () data))
1284                                         data))))
1285
1286         ;; When r is not an empty string...
1287         (when (and (stringp data)
1288                    (< 0 (length data)))
1289           ;; this function is not strictly necessary but I think it
1290           ;; makes the code clearer -tzz
1291           (let ((printer (lambda ()
1292                            ;; append the key (the symbol name of r)
1293                            ;; and the value in r
1294                            (format "%s%s %s"
1295                                    ;; prepend a space
1296                                    (if (zerop (length add)) "" " ")
1297                                    ;; remap auth-source tokens to netrc
1298                                    (case r
1299                                      (user   "login")
1300                                      (host   "machine")
1301                                      (secret "password")
1302                                      (port   "port") ; redundant but clearer
1303                                      (t (symbol-name r)))
1304                                    (if (string-match "[\" ]" data)
1305                                        (format "%S" data)
1306                                      data)))))
1307             (setq add (concat add (funcall printer)))))))
1308
1309     (plist-put
1310      artificial
1311      :save-function
1312      (lexical-let ((file file)
1313                    (add add))
1314        (lambda () (auth-source-netrc-saver file add))))
1315
1316     (list artificial)))
1317
1318 ;;(funcall (plist-get (nth 0 (auth-source-search :host '("nonesuch2") :user "tzz" :port "imap" :create t :max 1)) :save-function))
1319 (defun auth-source-netrc-saver (file add)
1320   "Save a line ADD in FILE, prompting along the way.
1321 Respects `auth-source-save-behavior'.  Uses
1322 `auth-source-netrc-cache' to avoid prompting more than once."
1323   (let* ((key (format "%s %s" file (rfc2104-hash 'md5 64 16 file add)))
1324          (cached (assoc key auth-source-netrc-cache)))
1325
1326     (if cached
1327         (auth-source-do-trivia
1328          "auth-source-netrc-saver: found previous run for key %s, returning"
1329          key)
1330       (with-temp-buffer
1331         (when (file-exists-p file)
1332           (insert-file-contents file))
1333         (when auth-source-gpg-encrypt-to
1334           ;; (see bug#7487) making `epa-file-encrypt-to' local to
1335           ;; this buffer lets epa-file skip the key selection query
1336           ;; (see the `local-variable-p' check in
1337           ;; `epa-file-write-region').
1338           (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
1339             (make-local-variable 'epa-file-encrypt-to))
1340           (if (listp auth-source-gpg-encrypt-to)
1341               (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
1342         ;; we want the new data to be found first, so insert at beginning
1343         (goto-char (point-min))
1344
1345         ;; Ask AFTER we've successfully opened the file.
1346         (let ((prompt (format "Save auth info to file %s? " file))
1347               (done (not (eq auth-source-save-behavior 'ask)))
1348               (bufname "*auth-source Help*")
1349               k)
1350           (while (not done)
1351             (setq k (auth-source-read-char-choice prompt '(?y ?n ?N ?e ??)))
1352             (case k
1353               (?y (setq done t))
1354               (?? (save-excursion
1355                     (with-output-to-temp-buffer bufname
1356                       (princ
1357                        (concat "(y)es, save\n"
1358                                "(n)o but use the info\n"
1359                                "(N)o and don't ask to save again\n"
1360                                "(e)dit the line\n"
1361                                "(?) for help as you can see.\n"))
1362                       ;; Why?  Doesn't with-output-to-temp-buffer already do
1363                       ;; the exact same thing anyway?  --Stef
1364                       (set-buffer standard-output)
1365                       (help-mode))))
1366               (?n (setq add ""
1367                         done t))
1368               (?N (setq add ""
1369                         done t
1370                         auth-source-save-behavior nil))
1371               (?e (setq add (read-string "Line to add: " add)))
1372               (t nil)))
1373
1374           (when (get-buffer-window bufname)
1375             (delete-window (get-buffer-window bufname)))
1376
1377           ;; Make sure the info is not saved.
1378           (when (null auth-source-save-behavior)
1379             (setq add ""))
1380
1381           (when (< 0 (length add))
1382             (progn
1383               (unless (bolp)
1384                 (insert "\n"))
1385               (insert add "\n")
1386               (write-region (point-min) (point-max) file nil 'silent)
1387               (auth-source-do-debug
1388                "auth-source-netrc-create: wrote 1 new line to %s"
1389                file)
1390               (message "Saved new authentication information to %s" file)
1391               nil))))
1392       (aput 'auth-source-netrc-cache key "ran"))))
1393
1394 ;;; Backend specific parsing: Secrets API backend
1395
1396 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :create t))
1397 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :delete t))
1398 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1))
1399 ;;; (let ((auth-sources '(default))) (auth-source-search))
1400 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1))
1401 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1 :signon_realm "https://git.gnus.org/Git"))
1402
1403 (defun* auth-source-secrets-search (&rest
1404                                     spec
1405                                     &key backend create delete label
1406                                     type max host user port
1407                                     &allow-other-keys)
1408   "Search the Secrets API; spec is like `auth-source'.
1409
1410 The :label key specifies the item's label.  It is the only key
1411 that can specify a substring.  Any :label value besides a string
1412 will allow any label.
1413
1414 All other search keys must match exactly.  If you need substring
1415 matching, do a wider search and narrow it down yourself.
1416
1417 You'll get back all the properties of the token as a plist.
1418
1419 Here's an example that looks for the first item in the 'Login'
1420 Secrets collection:
1421
1422  \(let ((auth-sources '(\"secrets:Login\")))
1423     (auth-source-search :max 1)
1424
1425 Here's another that looks for the first item in the 'Login'
1426 Secrets collection whose label contains 'gnus':
1427
1428  \(let ((auth-sources '(\"secrets:Login\")))
1429     (auth-source-search :max 1 :label \"gnus\")
1430
1431 And this one looks for the first item in the 'Login' Secrets
1432 collection that's a Google Chrome entry for the git.gnus.org site
1433 authentication tokens:
1434
1435  \(let ((auth-sources '(\"secrets:Login\")))
1436     (auth-source-search :max 1 :signon_realm \"https://git.gnus.org/Git\"))
1437 "
1438
1439   ;; TODO
1440   (assert (not create) nil
1441           "The Secrets API auth-source backend doesn't support creation yet")
1442   ;; TODO
1443   ;; (secrets-delete-item coll elt)
1444   (assert (not delete) nil
1445           "The Secrets API auth-source backend doesn't support deletion yet")
1446
1447   (let* ((coll (oref backend source))
1448          (max (or max 5000))     ; sanity check: default to stop at 5K
1449          (ignored-keys '(:create :delete :max :backend :label))
1450          (search-keys (loop for i below (length spec) by 2
1451                             unless (memq (nth i spec) ignored-keys)
1452                             collect (nth i spec)))
1453          ;; build a search spec without the ignored keys
1454          ;; if a search key is nil or t (match anything), we skip it
1455          (search-spec (apply 'append (mapcar
1456                                       (lambda (k)
1457                                         (if (or (null (plist-get spec k))
1458                                                 (eq t (plist-get spec k)))
1459                                             nil
1460                                           (list k (plist-get spec k))))
1461                               search-keys)))
1462          ;; needed keys (always including host, login, port, and secret)
1463          (returned-keys (mm-delete-duplicates (append
1464                                                '(:host :login :port :secret)
1465                                                search-keys)))
1466          (items (loop for item in (apply 'secrets-search-items coll search-spec)
1467                       unless (and (stringp label)
1468                                   (not (string-match label item)))
1469                       collect item))
1470          ;; TODO: respect max in `secrets-search-items', not after the fact
1471          (items (butlast items (- (length items) max)))
1472          ;; convert the item name to a full plist
1473          (items (mapcar (lambda (item)
1474                           (append
1475                            ;; make an entry for the secret (password) element
1476                            (list
1477                             :secret
1478                             (lexical-let ((v (secrets-get-secret coll item)))
1479                               (lambda () v)))
1480                            ;; rewrite the entry from ((k1 v1) (k2 v2)) to plist
1481                            (apply 'append
1482                                   (mapcar (lambda (entry)
1483                                             (list (car entry) (cdr entry)))
1484                                           (secrets-get-attributes coll item)))))
1485                         items))
1486          ;; ensure each item has each key in `returned-keys'
1487          (items (mapcar (lambda (plist)
1488                           (append
1489                            (apply 'append
1490                                   (mapcar (lambda (req)
1491                                             (if (plist-get plist req)
1492                                                 nil
1493                                               (list req nil)))
1494                                           returned-keys))
1495                            plist))
1496                         items)))
1497     items))
1498
1499 (defun* auth-source-secrets-create (&rest
1500                                     spec
1501                                     &key backend type max host user port
1502                                     &allow-other-keys)
1503   ;; TODO
1504   ;; (apply 'secrets-create-item (auth-get-source entry) name passwd spec)
1505   (debug spec))
1506
1507 ;;; older API
1508
1509 ;;; (auth-source-user-or-password '("login" "password") "imap.myhost.com" t "tzz")
1510
1511 ;; deprecate the old interface
1512 (make-obsolete 'auth-source-user-or-password
1513                'auth-source-search "Emacs 24.1")
1514 (make-obsolete 'auth-source-forget-user-or-password
1515                'auth-source-forget "Emacs 24.1")
1516
1517 (defun auth-source-user-or-password
1518   (mode host port &optional username create-missing delete-existing)
1519   "Find MODE (string or list of strings) matching HOST and PORT.
1520
1521 DEPRECATED in favor of `auth-source-search'!
1522
1523 USERNAME is optional and will be used as \"login\" in a search
1524 across the Secret Service API (see secrets.el) if the resulting
1525 items don't have a username.  This means that if you search for
1526 username \"joe\" and it matches an item but the item doesn't have
1527 a :user attribute, the username \"joe\" will be returned.
1528
1529 A non nil DELETE-EXISTING means deleting any matching password
1530 entry in the respective sources.  This is useful only when
1531 CREATE-MISSING is non nil as well; the intended use case is to
1532 remove wrong password entries.
1533
1534 If no matching entry is found, and CREATE-MISSING is non nil,
1535 the password will be retrieved interactively, and it will be
1536 stored in the password database which matches best (see
1537 `auth-sources').
1538
1539 MODE can be \"login\" or \"password\"."
1540   (auth-source-do-debug
1541    "auth-source-user-or-password: DEPRECATED get %s for %s (%s) + user=%s"
1542    mode host port username)
1543
1544   (let* ((listy (listp mode))
1545          (mode (if listy mode (list mode)))
1546          (cname (if username
1547                     (format "%s %s:%s %s" mode host port username)
1548                   (format "%s %s:%s" mode host port)))
1549          (search (list :host host :port port))
1550          (search (if username (append search (list :user username)) search))
1551          (search (if create-missing
1552                      (append search (list :create t))
1553                    search))
1554          (search (if delete-existing
1555                      (append search (list :delete t))
1556                    search))
1557          ;; (found (if (not delete-existing)
1558          ;;            (gethash cname auth-source-cache)
1559          ;;          (remhash cname auth-source-cache)
1560          ;;          nil)))
1561          (found nil))
1562     (if found
1563         (progn
1564           (auth-source-do-debug
1565            "auth-source-user-or-password: DEPRECATED cached %s=%s for %s (%s) + %s"
1566            mode
1567            ;; don't show the password
1568            (if (and (member "password" mode) t)
1569                "SECRET"
1570              found)
1571            host port username)
1572           found)                        ; return the found data
1573       ;; else, if not found, search with a max of 1
1574       (let ((choice (nth 0 (apply 'auth-source-search
1575                                   (append '(:max 1) search)))))
1576         (when choice
1577           (dolist (m mode)
1578             (cond
1579              ((equal "password" m)
1580               (push (if (plist-get choice :secret)
1581                       (funcall (plist-get choice :secret))
1582                     nil) found))
1583              ((equal "login" m)
1584               (push (plist-get choice :user) found)))))
1585         (setq found (nreverse found))
1586         (setq found (if listy found (car-safe found)))))
1587
1588         found))
1589
1590 (provide 'auth-source)
1591
1592 ;;; auth-source.el ends here