cgit.sxemacs.org Git - packages/blob - xemacs-packages/gnus/lisp/gnus-topic.el

   1 ;;; gnus-topic.el --- a folding minor mode for Gnus group buffers
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Ilja Weis <kult@uni-paderborn.de>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'gnus)
  34 (require 'gnus-group)
  35 (require 'gnus-start)
  36 (require 'gnus-util)
  37
  38 (defgroup gnus-topic nil
  39   "Group topics."
  40   :group 'gnus-group)
  41
  42 (defvar gnus-topic-mode nil
  43   "Minor mode for Gnus group buffers.")
  44
  45 (defcustom gnus-topic-mode-hook nil
  46   "Hook run in topic mode buffers."
  47   :type 'hook
  48   :group 'gnus-topic)
  49
  50 (when (featurep 'xemacs)
  51   (add-hook 'gnus-topic-mode-hook 'gnus-xmas-topic-menu-add))
  52
  53 (defcustom gnus-topic-line-format "%i[ %(%{%n%}%) -- %A ]%v\n"
  54   "Format of topic lines.
  55 It works along the same lines as a normal formatting string,
  56 with some simple extensions.
  57
  58 %i  Indentation based on topic level.
  59 %n  Topic name.
  60 %v  Nothing if the topic is visible, \"...\" otherwise.
  61 %g  Number of groups in the topic.
  62 %a  Number of unread articles in the groups in the topic.
  63 %A  Number of unread articles in the groups in the topic and its subtopics.
  64
  65 General format specifiers can also be used.
  66 See Info node `(gnus)Formatting Variables'."
  67   :link '(custom-manual "(gnus)Formatting Variables")
  68   :type 'string
  69   :group 'gnus-topic)
  70
  71 (defcustom gnus-topic-indent-level 2
  72   "*How much each subtopic should be indented."
  73   :type 'integer
  74   :group 'gnus-topic)
  75
  76 (defcustom gnus-topic-display-empty-topics t
  77   "*If non-nil, display the topic lines even of topics that have no unread articles."
  78   :type 'boolean
  79   :group 'gnus-topic)
  80
  81 ;; Internal variables.
  82
  83 (defvar gnus-topic-active-topology nil)
  84 (defvar gnus-topic-active-alist nil)
  85 (defvar gnus-topic-unreads nil)
  86
  87 (defvar gnus-topology-checked-p nil
  88   "Whether the topology has been checked in this session.")
  89
  90 (defvar gnus-topic-killed-topics nil)
  91 (defvar gnus-topic-inhibit-change-level nil)
  92
  93 (defconst gnus-topic-line-format-alist
  94   `((?n name ?s)
  95     (?v visible ?s)
  96     (?i indentation ?s)
  97     (?g number-of-groups ?d)
  98     (?a (gnus-topic-articles-in-topic entries) ?d)
  99     (?A total-number-of-articles ?d)
 100     (?l level ?d)))
 101
 102 (defvar gnus-topic-line-format-spec nil)
 103
 104 ;;; Utility functions
 105
 106 (defun gnus-group-topic-name ()
 107   "The name of the topic on the current line."
 108   (let ((topic (get-text-property (gnus-point-at-bol) 'gnus-topic)))
 109     (and topic (symbol-name topic))))
 110
 111 (defun gnus-group-topic-level ()
 112   "The level of the topic on the current line."
 113   (get-text-property (gnus-point-at-bol) 'gnus-topic-level))
 114
 115 (defun gnus-group-topic-unread ()
 116   "The number of unread articles in topic on the current line."
 117   (get-text-property (gnus-point-at-bol) 'gnus-topic-unread))
 118
 119 (defun gnus-topic-unread (topic)
 120   "Return the number of unread articles in TOPIC."
 121   (or (cdr (assoc topic gnus-topic-unreads))
 122       0))
 123
 124 (defun gnus-group-topic-p ()
 125   "Return non-nil if the current line is a topic."
 126   (gnus-group-topic-name))
 127
 128 (defun gnus-topic-visible-p ()
 129   "Return non-nil if the current topic is visible."
 130   (get-text-property (gnus-point-at-bol) 'gnus-topic-visible))
 131
 132 (defun gnus-topic-articles-in-topic (entries)
 133   (let ((total 0)
 134         number)
 135     (while entries
 136       (when (numberp (setq number (car (pop entries))))
 137         (incf total number)))
 138     total))
 139
 140 (defun gnus-group-topic (group)
 141   "Return the topic GROUP is a member of."
 142   (let ((alist gnus-topic-alist)
 143         out)
 144     (while alist
 145       (when (member group (cdar alist))
 146         (setq out (caar alist)
 147               alist nil))
 148       (setq alist (cdr alist)))
 149     out))
 150
 151 (defun gnus-group-parent-topic (group)
 152   "Return the topic GROUP is member of by looking at the group buffer."
 153   (save-excursion
 154     (set-buffer gnus-group-buffer)
 155     (if (gnus-group-goto-group group)
 156         (gnus-current-topic)
 157       (gnus-group-topic group))))
 158
 159 (defun gnus-topic-goto-topic (topic)
 160   (when topic
 161     (gnus-goto-char (text-property-any (point-min) (point-max)
 162                                        'gnus-topic (intern topic)))))
 163
 164 (defun gnus-topic-jump-to-topic (topic)
 165   "Go to TOPIC."
 166   (interactive
 167    (list (completing-read "Go to topic: "
 168                           (mapcar 'list (gnus-topic-list))
 169                           nil t)))
 170   (dolist (topic (gnus-current-topics topic))
 171     (gnus-topic-goto-topic topic)
 172     (gnus-topic-fold t))
 173   (gnus-topic-goto-topic topic))
 174
 175 (defun gnus-current-topic ()
 176   "Return the name of the current topic."
 177   (let ((result
 178          (or (get-text-property (point) 'gnus-topic)
 179              (save-excursion
 180                (and (gnus-goto-char (previous-single-property-change
 181                                      (point) 'gnus-topic))
 182                     (get-text-property (max (1- (point)) (point-min))
 183                                        'gnus-topic))))))
 184     (when result
 185       (symbol-name result))))
 186
 187 (defun gnus-current-topics (&optional topic)
 188   "Return a list of all current topics, lowest in hierarchy first.
 189 If TOPIC, start with that topic."
 190   (let ((topic (or topic (gnus-current-topic)))
 191         topics)
 192     (while topic
 193       (push topic topics)
 194       (setq topic (gnus-topic-parent-topic topic)))
 195     (nreverse topics)))
 196
 197 (defun gnus-group-active-topic-p ()
 198   "Say whether the current topic comes from the active topics."
 199   (save-excursion
 200     (beginning-of-line)
 201     (get-text-property (point) 'gnus-active)))
 202
 203 (defun gnus-topic-find-groups (topic &optional level all lowest recursive)
 204   "Return entries for all visible groups in TOPIC.
 205 If RECURSIVE is t, return groups in its subtopics too."
 206   (let ((groups (cdr (assoc topic gnus-topic-alist)))
 207         info clevel unread group params visible-groups entry active)
 208     (setq lowest (or lowest 1))
 209     (setq level (or level gnus-level-unsubscribed))
 210     ;; We go through the newsrc to look for matches.
 211     (while groups
 212       (when (setq group (pop groups))
 213         (setq entry (gnus-gethash group gnus-newsrc-hashtb)
 214               info (nth 2 entry)
 215               params (gnus-info-params info)
 216               active (gnus-active group)
 217               unread (or (car entry)
 218                          (and (not (equal group "dummy.group"))
 219                               active
 220                               (- (1+ (cdr active)) (car active))))
 221               clevel (or (gnus-info-level info)
 222                          (if (member group gnus-zombie-list)
 223                              gnus-level-zombie gnus-level-killed))))
 224       (and
 225        info                             ; nil means that the group is dead.
 226        (<= clevel level)
 227        (>= clevel lowest)               ; Is inside the level we want.
 228        (or all
 229            (if (or (eq unread t)
 230                    (eq unread nil))
 231                gnus-group-list-inactive-groups
 232              (> unread 0))
 233            (and gnus-list-groups-with-ticked-articles
 234                 (cdr (assq 'tick (gnus-info-marks info))))
 235            ;; Has right readedness.
 236            ;; Check for permanent visibility.
 237            (and gnus-permanently-visible-groups
 238                 (string-match gnus-permanently-visible-groups group))
 239            (memq 'visible params)
 240            (cdr (assq 'visible params)))
 241        ;; Add this group to the list of visible groups.
 242        (push (or entry group) visible-groups)))
 243     (setq visible-groups (nreverse visible-groups))
 244     (when recursive
 245       (if (eq recursive t)
 246           (setq recursive (cdr (gnus-topic-find-topology topic))))
 247       (mapcar (lambda (topic-topology)
 248                 (setq visible-groups
 249                       (nconc visible-groups
 250                              (gnus-topic-find-groups
 251                               (caar topic-topology)
 252                               level all lowest topic-topology))))
 253               (cdr recursive)))
 254     visible-groups))
 255
 256 (defun gnus-topic-goto-previous-topic (n)
 257   "Go to the N'th previous topic."
 258   (interactive "p")
 259   (gnus-topic-goto-next-topic (- n)))
 260
 261 (defun gnus-topic-goto-next-topic (n)
 262   "Go to the N'th next topic."
 263   (interactive "p")
 264   (let ((backward (< n 0))
 265         (n (abs n))
 266         (topic (gnus-current-topic)))
 267     (while (and (> n 0)
 268                 (setq topic
 269                       (if backward
 270                           (gnus-topic-previous-topic topic)
 271                         (gnus-topic-next-topic topic))))
 272       (gnus-topic-goto-topic topic)
 273       (setq n (1- n)))
 274     (when (/= 0 n)
 275       (gnus-message 7 "No more topics"))
 276     n))
 277
 278 (defun gnus-topic-previous-topic (topic)
 279   "Return the previous topic on the same level as TOPIC."
 280   (let ((top (cddr (gnus-topic-find-topology
 281                     (gnus-topic-parent-topic topic)))))
 282     (unless (equal topic (caaar top))
 283       (while (and top (not (equal (caaadr top) topic)))
 284         (setq top (cdr top)))
 285       (caaar top))))
 286
 287 (defun gnus-topic-parent-topic (topic &optional topology)
 288   "Return the parent of TOPIC."
 289   (unless topology
 290     (setq topology gnus-topic-topology))
 291   (let ((parent (car (pop topology)))
 292         result found)
 293     (while (and topology
 294                 (not (setq found (equal (caaar topology) topic)))
 295                 (not (setq result (gnus-topic-parent-topic
 296                                    topic (car topology)))))
 297       (setq topology (cdr topology)))
 298     (or result (and found parent))))
 299
 300 (defun gnus-topic-next-topic (topic &optional previous)
 301   "Return the next sibling of TOPIC."
 302   (let ((parentt (cddr (gnus-topic-find-topology
 303                         (gnus-topic-parent-topic topic))))
 304         prev)
 305     (while (and parentt
 306                 (not (equal (caaar parentt) topic)))
 307       (setq prev (caaar parentt)
 308             parentt (cdr parentt)))
 309     (if previous
 310         prev
 311       (caaadr parentt))))
 312
 313 (defun gnus-topic-forward-topic (num)
 314   "Go to the next topic on the same level as the current one."
 315   (let* ((topic (gnus-current-topic))
 316          (way (if (< num 0) 'gnus-topic-previous-topic
 317                 'gnus-topic-next-topic))
 318          (num (abs num)))
 319     (while (and (not (zerop num))
 320                 (setq topic (funcall way topic)))
 321       (when (gnus-topic-goto-topic topic)
 322         (decf num)))
 323     (unless (zerop num)
 324       (goto-char (point-max)))
 325     num))
 326
 327 (defun gnus-topic-find-topology (topic &optional topology level remove)
 328   "Return the topology of TOPIC."
 329   (unless topology
 330     (setq topology gnus-topic-topology)
 331     (setq level 0))
 332   (let ((top topology)
 333         result)
 334     (if (equal (caar topology) topic)
 335         (progn
 336           (when remove
 337             (delq topology remove))
 338           (cons level topology))
 339       (setq topology (cdr topology))
 340       (while (and topology
 341                   (not (setq result (gnus-topic-find-topology
 342                                      topic (car topology) (1+ level)
 343                                      (and remove top)))))
 344         (setq topology (cdr topology)))
 345       result)))
 346
 347 (defvar gnus-tmp-topics nil)
 348 (defun gnus-topic-list (&optional topology)
 349   "Return a list of all topics in the topology."
 350   (unless topology
 351     (setq topology gnus-topic-topology
 352           gnus-tmp-topics nil))
 353   (push (caar topology) gnus-tmp-topics)
 354   (mapcar 'gnus-topic-list (cdr topology))
 355   gnus-tmp-topics)
 356
 357 ;;; Topic parameter jazz
 358
 359 (defun gnus-topic-parameters (topic)
 360   "Return the parameters for TOPIC."
 361   (let ((top (gnus-topic-find-topology topic)))
 362     (when top
 363       (nth 3 (cadr top)))))
 364
 365 (defun gnus-topic-set-parameters (topic parameters)
 366   "Set the topic parameters of TOPIC to PARAMETERS."
 367   (let ((top (gnus-topic-find-topology topic)))
 368     (unless top
 369       (error "No such topic: %s" topic))
 370     ;; We may have to extend if there is no parameters here
 371     ;; to begin with.
 372     (unless (nthcdr 2 (cadr top))
 373       (nconc (cadr top) (list nil)))
 374     (unless (nthcdr 3 (cadr top))
 375       (nconc (cadr top) (list nil)))
 376     (setcar (nthcdr 3 (cadr top)) parameters)
 377     (gnus-dribble-enter
 378      (format "(gnus-topic-set-parameters %S '%S)" topic parameters))))
 379
 380 (defun gnus-group-topic-parameters (group)
 381   "Compute the group parameters for GROUP taking into account inheritance from topics."
 382   (let ((params-list (copy-sequence (gnus-group-get-parameter group))))
 383     (save-excursion
 384       (nconc params-list
 385              (gnus-topic-hierarchical-parameters
 386               ;; First we try to go to the group within the group
 387               ;; buffer and find the topic for the group that way.
 388               ;; This hopefully copes well with groups that are in
 389               ;; more than one topic.  Failing that (i.e. when the
 390               ;; group isn't visible in the group buffer) we find a
 391               ;; topic for the group via gnus-group-topic.
 392               (or (and (gnus-group-goto-group group)
 393                        (gnus-current-topic))
 394                   (gnus-group-topic group)))))))
 395
 396 (defun gnus-topic-hierarchical-parameters (topic)
 397   "Return a topic list computed for TOPIC."
 398   (let ((topics (gnus-current-topics topic))
 399         params-list param out params)
 400     (while topics
 401       (push (gnus-topic-parameters (pop topics)) params-list))
 402     ;; We probably have lots of nil elements here, so
 403     ;; we remove them.  Probably faster than doing this "properly".
 404     (setq params-list (delq nil params-list))
 405     ;; Now we have all the parameters, so we go through them
 406     ;; and do inheritance in the obvious way.
 407     (while (setq params (pop params-list))
 408       (while (setq param (pop params))
 409         (when (atom param)
 410           (setq param (cons param t)))
 411         ;; Override any old versions of this param.
 412         (gnus-pull (car param) out)
 413         (push param out)))
 414     ;; Return the resulting parameter list.
 415     out))
 416
 417 ;;; General utility functions
 418
 419 (defun gnus-topic-enter-dribble ()
 420   (gnus-dribble-enter
 421    (format "(setq gnus-topic-topology '%S)" gnus-topic-topology)))
 422
 423 ;;; Generating group buffers
 424
 425 (defun gnus-group-prepare-topics (level &optional predicate lowest
 426                                         regexp list-topic topic-level)
 427   "List all newsgroups with unread articles of level LEVEL or lower.
 428 Use the `gnus-group-topics' to sort the groups.
 429 If PREDICTE is a function, list groups that the function returns non-nil;
 430 if it is t, list groups that have no unread articles.
 431 If LOWEST is non-nil, list all newsgroups of level LOWEST or higher."
 432   (set-buffer gnus-group-buffer)
 433   (let ((buffer-read-only nil)
 434         (lowest (or lowest 1))
 435         (not-in-list
 436          (and gnus-group-listed-groups
 437               (copy-sequence gnus-group-listed-groups))))
 438
 439     (gnus-update-format-specifications nil 'topic)
 440
 441     (when (or (not gnus-topic-alist)
 442               (not gnus-topology-checked-p))
 443       (gnus-topic-check-topology))
 444
 445     (unless list-topic
 446       (erase-buffer))
 447
 448     ;; List dead groups?
 449     (when (or gnus-group-listed-groups
 450               (and (>= level gnus-level-zombie)
 451                    (<= lowest gnus-level-zombie)))
 452       (gnus-group-prepare-flat-list-dead
 453        (setq gnus-zombie-list (sort gnus-zombie-list 'string<))
 454        gnus-level-zombie ?Z
 455        regexp))
 456
 457     (when (or gnus-group-listed-groups
 458                (and (>= level gnus-level-killed)
 459                     (<= lowest gnus-level-killed)))
 460       (gnus-group-prepare-flat-list-dead
 461        (setq gnus-killed-list (sort gnus-killed-list 'string<))
 462        gnus-level-killed ?K regexp)
 463       (when not-in-list
 464         (unless gnus-killed-hashtb
 465           (gnus-make-hashtable-from-killed))
 466         (gnus-group-prepare-flat-list-dead
 467          (gnus-remove-if (lambda (group)
 468                            (or (gnus-gethash group gnus-newsrc-hashtb)
 469                                (gnus-gethash group gnus-killed-hashtb)))
 470                          not-in-list)
 471          gnus-level-killed ?K regexp)))
 472
 473     ;; Use topics.
 474     (prog1
 475         (when (or (< lowest gnus-level-zombie)
 476                   gnus-group-listed-groups)
 477           (if list-topic
 478               (let ((top (gnus-topic-find-topology list-topic)))
 479                 (gnus-topic-prepare-topic (cdr top) (car top)
 480                                           (or topic-level level) predicate
 481                                           nil lowest regexp))
 482             (gnus-topic-prepare-topic gnus-topic-topology 0
 483                                       (or topic-level level) predicate
 484                                       nil lowest regexp)))
 485       (gnus-group-set-mode-line)
 486       (setq gnus-group-list-mode (cons level predicate))
 487       (gnus-run-hooks 'gnus-group-prepare-hook))))
 488
 489 (defun gnus-topic-prepare-topic (topicl level &optional list-level
 490                                         predicate silent
 491                                         lowest regexp)
 492   "Insert TOPIC into the group buffer.
 493 If SILENT, don't insert anything.  Return the number of unread
 494 articles in the topic and its subtopics."
 495   (let* ((type (pop topicl))
 496          (entries (gnus-topic-find-groups
 497                    (car type)
 498                    (if gnus-group-listed-groups
 499                        gnus-level-killed
 500                      list-level)
 501                    (or predicate gnus-group-listed-groups
 502                        (cdr (assq 'visible
 503                                   (gnus-topic-hierarchical-parameters
 504                                    (car type)))))
 505                    (if gnus-group-listed-groups 0 lowest)))
 506          (visiblep (and (eq (nth 1 type) 'visible) (not silent)))
 507          (gnus-group-indentation
 508           (make-string (* gnus-topic-indent-level level) ? ))
 509          (beg (progn (beginning-of-line) (point)))
 510          (topicl (reverse topicl))
 511          (all-entries entries)
 512          (point-max (point-max))
 513          (unread 0)
 514          (topic (car type))
 515          info entry end active tick)
 516     ;; Insert any sub-topics.
 517     (while topicl
 518       (incf unread
 519             (gnus-topic-prepare-topic
 520              (pop topicl) (1+ level) list-level predicate
 521              (not visiblep) lowest regexp)))
 522     (setq end (point))
 523     (goto-char beg)
 524     ;; Insert all the groups that belong in this topic.
 525     (while (setq entry (pop entries))
 526       (when (if (stringp entry)
 527                 (gnus-group-prepare-logic
 528                  entry
 529                  (and
 530                   (or (not gnus-group-listed-groups)
 531                       (if (< list-level gnus-level-zombie) nil
 532                         (let ((entry-level
 533                                (if (member entry gnus-zombie-list)
 534                                    gnus-level-zombie gnus-level-killed)))
 535                           (and (<= entry-level list-level)
 536                                (>= entry-level lowest)))))
 537                   (cond
 538                    ((stringp regexp)
 539                     (string-match regexp entry))
 540                    ((functionp regexp)
 541                     (funcall regexp entry))
 542                    ((null regexp) t)
 543                    (t nil))))
 544               (setq info (nth 2 entry))
 545               (gnus-group-prepare-logic
 546                (gnus-info-group info)
 547                (and (or (not gnus-group-listed-groups)
 548                         (let ((entry-level (gnus-info-level info)))
 549                           (and (<= entry-level list-level)
 550                                (>= entry-level lowest))))
 551                     (or (not (functionp predicate))
 552                         (funcall predicate info))
 553                     (or (not (stringp regexp))
 554                         (string-match regexp (gnus-info-group info))))))
 555         (when visiblep
 556           (if (stringp entry)
 557               ;; Dead groups.
 558               (gnus-group-insert-group-line
 559                entry (if (member entry gnus-zombie-list)
 560                          gnus-level-zombie gnus-level-killed)
 561                nil (- (1+ (cdr (setq active (gnus-active entry))))
 562                       (car active))
 563                nil)
 564             ;; Living groups.
 565             (when (setq info (nth 2 entry))
 566               (gnus-group-insert-group-line
 567                (gnus-info-group info)
 568                (gnus-info-level info) (gnus-info-marks info)
 569                (car entry) (gnus-info-method info)))))
 570         (when (and (listp entry)
 571                    (numberp (car entry)))
 572           (incf unread (car entry)))
 573         (when (listp entry)
 574           (setq tick t))))
 575     (goto-char beg)
 576     ;; Insert the topic line.
 577     (when (and (not silent)
 578                (or gnus-topic-display-empty-topics ;We want empty topics
 579                    (not (zerop unread)) ;Non-empty
 580                    tick                 ;Ticked articles
 581                    (/= point-max (point-max)))) ;Unactivated groups
 582       (gnus-extent-start-open (point))
 583       (gnus-topic-insert-topic-line
 584        (car type) visiblep
 585        (not (eq (nth 2 type) 'hidden))
 586        level all-entries unread))
 587     (gnus-topic-update-unreads (car type) unread)
 588     (when gnus-group-update-tool-bar
 589       (gnus-put-text-property beg end 'point-entered
 590                               'gnus-tool-bar-update)
 591       (gnus-put-text-property beg end 'point-left
 592                               'gnus-tool-bar-update))
 593     (goto-char end)
 594     unread))
 595
 596 (defun gnus-topic-remove-topic (&optional insert total-remove hide in-level)
 597   "Remove the current topic."
 598   (let ((topic (gnus-group-topic-name))
 599         (level (gnus-group-topic-level))
 600         (beg (progn (beginning-of-line) (point)))
 601         buffer-read-only)
 602     (when topic
 603       (while (and (zerop (forward-line 1))
 604                   (> (or (gnus-group-topic-level) (1+ level)) level)))
 605       (delete-region beg (point))
 606       ;; Do the change in this rather odd manner because it has been
 607       ;; reported that some topics share parts of some lists, for some
 608       ;; reason.  I have been unable to determine why this is the
 609       ;; case, but this hack seems to take care of things.
 610       (let ((data (cadr (gnus-topic-find-topology topic))))
 611         (setcdr data
 612                 (list (if insert 'visible 'invisible)
 613                       (caddr data)
 614                       (cadddr data))))
 615       (if total-remove
 616           (setq gnus-topic-alist
 617                 (delq (assoc topic gnus-topic-alist) gnus-topic-alist))
 618         (gnus-topic-insert-topic topic in-level)))))
 619
 620 (defun gnus-topic-insert-topic (topic &optional level)
 621   "Insert TOPIC."
 622   (gnus-group-prepare-topics
 623    (car gnus-group-list-mode) (cdr gnus-group-list-mode)
 624    nil nil topic level))
 625
 626 (defun gnus-topic-fold (&optional insert topic)
 627   "Remove/insert the current topic."
 628   (let ((topic (or topic (gnus-group-topic-name))))
 629     (when topic
 630       (save-excursion
 631         (if (not (gnus-group-active-topic-p))
 632             (gnus-topic-remove-topic
 633              (or insert (not (gnus-topic-visible-p))))
 634           (let ((gnus-topic-topology gnus-topic-active-topology)
 635                 (gnus-topic-alist gnus-topic-active-alist)
 636                 (gnus-group-list-mode (cons 5 t)))
 637             (gnus-topic-remove-topic
 638              (or insert (not (gnus-topic-visible-p))) nil nil 9)
 639             (gnus-topic-enter-dribble)))))))
 640
 641 (defun gnus-topic-insert-topic-line (name visiblep shownp level entries
 642                                           &optional unread)
 643   (let* ((visible (if visiblep "" "..."))
 644          (indentation (make-string (* gnus-topic-indent-level level) ? ))
 645          (total-number-of-articles unread)
 646          (number-of-groups (length entries))
 647          (active-topic (eq gnus-topic-alist gnus-topic-active-alist))
 648          gnus-tmp-header)
 649     (gnus-topic-update-unreads name unread)
 650     (beginning-of-line)
 651     ;; Insert the text.
 652     (if shownp
 653         (gnus-add-text-properties
 654          (point)
 655          (prog1 (1+ (point))
 656            (eval gnus-topic-line-format-spec))
 657          (list 'gnus-topic (intern name)
 658                'gnus-topic-level level
 659                'gnus-topic-unread unread
 660                'gnus-active active-topic
 661                'gnus-topic-visible visiblep)))))
 662
 663 (defun gnus-topic-update-unreads (topic unreads)
 664   (setq gnus-topic-unreads (delq (assoc topic gnus-topic-unreads)
 665                                  gnus-topic-unreads))
 666   (push (cons topic unreads) gnus-topic-unreads))
 667
 668 (defun gnus-topic-update-topics-containing-group (group)
 669   "Update all topics that have GROUP as a member."
 670   (when (and (eq major-mode 'gnus-group-mode)
 671              gnus-topic-mode)
 672     (save-excursion
 673       (let ((alist gnus-topic-alist))
 674         ;; This is probably not entirely correct.  If a topic
 675         ;; isn't shown, then it's not updated.  But the updating
 676         ;; should be performed in any case, since the topic's
 677         ;; parent should be updated.  Pfft.
 678         (while alist
 679           (when (and (member group (cdar alist))
 680                      (gnus-topic-goto-topic (caar alist)))
 681             (gnus-topic-update-topic-line (caar alist)))
 682           (pop alist))))))
 683
 684 (defun gnus-topic-update-topic ()
 685   "Update all parent topics to the current group."
 686   (when (and (eq major-mode 'gnus-group-mode)
 687              gnus-topic-mode)
 688     (let ((group (gnus-group-group-name))
 689           (m (point-marker))
 690           (buffer-read-only nil))
 691       (when (and group
 692                  (gnus-get-info group)
 693                  (gnus-topic-goto-topic (gnus-current-topic)))
 694         (gnus-topic-update-topic-line (gnus-group-topic-name))
 695         (goto-char m)
 696         (set-marker m nil)
 697         (gnus-group-position-point)))))
 698
 699 (defun gnus-topic-goto-missing-group (group)
 700   "Place point where GROUP is supposed to be inserted."
 701   (let* ((topic (gnus-group-topic group))
 702          (groups (cdr (assoc topic gnus-topic-alist)))
 703          (g (cdr (member group groups)))
 704          (unfound t)
 705          entry)
 706     ;; Try to jump to a visible group.
 707     (while (and g
 708                 (not (gnus-group-goto-group (car g) t)))
 709       (pop g))
 710     ;; It wasn't visible, so we try to see where to insert it.
 711     (when (not g)
 712       (setq g (cdr (member group (reverse groups))))
 713       (while (and g unfound)
 714         (when (gnus-group-goto-group (pop g) t)
 715           (forward-line 1)
 716           (setq unfound nil)))
 717       (when (and unfound
 718                  topic
 719                  (not (gnus-topic-goto-missing-topic topic)))
 720         (gnus-topic-display-missing-topic topic)))))
 721
 722 (defun gnus-topic-display-missing-topic (topic)
 723   "Insert topic lines recursively for missing topics."
 724   (let ((parent (gnus-topic-find-topology
 725                  (gnus-topic-parent-topic topic))))
 726     (when (and parent
 727                (not (gnus-topic-goto-missing-topic (caadr parent))))
 728       (gnus-topic-display-missing-topic (caadr parent))))
 729   (gnus-topic-goto-missing-topic topic)
 730   (let* ((top (gnus-topic-find-topology topic))
 731          (children (cddr top))
 732          (type (cadr top))
 733          (unread 0)
 734          (entries (gnus-topic-find-groups
 735                    (car type) (car gnus-group-list-mode)
 736                    (cdr gnus-group-list-mode)))
 737         entry)
 738     (while children
 739       (incf unread (gnus-topic-unread (caar (pop children)))))
 740     (while (setq entry (pop entries))
 741       (when (numberp (car entry))
 742         (incf unread (car entry))))
 743     (gnus-topic-insert-topic-line
 744      topic t t (car (gnus-topic-find-topology topic)) nil unread)))
 745
 746 (defun gnus-topic-goto-missing-topic (topic)
 747   (if (gnus-topic-goto-topic topic)
 748       (forward-line 1)
 749     ;; Topic not displayed.
 750     (let* ((top (gnus-topic-find-topology
 751                  (gnus-topic-parent-topic topic)))
 752            (tp (reverse (cddr top))))
 753       (if (not top)
 754           (gnus-topic-insert-topic-line
 755            topic t t (car (gnus-topic-find-topology topic)) nil 0)
 756         (while (not (equal (caaar tp) topic))
 757           (setq tp (cdr tp)))
 758         (pop tp)
 759         (while (and tp
 760                     (not (gnus-topic-goto-topic (caaar tp))))
 761           (pop tp))
 762         (if tp
 763             (gnus-topic-forward-topic 1)
 764           (gnus-topic-goto-missing-topic (caadr top)))))
 765     nil))
 766
 767 (defun gnus-topic-update-topic-line (topic-name &optional reads)
 768   (let* ((top (gnus-topic-find-topology topic-name))
 769          (type (cadr top))
 770          (children (cddr top))
 771          (entries (gnus-topic-find-groups
 772                    (car type) (car gnus-group-list-mode)
 773                    (cdr gnus-group-list-mode)))
 774          (parent (gnus-topic-parent-topic topic-name))
 775          (all-entries entries)
 776          (unread 0)
 777          old-unread entry new-unread)
 778     (when (gnus-topic-goto-topic (car type))
 779       ;; Tally all the groups that belong in this topic.
 780       (if reads
 781           (setq unread (- (gnus-group-topic-unread) reads))
 782         (while children
 783           (incf unread (gnus-topic-unread (caar (pop children)))))
 784         (while (setq entry (pop entries))
 785           (when (numberp (car entry))
 786             (incf unread (car entry)))))
 787       (setq old-unread (gnus-group-topic-unread))
 788       ;; Insert the topic line.
 789       (gnus-topic-insert-topic-line
 790        (car type) (gnus-topic-visible-p)
 791        (not (eq (nth 2 type) 'hidden))
 792        (gnus-group-topic-level) all-entries unread)
 793       (gnus-delete-line)
 794       (forward-line -1)
 795       (setq new-unread (gnus-group-topic-unread)))
 796     (when parent
 797       (forward-line -1)
 798       (gnus-topic-update-topic-line
 799        parent
 800        (- (or old-unread 0) (or new-unread 0))))
 801     unread))
 802
 803 (defun gnus-topic-group-indentation ()
 804   (make-string
 805    (* gnus-topic-indent-level
 806       (or (save-excursion
 807             (forward-line -1)
 808             (gnus-topic-goto-topic (gnus-current-topic))
 809             (gnus-group-topic-level))
 810           0))
 811    ? ))
 812
 813 ;;; Initialization
 814
 815 (gnus-add-shutdown 'gnus-topic-close 'gnus)
 816
 817 (defun gnus-topic-close ()
 818   (setq gnus-topic-active-topology nil
 819         gnus-topic-active-alist nil
 820         gnus-topic-killed-topics nil
 821         gnus-topology-checked-p nil))
 822
 823 (defun gnus-topic-check-topology ()
 824   ;; The first time we set the topology to whatever we have
 825   ;; gotten here, which can be rather random.
 826   (unless gnus-topic-alist
 827     (gnus-topic-init-alist))
 828
 829   (setq gnus-topology-checked-p t)
 830   ;; Go through the topic alist and make sure that all topics
 831   ;; are in the topic topology.
 832   (let ((topics (gnus-topic-list))
 833         (alist gnus-topic-alist)
 834         changed)
 835     (while alist
 836       (unless (member (caar alist) topics)
 837         (nconc gnus-topic-topology
 838                (list (list (list (caar alist) 'visible))))
 839         (setq changed t))
 840       (setq alist (cdr alist)))
 841     (when changed
 842       (gnus-topic-enter-dribble))
 843     ;; Conversely, go through the topology and make sure that all
 844     ;; topologies have alists.
 845     (while topics
 846       (unless (assoc (car topics) gnus-topic-alist)
 847         (push (list (car topics)) gnus-topic-alist))
 848       (pop topics)))
 849   ;; Go through all living groups and make sure that
 850   ;; they belong to some topic.
 851   (let* ((tgroups (apply 'append (mapcar (lambda (entry) (cdr entry))
 852                                          gnus-topic-alist)))
 853          (entry (last (assoc (caar gnus-topic-topology) gnus-topic-alist)))
 854          (newsrc (cdr gnus-newsrc-alist))
 855          group)
 856     (while newsrc
 857       (unless (member (setq group (gnus-info-group (pop newsrc))) tgroups)
 858         (setcdr entry (list group))
 859         (setq entry (cdr entry)))))
 860   ;; Go through all topics and make sure they contain only living groups.
 861   (let ((alist gnus-topic-alist)
 862         topic)
 863     (while (setq topic (pop alist))
 864       (while (cdr topic)
 865         (if (and (cadr topic)
 866                  (gnus-gethash (cadr topic) gnus-newsrc-hashtb))
 867             (setq topic (cdr topic))
 868           (setcdr topic (cddr topic)))))))
 869
 870 (defun gnus-topic-init-alist ()
 871   "Initialize the topic structures."
 872   (setq gnus-topic-topology
 873         (cons (list "Gnus" 'visible)
 874               (mapcar (lambda (topic)
 875                         (list (list (car topic) 'visible)))
 876                       '(("misc")))))
 877   (setq gnus-topic-alist
 878         (list (cons "misc"
 879                     (mapcar (lambda (info) (gnus-info-group info))
 880                             (cdr gnus-newsrc-alist)))
 881               (list "Gnus")))
 882   (gnus-topic-enter-dribble))
 883
 884 ;;; Maintenance
 885
 886 (defun gnus-topic-clean-alist ()
 887   "Remove bogus groups from the topic alist."
 888   (let ((topic-alist gnus-topic-alist)
 889         result topic)
 890     (unless gnus-killed-hashtb
 891       (gnus-make-hashtable-from-killed))
 892     (while (setq topic (pop topic-alist))
 893       (let ((topic-name (pop topic))
 894             group filtered-topic)
 895         (while (setq group (pop topic))
 896           (when (and (or (gnus-gethash group gnus-active-hashtb)
 897                          (gnus-info-method (gnus-get-info group)))
 898                      (not (gnus-gethash group gnus-killed-hashtb)))
 899             (push group filtered-topic)))
 900         (push (cons topic-name (nreverse filtered-topic)) result)))
 901     (setq gnus-topic-alist (nreverse result))))
 902
 903 (defun gnus-topic-change-level (group level oldlevel &optional previous)
 904   "Run when changing levels to enter/remove groups from topics."
 905   (save-excursion
 906     (set-buffer gnus-group-buffer)
 907     (let ((buffer-read-only nil))
 908       (unless gnus-topic-inhibit-change-level
 909         (gnus-group-goto-group (or (car (nth 2 previous)) group))
 910         (when (and gnus-topic-mode
 911                    gnus-topic-alist
 912                    (not gnus-topic-inhibit-change-level))
 913           ;; Remove the group from the topics.
 914           (if (and (< oldlevel gnus-level-zombie)
 915                    (>= level gnus-level-zombie))
 916               (let ((alist gnus-topic-alist))
 917                 (while (gnus-group-goto-group group)
 918                   (gnus-delete-line))
 919                 (while alist
 920                   (when (member group (car alist))
 921                     (setcdr (car alist) (delete group (cdar alist))))
 922                   (pop alist)))
 923             ;; If the group is subscribed we enter it into the topics.
 924             (when (and (< level gnus-level-zombie)
 925                        (>= oldlevel gnus-level-zombie))
 926               (let* ((prev (gnus-group-group-name))
 927                      (gnus-topic-inhibit-change-level t)
 928                      (gnus-group-indentation
 929                       (make-string
 930                        (* gnus-topic-indent-level
 931                           (or (save-excursion
 932                                 (gnus-topic-goto-topic (gnus-current-topic))
 933                                 (gnus-group-topic-level))
 934                               0))
 935                        ? ))
 936                      (yanked (list group))
 937                      alist talist end)
 938                 ;; Then we enter the yanked groups into the topics
 939                 ;; they belong to.
 940                 (when (setq alist (assoc (save-excursion
 941                                            (forward-line -1)
 942                                            (or
 943                                             (gnus-current-topic)
 944                                             (caar gnus-topic-topology)))
 945                                          gnus-topic-alist))
 946                   (setq talist alist)
 947                   (when (stringp yanked)
 948                     (setq yanked (list yanked)))
 949                   (if (not prev)
 950                       (nconc alist yanked)
 951                     (if (not (cdr alist))
 952                         (setcdr alist (nconc yanked (cdr alist)))
 953                       (while (and (not end) (cdr alist))
 954                         (when (equal (cadr alist) prev)
 955                           (setcdr alist (nconc yanked (cdr alist)))
 956                           (setq end t))
 957                         (setq alist (cdr alist)))
 958                       (unless end
 959                         (nconc talist yanked))))))
 960               (gnus-topic-update-topic))))))))
 961
 962 (defun gnus-topic-goto-next-group (group props)
 963   "Go to group or the next group after group."
 964   (if (not group)
 965       (if (not (memq 'gnus-topic props))
 966           (goto-char (point-max))
 967         (gnus-topic-goto-topic (symbol-name (cadr (memq 'gnus-topic props)))))
 968     (if (gnus-group-goto-group group)
 969         t
 970       ;; The group is no longer visible.
 971       (let* ((list (assoc (gnus-group-topic group) gnus-topic-alist))
 972              (after (cdr (member group (cdr list)))))
 973         ;; First try to put point on a group after the current one.
 974         (while (and after
 975                     (not (gnus-group-goto-group (car after))))
 976           (setq after (cdr after)))
 977         ;; Then try to put point on a group before point.
 978         (unless after
 979           (setq after (cdr (member group (reverse (cdr list)))))
 980           (while (and after
 981                       (not (gnus-group-goto-group (car after))))
 982             (setq after (cdr after))))
 983         ;; Finally, just put point on the topic.
 984         (if (not (car list))
 985             (goto-char (point-min))
 986           (unless after
 987             (gnus-topic-goto-topic (car list))
 988             (setq after nil)))
 989         t))))
 990
 991 ;;; Topic-active functions
 992
 993 (defun gnus-topic-grok-active (&optional force)
 994   "Parse all active groups and create topic structures for them."
 995   ;; First we make sure that we have really read the active file.
 996   (when (or force
 997             (not gnus-topic-active-alist))
 998     (let (groups)
 999       ;; Get a list of all groups available.
1000       (mapatoms (lambda (g) (when (symbol-value g)
1001                               (push (symbol-name g) groups)))
1002                 gnus-active-hashtb)
1003       (setq groups (sort groups 'string<))
1004       ;; Init the variables.
1005       (setq gnus-topic-active-topology (list (list "" 'visible)))
1006       (setq gnus-topic-active-alist nil)
1007       ;; Descend the top-level hierarchy.
1008       (gnus-topic-grok-active-1 gnus-topic-active-topology groups)
1009       ;; Set the top-level topic names to something nice.
1010       (setcar (car gnus-topic-active-topology) "Gnus active")
1011       (setcar (car gnus-topic-active-alist) "Gnus active"))))
1012
1013 (defun gnus-topic-grok-active-1 (topology groups)
1014   (let* ((name (caar topology))
1015          (prefix (concat "^" (regexp-quote name)))
1016          tgroups ntopology group)
1017     (while (and groups
1018                 (string-match prefix (setq group (car groups))))
1019       (if (not (string-match "\\." group (match-end 0)))
1020           ;; There are no further hierarchies here, so we just
1021           ;; enter this group into the list belonging to this
1022           ;; topic.
1023           (push (pop groups) tgroups)
1024         ;; New sub-hierarchy, so we add it to the topology.
1025         (nconc topology (list (setq ntopology
1026                                     (list (list (substring
1027                                                  group 0 (match-end 0))
1028                                                 'invisible)))))
1029         ;; Descend the hierarchy.
1030         (setq groups (gnus-topic-grok-active-1 ntopology groups))))
1031     ;; We remove the trailing "." from the topic name.
1032     (setq name
1033           (if (string-match "\\.$" name)
1034               (substring name 0 (match-beginning 0))
1035             name))
1036     ;; Add this topic and its groups to the topic alist.
1037     (push (cons name (nreverse tgroups)) gnus-topic-active-alist)
1038     (setcar (car topology) name)
1039     ;; We return the rest of the groups that didn't belong
1040     ;; to this topic.
1041     groups))
1042
1043 ;;; Topic mode, commands and keymap.
1044
1045 (defvar gnus-topic-mode-map nil)
1046 (defvar gnus-group-topic-map nil)
1047
1048 (unless gnus-topic-mode-map
1049   (setq gnus-topic-mode-map (make-sparse-keymap))
1050
1051   ;; Override certain group mode keys.
1052   (gnus-define-keys gnus-topic-mode-map
1053     "=" gnus-topic-select-group
1054     "\r" gnus-topic-select-group
1055     " " gnus-topic-read-group
1056     "\C-c\C-x" gnus-topic-expire-articles
1057     "c" gnus-topic-catchup-articles
1058     "\C-k" gnus-topic-kill-group
1059     "\C-y" gnus-topic-yank-group
1060     "\M-g" gnus-topic-get-new-news-this-topic
1061     "AT" gnus-topic-list-active
1062     "Gp" gnus-topic-edit-parameters
1063     "#" gnus-topic-mark-topic
1064     "\M-#" gnus-topic-unmark-topic
1065     [tab] gnus-topic-indent
1066     [(meta tab)] gnus-topic-unindent
1067     "\C-i" gnus-topic-indent
1068     "\M-\C-i" gnus-topic-unindent
1069     gnus-mouse-2 gnus-mouse-pick-topic)
1070
1071   ;; Define a new submap.
1072   (gnus-define-keys (gnus-group-topic-map "T" gnus-group-mode-map)
1073     "#" gnus-topic-mark-topic
1074     "\M-#" gnus-topic-unmark-topic
1075     "n" gnus-topic-create-topic
1076     "m" gnus-topic-move-group
1077     "D" gnus-topic-remove-group
1078     "c" gnus-topic-copy-group
1079     "h" gnus-topic-hide-topic
1080     "s" gnus-topic-show-topic
1081     "j" gnus-topic-jump-to-topic
1082     "M" gnus-topic-move-matching
1083     "C" gnus-topic-copy-matching
1084     "\M-p" gnus-topic-goto-previous-topic
1085     "\M-n" gnus-topic-goto-next-topic
1086     "\C-i" gnus-topic-indent
1087     [tab] gnus-topic-indent
1088     "r" gnus-topic-rename
1089     "\177" gnus-topic-delete
1090     [delete] gnus-topic-delete
1091     "H" gnus-topic-toggle-display-empty-topics)
1092
1093   (gnus-define-keys (gnus-topic-sort-map "S" gnus-group-topic-map)
1094     "s" gnus-topic-sort-groups
1095     "a" gnus-topic-sort-groups-by-alphabet
1096     "u" gnus-topic-sort-groups-by-unread
1097     "l" gnus-topic-sort-groups-by-level
1098     "e" gnus-topic-sort-groups-by-server
1099     "v" gnus-topic-sort-groups-by-score
1100     "r" gnus-topic-sort-groups-by-rank
1101     "m" gnus-topic-sort-groups-by-method))
1102
1103 (defun gnus-topic-make-menu-bar ()
1104   (unless (boundp 'gnus-topic-menu)
1105     (easy-menu-define
1106      gnus-topic-menu gnus-topic-mode-map ""
1107      '("Topics"
1108        ["Toggle topics" gnus-topic-mode t]
1109        ("Groups"
1110         ["Copy..." gnus-topic-copy-group t]
1111         ["Move..." gnus-topic-move-group t]
1112         ["Remove" gnus-topic-remove-group t]
1113         ["Copy matching..." gnus-topic-copy-matching t]
1114         ["Move matching..." gnus-topic-move-matching t])
1115        ("Topics"
1116         ["Goto..." gnus-topic-jump-to-topic t]
1117         ["Show" gnus-topic-show-topic t]
1118         ["Hide" gnus-topic-hide-topic t]
1119         ["Delete" gnus-topic-delete t]
1120         ["Rename..." gnus-topic-rename t]
1121         ["Create..." gnus-topic-create-topic t]
1122         ["Mark" gnus-topic-mark-topic t]
1123         ["Indent" gnus-topic-indent t]
1124         ["Sort" gnus-topic-sort-topics t]
1125         ["Previous topic" gnus-topic-goto-previous-topic t]
1126         ["Next topic" gnus-topic-goto-next-topic t]
1127         ["Toggle hide empty" gnus-topic-toggle-display-empty-topics t]
1128         ["Edit parameters" gnus-topic-edit-parameters t])
1129        ["List active" gnus-topic-list-active t]))))
1130
1131 (defun gnus-topic-mode (&optional arg redisplay)
1132   "Minor mode for topicsifying Gnus group buffers."
1133   (interactive (list current-prefix-arg t))
1134   (when (eq major-mode 'gnus-group-mode)
1135     (make-local-variable 'gnus-topic-mode)
1136     (setq gnus-topic-mode
1137           (if (null arg) (not gnus-topic-mode)
1138             (> (prefix-numeric-value arg) 0)))
1139     ;; Infest Gnus with topics.
1140     (if (not gnus-topic-mode)
1141         (setq gnus-goto-missing-group-function nil)
1142       (when (gnus-visual-p 'topic-menu 'menu)
1143         (gnus-topic-make-menu-bar))
1144       (gnus-set-format 'topic t)
1145       (gnus-add-minor-mode 'gnus-topic-mode " Topic" gnus-topic-mode-map)
1146       (add-hook 'gnus-group-catchup-group-hook 'gnus-topic-update-topic)
1147       (set (make-local-variable 'gnus-group-prepare-function)
1148            'gnus-group-prepare-topics)
1149       (set (make-local-variable 'gnus-group-get-parameter-function)
1150            'gnus-group-topic-parameters)
1151       (set (make-local-variable 'gnus-group-goto-next-group-function)
1152            'gnus-topic-goto-next-group)
1153       (set (make-local-variable 'gnus-group-indentation-function)
1154            'gnus-topic-group-indentation)
1155       (set (make-local-variable 'gnus-group-update-group-function)
1156            'gnus-topic-update-topics-containing-group)
1157       (set (make-local-variable 'gnus-group-sort-alist-function)
1158            'gnus-group-sort-topic)
1159       (setq gnus-group-change-level-function 'gnus-topic-change-level)
1160       (setq gnus-goto-missing-group-function 'gnus-topic-goto-missing-group)
1161       (gnus-make-local-hook 'gnus-check-bogus-groups-hook)
1162       (add-hook 'gnus-check-bogus-groups-hook 'gnus-topic-clean-alist
1163                 nil 'local)
1164       (setq gnus-topology-checked-p nil)
1165       ;; We check the topology.
1166       (when gnus-newsrc-alist
1167         (gnus-topic-check-topology))
1168       (gnus-run-hooks 'gnus-topic-mode-hook))
1169     ;; Remove topic infestation.
1170     (unless gnus-topic-mode
1171       (remove-hook 'gnus-summary-exit-hook 'gnus-topic-update-topic)
1172       (setq gnus-group-change-level-function nil)
1173       (remove-hook 'gnus-check-bogus-groups-hook 'gnus-topic-clean-alist)
1174       (setq gnus-group-prepare-function 'gnus-group-prepare-flat)
1175       (setq gnus-group-sort-alist-function 'gnus-group-sort-flat))
1176     (when redisplay
1177       (gnus-group-list-groups))))
1178
1179 (defun gnus-topic-select-group (&optional all)
1180   "Select this newsgroup.
1181 No article is selected automatically.
1182 If the group is opened, just switch the summary buffer.
1183 If ALL is non-nil, already read articles become readable.
1184
1185 If ALL is a positive number, fetch this number of the latest
1186 articles in the group.  If ALL is a negative number, fetch this
1187 number of the earliest articles in the group.
1188
1189 If performed over a topic line, toggle folding the topic."
1190   (interactive "P")
1191   (when (and (eobp) (not (gnus-group-group-name)))
1192     (forward-line -1))
1193   (if (gnus-group-topic-p)
1194       (let ((gnus-group-list-mode
1195              (if all (cons (if (numberp all) all 7) t) gnus-group-list-mode)))
1196         (gnus-topic-fold all)
1197         (gnus-dribble-touch))
1198     (gnus-group-select-group all)))
1199
1200 (defun gnus-mouse-pick-topic (e)
1201   "Select the group or topic under the mouse pointer."
1202   (interactive "e")
1203   (mouse-set-point e)
1204   (gnus-topic-read-group nil))
1205
1206 (defun gnus-topic-expire-articles (topic)
1207   "Expire articles in this topic or group."
1208   (interactive (list (gnus-group-topic-name)))
1209   (if (not topic)
1210       (call-interactively 'gnus-group-expire-articles)
1211     (save-excursion
1212       (gnus-message 5 "Expiring groups in %s..." topic)
1213       (let ((gnus-group-marked
1214              (mapcar (lambda (entry) (car (nth 2 entry)))
1215                      (gnus-topic-find-groups topic gnus-level-killed t
1216                                              nil t))))
1217         (gnus-group-expire-articles nil))
1218       (gnus-message 5 "Expiring groups in %s...done" topic))))
1219
1220 (defun gnus-topic-catchup-articles (topic)
1221   "Catchup this topic or group.
1222 Also see `gnus-group-catchup'."
1223   (interactive (list (gnus-group-topic-name)))
1224   (if (not topic)
1225       (call-interactively 'gnus-group-catchup-current)
1226     (save-excursion
1227       (let* ((groups
1228              (mapcar (lambda (entry) (car (nth 2 entry)))
1229                      (gnus-topic-find-groups topic gnus-level-killed t
1230                                              nil t)))
1231              (buffer-read-only nil)
1232              (gnus-group-marked groups))
1233         (gnus-group-catchup-current)
1234         (mapcar 'gnus-topic-update-topics-containing-group groups)))))
1235
1236 (defun gnus-topic-read-group (&optional all no-article group)
1237   "Read news in this newsgroup.
1238 If the prefix argument ALL is non-nil, already read articles become
1239 readable.
1240
1241 If ALL is a positive number, fetch this number of the latest
1242 articles in the group.  If ALL is a negative number, fetch this
1243 number of the earliest articles in the group.
1244
1245 If the optional argument NO-ARTICLE is non-nil, no article will
1246 be auto-selected upon group entry.  If GROUP is non-nil, fetch
1247 that group.
1248
1249 If performed over a topic line, toggle folding the topic."
1250   (interactive "P")
1251   (if (gnus-group-topic-p)
1252       (let ((gnus-group-list-mode
1253              (if all (cons (if (numberp all) all 7) t) gnus-group-list-mode)))
1254         (gnus-topic-fold all))
1255     (gnus-group-read-group all no-article group)))
1256
1257 (defun gnus-topic-create-topic (topic parent &optional previous full-topic)
1258   "Create a new TOPIC under PARENT.
1259 When used interactively, PARENT will be the topic under point."
1260   (interactive
1261    (list
1262     (read-string "New topic: ")
1263     (gnus-current-topic)))
1264   ;; Check whether this topic already exists.
1265   (when (gnus-topic-find-topology topic)
1266     (error "Topic already exists"))
1267   (unless parent
1268     (setq parent (caar gnus-topic-topology)))
1269   (let ((top (cdr (gnus-topic-find-topology parent)))
1270         (full-topic (or full-topic (list (list topic 'visible nil nil)))))
1271     (unless top
1272       (error "No such parent topic: %s" parent))
1273     (if previous
1274         (progn
1275           (while (and (cdr top)
1276                       (not (equal (caaadr top) previous)))
1277             (setq top (cdr top)))
1278           (setcdr top (cons full-topic (cdr top))))
1279       (nconc top (list full-topic)))
1280     (unless (assoc topic gnus-topic-alist)
1281       (push (list topic) gnus-topic-alist)))
1282   (gnus-topic-enter-dribble)
1283   (gnus-group-list-groups)
1284   (gnus-topic-goto-topic topic))
1285
1286 ;; FIXME:
1287 ;;  1. When the marked groups are overlapped with the process
1288 ;;     region, the behavior of move or remove is not right.
1289 ;;  2. Can't process on several marked groups with a same name,
1290 ;;     because gnus-group-marked only keeps one copy.
1291
1292 (defun gnus-topic-move-group (n topic &optional copyp)
1293   "Move the next N groups to TOPIC.
1294 If COPYP, copy the groups instead."
1295   (interactive
1296    (list current-prefix-arg
1297          (gnus-completing-read "Move to topic" gnus-topic-alist nil t
1298                                'gnus-topic-history)))
1299   (let ((use-marked (and (not n) (not (gnus-region-active-p))
1300                          gnus-group-marked t))
1301         (groups (gnus-group-process-prefix n))
1302         (topicl (assoc topic gnus-topic-alist))
1303         (start-topic (gnus-group-topic-name))
1304         (start-group (progn (forward-line 1) (gnus-group-group-name)))
1305         entry)
1306     (if (and (not groups) (not copyp) start-topic)
1307         (gnus-topic-move start-topic topic)
1308       (mapcar
1309        (lambda (g)
1310          (gnus-group-remove-mark g use-marked)
1311          (when (and
1312                 (setq entry (assoc (gnus-current-topic) gnus-topic-alist))
1313                 (not copyp))
1314            (setcdr entry (gnus-delete-first g (cdr entry))))
1315          (nconc topicl (list g)))
1316        groups)
1317       (gnus-topic-enter-dribble)
1318       (if start-group
1319           (gnus-group-goto-group start-group)
1320         (gnus-topic-goto-topic start-topic))
1321       (gnus-group-list-groups))))
1322
1323 (defun gnus-topic-remove-group (&optional n)
1324   "Remove the current group from the topic."
1325   (interactive "P")
1326   (let ((use-marked (and (not n) (not (gnus-region-active-p))
1327                          gnus-group-marked t))
1328         (groups (gnus-group-process-prefix n)))
1329     (mapcar
1330      (lambda (group)
1331        (gnus-group-remove-mark group use-marked)
1332        (let ((topicl (assoc (gnus-current-topic) gnus-topic-alist))
1333              (buffer-read-only nil))
1334          (when (and topicl group)
1335            (gnus-delete-line)
1336            (gnus-delete-first group topicl))
1337          (gnus-topic-update-topic)))
1338      groups)
1339     (gnus-topic-enter-dribble)
1340     (gnus-group-position-point)))
1341
1342 (defun gnus-topic-copy-group (n topic)
1343   "Copy the current group to a topic."
1344   (interactive
1345    (list current-prefix-arg
1346          (completing-read "Copy to topic: " gnus-topic-alist nil t)))
1347   (gnus-topic-move-group n topic t))
1348
1349 (defun gnus-topic-kill-group (&optional n discard)
1350   "Kill the next N groups."
1351   (interactive "P")
1352   (if (gnus-group-topic-p)
1353       (let ((topic (gnus-group-topic-name)))
1354         (push (cons
1355                (gnus-topic-find-topology topic)
1356                (assoc topic gnus-topic-alist))
1357               gnus-topic-killed-topics)
1358         (gnus-topic-remove-topic nil t)
1359         (gnus-topic-find-topology topic nil nil gnus-topic-topology)
1360         (gnus-topic-enter-dribble))
1361     (gnus-group-kill-group n discard)
1362     (if (not (gnus-group-topic-p))
1363         (gnus-topic-update-topic)
1364       ;; Move up one line so that we update the right topic.
1365       (forward-line -1)
1366       (gnus-topic-update-topic)
1367       (forward-line 1))))
1368
1369 (defun gnus-topic-yank-group (&optional arg)
1370   "Yank the last topic."
1371   (interactive "p")
1372   (if gnus-topic-killed-topics
1373       (let* ((previous
1374               (or (gnus-group-topic-name)
1375                   (gnus-topic-next-topic (gnus-current-topic))))
1376              (data (pop gnus-topic-killed-topics))
1377              (alist (cdr data))
1378              (item (cdar data)))
1379         (push alist gnus-topic-alist)
1380         (gnus-topic-create-topic
1381          (caar item) (gnus-topic-parent-topic previous) previous
1382          item)
1383         (gnus-topic-enter-dribble)
1384         (gnus-topic-goto-topic (caar item)))
1385     (let* ((prev (gnus-group-group-name))
1386            (gnus-topic-inhibit-change-level t)
1387            (gnus-group-indentation
1388             (make-string
1389              (* gnus-topic-indent-level
1390                 (or (save-excursion
1391                       (gnus-topic-goto-topic (gnus-current-topic))
1392                       (gnus-group-topic-level))
1393                     0))
1394              ? ))
1395            yanked alist)
1396       ;; We first yank the groups the normal way...
1397       (setq yanked (gnus-group-yank-group arg))
1398       ;; Then we enter the yanked groups into the topics they belong
1399       ;; to.
1400       (setq alist (assoc (save-excursion
1401                            (forward-line -1)
1402                            (gnus-current-topic))
1403                          gnus-topic-alist))
1404       (when (stringp yanked)
1405         (setq yanked (list yanked)))
1406       (if (not prev)
1407           (nconc alist yanked)
1408         (if (not (cdr alist))
1409             (setcdr alist (nconc yanked (cdr alist)))
1410           (while (cdr alist)
1411             (when (equal (cadr alist) prev)
1412               (setcdr alist (nconc yanked (cdr alist)))
1413               (setq alist nil))
1414             (setq alist (cdr alist))))))
1415     (gnus-topic-update-topic)))
1416
1417 (defun gnus-topic-hide-topic (&optional permanent)
1418   "Hide the current topic.
1419 If PERMANENT, make it stay hidden in subsequent sessions as well."
1420   (interactive "P")
1421   (when (gnus-current-topic)
1422     (gnus-topic-goto-topic (gnus-current-topic))
1423     (if permanent
1424         (setcar (cddr
1425                  (cadr
1426                   (gnus-topic-find-topology (gnus-current-topic))))
1427                 'hidden))
1428     (gnus-topic-remove-topic nil nil)))
1429
1430 (defun gnus-topic-show-topic (&optional permanent)
1431   "Show the hidden topic.
1432 If PERMANENT, make it stay shown in subsequent sessions as well."
1433   (interactive "P")
1434   (when (gnus-group-topic-p)
1435     (if (not permanent)
1436         (gnus-topic-remove-topic t nil)
1437       (let ((topic
1438              (gnus-topic-find-topology
1439               (completing-read "Show topic: " gnus-topic-alist nil t))))
1440         (setcar (cddr (cadr topic)) nil)
1441         (setcar (cdr (cadr topic)) 'visible)
1442         (gnus-group-list-groups)))))
1443
1444 (defun gnus-topic-mark-topic (topic &optional unmark non-recursive)
1445   "Mark all groups in the TOPIC with the process mark.
1446 If NON-RECURSIVE (which is the prefix) is t, don't mark its subtopics."
1447   (interactive (list (gnus-group-topic-name)
1448                      nil
1449                      (and current-prefix-arg t)))
1450   (if (not topic)
1451       (call-interactively 'gnus-group-mark-group)
1452     (save-excursion
1453       (let ((groups (gnus-topic-find-groups topic gnus-level-killed t nil
1454                                             (not non-recursive))))
1455         (while groups
1456           (funcall (if unmark 'gnus-group-remove-mark 'gnus-group-set-mark)
1457                    (gnus-info-group (nth 2 (pop groups)))))))))
1458
1459 (defun gnus-topic-unmark-topic (topic &optional dummy non-recursive)
1460   "Remove the process mark from all groups in the TOPIC.
1461 If NON-RECURSIVE (which is the prefix) is t, don't unmark its subtopics."
1462   (interactive (list (gnus-group-topic-name)
1463                      nil
1464                      (and current-prefix-arg t)))
1465   (if (not topic)
1466       (call-interactively 'gnus-group-unmark-group)
1467     (gnus-topic-mark-topic topic t non-recursive)))
1468
1469 (defun gnus-topic-get-new-news-this-topic (&optional n)
1470   "Check for new news in the current topic."
1471   (interactive "P")
1472   (if (not (gnus-group-topic-p))
1473       (gnus-group-get-new-news-this-group n)
1474     (let* ((topic (gnus-group-topic-name))
1475            (data (cadr (gnus-topic-find-topology topic))))
1476       (save-excursion
1477         (gnus-topic-mark-topic topic nil (and n t))
1478         (gnus-group-get-new-news-this-group))
1479       (gnus-topic-remove-topic (eq 'visible (cadr data))))))
1480
1481 (defun gnus-topic-move-matching (regexp topic &optional copyp)
1482   "Move all groups that match REGEXP to some topic."
1483   (interactive
1484    (let (topic)
1485      (nreverse
1486       (list
1487        (setq topic (completing-read "Move to topic: " gnus-topic-alist nil t))
1488        (read-string (format "Move to %s (regexp): " topic))))))
1489   (gnus-group-mark-regexp regexp)
1490   (gnus-topic-move-group nil topic copyp))
1491
1492 (defun gnus-topic-copy-matching (regexp topic &optional copyp)
1493   "Copy all groups that match REGEXP to some topic."
1494   (interactive
1495    (let (topic)
1496      (nreverse
1497       (list
1498        (setq topic (completing-read "Copy to topic: " gnus-topic-alist nil t))
1499        (read-string (format "Copy to %s (regexp): " topic))))))
1500   (gnus-topic-move-matching regexp topic t))
1501
1502 (defun gnus-topic-delete (topic)
1503   "Delete a topic."
1504   (interactive (list (gnus-group-topic-name)))
1505   (unless topic
1506     (error "No topic to be deleted"))
1507   (let ((entry (assoc topic gnus-topic-alist))
1508         (buffer-read-only nil))
1509     (when (cdr entry)
1510       (error "Topic not empty"))
1511     ;; Delete if visible.
1512     (when (gnus-topic-goto-topic topic)
1513       (gnus-delete-line))
1514     ;; Remove from alist.
1515     (setq gnus-topic-alist (delq entry gnus-topic-alist))
1516     ;; Remove from topology.
1517     (gnus-topic-find-topology topic nil nil 'delete)
1518     (gnus-dribble-touch)))
1519
1520 (defun gnus-topic-rename (old-name new-name)
1521   "Rename a topic."
1522   (interactive
1523    (let ((topic (gnus-current-topic)))
1524      (list topic
1525            (read-string (format "Rename %s to: " topic) topic))))
1526   ;; Check whether the new name exists.
1527   (when (gnus-topic-find-topology new-name)
1528     (error "Topic '%s' already exists" new-name))
1529   ;; "nil" is an invalid name, for reasons I'd rather not go
1530   ;; into here.  Trust me.
1531   (when (equal new-name "nil")
1532     (error "Invalid name: %s" nil))
1533   ;; Do the renaming.
1534   (let ((top (gnus-topic-find-topology old-name))
1535         (entry (assoc old-name gnus-topic-alist)))
1536     (when top
1537       (setcar (cadr top) new-name))
1538     (when entry
1539       (setcar entry new-name))
1540     (forward-line -1)
1541     (gnus-dribble-touch)
1542     (gnus-group-list-groups)
1543     (forward-line 1)))
1544
1545 (defun gnus-topic-indent (&optional unindent)
1546   "Indent a topic -- make it a sub-topic of the previous topic.
1547 If UNINDENT, remove an indentation."
1548   (interactive "P")
1549   (if unindent
1550       (gnus-topic-unindent)
1551     (let* ((topic (gnus-current-topic))
1552            (parent (gnus-topic-previous-topic topic))
1553            (buffer-read-only nil))
1554       (unless parent
1555         (error "Nothing to indent %s into" topic))
1556       (when topic
1557         (gnus-topic-goto-topic topic)
1558         (gnus-topic-kill-group)
1559         (push (cdar gnus-topic-killed-topics) gnus-topic-alist)
1560         (gnus-topic-create-topic
1561          topic parent nil (cdar (car gnus-topic-killed-topics)))
1562         (pop gnus-topic-killed-topics)
1563         (or (gnus-topic-goto-topic topic)
1564             (gnus-topic-goto-topic parent))))))
1565
1566 (defun gnus-topic-unindent ()
1567   "Unindent a topic."
1568   (interactive)
1569   (let* ((topic (gnus-current-topic))
1570          (parent (gnus-topic-parent-topic topic))
1571          (grandparent (gnus-topic-parent-topic parent)))
1572     (unless grandparent
1573       (error "Nothing to indent %s into" topic))
1574     (when topic
1575       (gnus-topic-goto-topic topic)
1576       (gnus-topic-kill-group)
1577       (push (cdar gnus-topic-killed-topics) gnus-topic-alist)
1578       (gnus-topic-create-topic
1579        topic grandparent (gnus-topic-next-topic parent)
1580        (cdar (car gnus-topic-killed-topics)))
1581       (pop gnus-topic-killed-topics)
1582       (gnus-topic-goto-topic topic))))
1583
1584 (defun gnus-topic-list-active (&optional force)
1585   "List all groups that Gnus knows about in a topicsified fashion.
1586 If FORCE, always re-read the active file."
1587   (interactive "P")
1588   (when force
1589     (gnus-get-killed-groups))
1590   (gnus-topic-grok-active force)
1591   (let ((gnus-topic-topology gnus-topic-active-topology)
1592         (gnus-topic-alist gnus-topic-active-alist)
1593         gnus-killed-list gnus-zombie-list)
1594     (gnus-group-list-groups gnus-level-killed nil 1)))
1595
1596 (defun gnus-topic-toggle-display-empty-topics ()
1597   "Show/hide topics that have no unread articles."
1598   (interactive)
1599   (setq gnus-topic-display-empty-topics
1600         (not gnus-topic-display-empty-topics))
1601   (gnus-group-list-groups)
1602   (message "%s empty topics"
1603            (if gnus-topic-display-empty-topics
1604                "Showing" "Hiding")))
1605
1606 ;;; Topic sorting functions
1607
1608 (defun gnus-topic-edit-parameters (group)
1609   "Edit the group parameters of GROUP.
1610 If performed on a topic, edit the topic parameters instead."
1611   (interactive (list (gnus-group-group-name)))
1612   (if group
1613       (gnus-group-edit-group-parameters group)
1614     (if (not (gnus-group-topic-p))
1615         (error "Nothing to edit on the current line")
1616       (let ((topic (gnus-group-topic-name)))
1617         (gnus-edit-form
1618          (gnus-topic-parameters topic)
1619          (format "Editing the topic parameters for `%s'."
1620                  (or group topic))
1621          `(lambda (form)
1622             (gnus-topic-set-parameters ,topic form)))))))
1623
1624 (defun gnus-group-sort-topic (func reverse)
1625   "Sort groups in the topics according to FUNC and REVERSE."
1626   (let ((alist gnus-topic-alist))
1627     (while alist
1628       ;; !!!Sometimes nil elements sneak into the alist,
1629       ;; for some reason or other.
1630       (setcar alist (delq nil (car alist)))
1631       (setcar alist (delete "dummy.group" (car alist)))
1632       (gnus-topic-sort-topic (pop alist) func reverse))))
1633
1634 (defun gnus-topic-sort-topic (topic func reverse)
1635   ;; Each topic only lists the name of the group, while
1636   ;; the sort predicates expect group infos as inputs.
1637   ;; So we first transform the group names into infos,
1638   ;; then sort, and then transform back into group names.
1639   (setcdr
1640    topic
1641    (mapcar
1642     (lambda (info) (gnus-info-group info))
1643     (sort
1644      (mapcar
1645       (lambda (group) (gnus-get-info group))
1646       (cdr topic))
1647      func)))
1648   ;; Do the reversal, if necessary.
1649   (when reverse
1650     (setcdr topic (nreverse (cdr topic)))))
1651
1652 (defun gnus-topic-sort-groups (func &optional reverse)
1653   "Sort the current topic according to FUNC.
1654 If REVERSE, reverse the sorting order."
1655   (interactive (list gnus-group-sort-function current-prefix-arg))
1656   (let ((topic (assoc (gnus-current-topic) gnus-topic-alist)))
1657     (gnus-topic-sort-topic
1658      topic (gnus-make-sort-function func) reverse)
1659     (gnus-group-list-groups)))
1660
1661 (defun gnus-topic-sort-groups-by-alphabet (&optional reverse)
1662   "Sort the current topic alphabetically by group name.
1663 If REVERSE, sort in reverse order."
1664   (interactive "P")
1665   (gnus-topic-sort-groups 'gnus-group-sort-by-alphabet reverse))
1666
1667 (defun gnus-topic-sort-groups-by-unread (&optional reverse)
1668   "Sort the current topic by number of unread articles.
1669 If REVERSE, sort in reverse order."
1670   (interactive "P")
1671   (gnus-topic-sort-groups 'gnus-group-sort-by-unread reverse))
1672
1673 (defun gnus-topic-sort-groups-by-level (&optional reverse)
1674   "Sort the current topic by group level.
1675 If REVERSE, sort in reverse order."
1676   (interactive "P")
1677   (gnus-topic-sort-groups 'gnus-group-sort-by-level reverse))
1678
1679 (defun gnus-topic-sort-groups-by-score (&optional reverse)
1680   "Sort the current topic by group score.
1681 If REVERSE, sort in reverse order."
1682   (interactive "P")
1683   (gnus-topic-sort-groups 'gnus-group-sort-by-score reverse))
1684
1685 (defun gnus-topic-sort-groups-by-rank (&optional reverse)
1686   "Sort the current topic by group rank.
1687 If REVERSE, sort in reverse order."
1688   (interactive "P")
1689   (gnus-topic-sort-groups 'gnus-group-sort-by-rank reverse))
1690
1691 (defun gnus-topic-sort-groups-by-method (&optional reverse)
1692   "Sort the current topic alphabetically by backend name.
1693 If REVERSE, sort in reverse order."
1694   (interactive "P")
1695   (gnus-topic-sort-groups 'gnus-group-sort-by-method reverse))
1696
1697 (defun gnus-topic-sort-groups-by-server (&optional reverse)
1698   "Sort the current topic alphabetically by server name.
1699 If REVERSE, sort in reverse order."
1700   (interactive "P")
1701   (gnus-topic-sort-groups 'gnus-group-sort-by-server reverse))
1702
1703 (defun gnus-topic-sort-topics-1 (top reverse)
1704   (if (cdr top)
1705       (let ((subtop
1706              (mapcar (gnus-byte-compile
1707                       `(lambda (top)
1708                          (gnus-topic-sort-topics-1 top ,reverse)))
1709                      (sort (cdr top)
1710                            (lambda (t1 t2)
1711                              (string-lessp (caar t1) (caar t2)))))))
1712         (setcdr top (if reverse (reverse subtop) subtop))))
1713   top)
1714
1715 (defun gnus-topic-sort-topics (&optional topic reverse)
1716   "Sort topics in TOPIC alphabetically by topic name.
1717 If REVERSE, reverse the sorting order."
1718   (interactive
1719    (list (completing-read "Sort topics in : " gnus-topic-alist nil t
1720                           (gnus-current-topic))
1721          current-prefix-arg))
1722   (let ((topic-topology (or (and topic (cdr (gnus-topic-find-topology topic)))
1723                             gnus-topic-topology)))
1724     (gnus-topic-sort-topics-1 topic-topology reverse)
1725     (gnus-topic-enter-dribble)
1726     (gnus-group-list-groups)
1727     (gnus-topic-goto-topic topic)))
1728
1729 (defun gnus-topic-move (current to)
1730   "Move the CURRENT topic to TO."
1731   (interactive
1732    (list
1733     (gnus-group-topic-name)
1734     (completing-read "Move to topic: " gnus-topic-alist nil t)))
1735   (unless (and current to)
1736     (error "Can't find topic"))
1737   (let ((current-top (cdr (gnus-topic-find-topology current)))
1738         (to-top (cdr (gnus-topic-find-topology to))))
1739     (unless current-top
1740       (error "Can't find topic `%s'" current))
1741     (unless to-top
1742       (error "Can't find topic `%s'" to))
1743     (if (gnus-topic-find-topology to current-top 0);; Don't care the level
1744         (error "Can't move `%s' to its sub-level" current))
1745     (gnus-topic-find-topology current nil nil 'delete)
1746     (while (cdr to-top)
1747       (setq to-top (cdr to-top)))
1748     (setcdr to-top (list current-top))
1749     (gnus-topic-enter-dribble)
1750     (gnus-group-list-groups)
1751     (gnus-topic-goto-topic current)))
1752
1753 (defun gnus-subscribe-topics (newsgroup)
1754   (catch 'end
1755     (let (match gnus-group-change-level-function)
1756       (dolist (topic (gnus-topic-list))
1757         (when (and (setq match (cdr (assq 'subscribe
1758                                           (gnus-topic-parameters topic))))
1759                    (string-match match newsgroup))
1760           ;; Just subscribe the group.
1761           (gnus-subscribe-alphabetically newsgroup)
1762           ;; Add the group to the topic.
1763           (nconc (assoc topic gnus-topic-alist) (list newsgroup))
1764           ;; if this topic specifies a default level, use it
1765           (let ((subscribe-level (cdr (assq 'subscribe-level
1766                                             (gnus-topic-parameters topic)))))
1767             (when subscribe-level
1768                 (gnus-group-change-level newsgroup subscribe-level
1769                                          gnus-level-default-subscribed)))
1770           (throw 'end t)))
1771       nil)))
1772
1773 (provide 'gnus-topic)
1774
1775 ;;; arch-tag: bf176856-f30c-40f0-ae77-e41529a1134c
1776 ;;; gnus-topic.el ends here