cgit.sxemacs.org Git - gnus/blob - lisp/auth-source.el

   1 ;;; auth-source.el --- authentication sources for Gnus and Emacs
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is the auth-source.el package.  It lets users tell Gnus how to
  26 ;; authenticate in a single place.  Simplicity is the goal.  Instead
  27 ;; of providing 5000 options, we'll stick to simple, easy to
  28 ;; understand options.
  29
  30 ;; See the auth.info Info documentation for details.
  31
  32 ;; TODO:
  33
  34 ;; - never decode the backend file unless it's necessary
  35 ;; - a more generic way to match backends and search backend contents
  36 ;; - absorb netrc.el and simplify it
  37 ;; - protect passwords better
  38 ;; - allow creating and changing netrc lines (not files) e.g. change a password
  39
  40 ;;; Code:
  41
  42 (require 'password-cache)
  43 (require 'mm-util)
  44 (require 'gnus-util)
  45 (require 'assoc)
  46 (eval-when-compile (require 'cl))
  47 (eval-and-compile
  48   (or (ignore-errors (require 'eieio))
  49       ;; gnus-fallback-lib/ from gnus/lisp/gnus-fallback-lib
  50       (ignore-errors
  51         (let ((load-path (cons (expand-file-name
  52                                 "gnus-fallback-lib/eieio"
  53                                 (file-name-directory (locate-library "gnus")))
  54                                load-path)))
  55           (require 'eieio)))
  56       (error
  57        "eieio not found in `load-path' or gnus-fallback-lib/ directory.")))
  58
  59 (autoload 'secrets-create-item "secrets")
  60 (autoload 'secrets-delete-item "secrets")
  61 (autoload 'secrets-get-alias "secrets")
  62 (autoload 'secrets-get-attributes "secrets")
  63 (autoload 'secrets-get-secret "secrets")
  64 (autoload 'secrets-list-collections "secrets")
  65 (autoload 'secrets-search-items "secrets")
  66
  67 (autoload 'rfc2104-hash "rfc2104")
  68
  69 (defvar secrets-enabled)
  70
  71 (defgroup auth-source nil
  72   "Authentication sources."
  73   :version "23.1" ;; No Gnus
  74   :group 'gnus)
  75
  76 ;;;###autoload
  77 (defcustom auth-source-cache-expiry 7200
  78   "How many seconds passwords are cached, or nil to disable
  79 expiring.  Overrides `password-cache-expiry' through a
  80 let-binding."
  81   :group 'auth-source
  82   :type '(choice (const :tag "Never" nil)
  83                  (const :tag "All Day" 86400)
  84                  (const :tag "2 Hours" 7200)
  85                  (const :tag "30 Minutes" 1800)
  86                  (integer :tag "Seconds")))
  87
  88 (defclass auth-source-backend ()
  89   ((type :initarg :type
  90          :initform 'netrc
  91          :type symbol
  92          :custom symbol
  93          :documentation "The backend type.")
  94    (source :initarg :source
  95            :type string
  96            :custom string
  97            :documentation "The backend source.")
  98    (host :initarg :host
  99          :initform t
 100          :type t
 101          :custom string
 102          :documentation "The backend host.")
 103    (user :initarg :user
 104          :initform t
 105          :type t
 106          :custom string
 107          :documentation "The backend user.")
 108    (port :initarg :port
 109          :initform t
 110          :type t
 111          :custom string
 112          :documentation "The backend protocol.")
 113    (create-function :initarg :create-function
 114                     :initform ignore
 115                     :type function
 116                     :custom function
 117                     :documentation "The create function.")
 118    (search-function :initarg :search-function
 119                     :initform ignore
 120                     :type function
 121                     :custom function
 122                     :documentation "The search function.")))
 123
 124 (defcustom auth-source-protocols '((imap "imap" "imaps" "143" "993")
 125                                    (pop3 "pop3" "pop" "pop3s" "110" "995")
 126                                    (ssh  "ssh" "22")
 127                                    (sftp "sftp" "115")
 128                                    (smtp "smtp" "25"))
 129   "List of authentication protocols and their names"
 130
 131   :group 'auth-source
 132   :version "23.2" ;; No Gnus
 133   :type '(repeat :tag "Authentication Protocols"
 134                  (cons :tag "Protocol Entry"
 135                        (symbol :tag "Protocol")
 136                        (repeat :tag "Names"
 137                                (string :tag "Name")))))
 138
 139 ;;; generate all the protocols in a format Customize can use
 140 ;;; TODO: generate on the fly from auth-source-protocols
 141 (defconst auth-source-protocols-customize
 142   (mapcar (lambda (a)
 143             (let ((p (car-safe a)))
 144               (list 'const
 145                     :tag (upcase (symbol-name p))
 146                     p)))
 147           auth-source-protocols))
 148
 149 (defvar auth-source-creation-defaults nil
 150   "Defaults for creating token values.  Usually let-bound.")
 151
 152 (defvar auth-source-creation-prompts nil
 153   "Default prompts for token values.  Usually let-bound.")
 154
 155 (make-obsolete 'auth-source-hide-passwords nil "Emacs 24.1")
 156
 157 (defcustom auth-source-save-behavior 'ask
 158   "If set, auth-source will respect it for save behavior."
 159   :group 'auth-source
 160   :version "23.2" ;; No Gnus
 161   :type `(choice
 162           :tag "auth-source new token save behavior"
 163           (const :tag "Always save" t)
 164           (const :tag "Never save" nil)
 165           (const :tag "Ask" ask)))
 166
 167 ;; TODO: make the default (setq auth-source-netrc-use-gpg-tokens `((,(if (boundp 'epa-file-auto-mode-alist-entry) (car (symbol-value 'epa-file-auto-mode-alist-entry)) "\\.gpg\\'") never) (t gpg)))
 168 ;; TODO: or maybe leave as (setq auth-source-netrc-use-gpg-tokens 'never)
 169
 170 (defcustom auth-source-netrc-use-gpg-tokens 'never
 171   "Set this to tell auth-source when to create GPG password
 172 tokens in netrc files.  It's either an alist or `never'."
 173   :group 'auth-source
 174   :version "23.2" ;; No Gnus
 175   :type `(choice
 176           (const :tag "Always use GPG password tokens" (t gpg))
 177           (const :tag "Never use GPG password tokens" never)
 178           (repeat :tag "Use a lookup list"
 179                   (list
 180                    (choice :tag "Matcher"
 181                            (const :tag "Match anything" t)
 182                            (const :tag "The EPA encrypted file extensions"
 183                                   ,(if (boundp 'epa-file-auto-mode-alist-entry)
 184                                        (car (symbol-value
 185                                              'epa-file-auto-mode-alist-entry))
 186                                      "\\.gpg\\'"))
 187                            (regexp :tag "Regular expression"))
 188                    (choice :tag "What to do"
 189                            (const :tag "Save GPG-encrypted password tokens" gpg)
 190                            (const :tag "Don't encrypt tokens" never))))))
 191
 192 (defvar auth-source-magic "auth-source-magic ")
 193
 194 (defcustom auth-source-do-cache t
 195   "Whether auth-source should cache information with `password-cache'."
 196   :group 'auth-source
 197   :version "23.2" ;; No Gnus
 198   :type `boolean)
 199
 200 (defcustom auth-source-debug nil
 201   "Whether auth-source should log debug messages.
 202
 203 If the value is nil, debug messages are not logged.
 204
 205 If the value is t, debug messages are logged with `message'.  In
 206 that case, your authentication data will be in the clear (except
 207 for passwords).
 208
 209 If the value is a function, debug messages are logged by calling
 210  that function using the same arguments as `message'."
 211   :group 'auth-source
 212   :version "23.2" ;; No Gnus
 213   :type `(choice
 214           :tag "auth-source debugging mode"
 215           (const :tag "Log using `message' to the *Messages* buffer" t)
 216           (const :tag "Log all trivia with `message' to the *Messages* buffer"
 217                  trivia)
 218           (function :tag "Function that takes arguments like `message'")
 219           (const :tag "Don't log anything" nil)))
 220
 221 (defcustom auth-sources '("~/.authinfo" "~/.authinfo.gpg" "~/.netrc")
 222   "List of authentication sources.
 223
 224 The default will get login and password information from
 225 \"~/.authinfo.gpg\", which you should set up with the EPA/EPG
 226 packages to be encrypted.  If that file doesn't exist, it will
 227 try the unencrypted version \"~/.authinfo\" and the famous
 228 \"~/.netrc\" file.
 229
 230 See the auth.info manual for details.
 231
 232 Each entry is the authentication type with optional properties.
 233
 234 It's best to customize this with `M-x customize-variable' because the choices
 235 can get pretty complex."
 236   :group 'auth-source
 237   :version "24.1" ;; No Gnus
 238   :type `(repeat :tag "Authentication Sources"
 239                  (choice
 240                   (string :tag "Just a file")
 241                   (const :tag "Default Secrets API Collection" 'default)
 242                   (const :tag "Login Secrets API Collection" "secrets:Login")
 243                   (const :tag "Temp Secrets API Collection" "secrets:session")
 244                   (list :tag "Source definition"
 245                         (const :format "" :value :source)
 246                         (choice :tag "Authentication backend choice"
 247                                 (string :tag "Authentication Source (file)")
 248                                 (list
 249                                  :tag "Secret Service API/KWallet/GNOME Keyring"
 250                                  (const :format "" :value :secrets)
 251                                  (choice :tag "Collection to use"
 252                                          (string :tag "Collection name")
 253                                          (const :tag "Default" 'default)
 254                                          (const :tag "Login" "Login")
 255                                          (const
 256                                           :tag "Temporary" "session"))))
 257                         (repeat :tag "Extra Parameters" :inline t
 258                                 (choice :tag "Extra parameter"
 259                                         (list
 260                                          :tag "Host"
 261                                          (const :format "" :value :host)
 262                                          (choice :tag "Host (machine) choice"
 263                                                  (const :tag "Any" t)
 264                                                  (regexp
 265                                                   :tag "Regular expression")))
 266                                         (list
 267                                          :tag "Protocol"
 268                                          (const :format "" :value :port)
 269                                          (choice
 270                                           :tag "Protocol"
 271                                           (const :tag "Any" t)
 272                                           ,@auth-source-protocols-customize))
 273                                         (list :tag "User" :inline t
 274                                               (const :format "" :value :user)
 275                                               (choice
 276                                                :tag "Personality/Username"
 277                                                       (const :tag "Any" t)
 278                                                       (string
 279                                                        :tag "Name")))))))))
 280
 281 (defcustom auth-source-gpg-encrypt-to t
 282   "List of recipient keys that `authinfo.gpg' encrypted to.
 283 If the value is not a list, symmetric encryption will be used."
 284   :group 'auth-source
 285   :version "24.1" ;; No Gnus
 286   :type '(choice (const :tag "Symmetric encryption" t)
 287                  (repeat :tag "Recipient public keys"
 288                          (string :tag "Recipient public key"))))
 289
 290 ;; temp for debugging
 291 ;; (unintern 'auth-source-protocols)
 292 ;; (unintern 'auth-sources)
 293 ;; (customize-variable 'auth-sources)
 294 ;; (setq auth-sources nil)
 295 ;; (format "%S" auth-sources)
 296 ;; (customize-variable 'auth-source-protocols)
 297 ;; (setq auth-source-protocols nil)
 298 ;; (format "%S" auth-source-protocols)
 299 ;; (auth-source-pick nil :host "a" :port 'imap)
 300 ;; (auth-source-user-or-password "login" "imap.myhost.com" 'imap)
 301 ;; (auth-source-user-or-password "password" "imap.myhost.com" 'imap)
 302 ;; (auth-source-user-or-password-imap "login" "imap.myhost.com")
 303 ;; (auth-source-user-or-password-imap "password" "imap.myhost.com")
 304 ;; (auth-source-protocol-defaults 'imap)
 305
 306 ;; (let ((auth-source-debug 'debug)) (auth-source-do-debug "hello"))
 307 ;; (let ((auth-source-debug t)) (auth-source-do-debug "hello"))
 308 ;; (let ((auth-source-debug nil)) (auth-source-do-debug "hello"))
 309 (defun auth-source-do-debug (&rest msg)
 310   (when auth-source-debug
 311     (apply 'auth-source-do-warn msg)))
 312
 313 (defun auth-source-do-trivia (&rest msg)
 314   (when (or (eq auth-source-debug 'trivia)
 315             (functionp auth-source-debug))
 316     (apply 'auth-source-do-warn msg)))
 317
 318 (defun auth-source-do-warn (&rest msg)
 319   (apply
 320     ;; set logger to either the function in auth-source-debug or 'message
 321     ;; note that it will be 'message if auth-source-debug is nil
 322    (if (functionp auth-source-debug)
 323        auth-source-debug
 324      'message)
 325    msg))
 326
 327
 328 ;;; (auth-source-read-char-choice "enter choice? " '(?a ?b ?q))
 329 (defun auth-source-read-char-choice (prompt choices)
 330   "Read one of CHOICES by `read-char-choice', or `read-char'.
 331 `dropdown-list' support is disabled because it doesn't work reliably.
 332 Only one of CHOICES will be returned.  The PROMPT is augmented
 333 with \"[a/b/c] \" if CHOICES is '\(?a ?b ?c\)."
 334   (when choices
 335     (let* ((prompt-choices
 336             (apply 'concat (loop for c in choices
 337                                  collect (format "%c/" c))))
 338            (prompt-choices (concat "[" (substring prompt-choices 0 -1) "] "))
 339            (full-prompt (concat prompt prompt-choices))
 340            k)
 341
 342       (while (not (memq k choices))
 343         (setq k (cond
 344                  ((fboundp 'read-char-choice)
 345                   (read-char-choice full-prompt choices))
 346                  (t (message "%s" full-prompt)
 347                     (setq k (read-char))))))
 348       k)))
 349
 350 ;; (auth-source-pick nil :host "any" :port 'imap :user "joe")
 351 ;; (auth-source-pick t :host "any" :port 'imap :user "joe")
 352 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 353 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 354 ;;                   (:source (:secrets "Login") :host t :port t)
 355 ;;                   (:source "~/.authinfo.gpg" :host t :port t)))
 356
 357 ;; (setq auth-sources '((:source (:secrets default) :host t :port t :user "joe")
 358 ;;                   (:source (:secrets "session") :host t :port t :user "joe")
 359 ;;                   (:source (:secrets "Login") :host t :port t)
 360 ;;                   ))
 361
 362 ;; (setq auth-sources '((:source "~/.authinfo.gpg" :host t :port t)))
 363
 364 ;; (auth-source-backend-parse "myfile.gpg")
 365 ;; (auth-source-backend-parse 'default)
 366 ;; (auth-source-backend-parse "secrets:Login")
 367
 368 (defun auth-source-backend-parse (entry)
 369   "Creates an auth-source-backend from an ENTRY in `auth-sources'."
 370   (auth-source-backend-parse-parameters
 371    entry
 372    (cond
 373     ;; take 'default and recurse to get it as a Secrets API default collection
 374     ;; matching any user, host, and protocol
 375     ((eq entry 'default)
 376      (auth-source-backend-parse '(:source (:secrets default))))
 377     ;; take secrets:XYZ and recurse to get it as Secrets API collection "XYZ"
 378     ;; matching any user, host, and protocol
 379     ((and (stringp entry) (string-match "^secrets:\\(.+\\)" entry))
 380      (auth-source-backend-parse `(:source (:secrets ,(match-string 1 entry)))))
 381     ;; take just a file name and recurse to get it as a netrc file
 382     ;; matching any user, host, and protocol
 383     ((stringp entry)
 384      (auth-source-backend-parse `(:source ,entry)))
 385
 386     ;; a file name with parameters
 387     ((stringp (plist-get entry :source))
 388      (auth-source-backend
 389       (plist-get entry :source)
 390       :source (plist-get entry :source)
 391       :type 'netrc
 392       :search-function 'auth-source-netrc-search
 393       :create-function 'auth-source-netrc-create))
 394
 395     ;; the Secrets API.  We require the package, in order to have a
 396     ;; defined value for `secrets-enabled'.
 397     ((and
 398       (not (null (plist-get entry :source))) ; the source must not be nil
 399       (listp (plist-get entry :source))      ; and it must be a list
 400       (require 'secrets nil t)               ; and we must load the Secrets API
 401       secrets-enabled)                       ; and that API must be enabled
 402
 403      ;; the source is either the :secrets key in ENTRY or
 404      ;; if that's missing or nil, it's "session"
 405      (let ((source (or (plist-get (plist-get entry :source) :secrets)
 406                        "session")))
 407
 408        ;; if the source is a symbol, we look for the alias named so,
 409        ;; and if that alias is missing, we use "Login"
 410        (when (symbolp source)
 411          (setq source (or (secrets-get-alias (symbol-name source))
 412                           "Login")))
 413
 414        (if (featurep 'secrets)
 415            (auth-source-backend
 416             (format "Secrets API (%s)" source)
 417             :source source
 418             :type 'secrets
 419             :search-function 'auth-source-secrets-search
 420             :create-function 'auth-source-secrets-create)
 421          (auth-source-do-warn
 422           "auth-source-backend-parse: no Secrets API, ignoring spec: %S" entry)
 423          (auth-source-backend
 424           (format "Ignored Secrets API (%s)" source)
 425           :source ""
 426           :type 'ignore))))
 427
 428     ;; none of them
 429     (t
 430      (auth-source-do-warn
 431       "auth-source-backend-parse: invalid backend spec: %S" entry)
 432      (auth-source-backend
 433       "Empty"
 434       :source ""
 435       :type 'ignore)))))
 436
 437 (defun auth-source-backend-parse-parameters (entry backend)
 438   "Fills in the extra auth-source-backend parameters of ENTRY.
 439 Using the plist ENTRY, get the :host, :port, and :user search
 440 parameters."
 441   (let ((entry (if (stringp entry)
 442                    nil
 443                  entry))
 444         val)
 445     (when (setq val (plist-get entry :host))
 446       (oset backend host val))
 447     (when (setq val (plist-get entry :user))
 448       (oset backend user val))
 449     (when (setq val (plist-get entry :port))
 450       (oset backend port val)))
 451   backend)
 452
 453 ;; (mapcar 'auth-source-backend-parse auth-sources)
 454
 455 (defun* auth-source-search (&rest spec
 456                                   &key type max host user port secret
 457                                   require create delete
 458                                   &allow-other-keys)
 459   "Search or modify authentication backends according to SPEC.
 460
 461 This function parses `auth-sources' for matches of the SPEC
 462 plist.  It can optionally create or update an authentication
 463 token if requested.  A token is just a standard Emacs property
 464 list with a :secret property that can be a function; all the
 465 other properties will always hold scalar values.
 466
 467 Typically the :secret property, if present, contains a password.
 468
 469 Common search keys are :max, :host, :port, and :user.  In
 470 addition, :create specifies how tokens will be or created.
 471 Finally, :type can specify which backend types you want to check.
 472
 473 A string value is always matched literally.  A symbol is matched
 474 as its string value, literally.  All the SPEC values can be
 475 single values (symbol or string) or lists thereof (in which case
 476 any of the search terms matches).
 477
 478 :create t means to create a token if possible.
 479
 480 A new token will be created if no matching tokens were found.
 481 The new token will have only the keys the backend requires.  For
 482 the netrc backend, for instance, that's the user, host, and
 483 port keys.
 484
 485 Here's an example:
 486
 487 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 488                                         (A    . \"default A\"))))
 489   (auth-source-search :host \"mine\" :type 'netrc :max 1
 490                       :P \"pppp\" :Q \"qqqq\"
 491                       :create t))
 492
 493 which says:
 494
 495 \"Search for any entry matching host 'mine' in backends of type
 496  'netrc', maximum one result.
 497
 498  Create a new entry if you found none.  The netrc backend will
 499  automatically require host, user, and port.  The host will be
 500  'mine'.  We prompt for the user with default 'defaultUser' and
 501  for the port without a default.  We will not prompt for A, Q,
 502  or P.  The resulting token will only have keys user, host, and
 503  port.\"
 504
 505 :create '(A B C) also means to create a token if possible.
 506
 507 The behavior is like :create t but if the list contains any
 508 parameter, that parameter will be required in the resulting
 509 token.  The value for that parameter will be obtained from the
 510 search parameters or from user input.  If any queries are needed,
 511 the alist `auth-source-creation-defaults' will be checked for the
 512 default value.  If the user, host, or port are missing, the alist
 513 `auth-source-creation-prompts' will be used to look up the
 514 prompts IN THAT ORDER (so the 'user prompt will be queried first,
 515 then 'host, then 'port, and finally 'secret).  Each prompt string
 516 can use %u, %h, and %p to show the user, host, and port.
 517
 518 Here's an example:
 519
 520 \(let ((auth-source-creation-defaults '((user . \"defaultUser\")
 521                                         (A    . \"default A\")))
 522        (auth-source-creation-prompts
 523         '((password . \"Enter IMAP password for %h:%p: \"))))
 524   (auth-source-search :host '(\"nonesuch\" \"twosuch\") :type 'netrc :max 1
 525                       :P \"pppp\" :Q \"qqqq\"
 526                       :create '(A B Q)))
 527
 528 which says:
 529
 530 \"Search for any entry matching host 'nonesuch'
 531  or 'twosuch' in backends of type 'netrc', maximum one result.
 532
 533  Create a new entry if you found none.  The netrc backend will
 534  automatically require host, user, and port.  The host will be
 535  'nonesuch' and Q will be 'qqqq'.  We prompt for the password
 536  with the shown prompt.  We will not prompt for Q.  The resulting
 537  token will have keys user, host, port, A, B, and Q.  It will not
 538  have P with any value, even though P is used in the search to
 539  find only entries that have P set to 'pppp'.\"
 540
 541 When multiple values are specified in the search parameter, the
 542 user is prompted for which one.  So :host (X Y Z) would ask the
 543 user to choose between X, Y, and Z.
 544
 545 This creation can fail if the search was not specific enough to
 546 create a new token (it's up to the backend to decide that).  You
 547 should `catch' the backend-specific error as usual.  Some
 548 backends (netrc, at least) will prompt the user rather than throw
 549 an error.
 550
 551 :require (A B C) means that only results that contain those
 552 tokens will be returned.  Thus for instance requiring :secret
 553 will ensure that any results will actually have a :secret
 554 property.
 555
 556 :delete t means to delete any found entries.  nil by default.
 557 Use `auth-source-delete' in ELisp code instead of calling
 558 `auth-source-search' directly with this parameter.
 559
 560 :type (X Y Z) will check only those backend types.  'netrc and
 561 'secrets are the only ones supported right now.
 562
 563 :max N means to try to return at most N items (defaults to 1).
 564 When 0 the function will return just t or nil to indicate if any
 565 matches were found.  More than N items may be returned, depending
 566 on the search and the backend.
 567
 568 :host (X Y Z) means to match only hosts X, Y, or Z according to
 569 the match rules above.  Defaults to t.
 570
 571 :user (X Y Z) means to match only users X, Y, or Z according to
 572 the match rules above.  Defaults to t.
 573
 574 :port (P Q R) means to match only protocols P, Q, or R.
 575 Defaults to t.
 576
 577 :K (V1 V2 V3) for any other key K will match values V1, V2, or
 578 V3 (note the match rules above).
 579
 580 The return value is a list with at most :max tokens.  Each token
 581 is a plist with keys :backend :host :port :user, plus any other
 582 keys provided by the backend (notably :secret).  But note the
 583 exception for :max 0, which see above.
 584
 585 The token can hold a :save-function key.  If you call that, the
 586 user will be prompted to save the data to the backend.  You can't
 587 request that this should happen right after creation, because
 588 `auth-source-search' has no way of knowing if the token is
 589 actually useful.  So the caller must arrange to call this function.
 590
 591 The token's :secret key can hold a function.  In that case you
 592 must call it to obtain the actual value."
 593   (let* ((backends (mapcar 'auth-source-backend-parse auth-sources))
 594          (max (or max 1))
 595          (ignored-keys '(:require :create :delete :max))
 596          (keys (loop for i below (length spec) by 2
 597                      unless (memq (nth i spec) ignored-keys)
 598                      collect (nth i spec)))
 599          (cached (auth-source-remembered-p spec))
 600          ;; note that we may have cached results but found is still nil
 601          ;; (there were no results from the search)
 602          (found (auth-source-recall spec))
 603          filtered-backends accessor-key backend)
 604
 605     (if (and cached auth-source-do-cache)
 606         (auth-source-do-debug
 607          "auth-source-search: found %d CACHED results matching %S"
 608          (length found) spec)
 609
 610       (assert
 611        (or (eq t create) (listp create)) t
 612        "Invalid auth-source :create parameter (must be t or a list): %s %s")
 613
 614       (assert
 615        (listp require) t
 616        "Invalid auth-source :require parameter (must be a list): %s")
 617
 618       (setq filtered-backends (copy-sequence backends))
 619       (dolist (backend backends)
 620         (dolist (key keys)
 621           ;; ignore invalid slots
 622           (condition-case signal
 623               (unless (eval `(auth-source-search-collection
 624                               (plist-get spec key)
 625                               (oref backend ,key)))
 626                 (setq filtered-backends (delq backend filtered-backends))
 627                 (return))
 628             (invalid-slot-name))))
 629
 630       (auth-source-do-trivia
 631        "auth-source-search: found %d backends matching %S"
 632        (length filtered-backends) spec)
 633
 634       ;; (debug spec "filtered" filtered-backends)
 635       ;; First go through all the backends without :create, so we can
 636       ;; query them all.
 637       (setq found (auth-source-search-backends filtered-backends
 638                                                spec
 639                                                ;; to exit early
 640                                                max
 641                                                ;; create is always nil here
 642                                                nil delete
 643                                                require))
 644
 645       (auth-source-do-debug
 646        "auth-source-search: found %d results (max %d) matching %S"
 647        (length found) max spec)
 648
 649       ;; If we didn't find anything, then we allow the backend(s) to
 650       ;; create the entries.
 651       (when (and create
 652                  (not found))
 653         (setq found (auth-source-search-backends filtered-backends
 654                                                  spec
 655                                                  ;; to exit early
 656                                                  max
 657                                                  create delete
 658                                                  require))
 659         (auth-source-do-debug
 660          "auth-source-search: CREATED %d results (max %d) matching %S"
 661          (length found) max spec))
 662
 663       ;; note we remember the lack of result too, if it's applicable
 664       (when auth-source-do-cache
 665         (auth-source-remember spec found)))
 666
 667       found))
 668
 669 (defun auth-source-search-backends (backends spec max create delete require)
 670   (let (matches)
 671     (dolist (backend backends)
 672       (when (> max (length matches))   ; when we need more matches...
 673         (let* ((bmatches (apply
 674                           (slot-value backend 'search-function)
 675                           :backend backend
 676                           ;; note we're overriding whatever the spec
 677                           ;; has for :require, :create, and :delete
 678                           :require require
 679                           :create create
 680                           :delete delete
 681                           spec)))
 682           (when bmatches
 683             (auth-source-do-trivia
 684              "auth-source-search-backend: got %d (max %d) in %s:%s matching %S"
 685              (length bmatches) max
 686              (slot-value backend :type)
 687              (slot-value backend :source)
 688              spec)
 689             (setq matches (append matches bmatches))))))
 690     matches))
 691
 692 ;;; (auth-source-search :max 1)
 693 ;;; (funcall (plist-get (nth 0 (auth-source-search :max 1)) :secret))
 694 ;;; (auth-source-search :host "nonesuch" :type 'netrc :K 1)
 695 ;;; (auth-source-search :host "nonesuch" :type 'secrets)
 696
 697 (defun* auth-source-delete (&rest spec
 698                                   &key delete
 699                                   &allow-other-keys)
 700   "Delete entries from the authentication backends according to SPEC.
 701 Calls `auth-source-search' with the :delete property in SPEC set to t.
 702 The backend may not actually delete the entries.
 703
 704 Returns the deleted entries."
 705   (auth-source-search (plist-put spec :delete t)))
 706
 707 (defun auth-source-search-collection (collection value)
 708   "Returns t is VALUE is t or COLLECTION is t or contains VALUE."
 709   (when (and (atom collection) (not (eq t collection)))
 710     (setq collection (list collection)))
 711
 712   ;; (debug :collection collection :value value)
 713   (or (eq collection t)
 714       (eq value t)
 715       (equal collection value)
 716       (member value collection)))
 717
 718 (defvar auth-source-netrc-cache nil)
 719
 720 (defun auth-source-forget-all-cached ()
 721   "Forget all cached auth-source data."
 722   (interactive)
 723   (loop for sym being the symbols of password-data
 724         ;; when the symbol name starts with auth-source-magic
 725         when (string-match (concat "^" auth-source-magic)
 726                            (symbol-name sym))
 727         ;; remove that key
 728         do (password-cache-remove (symbol-name sym)))
 729   (setq auth-source-netrc-cache nil))
 730
 731 (defun auth-source-remember (spec found)
 732   "Remember FOUND search results for SPEC."
 733   (let ((password-cache-expiry auth-source-cache-expiry))
 734     (password-cache-add
 735      (concat auth-source-magic (format "%S" spec)) found)))
 736
 737 (defun auth-source-recall (spec)
 738   "Recall FOUND search results for SPEC."
 739   (password-read-from-cache
 740    (concat auth-source-magic (format "%S" spec))))
 741
 742 (defun auth-source-remembered-p (spec)
 743   "Check if SPEC is remembered."
 744   (password-in-cache-p
 745    (concat auth-source-magic (format "%S" spec))))
 746
 747 (defun auth-source-forget (spec)
 748   "Forget any cached data matching SPEC exactly.
 749
 750 This is the same SPEC you passed to `auth-source-search'.
 751 Returns t or nil for forgotten or not found."
 752   (password-cache-remove (concat auth-source-magic (format "%S" spec))))
 753
 754 ;;; (loop for sym being the symbols of password-data when (string-match (concat "^" auth-source-magic) (symbol-name sym)) collect (symbol-name sym))
 755
 756 ;;; (auth-source-remember '(:host "wedd") '(4 5 6))
 757 ;;; (auth-source-remembered-p '(:host "wedd"))
 758 ;;; (auth-source-remember '(:host "xedd") '(1 2 3))
 759 ;;; (auth-source-remembered-p '(:host "xedd"))
 760 ;;; (auth-source-remembered-p '(:host "zedd"))
 761 ;;; (auth-source-recall '(:host "xedd"))
 762 ;;; (auth-source-recall '(:host t))
 763 ;;; (auth-source-forget+ :host t)
 764
 765 (defun* auth-source-forget+ (&rest spec &allow-other-keys)
 766   "Forget any cached data matching SPEC.  Returns forgotten count.
 767
 768 This is not a full `auth-source-search' spec but works similarly.
 769 For instance, \(:host \"myhost\" \"yourhost\") would find all the
 770 cached data that was found with a search for those two hosts,
 771 while \(:host t) would find all host entries."
 772   (let ((count 0)
 773         sname)
 774     (loop for sym being the symbols of password-data
 775           ;; when the symbol name matches with auth-source-magic
 776           when (and (setq sname (symbol-name sym))
 777                     (string-match (concat "^" auth-source-magic "\\(.+\\)")
 778                                   sname)
 779                     ;; and the spec matches what was stored in the cache
 780                     (auth-source-specmatchp spec (read (match-string 1 sname))))
 781           ;; remove that key
 782           do (progn
 783                (password-cache-remove sname)
 784                (incf count)))
 785     count))
 786
 787 (defun auth-source-specmatchp (spec stored)
 788   (let ((keys (loop for i below (length spec) by 2
 789                    collect (nth i spec))))
 790     (not (eq
 791           (dolist (key keys)
 792             (unless (auth-source-search-collection (plist-get stored key)
 793                                                    (plist-get spec key))
 794               (return 'no)))
 795           'no))))
 796
 797 ;;; (auth-source-pick-first-password :host "z.lifelogs.com")
 798 ;;; (auth-source-pick-first-password :port "imap")
 799 (defun auth-source-pick-first-password (&rest spec)
 800   "Pick the first secret found from applying SPEC to `auth-source-search'."
 801   (let* ((result (nth 0 (apply 'auth-source-search (plist-put spec :max 1))))
 802          (secret (plist-get result :secret)))
 803
 804     (if (functionp secret)
 805         (funcall secret)
 806       secret)))
 807
 808 ;; (auth-source-format-prompt "test %u %h %p" '((?u "user") (?h "host")))
 809 (defun auth-source-format-prompt (prompt alist)
 810   "Format PROMPT using %x (for any character x) specifiers in ALIST."
 811   (dolist (cell alist)
 812     (let ((c (nth 0 cell))
 813           (v (nth 1 cell)))
 814       (when (and c v)
 815         (setq prompt (replace-regexp-in-string (format "%%%c" c)
 816                                                (format "%s" v)
 817                                                prompt)))))
 818   prompt)
 819
 820 (defun auth-source-ensure-strings (values)
 821   (unless (listp values)
 822     (setq values (list values)))
 823   (mapcar (lambda (value)
 824             (if (numberp value)
 825                 (format "%s" value)
 826               value))
 827           values))
 828
 829 ;;; Backend specific parsing: netrc/authinfo backend
 830
 831 ;;; (auth-source-netrc-parse "~/.authinfo.gpg")
 832 (defun* auth-source-netrc-parse (&rest
 833                                  spec
 834                                  &key file max host user port delete require
 835                                  &allow-other-keys)
 836   "Parse FILE and return a list of all entries in the file.
 837 Note that the MAX parameter is used so we can exit the parse early."
 838   (if (listp file)
 839       ;; We got already parsed contents; just return it.
 840       file
 841     (when (file-exists-p file)
 842       (setq port (auth-source-ensure-strings port))
 843       (with-temp-buffer
 844         (let* ((tokens '("machine" "host" "default" "login" "user"
 845                          "password" "account" "macdef" "force"
 846                          "port" "protocol"))
 847                (max (or max 5000))       ; sanity check: default to stop at 5K
 848                (modified 0)
 849                (cached (cdr-safe (assoc file auth-source-netrc-cache)))
 850                (cached-mtime (plist-get cached :mtime))
 851                (cached-secrets (plist-get cached :secret))
 852                alist elem result pair)
 853
 854           (if (and (functionp cached-secrets)
 855                    (equal cached-mtime
 856                           (nth 5 (file-attributes file))))
 857               (progn
 858                 (auth-source-do-trivia
 859                  "auth-source-netrc-parse: using CACHED file data for %s"
 860                  file)
 861                 (insert (funcall cached-secrets)))
 862             (insert-file-contents file)
 863             ;; cache all netrc files (used to be just .gpg files)
 864             ;; Store the contents of the file heavily encrypted in memory.
 865             ;; (note for the irony-impaired: they are just obfuscated)
 866             (aput 'auth-source-netrc-cache file
 867                   (list :mtime (nth 5 (file-attributes file))
 868                         :secret (lexical-let ((v (rot13-string
 869                                                   (base64-encode-string
 870                                                    (buffer-string)))))
 871                                   (lambda () (base64-decode-string
 872                                          (rot13-string v)))))))
 873           (goto-char (point-min))
 874           ;; Go through the file, line by line.
 875           (while (and (not (eobp))
 876                       (> max 0))
 877
 878             (narrow-to-region (point) (point-at-eol))
 879             ;; For each line, get the tokens and values.
 880             (while (not (eobp))
 881               (skip-chars-forward "\t ")
 882               ;; Skip lines that begin with a "#".
 883               (if (eq (char-after) ?#)
 884                   (goto-char (point-max))
 885                 (unless (eobp)
 886                   (setq elem
 887                         (if (= (following-char) ?\")
 888                             (read (current-buffer))
 889                           (buffer-substring
 890                            (point) (progn (skip-chars-forward "^\t ")
 891                                           (point)))))
 892                   (cond
 893                    ((equal elem "macdef")
 894                     ;; We skip past the macro definition.
 895                     (widen)
 896                     (while (and (zerop (forward-line 1))
 897                                 (looking-at "$")))
 898                     (narrow-to-region (point) (point)))
 899                    ((member elem tokens)
 900                     ;; Tokens that don't have a following value are ignored,
 901                     ;; except "default".
 902                     (when (and pair (or (cdr pair)
 903                                         (equal (car pair) "default")))
 904                       (push pair alist))
 905                     (setq pair (list elem)))
 906                    (t
 907                     ;; Values that haven't got a preceding token are ignored.
 908                     (when pair
 909                       (setcdr pair elem)
 910                       (push pair alist)
 911                       (setq pair nil)))))))
 912
 913             (when (and alist
 914                        (> max 0)
 915                        (auth-source-search-collection
 916                         host
 917                         (or
 918                          (aget alist "machine")
 919                          (aget alist "host")
 920                          t))
 921                        (auth-source-search-collection
 922                         user
 923                         (or
 924                          (aget alist "login")
 925                          (aget alist "account")
 926                          (aget alist "user")
 927                          t))
 928                        (auth-source-search-collection
 929                         port
 930                         (or
 931                          (aget alist "port")
 932                          (aget alist "protocol")
 933                          t))
 934                        (or
 935                         ;; the required list of keys is nil, or
 936                         (null require)
 937                         ;; every element of require is in the normalized list
 938                         (let ((normalized (nth 0 (auth-source-netrc-normalize
 939                                                  (list alist) file))))
 940                           (loop for req in require
 941                                 always (plist-get normalized req)))))
 942               (decf max)
 943               (push (nreverse alist) result)
 944               ;; to delete a line, we just comment it out
 945               (when delete
 946                 (goto-char (point-min))
 947                 (insert "#")
 948                 (incf modified)))
 949             (setq alist nil
 950                   pair nil)
 951             (widen)
 952             (forward-line 1))
 953
 954           (when (< 0 modified)
 955             (when auth-source-gpg-encrypt-to
 956               ;; (see bug#7487) making `epa-file-encrypt-to' local to
 957               ;; this buffer lets epa-file skip the key selection query
 958               ;; (see the `local-variable-p' check in
 959               ;; `epa-file-write-region').
 960               (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
 961                 (make-local-variable 'epa-file-encrypt-to))
 962               (if (listp auth-source-gpg-encrypt-to)
 963                   (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
 964
 965             ;; ask AFTER we've successfully opened the file
 966             (when (y-or-n-p (format "Save file %s? (%d deletions)"
 967                                     file modified))
 968               (write-region (point-min) (point-max) file nil 'silent)
 969               (auth-source-do-debug
 970                "auth-source-netrc-parse: modified %d lines in %s"
 971                modified file)))
 972
 973           (nreverse result))))))
 974
 975 (defmacro with-auth-source-epa-overrides (&rest body)
 976   `(let ((file-name-handler-alist
 977           ',(if (boundp 'epa-file-handler)
 978                 (remove (symbol-value 'epa-file-handler)
 979                         file-name-handler-alist)
 980               file-name-handler-alist))
 981          (,(if (boundp 'find-file-hook) 'find-file-hook 'find-file-hooks)
 982           ',(remove
 983              'epa-file-find-file-hook
 984              (if (boundp 'find-file-hook) 'find-file-hook 'find-file-hooks)))
 985          (auto-mode-alist
 986           ',(if (boundp 'epa-file-auto-mode-alist-entry)
 987                 (remove (symbol-value 'epa-file-auto-mode-alist-entry)
 988                         auto-mode-alist)
 989               auto-mode-alist)))
 990      ,@body))
 991
 992 (defun auth-source-epa-make-gpg-token (secret file)
 993   (require 'epa nil t)
 994   (unless (featurep 'epa)
 995     (error "EPA could not be loaded."))
 996   (let* ((base (file-name-sans-extension file))
 997          (passkey (format "gpg:-%s" base))
 998          (stash (concat base ".gpg"))
 999          ;; temporarily disable EPA
1000          (stashfile
1001           (with-auth-source-epa-overrides
1002            (make-temp-file "gpg-token" nil
1003                            stash)))
1004          (epa-file-passphrase-alist
1005           `((,stashfile
1006              . ,(password-read
1007                  (format
1008                   "token pass for %s? "
1009                   file)
1010                  passkey)))))
1011     (write-region secret nil stashfile)
1012     ;; temporarily disable EPA
1013     (unwind-protect
1014         (with-auth-source-epa-overrides
1015          (with-temp-buffer
1016            (insert-file-contents stashfile)
1017            (base64-encode-region (point-min) (point-max) t)
1018            (concat "gpg:"
1019                    (buffer-substring-no-properties
1020                     (point-min)
1021                     (point-max)))))
1022       (delete-file stashfile))))
1023
1024 (defun auth-source-netrc-normalize (alist filename)
1025   (mapcar (lambda (entry)
1026             (let (ret item)
1027               (while (setq item (pop entry))
1028                 (let ((k (car item))
1029                       (v (cdr item)))
1030
1031                   ;; apply key aliases
1032                   (setq k (cond ((member k '("machine")) "host")
1033                                 ((member k '("login" "account")) "user")
1034                                 ((member k '("protocol")) "port")
1035                                 ((member k '("password")) "secret")
1036                                 (t k)))
1037
1038                   ;; send back the secret in a function (lexical binding)
1039                   (when (equal k "secret")
1040                     (setq v (lexical-let ((v v)
1041                                           (filename filename)
1042                                           (base (file-name-nondirectory
1043                                                  filename))
1044                                           (token-decoder nil)
1045                                           (gpgdata nil)
1046                                           (stash nil))
1047                               (setq stash (concat base ".gpg"))
1048                               (when (string-match "gpg:\\(.+\\)" v)
1049                                 (require 'epa nil t)
1050                                 (unless (featurep 'epa)
1051                                   (error "EPA could not be loaded."))
1052                                 (setq gpgdata (base64-decode-string
1053                                                (match-string 1 v)))
1054                                 ;; it's a GPG token
1055                                 (setq
1056                                  token-decoder
1057                                  (lambda (gpgdata)
1058 ;;; FIXME: this relies on .gpg files being handled by EPA/EPG
1059                                    (let* ((passkey (format "gpg:-%s" base))
1060                                           ;; temporarily disable EPA
1061                                           (stashfile
1062                                            (with-auth-source-epa-overrides
1063                                             (make-temp-file "gpg-token" nil
1064                                                             stash)))
1065                                           (epa-file-passphrase-alist
1066                                            `((,stashfile
1067                                               . ,(password-read
1068                                                   (format
1069                                                    "token pass for %s? "
1070                                                    filename)
1071                                                   passkey)))))
1072                                      (unwind-protect
1073                                          (progn
1074                                            ;; temporarily disable EPA
1075                                            (with-auth-source-epa-overrides
1076                                             (write-region gpgdata
1077                                                           nil
1078                                                           stashfile))
1079                                            (setq
1080                                             v
1081                                             (with-temp-buffer
1082                                               (insert-file-contents stashfile)
1083                                               (buffer-substring-no-properties
1084                                                (point-min)
1085                                                (point-max)))))
1086                                        (delete-file stashfile)))
1087                                    ;; clear out the decoder at end
1088                                    (setq token-decoder nil
1089                                          gpgdata nil))))
1090                           (lambda ()
1091                             (when token-decoder
1092                               (funcall token-decoder gpgdata))
1093                             v))))
1094                 (setq ret (plist-put ret
1095                                      (intern (concat ":" k))
1096                                      v))))
1097             ret))
1098   alist))
1099
1100 ;;; (setq secret (plist-get (nth 0 (auth-source-search :host t :type 'netrc :K 1 :max 1)) :secret))
1101 ;;; (funcall secret)
1102
1103 (defun* auth-source-netrc-search (&rest
1104                                   spec
1105                                   &key backend require create delete
1106                                   type max host user port
1107                                   &allow-other-keys)
1108 "Given a property list SPEC, return search matches from the :backend.
1109 See `auth-source-search' for details on SPEC."
1110   ;; just in case, check that the type is correct (null or same as the backend)
1111   (assert (or (null type) (eq type (oref backend type)))
1112           t "Invalid netrc search: %s %s")
1113
1114   (let ((results (auth-source-netrc-normalize
1115                   (auth-source-netrc-parse
1116                    :max max
1117                    :require require
1118                    :delete delete
1119                    :file (oref backend source)
1120                    :host (or host t)
1121                    :user (or user t)
1122                    :port (or port t))
1123                   (oref backend source))))
1124
1125     ;; if we need to create an entry AND none were found to match
1126     (when (and create
1127                (not results))
1128
1129       ;; create based on the spec and record the value
1130       (setq results (or
1131                      ;; if the user did not want to create the entry
1132                      ;; in the file, it will be returned
1133                      (apply (slot-value backend 'create-function) spec)
1134                      ;; if not, we do the search again without :create
1135                      ;; to get the updated data.
1136
1137                      ;; the result will be returned, even if the search fails
1138                      (apply 'auth-source-netrc-search
1139                             (plist-put spec :create nil)))))
1140     results))
1141
1142 (defun auth-source-netrc-element-or-first (v)
1143   (if (listp v)
1144       (nth 0 v)
1145     v))
1146
1147 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t)
1148 ;;; (auth-source-search :host "nonesuch" :type 'netrc :max 1 :create t :create-extra-keys '((A "default A") (B)))
1149
1150 (defun* auth-source-netrc-create (&rest spec
1151                                         &key backend
1152                                         secret host user port create
1153                                         &allow-other-keys)
1154   (let* ((base-required '(host user port secret))
1155          ;; we know (because of an assertion in auth-source-search) that the
1156          ;; :create parameter is either t or a list (which includes nil)
1157          (create-extra (if (eq t create) nil create))
1158          (current-data (car (auth-source-search :max 1
1159                                                 :host host
1160                                                 :port port)))
1161          (required (append base-required create-extra))
1162          (file (oref backend source))
1163          (add "")
1164          ;; `valist' is an alist
1165          valist
1166          ;; `artificial' will be returned if no creation is needed
1167          artificial)
1168
1169     ;; only for base required elements (defined as function parameters):
1170     ;; fill in the valist with whatever data we may have from the search
1171     ;; we complete the first value if it's a list and use the value otherwise
1172     (dolist (br base-required)
1173       (when (symbol-value br)
1174         (let ((br-choice (cond
1175                           ;; all-accepting choice (predicate is t)
1176                           ((eq t (symbol-value br)) nil)
1177                           ;; just the value otherwise
1178                           (t (symbol-value br)))))
1179           (when br-choice
1180             (aput 'valist br br-choice)))))
1181
1182     ;; for extra required elements, see if the spec includes a value for them
1183     (dolist (er create-extra)
1184       (let ((name (concat ":" (symbol-name er)))
1185             (keys (loop for i below (length spec) by 2
1186                         collect (nth i spec))))
1187         (dolist (k keys)
1188           (when (equal (symbol-name k) name)
1189             (aput 'valist er (plist-get spec k))))))
1190
1191     ;; for each required element
1192     (dolist (r required)
1193       (let* ((data (aget valist r))
1194              ;; take the first element if the data is a list
1195              (data (or (auth-source-netrc-element-or-first data)
1196                        (plist-get current-data
1197                                   (intern (format ":%s" r) obarray))))
1198              ;; this is the default to be offered
1199              (given-default (aget auth-source-creation-defaults r))
1200              ;; the default supplementals are simple:
1201              ;; for the user, try `given-default' and then (user-login-name);
1202              ;; otherwise take `given-default'
1203              (default (cond
1204                        ((and (not given-default) (eq r 'user))
1205                         (user-login-name))
1206                        (t given-default)))
1207              (printable-defaults (list
1208                                   (cons 'user
1209                                         (or
1210                                          (auth-source-netrc-element-or-first
1211                                           (aget valist 'user))
1212                                          (plist-get artificial :user)
1213                                          "[any user]"))
1214                                   (cons 'host
1215                                         (or
1216                                          (auth-source-netrc-element-or-first
1217                                           (aget valist 'host))
1218                                          (plist-get artificial :host)
1219                                          "[any host]"))
1220                                   (cons 'port
1221                                         (or
1222                                          (auth-source-netrc-element-or-first
1223                                           (aget valist 'port))
1224                                          (plist-get artificial :port)
1225                                          "[any port]"))))
1226              (prompt (or (aget auth-source-creation-prompts r)
1227                          (case r
1228                            (secret "%p password for %u@%h: ")
1229                            (user "%p user name for %h: ")
1230                            (host "%p host name for user %u: ")
1231                            (port "%p port for %u@%h: "))
1232                          (format "Enter %s (%%u@%%h:%%p): " r)))
1233              (prompt (auth-source-format-prompt
1234                       prompt
1235                       `((?u ,(aget printable-defaults 'user))
1236                         (?h ,(aget printable-defaults 'host))
1237                         (?p ,(aget printable-defaults 'port))))))
1238
1239         ;; Store the data, prompting for the password if needed.
1240         (setq data
1241               (cond
1242                ((and (null data) (eq r 'secret))
1243                 ;; Special case prompt for passwords.
1244 ;; TODO: make the default (setq auth-source-netrc-use-gpg-tokens `((,(if (boundp 'epa-file-auto-mode-alist-entry) (car (symbol-value 'epa-file-auto-mode-alist-entry)) "\\.gpg\\'") nil) (t gpg)))
1245 ;; TODO: or maybe leave as (setq auth-source-netrc-use-gpg-tokens 'never)
1246                 (let* ((ep (format "Use GPG password tokens in %s?" file))
1247                        (gpg-encrypt
1248                         (cond
1249                          ((eq auth-source-netrc-use-gpg-tokens 'never)
1250                           'never)
1251                          ((listp auth-source-netrc-use-gpg-tokens)
1252                           (let ((check (copy-sequence
1253                                         auth-source-netrc-use-gpg-tokens))
1254                                 item ret)
1255                             (while check
1256                               (setq item (pop check))
1257                               (when (or (eq (car item) t)
1258                                         (string-match (car item) file))
1259                                 (setq ret (cdr item))
1260                                 (setq check nil)))))
1261                          (t 'never)))
1262                         (plain (read-passwd prompt)))
1263                   ;; ask if we don't know what to do (in which case
1264                   ;; auth-source-netrc-use-gpg-tokens must be a list)
1265                   (unless gpg-encrypt
1266                     (setq gpg-encrypt (if (y-or-n-p ep) 'gpg 'never))
1267                     ;; TODO: save the defcustom now? or ask?
1268                     (setq auth-source-netrc-use-gpg-tokens
1269                           (cons `(,file ,gpg-encrypt)
1270                                 auth-source-netrc-use-gpg-tokens)))
1271                   (if (eq gpg-encrypt 'gpg)
1272                       (auth-source-epa-make-gpg-token plain file)
1273                     plain)))
1274                ((null data)
1275                 (when default
1276                   (setq prompt
1277                         (if (string-match ": *\\'" prompt)
1278                             (concat (substring prompt 0 (match-beginning 0))
1279                                     " (default " default "): ")
1280                           (concat prompt "(default " default ") "))))
1281                 (read-string prompt nil nil default))
1282                (t (or data default))))
1283
1284         (when data
1285           (setq artificial (plist-put artificial
1286                                       (intern (concat ":" (symbol-name r)))
1287                                       (if (eq r 'secret)
1288                                           (lexical-let ((data data))
1289                                             (lambda () data))
1290                                         data))))
1291
1292         ;; When r is not an empty string...
1293         (when (and (stringp data)
1294                    (< 0 (length data)))
1295           ;; this function is not strictly necessary but I think it
1296           ;; makes the code clearer -tzz
1297           (let ((printer (lambda ()
1298                            ;; append the key (the symbol name of r)
1299                            ;; and the value in r
1300                            (format "%s%s %s"
1301                                    ;; prepend a space
1302                                    (if (zerop (length add)) "" " ")
1303                                    ;; remap auth-source tokens to netrc
1304                                    (case r
1305                                      (user   "login")
1306                                      (host   "machine")
1307                                      (secret "password")
1308                                      (port   "port") ; redundant but clearer
1309                                      (t (symbol-name r)))
1310                                    (if (string-match "[\" ]" data)
1311                                        (format "%S" data)
1312                                      data)))))
1313             (setq add (concat add (funcall printer)))))))
1314
1315     (plist-put
1316      artificial
1317      :save-function
1318      (lexical-let ((file file)
1319                    (add add))
1320        (lambda () (auth-source-netrc-saver file add))))
1321
1322     (list artificial)))
1323
1324 ;;(funcall (plist-get (nth 0 (auth-source-search :host '("nonesuch2") :user "tzz" :port "imap" :create t :max 1)) :save-function))
1325 (defun auth-source-netrc-saver (file add)
1326   "Save a line ADD in FILE, prompting along the way.
1327 Respects `auth-source-save-behavior'.  Uses
1328 `auth-source-netrc-cache' to avoid prompting more than once."
1329   (let* ((key (format "%s %s" file (rfc2104-hash 'md5 64 16 file add)))
1330          (cached (assoc key auth-source-netrc-cache)))
1331
1332     (if cached
1333         (auth-source-do-trivia
1334          "auth-source-netrc-saver: found previous run for key %s, returning"
1335          key)
1336       (with-temp-buffer
1337         (when (file-exists-p file)
1338           (insert-file-contents file))
1339         (when auth-source-gpg-encrypt-to
1340           ;; (see bug#7487) making `epa-file-encrypt-to' local to
1341           ;; this buffer lets epa-file skip the key selection query
1342           ;; (see the `local-variable-p' check in
1343           ;; `epa-file-write-region').
1344           (unless (local-variable-p 'epa-file-encrypt-to (current-buffer))
1345             (make-local-variable 'epa-file-encrypt-to))
1346           (if (listp auth-source-gpg-encrypt-to)
1347               (setq epa-file-encrypt-to auth-source-gpg-encrypt-to)))
1348         ;; we want the new data to be found first, so insert at beginning
1349         (goto-char (point-min))
1350
1351         ;; Ask AFTER we've successfully opened the file.
1352         (let ((prompt (format "Save auth info to file %s? " file))
1353               (done (not (eq auth-source-save-behavior 'ask)))
1354               (bufname "*auth-source Help*")
1355               k)
1356           (while (not done)
1357             (setq k (auth-source-read-char-choice prompt '(?y ?n ?N ?e ??)))
1358             (case k
1359               (?y (setq done t))
1360               (?? (save-excursion
1361                     (with-output-to-temp-buffer bufname
1362                       (princ
1363                        (concat "(y)es, save\n"
1364                                "(n)o but use the info\n"
1365                                "(N)o and don't ask to save again\n"
1366                                "(e)dit the line\n"
1367                                "(?) for help as you can see.\n"))
1368                       ;; Why?  Doesn't with-output-to-temp-buffer already do
1369                       ;; the exact same thing anyway?  --Stef
1370                       (set-buffer standard-output)
1371                       (help-mode))))
1372               (?n (setq add ""
1373                         done t))
1374               (?N (setq add ""
1375                         done t
1376                         auth-source-save-behavior nil))
1377               (?e (setq add (read-string "Line to add: " add)))
1378               (t nil)))
1379
1380           (when (get-buffer-window bufname)
1381             (delete-window (get-buffer-window bufname)))
1382
1383           ;; Make sure the info is not saved.
1384           (when (null auth-source-save-behavior)
1385             (setq add ""))
1386
1387           (when (< 0 (length add))
1388             (progn
1389               (unless (bolp)
1390                 (insert "\n"))
1391               (insert add "\n")
1392               (write-region (point-min) (point-max) file nil 'silent)
1393               (auth-source-do-debug
1394                "auth-source-netrc-create: wrote 1 new line to %s"
1395                file)
1396               (message "Saved new authentication information to %s" file)
1397               nil))))
1398       (aput 'auth-source-netrc-cache key "ran"))))
1399
1400 ;;; Backend specific parsing: Secrets API backend
1401
1402 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :create t))
1403 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1 :delete t))
1404 ;;; (let ((auth-sources '(default))) (auth-source-search :max 1))
1405 ;;; (let ((auth-sources '(default))) (auth-source-search))
1406 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1))
1407 ;;; (let ((auth-sources '("secrets:Login"))) (auth-source-search :max 1 :signon_realm "https://git.gnus.org/Git"))
1408
1409 (defun* auth-source-secrets-search (&rest
1410                                     spec
1411                                     &key backend create delete label
1412                                     type max host user port
1413                                     &allow-other-keys)
1414   "Search the Secrets API; spec is like `auth-source'.
1415
1416 The :label key specifies the item's label.  It is the only key
1417 that can specify a substring.  Any :label value besides a string
1418 will allow any label.
1419
1420 All other search keys must match exactly.  If you need substring
1421 matching, do a wider search and narrow it down yourself.
1422
1423 You'll get back all the properties of the token as a plist.
1424
1425 Here's an example that looks for the first item in the 'Login'
1426 Secrets collection:
1427
1428  \(let ((auth-sources '(\"secrets:Login\")))
1429     (auth-source-search :max 1)
1430
1431 Here's another that looks for the first item in the 'Login'
1432 Secrets collection whose label contains 'gnus':
1433
1434  \(let ((auth-sources '(\"secrets:Login\")))
1435     (auth-source-search :max 1 :label \"gnus\")
1436
1437 And this one looks for the first item in the 'Login' Secrets
1438 collection that's a Google Chrome entry for the git.gnus.org site
1439 authentication tokens:
1440
1441  \(let ((auth-sources '(\"secrets:Login\")))
1442     (auth-source-search :max 1 :signon_realm \"https://git.gnus.org/Git\"))
1443 "
1444
1445   ;; TODO
1446   (assert (not create) nil
1447           "The Secrets API auth-source backend doesn't support creation yet")
1448   ;; TODO
1449   ;; (secrets-delete-item coll elt)
1450   (assert (not delete) nil
1451           "The Secrets API auth-source backend doesn't support deletion yet")
1452
1453   (let* ((coll (oref backend source))
1454          (max (or max 5000))     ; sanity check: default to stop at 5K
1455          (ignored-keys '(:create :delete :max :backend :label))
1456          (search-keys (loop for i below (length spec) by 2
1457                             unless (memq (nth i spec) ignored-keys)
1458                             collect (nth i spec)))
1459          ;; build a search spec without the ignored keys
1460          ;; if a search key is nil or t (match anything), we skip it
1461          (search-spec (apply 'append (mapcar
1462                                       (lambda (k)
1463                                         (if (or (null (plist-get spec k))
1464                                                 (eq t (plist-get spec k)))
1465                                             nil
1466                                           (list k (plist-get spec k))))
1467                               search-keys)))
1468          ;; needed keys (always including host, login, port, and secret)
1469          (returned-keys (mm-delete-duplicates (append
1470                                                '(:host :login :port :secret)
1471                                                search-keys)))
1472          (items (loop for item in (apply 'secrets-search-items coll search-spec)
1473                       unless (and (stringp label)
1474                                   (not (string-match label item)))
1475                       collect item))
1476          ;; TODO: respect max in `secrets-search-items', not after the fact
1477          (items (butlast items (- (length items) max)))
1478          ;; convert the item name to a full plist
1479          (items (mapcar (lambda (item)
1480                           (append
1481                            ;; make an entry for the secret (password) element
1482                            (list
1483                             :secret
1484                             (lexical-let ((v (secrets-get-secret coll item)))
1485                               (lambda () v)))
1486                            ;; rewrite the entry from ((k1 v1) (k2 v2)) to plist
1487                            (apply 'append
1488                                   (mapcar (lambda (entry)
1489                                             (list (car entry) (cdr entry)))
1490                                           (secrets-get-attributes coll item)))))
1491                         items))
1492          ;; ensure each item has each key in `returned-keys'
1493          (items (mapcar (lambda (plist)
1494                           (append
1495                            (apply 'append
1496                                   (mapcar (lambda (req)
1497                                             (if (plist-get plist req)
1498                                                 nil
1499                                               (list req nil)))
1500                                           returned-keys))
1501                            plist))
1502                         items)))
1503     items))
1504
1505 (defun* auth-source-secrets-create (&rest
1506                                     spec
1507                                     &key backend type max host user port
1508                                     &allow-other-keys)
1509   ;; TODO
1510   ;; (apply 'secrets-create-item (auth-get-source entry) name passwd spec)
1511   (debug spec))
1512
1513 ;;; older API
1514
1515 ;;; (auth-source-user-or-password '("login" "password") "imap.myhost.com" t "tzz")
1516
1517 ;; deprecate the old interface
1518 (make-obsolete 'auth-source-user-or-password
1519                'auth-source-search "Emacs 24.1")
1520 (make-obsolete 'auth-source-forget-user-or-password
1521                'auth-source-forget "Emacs 24.1")
1522
1523 (defun auth-source-user-or-password
1524   (mode host port &optional username create-missing delete-existing)
1525   "Find MODE (string or list of strings) matching HOST and PORT.
1526
1527 DEPRECATED in favor of `auth-source-search'!
1528
1529 USERNAME is optional and will be used as \"login\" in a search
1530 across the Secret Service API (see secrets.el) if the resulting
1531 items don't have a username.  This means that if you search for
1532 username \"joe\" and it matches an item but the item doesn't have
1533 a :user attribute, the username \"joe\" will be returned.
1534
1535 A non nil DELETE-EXISTING means deleting any matching password
1536 entry in the respective sources.  This is useful only when
1537 CREATE-MISSING is non nil as well; the intended use case is to
1538 remove wrong password entries.
1539
1540 If no matching entry is found, and CREATE-MISSING is non nil,
1541 the password will be retrieved interactively, and it will be
1542 stored in the password database which matches best (see
1543 `auth-sources').
1544
1545 MODE can be \"login\" or \"password\"."
1546   (auth-source-do-debug
1547    "auth-source-user-or-password: DEPRECATED get %s for %s (%s) + user=%s"
1548    mode host port username)
1549
1550   (let* ((listy (listp mode))
1551          (mode (if listy mode (list mode)))
1552          (cname (if username
1553                     (format "%s %s:%s %s" mode host port username)
1554                   (format "%s %s:%s" mode host port)))
1555          (search (list :host host :port port))
1556          (search (if username (append search (list :user username)) search))
1557          (search (if create-missing
1558                      (append search (list :create t))
1559                    search))
1560          (search (if delete-existing
1561                      (append search (list :delete t))
1562                    search))
1563          ;; (found (if (not delete-existing)
1564          ;;            (gethash cname auth-source-cache)
1565          ;;          (remhash cname auth-source-cache)
1566          ;;          nil)))
1567          (found nil))
1568     (if found
1569         (progn
1570           (auth-source-do-debug
1571            "auth-source-user-or-password: DEPRECATED cached %s=%s for %s (%s) + %s"
1572            mode
1573            ;; don't show the password
1574            (if (and (member "password" mode) t)
1575                "SECRET"
1576              found)
1577            host port username)
1578           found)                        ; return the found data
1579       ;; else, if not found, search with a max of 1
1580       (let ((choice (nth 0 (apply 'auth-source-search
1581                                   (append '(:max 1) search)))))
1582         (when choice
1583           (dolist (m mode)
1584             (cond
1585              ((equal "password" m)
1586               (push (if (plist-get choice :secret)
1587                       (funcall (plist-get choice :secret))
1588                     nil) found))
1589              ((equal "login" m)
1590               (push (plist-get choice :user) found)))))
1591         (setq found (nreverse found))
1592         (setq found (if listy found (car-safe found)))))
1593
1594         found))
1595
1596 (provide 'auth-source)
1597
1598 ;;; auth-source.el ends here