cgit.sxemacs.org Git - packages/blob - xemacs-packages/xemacs-base/timezone.el

   1 ;;; timezone.el --- time zone package for XEmacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996, 1999 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu Umeda
   6 ;; Maintainer: XEmacs Development Team
   7 ;; Keywords: news
   8
   9 ;; This file is part of XEmacs.
  10
  11 ;; XEmacs is free software; you can redistribute it and/or modify it
  12 ;; under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; XEmacs is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with XEmacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Synched up with: FSF 21.3.
  27
  28 ;;; Commentary:
  29
  30 ;; Modified 1 February 1994 by Kyle Jones to fix broken
  31 ;; timezone-floor function.
  32
  33 ;; Modified 25 January 1994 by Kyle Jones so that it will
  34 ;; work under version 18 of Emacs.  Provided timezone-floor
  35 ;; and timezone-abs functions.
  36
  37 ;;; Code:
  38
  39 (defvar timezone-world-timezones
  40   '(("PST" .  -800)
  41     ("PDT" .  -700)
  42     ("MST" .  -700)
  43     ("MDT" .  -600)
  44     ("CST" .  -600)
  45     ("CDT" .  -500)
  46     ("EST" .  -500)
  47     ("EDT" .  -400)
  48     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  49     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  50     ("UT"  .  +000)
  51     ("GMT" .  +000)
  52     ("BST" .  +100)
  53     ("MET" .  +100)
  54     ("EET" .  +200)
  55     ("JST" .  +900)
  56     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  57     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  58     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  59     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  60     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  61     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  62     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  63     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  64   "*Time differentials of timezone from GMT in +-HHMM form.
  65 This list is obsolescent, and is present only for backwards compatibility,
  66 because time zone names are ambiguous in practice.
  67 Use `current-time-zone' instead.")
  68
  69 (defvar timezone-months-assoc
  70   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  71     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  72     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  73     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  74   "Alist of first three letters of a month and its numerical representation.")
  75
  76 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  77   "Convert DATE to an arpanet standard date.
  78 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  79 if nil, GMT is assumed.
  80 Optional 3rd argument TIMEZONE specifies a time zone to be represented in;
  81 if nil, the local time zone is assumed."
  82   (let ((new (timezone-fix-time date local timezone)))
  83     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  84                              (timezone-make-time-string
  85                               (aref new 3) (aref new 4) (aref new 5))
  86                              (aref new 6))
  87     ))
  88
  89 (defun timezone-make-date-sortable (date &optional local timezone)
  90   "Convert DATE to a sortable date string.
  91 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  92 if nil, GMT is assumed.
  93 Optional 3rd argument TIMEZONE specifies a timezone to be represented in;
  94 if nil, the local time zone is assumed."
  95   (let ((new (timezone-fix-time date local timezone)))
  96     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  97                                  (timezone-make-time-string
  98                                   (aref new 3) (aref new 4) (aref new 5)))
  99     ))
 100
 101 \f
 102 ;;
 103 ;; Parsers and Constructors of Date and Time
 104 ;;
 105
 106 (defun timezone-make-arpa-date (year month day time &optional timezone)
 107   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
 108 Optional argument TIMEZONE specifies a time zone."
 109   (let ((zone
 110          (if (listp timezone)
 111              (let* ((m (timezone-zone-to-minute timezone))
 112                     (absm (if (< m 0) (- m) m)))
 113                (format "%c%02d%02d"
 114                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 115            timezone)))
 116     (format "%02d %s %04d %s %s"
 117             day
 118             (capitalize (car (rassq month timezone-months-assoc)))
 119             year
 120             time
 121             zone)))
 122
 123 (defun timezone-make-sortable-date (year month day time)
 124   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 125   (format "%4d%02d%02d%s"
 126           year month day time))
 127
 128 (defun timezone-make-time-string (hour minute second)
 129   "Make time string from HOUR, MINUTE, and SECOND."
 130   (format "%02d:%02d:%02d" hour minute second))
 131
 132 ;;;###autoload
 133 (define-error 'invalid-date "Invalid date string")
 134
 135 (defun timezone-parse-date (date)
 136   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 137 Two-digit dates are `windowed'.  Those <69 have 2000 added; otherwise 1900
 138 is added.  Three-digit dates have 1900 added.
 139 TIMEZONE is nil for DATEs without a zone field.
 140
 141 Understands the following styles:
 142  (1) 14 Apr 89 03:20[:12] [GMT]
 143  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 144  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 145  (4) 6 May 1992 1641-JST (Wednesday)
 146  (5) 22-AUG-1993 10:59:12.82
 147  (6) Thu, 11 Apr 16:17:12 91 [MET]
 148  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 149  (8) 1996-06-24 21:13:12 [GMT]
 150  (9) 1996-06-24 21:13-ZONE"
 151   ;; XEmacs addition: surround with condition-case
 152   (condition-case nil
 153       (progn
 154  ;; Get rid of any text properties.
 155   (and (stringp date)
 156        (or (text-properties-at 0 date)
 157            (next-property-change 0 date))
 158        (setq date (copy-sequence date))
 159        (set-text-properties 0 (length date) nil date))
 160   (let ((date (or date ""))
 161         (year nil)
 162         (month nil)
 163         (day nil)
 164         (time nil)
 165         (zone nil))                     ;This may be nil.
 166     (cond ((string-match
 167             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 168            ;; Styles: (1) and (2) with timezone and buggy timezone
 169            ;; This is most common in mail and news,
 170            ;; so it is worth trying first.
 171            (setq year 3 month 2 day 1 time 4 zone 5))
 172           ((string-match
 173             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 174            ;; Styles: (1) and (2) without timezone
 175            (setq year 3 month 2 day 1 time 4 zone nil))
 176           ((string-match
 177             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 178            ;; Styles: (6) and (7) without timezone
 179            (setq year 6 month 3 day 2 time 4 zone nil))
 180           ((string-match
 181             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 182            ;; Styles: (6) and (7) with timezone and buggy timezone
 183            (setq year 6 month 3 day 2 time 4 zone 7))
 184           ((string-match
 185             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 186            ;; Styles: (3) without timezone
 187            (setq year 4 month 1 day 2 time 3 zone nil))
 188           ((string-match
 189             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 190            ;; Styles: (3) with timezone
 191            (setq year 5 month 1 day 2 time 3 zone 4))
 192           ((string-match
 193             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 194            ;; Styles: (4) with timezone
 195            (setq year 3 month 2 day 1 time 4 zone 5))
 196           ((string-match
 197             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 198            ;; Styles: (5) with timezone.
 199            (setq year 3 month 2 day 1 time 4 zone 6))
 200           ((string-match
 201             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?" date)
 202            ;; Styles: (5) without timezone.
 203            (setq year 3 month 2 day 1 time 4 zone nil))
 204           ((string-match
 205             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 206            ;; Styles: (8) with timezone.
 207            (setq year 1 month 2 day 3 time 4 zone 5))
 208           ((string-match
 209             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+\\)[ \t]+\\([-+a-zA-Z0-9:]+\\)" date)
 210            ;; Styles: (8) with timezone with a colon in it.
 211            (setq year 1 month 2 day 3 time 4 zone 5))
 212           ((string-match
 213             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 214            ;; Styles: (8) without timezone.
 215            (setq year 1 month 2 day 3 time 4 zone nil))
 216           )
 217     (when year
 218       (setq year (match-string year date))
 219       ;; Guess ambiguous years.  Assume years < 69 don't predate the
 220       ;; Unix Epoch, so are 2000+.  Three-digit years are assumed to
 221       ;; be relative to 1900.
 222       (if (< (length year) 4)
 223           (let ((y (string-to-int year)))
 224             (if (< y 69)
 225                 (setq y (+ y 100)))
 226             (setq year (int-to-string (+ 1900 y)))))
 227       (setq month
 228             (if (= (aref date (+ (match-beginning month) 2)) ?-)
 229                 ;; Handle numeric months, spanning exactly two digits.
 230                 (substring date
 231                            (match-beginning month)
 232                            (+ (match-beginning month) 2))
 233               (let* ((string (substring date
 234                                         (match-beginning month)
 235                                         (+ (match-beginning month) 3)))
 236                      (monthnum
 237                       (cdr (assoc (upcase string) timezone-months-assoc))))
 238                 (if monthnum
 239                     (int-to-string monthnum)))))
 240       (setq day (match-string day date))
 241       (setq time (match-string time date)))
 242     (if zone (setq zone (match-string zone date)))
 243     ;; Return a vector.
 244     (if (and year month)
 245         (vector year month day time zone)
 246       (vector "0" "0" "0" "0" nil))))
 247     (t (signal 'invalid-date (list date)))))
 248
 249 (defun timezone-parse-time (time)
 250   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 251 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 252   (let ((time (or time ""))
 253         hour minute second)
 254     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 255            ;; HH:MM:SS
 256            (setq hour 1 minute 2 second 3))
 257           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 258            ;; HH:MM
 259            (setq hour 1 minute 2 second nil))
 260           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 261            ;; HHMMSS
 262            (setq hour 1 minute 2 second 3))
 263           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 264            ;; HHMM
 265            (setq hour 1 minute 2 second nil))
 266           )
 267     ;; Return [hour minute second]
 268     (vector
 269      (if hour (match-string hour time) "0")
 270      (if minute (match-string minute time) "0")
 271      (if second (match-string second time) "0"))))
 272
 273 \f
 274 ;; Miscellaneous
 275
 276 (defun timezone-zone-to-minute (timezone)
 277   "Translate TIMEZONE to an integer minute offset from GMT.
 278 TIMEZONE can be a cons cell containing the output of current-time-zone,
 279 or an integer of the form +-HHMM, or a time zone name."
 280   (cond
 281      ((consp timezone)
 282       (/ (car timezone) 60))
 283      (timezone
 284       (progn
 285         (setq timezone
 286               (or (and (stringp timezone) (cdr (assoc (upcase timezone) timezone-world-timezones)))
 287                   ;; +900
 288                   timezone))
 289         (if (stringp timezone)
 290             (setq timezone (string-to-int timezone)))
 291         ;; Taking account of minute in timezone.
 292         ;; HHMM -> MM
 293         (let* ((abszone (timezone-abs timezone))
 294                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 295           (if (< timezone 0) (- minutes) minutes))))
 296      (t 0)))
 297
 298 (defun timezone-time-from-absolute (date seconds)
 299   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 300 Return a list suitable as an argument to current-time-zone,
 301 or nil if the date cannot be thus represented.
 302 DATE is the number of days elapsed since the (imaginary)
 303 Gregorian date Sunday, December 31, 1 BC."
 304   (let* ((current-time-origin 719163)
 305             ;; (timezone-absolute-from-gregorian 1 1 1970)
 306          (days (- date current-time-origin))
 307          (seconds-per-day (float 86400))
 308          (seconds (+ seconds (* days seconds-per-day)))
 309          (current-time-arithmetic-base (float 65536))
 310          (hi (timezone-floor (/ seconds current-time-arithmetic-base)))
 311          (hibase (* hi current-time-arithmetic-base))
 312          (lo (timezone-floor (- seconds hibase))))
 313      (and (< (timezone-abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 314           (cons hi lo))))
 315
 316 (defun timezone-time-zone-from-absolute (date seconds)
 317   "Compute the local time zone for DATE at time SECONDS after midnight.
 318 Return a list in the same format as current-time-zone's result,
 319 or nil if the local time zone could not be computed.
 320 DATE is the number of days elapsed since the (imaginary)
 321 Gregorian date Sunday, December 31, 1 BC."
 322    (and (fboundp 'current-time-zone)
 323         (let ((utc-time (timezone-time-from-absolute date seconds)))
 324           (and utc-time
 325                (let ((zone (current-time-zone utc-time)))
 326                  (and (car zone) zone))))))
 327
 328 (defun timezone-fix-time (date local timezone)
 329   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 330 If LOCAL is nil, it is assumed to be GMT.
 331 If TIMEZONE is nil, use the local time zone."
 332   (let* ((date   (timezone-parse-date date))
 333          (year   (string-to-int (aref date 0)))
 334          (year   (cond ((< year 69)
 335                         (+ year 2000))
 336                        ((< year 100)
 337                         (+ year 1900))
 338                        ((< year 1000)   ; possible 3-digit years.
 339                         (+ year 1900))
 340                        (t year)))
 341          (month  (string-to-int (aref date 1)))
 342          (day    (string-to-int (aref date 2)))
 343          (time   (timezone-parse-time (aref date 3)))
 344          (hour   (string-to-int (aref time 0)))
 345          (minute (string-to-int (aref time 1)))
 346          (second (string-to-int (aref time 2)))
 347          (local  (or (aref date 4) local)) ;Use original if defined
 348          (timezone
 349           (or timezone
 350               (timezone-time-zone-from-absolute
 351                (timezone-absolute-from-gregorian month day year)
 352                (+ second (* 60 (+ minute (* 60 hour)))))))
 353          (diff   (- (timezone-zone-to-minute timezone)
 354                     (timezone-zone-to-minute local)))
 355          (minute (+ minute diff))
 356          (hour-fix (timezone-floor minute 60)))
 357     (setq hour (+ hour hour-fix))
 358     (setq minute (- minute (* 60 hour-fix)))
 359     ;; HOUR may be larger than 24 or smaller than 0.
 360     (cond ((<= 24 hour)                 ;24 -> 00
 361            (setq hour (- hour 24))
 362            (setq day  (1+ day))
 363            (when (< (timezone-last-day-of-month month year) day)
 364              (setq month (1+ month))
 365              (setq day 1)
 366              (when (< 12 month)
 367                (setq month 1)
 368                (setq year (1+ year)))))
 369           ((> 0 hour)
 370            (setq hour (+ hour 24))
 371            (setq day  (1- day))
 372            (when (> 1 day)
 373              (setq month (1- month))
 374              (when (> 1 month)
 375                (setq month 12)
 376                (setq year (1- year)))
 377              (setq day (timezone-last-day-of-month month year)))))
 378     (vector year month day hour minute second timezone)))
 379
 380 ;; Partly copied from Calendar program by Edward M. Reingold.
 381 ;; Thanks a lot.
 382
 383 (defun timezone-last-day-of-month (month year)
 384   "The last day in MONTH during YEAR."
 385   (if (and (= month 2) (timezone-leap-year-p year))
 386       29
 387     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 388
 389 (defun timezone-leap-year-p (year)
 390   "Returns t if YEAR is a Gregorian leap year."
 391   (or (and (zerop  (% year 4))
 392            (not (zerop (% year 100))))
 393       (zerop (% year 400))))
 394
 395 (defun timezone-day-number (month day year)
 396   "Return the day number within the year of the date month/day/year."
 397   (let ((day-of-year (+ day (* 31 (1- month)))))
 398     (if (> month 2)
 399         (progn
 400           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 401           (if (timezone-leap-year-p year)
 402               (setq day-of-year (1+ day-of-year)))))
 403     day-of-year))
 404
 405 (defun timezone-absolute-from-gregorian (month day year)
 406   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 407 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 408   (+ (timezone-day-number month day year);; Days this year
 409      (* 365 (1- year));;        + Days in prior years
 410      (/ (1- year) 4);;          + Julian leap years
 411      (- (/ (1- year) 100));;    - century years
 412      (/ (1- year) 400)));;      + Gregorian leap years
 413
 414 (defun timezone-abs (n)
 415   (if (fboundp 'abs)
 416       (abs n)
 417     (if (< n 0) (- n) n)))
 418
 419 (defun timezone-floor (n &optional divisor)
 420   (if (fboundp 'floor)
 421       (floor n divisor)
 422     (if (null divisor)
 423         (setq divisor 1))
 424     (if (< n 0)
 425         (- (/ (- divisor 1 n) divisor))
 426       (/ n divisor))))
 427
 428 (provide 'timezone)
 429
 430 ;;; timezone.el ends here